5.10.0

名前

perlunifaq - Perl Unicode FAQ

perlunifaq - Perl Unicode FAQ

Q and A

This is a list of questions and answers about Unicode in Perl, intended to be read after perlunitut.

これは、perlunitut の後で読むことを想定した、Perl での Unicode に関する 質問と答えの一覧です。

perlunitut は実際には Unicode チュートリアルじゃないんじゃないの?

No, and this isn't really a Unicode FAQ.

はい、違います; そしてこれは実際には Unicode FAQ ではありません。

Perl has an abstracted interface for all supported character encodings, so they is actually a generic Encode tutorial and Encode FAQ. But many people think that Unicode is special and magical, and I didn't want to disappoint them, so I decided to call the document a Unicode tutorial.

Perl は対応している全ての文字エンコーディングへの抽象インターフェースを 持っているので、実際には汎用の Encode チュートリアルと Encode FAQ です。 しかし、多くの人々が、Unicode は特別でマジカルなものだと考えていて、 私は彼らを失望させたくなかったので、そのドキュメントを Unicode チュートリアルと呼ぶことに決めました。

Perl が対応している文字エンコーディングは何?

To find out which character encodings your Perl supports, run:

Perl がどの文字エンコーディングに対応しているかを見つけるには、以下を 実行してください:

    perl -MEncode -le "print for Encode->encodings(':all')"

どのバージョンの perl を使うべき?

Well, if you can, upgrade to the most recent, but certainly 5.8.1 or newer. The tutorial and FAQ are based on the status quo as of 5.8.8.

うーん、もし可能なら、最新にアップグレードしてください; 但し、確実に 5.8.1 以降にはしてください。 チュートリアルと FAQ は 5.8.8 の状態を基にしています。

You should also check your modules, and upgrade them if necessary. For example, HTML::Entities requires version >= 1.32 to function correctly, even though the changelog is silent about this.

モジュールもチェックして、もし必要ならアップグレードするべきです。 例えば HTML::Entities は、changelog は何も触れていませんが、正しく 動作するためにはバージョン >= 1.32 が必要です。

イメージのようなバイナリデータはどうするの?

Well, apart from a bare binmode $fh, you shouldn't treat them specially. (The binmode is needed because otherwise Perl may convert line endings on Win32 systems.)

うーん、生の binmode $fh を別として、特別に扱う必要はないはずです。 (Win32 システムで Perl が行端を変更しないようにするために、binmode が 必要です。)

Be careful, though, to never combine text strings with binary strings. If you need text in a binary stream, encode your text strings first using the appropriate encoding, then join them with binary strings. See also: "What if I don't encode?".

但し、決してテキスト文字列とバイナリ文字列を結合しないように 注意してください。 もしバイナリストリームにテキストが必要なら、まずテキスト文字列を適切な エンコーディングを使ってエンコードして、それをバイナリ文字列と 結合してください。 "What if I don't encode?" も参照してください。

デコードやエンコードはいつ行うべき?

Whenever you're communicating text with anything that is external to your perl process, like a database, a text file, a socket, or another program. Even if the thing you're communicating with is also written in Perl.

データベース、テキストファイル、ソケット、他のプログラムといった、自分の perl プロセスの外側にある何かとテキストを通信するときはいつでも、です。 通信の相手が Perl で書かれている場合も同じです。

デコードしないとどうなるの?

Whenever your encoded, binary string is used together with a text string, Perl will assume that your binary string was encoded with ISO-8859-1, also known as latin-1. If it wasn't latin-1, then your data is unpleasantly converted. For example, if it was UTF-8, the individual bytes of multibyte characters are seen as separate characters, and then again converted to UTF-8. Such double encoding can be compared to double HTML encoding (>), or double URI encoding (%253E).

エンコードされたバイナリ文字列をテキスト文字列と一緒に使ったときはいつでも、 Perl はバイナリ文字列が ISO-8859-1 またの名を latin-1 と仮定します。 もしこれが latin-1 でなかった場合、データは不愉快な形に変換されます。 例えば、もしデータが UTF-8 だった場合、マルチバイト文字のそれぞれのバイトが 文字として扱われ、それから再び UTF-8 に変換されます。 このような二重エンコードは二重 HTML エンコーディング (>) や 二重 URI エンコーディング (%253E) と比較できます。

This silent implicit decoding is known as "upgrading". That may sound positive, but it's best to avoid it.

この、暗黙のうちに行われるデコードは「昇格」("upgrading")と呼ばれます。 これは前向きなことに聞こえるかもしれませんが、避けるのが最良です。

エンコードしないとどうなるの?

