名前¶

List::Util - 一般的に有用なリストサブルーチン集

概要¶

    use List::Util qw(first max maxstr min minstr reduce shuffle sum);

説明¶

List::Util は、人々が perl コアにあればいいのにと表明するけれども、 キーワードの使用を保証し、独立した拡張にするのが無駄なほどサイズが小さい、と いうほど実際の使用頻度が高くないサブルーチン集です。

デフォルトでは List::Util は何のサブルーチンもエクスポートしません。 定義されているサブルーチンは:

first BLOCK LIST

Similar to grep in that it evaluates BLOCK setting $_ to each element of LIST in turn. first returns the first element where the result from BLOCK is a true value. If BLOCK never returns true or LIST was empty then undef is returned.

LIST のそれぞれの要素を順に $_ 設定して BLOCK を評価するという意味で grep と似ています。 first は、BLOCK の結果が真の値になった最初の値を返します。 BLOCK が真を返さなかったり、LIST が空の場合は、undef が返されます。

    $foo = first { defined($_) } @list    # first defined value in @list
    $foo = first { $_ > $value } @list    # first value in @list which
                                          # is greater than $value

This function could be implemented using reduce like this

この関数は、reduce を使って次のようにして実装できます:

    $foo = reduce { defined($a) ? $a : wanted($b) ? $b : undef } undef, @list

for example wanted() could be defined() which would return the first defined value in @list

例えば、wanted() が defined() なら @list の中で最初の定義された値を返します。

max LIST

Returns the entry in the list with the highest numerical value. If the list is empty then undef is returned.

リストのエントリの中で最大の数値を返します。 リストが空の場合、undef が返されます。

    $foo = max 1..10                # 10
    $foo = max 3,9,12               # 12
    $foo = max @bar, @baz           # whatever

This function could be implemented using reduce like this

この関数は、reduce を使って次のようにして実装できます:

    $foo = reduce { $a > $b ? $a : $b } 1..10

maxstr LIST

Similar to max, but treats all the entries in the list as strings and returns the highest string as defined by the gt operator. If the list is empty then undef is returned.

max と同様ですが、リストの中の全てのエントリを文字列として扱い、 gt 演算子で定義される最大の文字列を返します。 リストが空の場合、undef が返されます。

    $foo = maxstr 'A'..'Z'          # 'Z'
    $foo = maxstr "hello","world"   # "world"
    $foo = maxstr @bar, @baz        # whatever

This function could be implemented using reduce like this

この関数は、reduce を使って次のようにして実装できます:

    $foo = reduce { $a gt $b ? $a : $b } 'A'..'Z'

min LIST

Similar to max but returns the entry in the list with the lowest numerical value. If the list is empty then undef is returned.

max と同様ですが、リストのエントリの中で最小の数値を返します。 リストが空の場合、undef が返されます。

    $foo = min 1..10                # 1
    $foo = min 3,9,12               # 3
    $foo = min @bar, @baz           # whatever

This function could be implemented using reduce like this

この関数は、reduce を使って次のようにして実装できます:

    $foo = reduce { $a < $b ? $a : $b } 1..10

minstr LIST

Similar to min, but treats all the entries in the list as strings and returns the lowest string as defined by the lt operator. If the list is empty then undef is returned.

min と同様ですが、リストの中の全てのエントリを文字列として扱い、 lt 演算子で定義される最小の文字列を返します。 リストが空の場合、undef が返されます。

    $foo = minstr 'A'..'Z'          # 'A'
    $foo = minstr "hello","world"   # "hello"
    $foo = minstr @bar, @baz        # whatever

This function could be implemented using reduce like this

この関数は、reduce を使って次のようにして実装できます:

    $foo = reduce { $a lt $b ? $a : $b } 'A'..'Z'

reduce BLOCK LIST

Reduces LIST by calling BLOCK, in a scalar context, multiple times, setting $a and $b each time. The first call will be with $a and $b set to the first two elements of the list, subsequent calls will be done by setting $a to the result of the previous call and $b to the next element in the list.

BLOCK をスカラコンテキストで複数回、毎回 $a と $b を設定して 呼び出すことで LIST を縮小(reduce)します。 最初の呼び出しでは $a と $b はリストの最初の二つの要素を設定し、 引き続く呼び出しでは $a に前回の呼び出しの結果を、 $b にリストの次の要素を設定して呼び出します。

Returns the result of the last call to BLOCK. If LIST is empty then undef is returned. If LIST only contains one element then that element is returned and BLOCK is not executed.

BLOCK の最後の呼び出しの結果を返します。 LIST が空の場合、undef が返されます。 LIST が 1 要素しか持たない場合、その要素が返され、BLOCK は実行されません。

    $foo = reduce { $a < $b ? $a : $b } 1..10       # min
    $foo = reduce { $a lt $b ? $a : $b } 'aa'..'zz' # minstr
    $foo = reduce { $a + $b } 1 .. 10               # sum
    $foo = reduce { $a . $b } @bar                  # concat

If your algorithm requires that reduce produce an identity value, then make sure that you always pass that identity value as the first argument to prevent undef being returned

reduce が単位元を出力することがあなたのアルゴリズムにとって必要な場合、 undef を返すのを避けるために常に最初の要素として単位元を 渡すようにしてください:

  $foo = reduce { $a + $b } 0, @values;             # sum with 0 identity value

shuffle LIST

Returns the elements of LIST in a random order

LIST の要素をランダムな順序で返します:

    @cards = shuffle 0..51      # 0..51 in a random order

sum LIST

Returns the sum of all the elements in LIST. If LIST is empty then undef is returned.

LIST の全ての要素の合計を返します。 LIST が空の場合、undef が返されます。

    $foo = sum 1..10                # 55
    $foo = sum 3,9,12               # 24
    $foo = sum @bar, @baz           # whatever

This function could be implemented using reduce like this

この関数は、reduce を使って次のようにして実装できます:

    $foo = reduce { $a + $b } 1..10

If your algorithm requires that sum produce an identity of 0, then make sure that you always pass 0 as the first argument to prevent undef being returned

sum が単位元の 0 を出力することがあなたのアルゴリズムにとって 必要な場合、 undef を返すのを避けるために常に最初の要素として 0 を 渡すようにしてください:

  $foo = sum 0, @values;

既知のバグ¶

バージョン 5.005 より前の perl では、場合によっては reduce が 間違った結果を返すことがありました。 これは reduce.t のテスト 7 の失敗として現れます。

提案された拡張¶

以下のものは要望された拡張ですが、私は追加するのに気乗りしません; perl で実装するのがとても簡単だからです:

  # One argument is true

  sub any { $_ && return 1 for @_; 0 }

  # All arguments are true

  sub all { $_ || return 0 for @_; 1 }

  # All arguments are false

  sub none { $_ && return 0 for @_; 1 }

  # One argument is false

  sub notall { $_ || return 1 for @_; 0 }

  # How many elements are true

  sub true { scalar grep { $_ } @_ }

  # How many elements are false

  sub false { scalar grep { !$_ } @_ }

SEE ALSO¶

Scalar::Util, List::MoreUtils

コピーライト¶

Copyright (c) 1997-2007 Graham Barr <gbarr@pobox.com>. All rights reserved. This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.