Your text string will be sent using the bytes in Perl's internal format. In some cases, Perl will warn you that you're doing something wrong, with a friendly warning:

テキスト文字列は Perl の内部形式のバイト列を使って送信されます。 いくつかの場合では、Perl は何かが間違っていることを、親切なメッセージで 警告します:

    Wide character in print at example.pl line 2.

Because the internal format is often UTF-8, these bugs are hard to spot, because UTF-8 is usually the encoding you wanted! But don't be lazy, and don't use the fact that Perl's internal format is UTF-8 to your advantage. Encode explicitly to avoid weird bugs, and to show to maintenance programmers that you thought this through.

内部形式はしばしば UTF-8 なので、このバグは発見しにくいです; なぜなら あなたがほしいのは普通 UTF-8 だからです! しかし、手を抜かないでください; そして Perl の内部形式が UTF-8 であることを 利用しようとしないでください。 奇妙なバグを防ぐため、そして保守プログラマに対してあなたが何を考えたかを 示すために、明示的にエンコードしてください。

自動的にデコードやエンコードする方法はある?

If all data that comes from a certain handle is encoded in exactly the same way, you can tell the PerlIO system to automatically decode everything, with the encoding layer. If you do this, you can't accidentally forget to decode or encode anymore, on things that use the layered handle.

もし、あるハンドルから来る全てのデータが正確に同じ方法で エンコードされているなら、encoding 層を使って、 PerlIO システムに自動的に 全てをデコードするように伝えることができます。 これを行えば、この層のハンドルを使っている限り、うっかりデコードや エンコードを忘れることはありません。

You can provide this layer when opening the file:

ファイルを open するときにこの層を指定することができます:

    open my $fh, '>:encoding(UTF-8)', $filename;  # auto encoding on write
    open my $fh, '<:encoding(UTF-8)', $filename;  # auto decoding on read

Or if you already have an open filehandle:

あるいは既にオープンしているファイルハンドルがあるなら:

    binmode $fh, ':encoding(UTF-8)';

Some database drivers for DBI can also automatically encode and decode, but that is sometimes limited to the UTF-8 encoding.

DBI のデータベースドライバのいくつかも、エンコードとデコードを自動的に 行いますが、ときどきこれは UTF-8 エンコーディングに制限されています。

どのエンコーディングが使われているかわからないときは?

Do whatever you can to find out, and if you have to: guess. (Don't forget to document your guess with a comment.)

なんとかして見つけるか、もし必要なら、推測してください。 (どう推測したかをコメントとして文書化するのを忘れないでください。)

You could open the document in a web browser, and change the character set or character encoding until you can visually confirm that all characters look the way they should.

ドキュメントを web ブラウザで開いて、全ての文字があるべき形であることを 視覚的に確認できるまで文字集合や文字エンコーディングを変更する方法も あります。

There is no way to reliably detect the encoding automatically, so if people keep sending you data without charset indication, you may have to educate them.

エンコーディングを自動的に検出するための信頼性のある方法はないので、 もし人々があなたに文字集合の指示なしにデータを送り続けるなら、彼らを 教育する必要があるかもしれません。

Perl のソースコードに Unicode は使える?

Yes, you can! If your sources are UTF-8 encoded, you can indicate that with the use utf8 pragma.

はい、できます! ソースコードが UTF-8 でエンコードされているなら、use utf8 プラグマを 使ってそれを示すことができます。

    use utf8;

This doesn't do anything to your input, or to your output. It only influences the way your sources are read. You can use Unicode in string literals, in identifiers (but they still have to be "word characters" according to \w), and even in custom delimiters.

これは入出力に対しては何も行いません。 ソースを読み込む方法のみに影響を与えます。 文字列リテラル、識別子(しかし \w に従った「単語文字」である必要が あります)、そして独自デリミタにすら Unicode が使えます。

Data::Dumper は UTF8 フラグを復元しません; これは壊れてるの?

No, Data::Dumper's Unicode abilities are as they should be. There have been some complaints that it should restore the UTF8 flag when the data is read again with eval. However, you should really not look at the flag, and nothing indicates that Data::Dumper should break this rule.

いいえ、Data::Dumper の Unicode 能力は、あるべき形であります。 eval で再びデータを読み込むとき、UTF8 フラグを復元するべきだという 苦情が来ることがあります。 しかし、実際にはフラグを見るべきではないですし、Data::Dumper がこの規則を 破っていることを示すものは何もありません。

Here's what happens: when Perl reads in a string literal, it sticks to 8 bit encoding as long as it can. (But perhaps originally it was internally encoded as UTF-8, when you dumped it.) When it has to give that up because other characters are added to the text string, it silently upgrades the string to UTF-8.

起きているのは以下のようなことです: Perl が文字列リテラルを読み込むとき、 可能な限り長く 8 ビットエンコーディングにこだわります。 (しかしおそらく、これをダンプしたときには内部では UTF-8 でエンコード されていました。) それ以外の文字をテキスト文字列に追加するためにこれを諦めなければならない とき、Perl は暗黙のうちに文字列を UTF-8 に昇格させます。

If you properly encode your strings for output, none of this is of your concern, and you can just eval dumped data as always.

出力用の文字列を適切にエンコードしていれば、これについてあなたは何も 心配することはなく、いつも通りにダンプしたデータを eval できます。

なぜ正規表現文字クラスは時々 ASCII の範囲にしかマッチしないの?

なぜいくつかの文字は正しく大文字や小文字にならないの?

It seemed like a good idea at the time, to keep the semantics the same for standard strings, when Perl got Unicode support. While it might be repaired in the future, we now have to deal with the fact that Perl treats equal strings differently, depending on the internal state.

Perl が Unicode 対応になった時点では、これは標準文字列と同じ意味論を 維持するのにいい考えだと思われました。 一方、これは将来修正されるかもしれないので、Perl が同じ文字列を内部状態に よって異なる扱いをするという事実に対応する必要が出てきました。

Affected are uc, lc, ucfirst, lcfirst, \U, \L, \u, \l, \d, \s, \w, \D, \S, \W, /.../i, (?i:...), /[[:posix:]]/.

影響を受けるのは uc, lc, ucfirst, lcfirst, \U, \L, \u, \l, \d, \s, \w, \D, \S, \W, /.../i, (?i:...), /[[:posix:]]/ です。

To force Unicode semantics, you can upgrade the internal representation to by doing utf8::upgrade($string). This does not change strings that were already upgraded.

Unicode の意味論を強制するために、utf8::upgrade($string) とすることで 内部表現を昇格できます。 これは既に昇格している文字列は変更しません。

For a more detailed discussion, see Unicode::Semantics on CPAN.

さらなる詳細な議論については、CPAN の Unicode::Semantics を 参照してください。

文字列がテキスト文字列かバイナリ文字列かを決定するには?

You can't. Some use the UTF8 flag for this, but that's misuse, and makes well behaved modules like Data::Dumper look bad. The flag is useless for this purpose, because it's off when an 8 bit encoding (by default ISO-8859-1) is used to store the string.

それはできません。 このために UTF8 フラグを使う人もいますが、これは誤用で、Data::Dumper のように 正しく振る舞うモジュールをおかしくします。 このフラグはこの目的のためには使えません; なぜなら文字列の保管に 8 ビット エンコーディングが使われている場合 (デフォルトでは ISO-8859-1 です)、 オフだからです。

This is something you, the programmer, has to keep track of; sorry. You could consider adopting a kind of "Hungarian notation" to help with this.

把握しておく必要があるプログラマに言えることはこれです; ごめんなさい。 これを助けるために、「ハンガリアン記法」のようなものの採用を 検討することもできます。

エンコーディング FOO から エンコーディング BAR に変換するには?

By first converting the FOO-encoded byte string to a text string, and then the text string to a BAR-encoded byte string:

まず FOO でエンコードされたバイト文字列をテキスト文字列に変化し、 それからテキスト文字列を BAR エンコードされたバイト文字列に変換します:

    my $text_string = decode('FOO', $foo_string);
    my $bar_string  = encode('BAR', $text_string);

or by skipping the text string part, and going directly from one binary encoding to the other:

あるいは、テキスト文字列の部分を飛ばして、あるバイナリエンコーディングから 他のものへ直接変換します:

    use Encode qw(from_to);
    from_to($string, 'FOO', 'BAR');  # changes contents of $string

or by letting automatic decoding and encoding do all the work:

あるいは、自動でデコードとエンコードをさせることで全ての作業を行います:

    open my $foofh, '<:encoding(FOO)', 'example.foo.txt';
    open my $barfh, '>:encoding(BAR)', 'example.bar.txt';
    print { $barfh } $_ while <$foofh>;

What are decode_utf8 and encode_utf8?

(decode_utf8encode_utf8 って何?)

These are alternate syntaxes for decode('utf8', ...) and encode('utf8', ...).

これらは decode('utf8', ...) および encode('utf8', ...) のもう一つの 文法です。

「ワイド文字」って何?

This is a term used both for characters with an ordinal value greater than 127, characters with an ordinal value greater than 255, or any character occupying than one byte, depending on the context.

これは文脈に依存して、 127 より大きい序数を持つ文字、255 より大きい序数を 持つ文字、1 バイトで収まらない文字、のいずれかの意味で使われる用語です。

The Perl warning "Wide character in ..." is caused by a character with an ordinal value greater than 255. With no specified encoding layer, Perl tries to fit things in ISO-8859-1 for backward compatibility reasons. When it can't, it emits this warning (if warnings are enabled), and outputs UTF-8 encoded data instead.

Perl の警告 "Wide character in ..." は 255 より大きい序数を持つ文字によって 引き起こされます。 エンコーディング層が指定されていない場合、Perl は過去互換性の理由によって 文字を ISO-8859-1 に合わせようとします。 これができないと、(警告が有効なら)この警告が出力され、代わりに UTF-8 で エンコードされたデータが出力されます。

To avoid this warning and to avoid having different output encodings in a single stream, always specify an encoding explicitly, for example with a PerlIO layer:

この警告を回避し、一つのストリームに異なった出力エンコーディングが 出力されることを回避するには、常に明示的にエンコーディングを指定してください; 例えば PerlIO 層を使って:

    binmode STDOUT, ":encoding(UTF-8)";

内部構造

「UTF8 フラグ」って何?

Please, unless you're hacking the internals, or debugging weirdness, don't think about the UTF8 flag at all. That means that you very probably shouldn't use is_utf8, _utf8_on or _utf8_off at all.

内部をハックしようとしているか、変なものをデバッグしようとしているのでない 限り、どうか UTF8 フラグのことは一切考えないでください。 これは、まず間違いなく is_utf8, _utf8_on, _utf8_off を 一切使うべきでないことを意味します。

The UTF8 flag, also called SvUTF8, is an internal flag that indicates that the current internal representation is UTF-8. Without the flag, it is assumed to be ISO-8859-1. Perl converts between these automatically.

UTF8 フラグ(SvUTF8 とも呼ばれます)は、現在の内部表現が UTF-8 であることを 示す内部フラグです。 このフラグがない場合、ISO-8859-1 と仮定します。 Perl はこれらを自動的に変換します。

One of Perl's internal formats happens to be UTF-8. Unfortunately, Perl can't keep a secret, so everyone knows about this. That is the source of much confusion. It's better to pretend that the internal format is some unknown encoding, and that you always have to encode and decode explicitly.

Perl の内部表現の一つはたまたま UTF-8 です。 残念ながら、Perl は秘密を守れないので、このことはみんな知っています。 これが多くの混乱の源です。 内部表現は何か分からないエンコーディングで、常に明示的にエンコードと デコードが必要ということにしておいた方がよいです。

What about the use bytes pragma?

(use bytes プラグマって何?)

Don't use it. It makes no sense to deal with bytes in a text string, and it makes no sense to deal with characters in a byte string. Do the proper conversions (by decoding/encoding), and things will work out well: you get character counts for decoded data, and byte counts for encoded data.

これは使わないでください。 テキスト文字列をバイト単位で扱うことに意味はありませんし、 バイト文字列を文字単位で扱うことには意味はありません。 適切な変換(デコードかエンコード)を行えば、物事はうまくいきます: デコードしたデータの文字数を得られますし、エンコードしたデータのバイト数を 得られます。

use bytes is usually a failed attempt to do something useful. Just forget about it.

use bytes は何か有用なことをしようとするためには間違った方法です。 これのことは単に忘れてください。

What about the use encoding pragma?

(use encoding プラグマって何?)

Don't use it. Unfortunately, it assumes that the programmer's environment and that of the user will use the same encoding. It will use the same encoding for the source code and for STDIN and STDOUT. When a program is copied to another machine, the source code does not change, but the STDIO environment might.

これは使わないでください。 残念ながら、これはプログラマの環境とユーザーの環境が同じであると仮定します。 これはソースコードと STDIN や STDOUT で同じエンコーディングを使います。 プログラムが他のマシンにコピーされると、ソースコードは変わりませんが、 STDIO 環境は変わるかもしれません。

If you need non-ASCII characters in your source code, make it a UTF-8 encoded file and use utf8.

もしソースコードに非 ASCII 文字が必要なら、ファイルを UTF-8 で エンコードして、use utf8 を使ってください。

If you need to set the encoding for STDIN, STDOUT, and STDERR, for example based on the user's locale, use open.

もし STDIN, STDOUT, STDERR のエンコーディングを、例えばユーザーのロケールに 合わせてセットする必要があるなら、use open してください。

What is the difference between :encoding and :utf8?

(:encoding:utf8 の違いは?)

Because UTF-8 is one of Perl's internal formats, you can often just skip the encoding or decoding step, and manipulate the UTF8 flag directly.

UTF-8 は Perl の内部形式のひとつなので、しばしばエンコードやデコードの 手順を省略して、UTF8 フラグを直接操作できます。

Instead of :encoding(UTF-8), you can simply use :utf8, which skips the encoding step if the data was already represented as UTF8 internally. This is widely accepted as good behavior when you're writing, but it can be dangerous when reading, because it causes internal inconsistency when you have invalid byte sequences. Using :utf8 for input can sometimes result in security breaches, so please use :encoding(UTF-8) instead.

:encoding(UTF-8) の代わりに単に :utf8 を使うことで、もしデータが 内部で既に UTF8 で表現されていれば、エンコードの手順を省略します。 これは、書き込むときにはよい振る舞いであると広く受け入れられていますが、 読み込むときには危険があります; なぜなら不正なバイト列を受け取ると 内部矛盾を引き起こすからです。 入力に :utf8 を使うとセキュリティ侵害を引き起こす可能性があるので、 どうか代わりに :encoding(UTF-8) を使ってください。

Instead of decode and encode, you could use _utf8_on and _utf8_off, but this is considered bad style. Especially _utf8_on can be dangerous, for the same reason that :utf8 can.

decodeencode の代わりに、_utf8_on_utf8_off を 使えますが、これは悪いスタイルと考えられています。 特に _utf8_on は、:utf8 と同じ理由で危険です。

There are some shortcuts for oneliners; see -C in perlrun.

一行野郎のための省略形があります; perlrun-C を参照してください。

What's the difference between UTF-8 and utf8?

(UTF-8utf8 の違いは?)

UTF-8 is the official standard. utf8 is Perl's way of being liberal in what it accepts. If you have to communicate with things that aren't so liberal, you may want to consider using UTF-8. If you have to communicate with things that are too liberal, you may have to use utf8. The full explanation is in Encode.

UTF-8 は公式な標準です。 utf8 は、何を受け入れるかに関して自由な Perl のやり方です。 もしそれほど自由でないものと対話する必要があるなら、 UTF-8 を使うことを考えたくなるかもしれません。 自由すぎるものと対話する必要があるなら、utf8 を 使わなければならないかもしれません。 完全な説明は Encode にあります。

UTF-8 is internally known as utf-8-strict. The tutorial uses UTF-8 consistently, even where utf8 is actually used internally, because the distinction can be hard to make, and is mostly irrelevant.

UTF-8 は内部では utf-8-strict として知られます。 チュートリアルでは、たとえ内部では実際には utf8 が使われる場合でも 一貫して UTF-8 を使っています; なぜなら区別をつけるのは難しく、ほとんど 無意味だからです。

For example, utf8 can be used for code points that don't exist in Unicode, like 9999999, but if you encode that to UTF-8, you get a substitution character (by default; see "Handling Malformed Data" in Encode for more ways of dealing with this.)

例えば utf8 は、9999999 のような、Unicode に存在しない符号位置も使えますが、 これを UTF-8 でエンコードすると、代替文字を得ることになります(これは デフォルトの場合です; これを扱う他の方法については "Handling Malformed Data" in Encode を参照してください。)

Okay, if you insist: the "internal format" is utf8, not UTF-8. (When it's not some other encoding.)

わかりました、どうしてもと言うのなら:「内部形式」は utf8 であって、 UTF-8 ではありません。 (もしその他のエンコーディングでないのなら。)

迷子になりました; 実際のところ内部形式のエンコーディングは何?

It's good that you lost track, because you shouldn't depend on the internal format being any specific encoding. But since you asked: by default, the internal format is either ISO-8859-1 (latin-1), or utf8, depending on the history of the string. On EBCDIC platforms, this may be different even.

迷子になったのはよいことです; なぜなら内部形式が特定のエンコーディングで あることに依存するべきではないからです。 しかし聞かれたので答えましょう: デフォルトでは、内部形式は ISO-8859-1 (latin-1) か utf8 で、どちらになるかは文字列の歴史に 依存します。 EBCDIC プラットフォームでは、これは異なっているかもしれません。

Perl knows how it stored the string internally, and will use that knowledge when you encode. In other words: don't try to find out what the internal encoding for a certain string is, but instead just encode it into the encoding that you want.

Perl は文字列が内部でどのように保管されているかを知っていて、この知識を エンコードする ときに使います。 言い換えると: 特定の文字列の内部エンコーディングが何かを 調べようとしてはいけません; 代わりに、単に望みのエンコーディングに エンコードしてください。

作者

Juerd Waalboer <[email protected]>

SEE ALSO

perlunicode, perluniintro, Encode