5.14.1

名前

perltrap - Perl traps for the unwary

perltrap - 不注意による Perl の罠

説明

The biggest trap of all is forgetting to use warnings or use the -w switch; see perllexwarn and perlrun. The second biggest trap is not making your entire program runnable under use strict. The third biggest trap is not reading the list of changes in this version of Perl; see perldelta.

最も大きな罠とは、use warnings あるいは -w スイッチを使うのを 忘れてしまうということです; perllexwarnperlrun を 参照してください。 二番目に大きな罠とは、あなたのプログラム全体を use strict の元で 実行しないということです。 三番目の罠は、このバージョンの Perl での変更点を読まないということです; perldelta を参照してください。

awk の罠

Accustomed awk users should take special note of the following:

awk に慣れた方は、以下のようなことに特に注意してください:

  • A Perl program executes only once, not once for each input line. You can do an implicit loop with -n or -p.

    Perl のプログラムは、1 度だけ実行されます; 入力行毎ではありません。 -n-p を使って暗黙のループを使えます。

  • The English module, loaded via

    Englishモジュールを

        use English;

    allows you to refer to special variables (like $/) with names (like $RS), as though they were in awk; see perlvar for details.

    のようにしてロードすれば、awk でそうであったように ($/ のような)特殊変数を($RS のような)名前で参照することができます。 詳しくは perlvar を参照してください。

  • Semicolons are required after all simple statements in Perl (except at the end of a block). Newline is not a statement delimiter.

    Perlでは、すべての単純文(simple statement)の末尾にセミコロンが必要です (ブロックの最後に置かれたときを除きます)。 改行は文の区切りとはなりません。

  • Curly brackets are required on ifs and whiles.

    ifwhile では中かっこが必要です。

  • Variables begin with "$", "@" or "%" in Perl.

    Perlでは、変数は“$”"か“@”か“%”で始まります。

  • Arrays index from 0. Likewise string positions in substr() and index().

    配列の添え字は 0 から始まります。 substr() や index() での文字列の位置も同様です。

  • You have to decide whether your array has numeric or string indices.

    配列の添え字が数値であるか、文字列であるかを決めなければなりません。

  • Hash values do not spring into existence upon mere reference.

    ハッシュ(連想配列)の値は、単に参照するだけでは存在することに なりません。

  • You have to decide whether you want to use string or numeric comparisons.

    比較を文字列によって行うのか、数値によって行うのかを 決めなければなりません。

  • Reading an input line does not split it for you. You get to split it to an array yourself. And the split() operator has different arguments than awk's.

    入力を読み込むだけでは split は行われません。 配列への split は自分で行います。 また、split() 演算子の引数は awk のものと異なっています。

  • The current input line is normally in $_, not $0. It generally does not have the newline stripped. ($0 is the name of the program executed.) See perlvar.

    通常、カレント行は $0 ではなく $_ にあります。 一般的に、改行は取り除かれません。 ($0 には実行しているプログラムの名前があります)。 perlvar を参照してください。

  • $<digit> does not refer to fields--it refers to substrings matched by the last match pattern.

    $<digit> はフィールドを参照しません。 これは直前に行ったパターンマッチングの部分文字列を参照します。

  • The print() statement does not add field and record separators unless you set $, and $\. You can set $OFS and $ORS if you're using the English module.

    print() 文は、$,$\ に値を設定しない限りフィールド区切り子や レコード区切り子を付加しません English モジュールを使っていれば、$OFS や $ORS に対して設定することでも OK です。

  • You must open your files before you print to them.

    ファイルに対して出力する前には、そのファイルをあらかじめオープンして おかなければなりません。

  • The range operator is "..", not comma. The comma operator works as in C.

    範囲演算子は“..”であって、カンマではありません。 カンマ演算子は C と同じような振る舞いをします。

  • The match operator is "=~", not "~". ("~" is the one's complement operator, as in C.)

    マッチ演算子は“=~”であって、“~”ではありません。 (“~”はCと同様に、1の補数を取る演算子です)。

  • The exponentiation operator is "**", not "^". "^" is the XOR operator, as in C. (You know, one could get the feeling that awk is basically incompatible with C.)

    べき乗の演算子は“**”であって、“^”ではありません。 “^”は C と同様、XOR 演算子です。 (awk が基本的に C と非互換であることにお気付きかもしれませんね)。

  • The concatenation operator is ".", not the null string. (Using the null string would render /pat/ /pat/ unparsable, because the third slash would be interpreted as a division operator--the tokenizer is in fact slightly context sensitive for operators like "/", "?", and ">". And in fact, "." itself can be the beginning of a number.)

    連接演算子は“.”であって、空文字列ではありません。 (空文字列を使ってしまうと /pat/ /pat/ が、その 3 番目のスラッシュが 除算演算子と解釈されてしまうので正しく解析できなくなります。 Perl の字句解析器は "/", "?", ">" といった演算子に対して 多少文脈依存となっています。 実際、"." 自身も数値の始まりとなる可能性もあります。)

  • The next, exit, and continue keywords work differently.

    キーワード next, exit, continue の振る舞いが異なります。

  • The following variables work differently:

    以下の変数の働きが異なります。

          Awk       Perl
          ARGC      scalar @ARGV (compare with $#ARGV)
          ARGV[0]   $0
          FILENAME  $ARGV
          FNR       $. - something
          FS        (whatever you like)
          NF        $#Fld, or some such
          NR        $.
          OFMT      $#
          OFS       $,
          ORS       $\
          RLENGTH   length($&)
          RS        $/
          RSTART    length($`)
          SUBSEP    $;
  • You cannot set $RS to a pattern, only a string.

    $RS に正規表現をセットすることはできません; できるのは文字列だけです。

  • When in doubt, run the awk construct through a2p and see what it gives you.

    妙だと思ったときには awk の構文を a2p に通して、出力されたものを 見てみましょう。

C/++ の罠

Cerebral C and C++ programmers should take note of the following:

知的な C と C++ のプログラマは以下のことに注意すべきです:

  • Curly brackets are required on if's and while's.

    ifwhile には中かっこが必要です。

  • You must use elsif rather than else if.

    else if ではなく、elsif を使わなければなりません。

  • The break and continue keywords from C become in Perl last and next, respectively. Unlike in C, these do not work within a do { } while construct. See "Loop Control" in perlsyn.

    C の breakcontinue は、Perl ではそれぞれ lastnext となります。 C とは異なり、これらは do { } while 構文では 使えません"Loop Control" in perlsyn を参照してください。

  • The switch statement is called given/when and only available in perl 5.10 or newer. See "Switch statements" in perlsyn.

    switch 文は given/when と呼ばれ、perl 5.10 以降でのみ利用可能です。 "Switch statements" in perlsyn を参照してください。

  • Variables begin with "$", "@" or "%" in Perl.

    Perlでは、変数は“$”"か“@”か“%”で始まります。

  • Comments begin with "#", not "/*" or "//". Perl may interpret C/C++ comments as division operators, unterminated regular expressions or the defined-or operator.

    コメントの始まりは、“#”であり、“/*”や "//" ではありません。 Perl は C/C++ のコメントを除算演算子、終端していない正規表現、 定義性和演算子として解釈するかもしれません。

  • You can't take the address of anything, although a similar operator in Perl is the backslash, which creates a reference.

    なにかのアドレスを得ることはできません。 Perl には似たような演算子であるバックスラッシュがありますが、これは リファレンスを生成します。

  • ARGV must be capitalized. $ARGV[0] is C's argv[1], and argv[0] ends up in $0.

    ARGV は大文字でなければなりません。 $ARGV[0] が C での argv[1] に相当し、argv[0] にあたるものは $0 です。

  • System calls such as link(), unlink(), rename(), etc. return nonzero for success, not 0. (system(), however, returns zero for success.)

    link(), unlink(), rename() などのシステムコールは、成功時に 0 ではなく非 0 の値を返します。 (但し、system() は成功時に 0 を返します。)

  • Signal handlers deal with signal names, not numbers. Use kill -l to find their names on your system.

    シグナルハンドラは、シグナル番号ではなくシグナル名を扱います。 使用できるシグナル名は、kill -l として確かめてください。

sed の罠

Seasoned sed programmers should take note of the following:

熟練した sed プログラマは以下のことに注意すべきです:

  • A Perl program executes only once, not once for each input line. You can do an implicit loop with -n or -p.

    Perl のプログラムは、1 度だけ実行されます; 入力行毎ではありません。 -n-p を使って暗黙のループを使えます。

  • Backreferences in substitutions use "$" rather than "\".

    置換における後方参照には、“\”ではなく“$”を使います。

  • The pattern matching metacharacters "(", ")", and "|" do not have backslashes in front.

    "(", ")", "|" といったパターンマッチのメタキャラクタは、その直前に バックスラッシュを置く必要はありません。

  • The range operator is ..., rather than comma.

    範囲演算子は ... であって、カンマではありません。

shell の罠

Sharp shell programmers should take note of the following:

鋭いシェルプログラマは以下のことに注意すべきです:

  • The backtick operator does variable interpolation without regard to the presence of single quotes in the command.

    バッククォート演算子は、コマンド内にシングルクォートがあっても 変数の展開を行ないます。

  • The backtick operator does no translation of the return value, unlike csh.

    バッククォート演算子は csh とは違って、返された値を変換しません。

  • Shells (especially csh) do several levels of substitution on each command line. Perl does substitution in only certain constructs such as double quotes, backticks, angle brackets, and search patterns.

    シェル (特に csh) は、コマンドラインごとに何段階もの置換を行ないます。 Perl はダブルクォート、バッククォート、山かっこ、検索パターンといった 特定の構造でだけ置換を行ないます。

  • Shells interpret scripts a little bit at a time. Perl compiles the entire program before executing it (except for BEGIN blocks, which execute at compile time).

    シェルは一度に少しずつ解釈を行ないます。 Perl は実行前にプログラム全体をコンパイルします (コンパイル時に実行される BEGIN ブロックを除く)。

  • The arguments are available via @ARGV, not $1, $2, etc.

    引数は $1, $2 などではなく、@ARGV から得られます。

  • The environment is not automatically made available as separate scalar variables.

    環境変数は、自動的には独立したスカラ変数として利用できるように なりません。

  • The shell's test uses "=", "!=", "<" etc for string comparisons and "-eq", "-ne", "-lt" etc for numeric comparisons. This is the reverse of Perl, which uses eq, ne, lt for string comparisons, and ==, != < etc for numeric comparisons.

    シェルの test は "=", "!=", "<" などを文字列比較に使い、"-eq", "-ne", "-lt" などを数値比較に使います。 これは Perl とは逆です; Perl では eq, ne, lt を文字列比較に使い、 ==, != < などを数値比較に使います。

Perl の罠

Practicing Perl Programmers should take note of the following:

実践的な Perl プログラマは以下のことに注意すべきです:

  • Remember that many operations behave differently in a list context than they do in a scalar one. See perldata for details.

    多くの演算子がリストコンテキストとスカラコンテキストとで 振る舞いが変わることを忘れないでください。 詳しくは perldata を参照してください。

  • Avoid barewords if you can, especially all lowercase ones. You can't tell by just looking at it whether a bareword is a function or a string. By using quotes on strings and parentheses on function calls, you won't ever get them confused.

    裸の単語、特に全てが小文字のものはできる限り使わないでください。 見た目だけではその「裸の単語」が関数なのか、 文字列なのかが判断できません。文字列にはクォートを、 関数呼び出しには括弧をつければ、迷うこともないでしょう。

  • You cannot discern from mere inspection which builtins are unary operators (like chop() and chdir()) and which are list operators (like print() and unlink()). (Unless prototyped, user-defined subroutines can only be list operators, never unary ones.) See perlop and perlsub.

    組込み関数のどれが(chop() や chdir())のような単項演算子で、 どれが(print() や unlink())のような リスト演算子であるかは見ただけではわかりません (プロトタイプがなければ、ユーザー定義サブルーチンは リスト演算子として のみ 定義でき、単項演算子にはできません)。 perlopperlsub を参照してください。

  • People have a hard time remembering that some functions default to $_, or @ARGV, or whatever, but that others which you might expect to do not.

    いくつかの関数が $_ や @ARGV などをデフォルトにしていますが、 同じことを期待する他の関数がデフォルトになっていないことを覚えるのに、 辛いタイピングが必要でしょう。

  • The <FH> construct is not the name of the filehandle, it is a readline operation on that handle. The data read is assigned to $_ only if the file read is the sole condition in a while loop:

    <FH> 構造はファイルハンドルではなく、そのハンドルに対する行読み込みの 操作(readline operation)です。 while ループの条件式の中にこのファイル読み込みだけがあった場合には 読み込まれたデータは $_ に代入されます。

        while (<FH>)      { }
        while (defined($_ = <FH>)) { }..
        <FH>;  # data discarded!
  • Remember not to use = when you need =~; these two constructs are quite different:

    =~ が必要なところで c<=> を使わない、ということを忘れないでください。 これら二つの構造はかなり違います。

        $x =  /foo/;
        $x =~ /foo/;
  • The do {} construct isn't a real loop that you can use loop control on.

    do {} 構造は、ループ制御を行えるような本当のループではありません。

  • Use my() for local variables whenever you can get away with it (but see perlform for where you can't). Using local() actually gives a local value to a global variable, which leaves you open to unforeseen side-effects of dynamic scoping.

    ローカル変数は、my() で済むところではこれで済ませること (使えない場所については、perlform を参照してください)。 local() を使えばグローバル変数に対するローカルな値を与えますが、 動的スコープの不慮の副作用の可能性は、そのままです。

  • If you localize an exported variable in a module, its exported value will not change. The local name becomes an alias to a new value but the external name is still an alias for the original.

    モジュールにある export された変数を局所化すると、その export された 値は変更されません。 ローカル名は新しい値の別名(alias)となりますが、 外部名は元々の値の別名のままです。

Perl4 から Perl5 への罠

Practicing Perl4 Programmers should take note of the following Perl4-to-Perl5 specific traps.

実践的な Perl4 プログラマは 以下に挙げる Perl4 と Perl5 の違いに特有な罠に気をつけた 方が良いでしょう。

They're crudely ordered according to the following list:

以下は順不同のリストです。

Discontinuance, Deprecation, and BugFix traps

Anything that's been fixed as a perl4 bug, removed as a perl4 feature or deprecated as a perl4 feature with the intent to encourage usage of some other perl5 feature.

修正された perl4 のバグや、なくなった perl4 の仕様、 perl5 で仕様の変わったもの。

Parsing Traps

Traps that appear to stem from the new parser.

新しい構文解析器によって引き起こされるもの。

Numerical Traps

Traps having to do with numerical or mathematical operators.

数値や算術演算子に関する罠。

General data type traps

Traps involving perl standard data types.

perlの標準的なデータ型に内包される罠。

Context Traps - scalar, list contexts

Traps related to context within lists, scalar statements/declarations.

リスト内のコンテキストや、スカラ文/宣言に関する罠。

Precedence Traps

Traps related to the precedence of parsing, evaluation, and execution of code.

構文解析、評価、コードの実行の優先順に関係した罠。

General Regular Expression Traps using s///, etc.

Traps related to the use of pattern matching.

パターンマッチングの仕様に関する罠。

Subroutine, Signal, Sorting Traps

Traps related to the use of signals and signal handlers, general subroutines, and sorting, along with sorting subroutines.

シグナル及びシグナルハンドラ、一般的なサブルーチン、ソート、 ソートのためのサブルーチンに関連した罠。

OS Traps

OS-specific traps.

OS特有の罠。

DBM Traps

Traps specific to the use of dbmopen(), and specific dbm implementations.

dbmopen() の使用や、dbm の実装に関連した罠。

Unclassified Traps

Everything else.

その他の罠。

If you find an example of a conversion trap that is not listed here, please submit it to <perlbug@perl.org> for inclusion. Also note that at least some of these can be caught with the use warnings pragma or the -w switch.

もしここで挙げたリストにはないような変換の罠の 例を見つけたら、それを <perlbug@perl.org> まで送ってください。 また、少なくともこれらのいくつかは use warnings プラグマか -w スイッチで捕捉できることに注意してください。

なくなったり非推奨になったりバグ修正されたことによる罠

Anything that has been discontinued, deprecated, or fixed as a bug from perl4.

perl4 から、なくなったり修正されたことがら。

  • Symbols starting with "_" no longer forced into main

    ("_" で始まるシンボルはもはや main パッケージに強制的に結び付けられません)

    Symbols starting with "_" are no longer forced into package main, except for $_ itself (and @_, etc.).

    “_”で始まるシンボルはもはや main パッケージに強制的に結び付けられることは、 $_ 自身(と @- など)を除いてはなくなりました。

        package test;
        $_legacy = 1;
    
        package main;
        print "\$_legacy is ",$_legacy,"\n";
    
        # perl4 prints: $_legacy is 1
        # perl5 prints: $_legacy is
  • Double-colon valid package separator in variable name

    (ダブルコロンは変数名の中で有効なパッケージセパレータです)

    Double-colon is now a valid package separator in a variable name. Thus these behave differently in perl4 vs. perl5, because the packages don't exist.

    ダブルコロンは、変数名の中でパッケージセパレータになるようになりました。 このため、以下の例では perl4 と perl5 とでは振る舞いが変わります。 これはパッケージが実在してないためです。

        $a=1;$b=2;$c=3;$var=4;
        print "$a::$b::$c ";
        print "$var::abc::xyz\n";
    
        # perl4 prints: 1::2::3 4::abc::xyz
        # perl5 prints: 3

    Given that :: is now the preferred package delimiter, it is debatable whether this should be classed as a bug or not. (The older package delimiter, ' ,is used here)

    :: は今では、(これがバグとして分類すべきかどうかはともかく) パッケージデリミタとしてみなされるようになっています (ここでは古いパッケージデリミタの ' を使っています)。

        $x = 10;
        print "x=${'x}\n";
    
        # perl4 prints: x=10
        # perl5 prints: Can't find string terminator "'" anywhere before EOF

    You can avoid this problem, and remain compatible with perl4, if you always explicitly include the package name:

    常にパッケージ名を含めることで、この問題を避けつつ、perl4 との 互換性を維持することができます:

        $x = 10;
        print "x=${main'x}\n";

    Also see precedence traps, for parsing $:.

    $: の解析については、優先順位の罠 も参照してください。

  • 2nd and 3rd args to splice() are now in scalar context

    (splice() の第 2、第 3 引数はスカラコンテキストになりました)

    The second and third arguments of splice() are now evaluated in scalar context (as the Camel says) rather than list context.

    splice() の第 2、第 3 引数は (ラクダ本にある通り)リストコンテキストではなく スカラコンテキストで評価されるようになりました。

        sub sub1{return(0,2) }          # return a 2-element list
        sub sub2{ return(1,2,3)}        # return a 3-element list
        @a1 = ("a","b","c","d","e");
        @a2 = splice(@a1,&sub1,&sub2);
        print join(' ',@a2),"\n";
    
        # perl4 prints: a b
        # perl5 prints: c d e
  • Can't do goto into a block that is optimized away

    (最適化によってなくなってしまうようなブロックの中に飛び込む goto は使えません)

    You can't do a goto into a block that is optimized away. Darn.

    最適化によってなくなってしまうようなブロックの中に 飛び込む goto は使えなくなりました。 ちぇっ。

        goto marker1;
    
        for(1){
        marker1:
            print "Here I is!\n";
        }
    
        # perl4 prints: Here I is!
        # perl5 errors: Can't "goto" into the middle of a foreach loop
  • Can't use whitespace as variable name or quote delimiter

    (空白を変数名やクォートの区切りに使えません)

    It is no longer syntactically legal to use whitespace as the name of a variable, or as a delimiter for any kind of quote construct. Double darn.

    空白を変数の名前や、クォート構造の区切りに使うことは 構文的に正当なものではなくなりました。ちぇっ、ちぇっ。

        $a = ("foo bar");
        $b = q baz ;
        print "a is $a, b is $b\n";
    
        # perl4 prints: a is foo bar, b is baz
        # perl5 errors: Bareword found where operator expected
  • while/if BLOCK BLOCK gone

    (while/if BLOCK BLOCK 対応はなくなりました)

    The archaic while/if BLOCK BLOCK syntax is no longer supported.

    古い while/if BLOCK BLOCK の構文は、もはやサポートされていません。

        if { 1 } {
            print "True!";
        }
        else {
            print "False!";
        }
    
        # perl4 prints: True!
        # perl5 errors: syntax error at test.pl line 1, near "if {"
  • ** binds tighter than unary minus

    (** は単項のマイナスよりも優先順位が高いです)

    The ** operator now binds more tightly than unary minus. It was documented to work this way before, but didn't.

    ** 演算子の優先順位は、単項のマイナスよりも高くなりました。 これは以前からドキュメントにはそうあったのですが、実際は違っていました。

        print -4**2,"\n";
    
        # perl4 prints: 16
        # perl5 prints: -16
  • foreach changed when iterating over a list

    (リストを反復するときの foreach が変わりました)

    The meaning of foreach{} has changed slightly when it is iterating over a list which is not an array. This used to assign the list to a temporary array, but no longer does so (for efficiency). This means that you'll now be iterating over the actual values, not over copies of the values. Modifications to the loop variable can change the original values.

    配列ではないリストに対する繰り返しで あるときの foreach{} の意味が変わりました。 以前はそういったリストはテンポラリな配列に代入されていましたが、 現在はそうではありません(効率上の理由です)。 これは、現在では値のコピーに対して繰り返しをするのではなく 実際の値に対して繰り返しをするということです。

        @list = ('ab','abc','bcd','def');
        foreach $var (grep(/ab/,@list)){
            $var = 1;
        }
        print (join(':',@list));
    
        # perl4 prints: ab:abc:bcd:def
        # perl5 prints: 1:1:bcd:def

    To retain Perl4 semantics you need to assign your list explicitly to a temporary array and then iterate over that. For example, you might need to change

    perl4 と同じようにするには、自分で陽にテンポラリの配列へと コピーしてからその配列に対して繰り返しを行います。 例えば、次のものを変更する必要があるかもしれません:

        foreach $var (grep(/ab/,@list)){

    to

    このように:

        foreach $var (@tmp = grep(/ab/,@list)){

    Otherwise changing $var will clobber the values of @list. (This most often happens when you use $_ for the loop variable, and call subroutines in the loop that don't properly localize $_.)

    そうしないと、$var を変更したときに @list の値に影響が出ます (これはループ変数に $_ を使っていて、かつ、 $_ を局所化していないようなサブルーチンを ループの中で呼ぶようなときに良く起こります)。

  • split with no args behavior changed

    (引数なしの split の振る舞いが変わりました)

    split with no arguments now behaves like split ' ' (which doesn't return an initial null field if $_ starts with whitespace), it used to behave like split /\s+/ (which does).

    引数なしの split の振る舞いは、split /\s+/ ($_ が空白から始まっているときに先頭のフィールドが空になる)

        $_ = ' hi mom';
        print join(':', split);
    
        # perl4 prints: :hi:mom
        # perl5 prints: hi:mom
  • -e behavior fixed

    (-e の振る舞いが修正されました)

    Perl 4 would ignore any text which was attached to an -e switch, always taking the code snippet from the following arg. Additionally, it would silently accept an -e switch without a following arg. Both of these behaviors have been fixed.

    perl4 では、-e スイッチにアタッチされたテキストは無視されて、常に 後に続く引数からプログラムが取り出されていました。さらに、 -e スイッチの後に引数を渡さない場合も受け付けていました。 これらの振る舞いは両方とも修正されました。

        perl -e'print "attached to -e"' 'print "separate arg"'
    
        # perl4 prints: separate arg
        # perl5 prints: attached to -e
    
        perl -e
    
        # perl4 prints:
        # perl5 dies: No code specified for -e.
  • push returns number of elements in resulting list

    (push は結果リストの要素数を返すようになりました)

    In Perl 4 the return value of push was undocumented, but it was actually the last value being pushed onto the target list. In Perl 5 the return value of push is documented, but has changed, it is the number of elements in the resulting list.

    perl4 では push の戻り値はドキュメントに書かれていませんでしたが、 実際には対象となるリストに最後にpushした値が返されていました。 Perl5 では、push の戻り値はドキュメントに明記され、かつそれは perl4 から変更されました。これは push した後のリストにある要素の数を 返します。

        @x = ('existing');
        print push(@x, 'first new', 'second new');
    
        # perl4 prints: second new
        # perl5 prints: 3
  • Some error messages differ

    (一部のエラーメッセージが異なっています)

    Some error messages will be different.

    一部のエラーメッセージが異なっています。

  • split() honors subroutine args

    (split() はサブルーチンの引数を尊重します)

    In Perl 4, if in list context the delimiters to the first argument of split() were ??, the result would be placed in @_ as well as being returned. Perl 5 has more respect for your subroutine arguments.

    Perl 4 では、リストコンテキストで split() の最初の引数の デリミタが ?? だった場合、返される結果が @_ にも設定されました。 Perl 5 ではサブルーチンの引数により多くの敬意を払います。

  • Bugs removed

    (バグが修正されました)

    Some bugs may have been inadvertently removed. :-)

    幾つかのバグがうかつにも修正されているかもしれません :-)

パースの罠

Perl4-to-Perl5 traps from having to do with parsing.

パースに関する Perl4 と Perl5 の違いの罠です。

  • Space between . and = triggers syntax error

    (. と = の間に空白を入れると文法エラーになります)

    Note the space between . and =

    . と = の間にあるスペースに注意。

        $string . = "more string";
        print $string;
    
        # perl4 prints: more string
        # perl5 prints: syntax error at - line 1, near ". ="
  • Better parsing in perl 5

    (perl 5 でのよりよいパース)

    Better parsing in perl 5

    perl5 では構文解析が改良されました。

        sub foo {}
        &foo
        print("hello, world\n");
    
        # perl4 prints: hello, world
        # perl5 prints: syntax error
  • Function parsing

    (関数のパース)

    "if it looks like a function, it is a function" rule.

    “それが関数に見えるのなら、それは関数だ”のルール。

      print
        ($foo == 1) ? "is one\n" : "is zero\n";
    
        # perl4 prints: is zero
        # perl5 warns: "Useless use of a constant in void context" if using -w
  • String interpolation of $#array differs

    ($#array の文字列展開が異なります)

    String interpolation of the $#array construct differs when braces are to used around the name.

    $#array 構造の文字列展開で名前の周りにブレースがあるときには 違いがあります。

        @a = (1..3);
        print "${#a}";
    
        # perl4 prints: 2
        # perl5 fails with syntax error
    
        @a = (1..3);
        print "$#{a}";
    
        # perl4 prints: {a}
        # perl5 prints: 2
  • Perl guesses on map, grep followed by { if it starts BLOCK or hash ref

    (Perl は map, grep の後の { が BLOCK の開始かハッシュリファレンスかを推測します)

    When perl sees map { (or grep {), it has to guess whether the { starts a BLOCK or a hash reference. If it guesses wrong, it will report a syntax error near the } and the missing (or unexpected) comma.

    perl が map { (または grep {) を見つけると、{ が BLOCK の開始か ハッシュリファレンスかを推測します。 推測に失敗すると、} の近くでカンマがない (あるいは予想外の位置に カンマがある) という文法エラーが報告されます。

    Use unary + before { on a hash reference, and unary + applied to the first thing in a BLOCK (after {), for perl to guess right all the time. (See "map" in perlfunc.)

    ハッシュリファレンスの { の前に単項の + を、また BLOCK 内の最初の ものに({ の後に) 単項の + を使ってください; perl がいつでも正しく 推測できるようにするためです ("map" in perlfunc を参照してください)。

数値の罠

Perl4-to-Perl5 traps having to do with numerical operators, operands, or output from same.

同じものに対する数値演算子、オペランド、出力に関する Perl4 と Perl5 の違いの罠です。

  • Formatted output and significant digits

    (書式指定された出力と最下位の数字)

    Formatted output and significant digits. In general, Perl 5 tries to be more precise. For example, on a Solaris Sparc:

    書式指定された出力と、最下位の数字。 一般的に Perl 5 はより的確に試します。 例えば、Solaris Sparc では:

        print 7.373504 - 0, "\n";
        printf "%20.18f\n", 7.373504 - 0;
    
        # Perl4 prints:
        7.3750399999999996141
        7.375039999999999614
    
        # Perl5 prints:
        7.373504
        7.373503999999999614

    Notice how the first result looks better in Perl 5.

    Perl 5 では、最初の結果がより良いものであることに注目してください。

    Your results may vary, since your floating point formatting routines and even floating point format may be slightly different.

    あなたが実行した結果は違うかもしれません; あなたの浮動小数点フォーマット ルーチンや、そもそも浮動小数点フォーマットが少し違うかもしれないからです。

  • Auto-increment operator over signed int limit deleted

    (符号付き整数の限界を超えたオートインクリメント演算子は削除されました)

    This specific item has been deleted. It demonstrated how the auto-increment operator would not catch when a number went over the signed int limit. Fixed in version 5.003_04. But always be wary when using large integers. If in doubt:

    ここに記述されていた項目は削除されました。 以前あったものでは、オートインクリメント演算子が符号付き整数の限界を越えたことを 検知しないということを紹介していました。 これはバージョン 5.003_04 で修正されましたが、大きな整数を取り扱うことに 不安を感じているのであれば

       use Math::BigInt;
  • Assignment of return values from numeric equality tests doesn't work

    (数値の等価性の比較の結果を代入は正しく動作しません)

    Assignment of return values from numeric equality tests does not work in perl5 when the test evaluates to false (0). Logical tests now return a null, instead of 0

    数値の等価性の比較の結果を代入しても、perl ではその比較の結果が 偽 (0) であったときにはうまくいきません。 論理比較は、現在 0 ではなく null を返します。

        $p = ($test == 1);
        print $p,"\n";
    
        # perl4 prints: 0
        # perl5 prints:

    Also see "//, etc."" in "General Regular Expression Traps using s for another example of this new feature...

    この新しい仕様の別の例は "//, etc."" in "General Regular Expression Traps using s を参照してください。

  • Bitwise string ops

    (ビット単位文字列演算子)

    When bitwise operators which can operate upon either numbers or strings (& | ^ ~) are given only strings as arguments, perl4 would treat the operands as bitstrings so long as the program contained a call to the vec() function. perl5 treats the string operands as bitstrings. (See "Bitwise String Operators" in perlop for more details.)

    数値としても文字列としても操作可能なビット操作演算子 (& | ^ ~) が 文字列のみを引数として与えられた場合、 perl4 は、プログラムが vec() 関数の呼び出しを含んでいればオペランドを ビット文字列として扱います。 perl5 は文字列オペランドをビット文字列として扱います (さらなる詳細については "Bitwise String Operators" in perlop を参照してください)。

        $fred = "10";
        $barney = "12";
        $betty = $fred & $barney;
        print "$betty\n";
        # Uncomment the next line to change perl4's behavior
        # ($dummy) = vec("dummy", 0, 0);
    
        # Perl4 prints:
        8
    
        # Perl5 prints:
        10
    
        # If vec() is used anywhere in the program, both print:
        10

一般的なデータ型の罠

Perl4-to-Perl5 traps involving most data-types, and their usage within certain expressions and/or context.

ほとんどのデータ型と、それらの特定の表現やコンテキストでの 使い方に関する Perl4 と Perl5 の違いの罠です。

  • Negative array subscripts now count from the end of array

    (配列の添え字が負であったとき配列の終端から数えられるようになりました)

    Negative array subscripts now count from the end of the array.

    配列の添え字が負であったとき、それは配列の終端から数えられるように なりました。

        @a = (1, 2, 3, 4, 5);
        print "The third element of the array is $a[3] also expressed as $a[-2] \n";
    
        # perl4 prints: The third element of the array is 4 also expressed as
        # perl5 prints: The third element of the array is 4 also expressed as 4
  • Setting $#array lower now discards array elements

    ($#array により小さな値を設定すると配列要素が捨てられるようになりました)

    Setting $#array lower now discards array elements, and makes them impossible to recover.

    $#array に(それまでよりも)小さな値を設定したときには、余計な 配列要素は捨てられ、さらにそれが元に戻せないようになりました。

        @a = (a,b,c,d,e);
        print "Before: ",join('',@a);
        $#a =1;
        print ", After: ",join('',@a);
        $#a =3;
        print ", Recovered: ",join('',@a),"\n";
    
        # perl4 prints: Before: abcde, After: ab, Recovered: abcd
        # perl5 prints: Before: abcde, After: ab, Recovered: ab
  • Hashes get defined before use

    (ハッシュは使われる前に定義されます)

    Hashes get defined before use

    ハッシュは使われる前に定義されます。

        local($s,@a,%h);
        die "scalar \$s defined" if defined($s);
        die "array \@a defined" if defined(@a);
        die "hash \%h defined" if defined(%h);
    
        # perl4 prints:
        # perl5 dies: hash %h defined

    Perl will now generate a warning when it sees defined(@a) and defined(%h).

    Perl は defined(@a) と defined(%h) に警告を出すようになりました。

  • Glob assignment from localized variable to variable

    (ある変数から別の変数へのグロブの代入)

    glob assignment from variable to variable will fail if the assigned variable is localized subsequent to the assignment

    ある変数から別の変数へのグロブの代入は、 代入された変数が代入の後で局所化されているときには 失敗します。

        @a = ("This is Perl 4");
        *b = *a;
        local(@a);
        print @b,"\n";
    
        # perl4 prints: This is Perl 4
        # perl5 prints:
  • Assigning undef to glob

    (undef のグロブへの代入)

    Assigning undef to a glob has no effect in Perl 5. In Perl 4 it undefines the associated scalar (but may have other side effects including SEGVs). Perl 5 will also warn if undef is assigned to a typeglob. (Note that assigning undef to a typeglob is different than calling the undef function on a typeglob (undef *foo), which has quite a few effects.

    undef のグロブへの代入は Perl5 では何の影響も及ぼしません。 Perl4 では結び付けられたスカラを undefine します (しかし SEGV を含め、なんらかの副作用があるかもしれません)。 Perl 5 はまた型グロブに undef を代入すると警告されます。 (型グロブに undef を代入するのは、型グロブに対して undef 関数を呼び出すのとは違います)。いくつかの効果があります。

        $foo = "bar";
        *foo = undef;
        print $foo;
    
        # perl4 prints:
        # perl4 warns: "Use of uninitialized variable" if using -w
        # perl5 prints: bar
        # perl5 warns: "Undefined value assigned to typeglob" if using -w
  • Changes in unary negation (of strings)

    ((文字列に対する)単項の符号反転の意味が変わりました)

    Changes in unary negation (of strings) This change effects both the return value and what it does to auto(magic)increment.

    (文字列に対する)単項の符号反転の意味が変わりました。 この変更は戻り値と、マジックインクリメントの両方に影響します。

        $x = "aaa";
        print ++$x," : ";
        print -$x," : ";
        print ++$x,"\n";
    
        # perl4 prints: aab : -0 : 1
        # perl5 prints: aab : -aab : aac
  • Modifying of constants prohibited

    (定数の修正は禁止されました)

    perl 4 lets you modify constants:

    perl4 では定数を変更してしまいます。

        $foo = "x";
        &mod($foo);
        for ($x = 0; $x < 3; $x++) {
            &mod("a");
        }
        sub mod {
            print "before: $_[0]";
            $_[0] = "m";
            print "  after: $_[0]\n";
        }
    
        # perl4:
        # before: x  after: m
        # before: a  after: m
        # before: m  after: m
        # before: m  after: m
    
        # Perl5:
        # before: x  after: m
        # Modification of a read-only value attempted at foo.pl line 12.
        # before: a
  • defined $var behavior changed

    (defined $var の振る舞いは変わりました)

    The behavior is slightly different for:

    perl4 と perl5 とで全然違う動作:

        print "$x", defined $x
    
        # perl 4: 1
        # perl 5: <no output, $x is not called into existence>
  • Variable Suicide

    (変数の自殺)

    Variable suicide behavior is more consistent under Perl 5. Perl5 exhibits the same behavior for hashes and scalars, that perl4 exhibits for only scalars.

    perl5 では、変数の自殺(variable sucide)の振る舞いはより 首尾一貫したものとなりました。 perl4 ではスカラのみがそうであるような振る舞いを、 perl5 ではハッシュとスカラで示します。

        $aGlobal{ "aKey" } = "global value";
        print "MAIN:", $aGlobal{"aKey"}, "\n";
        $GlobalLevel = 0;
        &test( *aGlobal );
    
        sub test {
            local( *theArgument ) = @_;
            local( %aNewLocal ); # perl 4 != 5.001l,m
            $aNewLocal{"aKey"} = "this should never appear";
            print "SUB: ", $theArgument{"aKey"}, "\n";
            $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
            $GlobalLevel++;
            if( $GlobalLevel<4 ) {
                &test( *aNewLocal );
            }
        }
    
        # Perl4:
        # MAIN:global value
        # SUB: global value
        # SUB: level 0
        # SUB: level 1
        # SUB: level 2
    
        # Perl5:
        # MAIN:global value
        # SUB: global value
        # SUB: this should never appear
        # SUB: this should never appear
        # SUB: this should never appear

コンテキストの罠 - スカラコンテキストとリストコンテキスト

  • Elements of argument lists for formats evaluated in list context

    (フォーマットに対する引数リストの要素はリストコンテキストで評価されるようになりました)

    The elements of argument lists for formats are now evaluated in list context. This means you can interpolate list values now.

    フォーマットに対する引数リストの要素は、リストコンテキストで 評価されるようになりました。 これは、今やリストの値が 展開できるようになったということです。

        @fmt = ("foo","bar","baz");
        format STDOUT=
        @<<<<< @||||| @>>>>>
        @fmt;
        .
        write;
    
        # perl4 errors:  Please use commas to separate fields in file
        # perl5 prints: foo     bar      baz
  • caller() returns false value in scalar context if no caller present

    (caller() 関数は呼び出し元がなくスカラコンテキストで呼ばれた場合には偽を返します)

    The caller() function now returns a false value in a scalar context if there is no caller. This lets library files determine if they're being required.

    caller() 関数は呼び出し元がなく、スカラコンテキストで呼ばれた 場合には偽を返すようになりました。 これによりライブラリファイルが (自分が)require されたのかを判断することができます。

        caller() ? (print "You rang?\n") : (print "Got a 0\n");
    
        # perl4 errors: There is no caller
        # perl5 prints: Got a 0
  • Comma operator in scalar context gives scalar context to args

    (スカラコンテキストにあるカンマ演算子はその引数に対してスカラコンテキストを与えます)

    The comma operator in a scalar context is now guaranteed to give a scalar context to its last argument. It gives scalar or void context to any preceding arguments, depending on circumstances.

    スカラコンテキストにあるカンマ演算子は、その最後の引数に対して スカラコンテキストを与えるようになりました。 環境に依存して、前にある引数にスカラコンテキストか無効コンテキストを 与えます。

        @y= ('a','b','c');
        $x = (1, 2, @y);
        print "x = $x\n";
    
        # Perl4 prints:  x = c   # Interpolates array @y into the list
        # Perl5 prints:  x = 3   # Evaluates array @y in scalar context
  • sprintf() prototyped as ($;@)

    (sprintf() のプロトタイプは ($;@))

    sprintf() is prototyped as ($;@), so its first argument is given scalar context. Thus, if passed an array, it will probably not do what you want, unlike Perl 4:

    sprintf() のプロトタイプは ($;@) なので、最初の引数は スカラコンテキストです。従って、配列を渡すと、 Perl 4 とは違っておそらくあなたの望まない結果になるでしょう。

        @z = ('%s%s', 'foo', 'bar');
        $x = sprintf(@z);
        print $x;
    
        # perl4 prints: foobar
        # perl5 prints: 3

    printf() works the same as it did in Perl 4, though:

    しかし、printf() のほうは Perl 4 と同じように動きます:

        @z = ('%s%s', 'foo', 'bar');
        printf STDOUT (@z);
    
        # perl4 prints: foobar
        # perl5 prints: foobar

評価順序の罠

Perl4-to-Perl5 traps involving precedence order.

評価順序に関する Perl4 と Perl5 の違いの罠です。

Perl 4 has almost the same precedence rules as Perl 5 for the operators that they both have. Perl 4 however, seems to have had some inconsistencies that made the behavior differ from what was documented.

Perl4 はほとんどの演算子で Perl5 と同じ優先順位を持っています。 しかし Perl4 では、ドキュメントとは少々異なるような 一貫性に欠けるものがあります。

  • LHS vs. RHS of any assignment operator

    (代入演算子の LHS 対 RHS)

    LHS vs. RHS of any assignment operator. LHS is evaluated first in perl4, second in perl5; this can affect the relationship between side-effects in sub-expressions.

    左辺と右辺は両方とも演算子を取るようになりました。 LHS は perl4 では最初に、perl5 では 2 番目に評価されます; これは 部分式の副作用の関係に影響を与えることがあります。

        @arr = ( 'left', 'right' );
        $a{shift @arr} = shift @arr;
        print join( ' ', keys %a );
    
        # perl4 prints: left
        # perl5 prints: right
  • Semantic errors introduced due to precedence

    These are now semantic errors because of precedence:

    以下の例は、優先順位の関係で意味エラー(semantic error)となるようになりました。

        @list = (1,2,3,4,5);
        %map = ("a",1,"b",2,"c",3,"d",4);
        $n = shift @list + 2;   # first item in list plus 2
        print "n is $n, ";
        $m = keys %map + 2;     # number of items in hash plus 2
        print "m is $m\n";
    
        # perl4 prints: n is 3, m is 6
        # perl5 errors and fails to compile
  • Precedence of assignment operators same as the precedence of assignment

    (代入演算子の優先順位は代入と同じ)

    The precedence of assignment operators is now the same as the precedence of assignment. Perl 4 mistakenly gave them the precedence of the associated operator. So you now must parenthesize them in expressions like

    代入演算子の優先順位は、代入と同じとなりました。 perl4 は間違って、この優先順位が関連演算子と同じものに なっています。このため、式の中にあるのと同じように括弧でくくらなければ ならなくなりました。

        /foo/ ? ($a += 2) : ($a -= 2);

    Otherwise

    下のようにしてしまうと、

        /foo/ ? $a += 2 : $a -= 2

    would be erroneously parsed as

    これは

        (/foo/ ? $a += 2 : $a) -= 2;

    On the other hand,

    のように間違って解析されてしまいます。 その一方で、

        $a += /foo/ ? 1 : 2;

    now works as a C programmer would expect.

    これは C プログラマーが期待するであろう動作になりました。

  • open requires parentheses around filehandle

    (open はファイルハンドルの周りにかっこが必要です)

        open FOO || die;

    is now incorrect. You need parentheses around the filehandle. Otherwise, perl5 leaves the statement as its default precedence:

    これはもはや正しくなくなりました。ここではファイルハンドルを 括弧で括る必要があります。さもなければ、perl5 はこういった文を そのデフォルトの優先順位のまま放っておきます(以下の例参照)。

        open(FOO || die);
    
        # perl4 opens or dies
        # perl5 opens FOO, dying only if 'FOO' is false, i.e. never
  • $: precedence over $:: gone

    ($:$:: と同じ優先順位)

    perl4 gives the special variable, $: precedence, where perl5 treats $:: as main package

    perl4 は特殊変数 $: の優先順位に、perl5 が $:: を main パッケージと みなすのと同じ優先順位を与えます。

        $a = "x"; print "$::a";
    
        # perl 4 prints: -:a
        # perl 5 prints: x
  • Precedence of file test operators documented

    (ファイルテスト演算子の優先順位が文書化)

    perl4 had buggy precedence for the file test operators vis-a-vis the assignment operators. Thus, although the precedence table for perl4 leads one to believe -e $foo .= "q" should parse as ((-e $foo) .= "q"), it actually parses as (-e ($foo .= "q")). In perl5, the precedence is as documented.

    perl には、ファイルテスト演算子と代入演算子を組み合わせたときに 優先順位のバグがありました。したがって、Perl4 の優先順位テーブルでは -e $foo .= "q"((-e $foo) .= "q") と解釈すべきなのに実際には ((-e $foo) .= "q") と解釈していました。 Perl5 ではドキュメントにある通りの優先順位です。

        -e $foo .= "q"
    
        # perl4 prints: no output
        # perl5 prints: Can't modify -e in concatenation
  • keys, each, values are regular named unary operators

    (keys, each, values は通常の名前付き単項演算子)

    In perl4, keys(), each() and values() were special high-precedence operators that operated on a single hash, but in perl5, they are regular named unary operators. As documented, named unary operators have lower precedence than the arithmetic and concatenation operators + - ., but the perl4 variants of these operators actually bind tighter than + - .. Thus, for:

    perl4 では、key()、each()、values() はシングルハッシュに対する 特別に高い評価順序を持った演算子でした。 しかし perl5 では、これらの演算子は通常の名前付き単項演算子となりました。 ドキュメントにある通り、名前付き単項演算子は、+ - . のような 数学演算子や連結演算子よりも低い優先順位を持っています。 しかし、perl4 ではこれらの演算子よりも key() などのほうが強く演算対象と 結び付いていたのです。 したがって、以下の例のようになります:

        %foo = 1..10;
        print keys %foo - 1
    
        # perl4 prints: 4
        # perl5 prints: Type of arg 1 to keys must be hash (not subtraction)

    The perl4 behavior was probably more useful, if less consistent.

    この perl4 の振る舞いは便利であるかもしれませんが、一貫性に欠けます。

s/// などを使ったときの一般的な正規表現の罠

All types of RE traps.

正規表現に関する全てのタイプの罠。

  • s'$lhs'$rhs' interpolates on either side

    s'$lhs'$rhs' now does no interpolation on either side. It used to interpolate $lhs but not $rhs. (And still does not match a literal '$' in string)

    s'$lhs'$rhs' はもはやいずれの辺にあっても展開されなくなりました。 以前は $lhs は展開し、$rhs を展開しませんでした。 (文字列にあるリテラルの '$' にはいまでもマッチしません)。

        $a=1;$b=2;
        $string = '1 2 $a $b';
        $string =~ s'$a'$b';
        print $string,"\n";
    
        # perl4 prints: $b 2 $a $b
        # perl5 prints: 1 2 $a $b
  • m//g attaches its state to the searched string

    m//g now attaches its state to the searched string rather than the regular expression. (Once the scope of a block is left for the sub, the state of the searched string is lost)

    m//g は、その状態を正規表現ではなく検索対象の文字列に 結び付けるようになりました (sub に対するブロックのスコープが残っているのであれば、 検索文字列の状態は失われます)。

        $_ = "ababab";
        while(m/ab/g){
            &doit("blah");
        }
        sub doit{local($_) = shift; print "Got $_ "}
    
        # perl4 prints: Got blah Got blah Got blah Got blah
        # perl5 prints: infinite loop blah...
  • m//o used within an anonymous sub

    Currently, if you use the m//o qualifier on a regular expression within an anonymous sub, all closures generated from that anonymous sub will use the regular expression as it was compiled when it was used the very first time in any such closure. For instance, if you say

    現在のところ、m//o 量指定子を無名サブルーチンの中にある正規表現で 使った場合、すべての クロージャーはそのような無名サブルーチンから、 そういったクロージャの中で一番最初に使われたものの中で コンパイルされたかのような正規表現を生成します。

        sub build_match {
            my($left,$right) = @_;
            return sub { $_[0] =~ /$left stuff $right/o; };
        }
        $good = build_match('foo','bar');
        $bad = build_match('baz','blarch');
        print $good->('foo stuff bar') ? "ok\n" : "not ok\n";
        print $bad->('baz stuff blarch') ? "ok\n" : "not ok\n";
        print $bad->('foo stuff bar') ? "not ok\n" : "ok\n";

    For most builds of Perl5, this will print: ok not ok not ok

    Perl5 のほとんどのビルドでは、これは以下のように出力します:

    build_match() will always return a sub which matches the contents of $left and $right as they were the first time that build_match() was called, not as they are in the current call.

    この例の場合、build_match() は常に最初に build_match() が呼ばれたときの $left と $right の内容にマッチするようなサブルーチンを返します。 呼び出されたその時点での値ではありません。

  • $+ isn't set to whole match

    If no parentheses are used in a match, Perl4 sets $+ to the whole match, just like $&. Perl5 does not.

    マッチングの中で括弧が使われなかった場合、perl4 では $+ には $& と同じようにマッチした全体がセットされますが、 Perl5 ではそうではありません。

        "abcdef" =~ /b.*e/;
        print "\$+ = $+\n";
    
        # perl4 prints: bcde
        # perl5 prints:
  • Substitution now returns null string if it fails

    substitution now returns the null string if it fails

    置換は、失敗したときには空文字列を返すようになりました。

        $string = "test";
        $value = ($string =~ s/foo//);
        print $value, "\n";
    
        # perl4 prints: 0
        # perl5 prints:

    Also see "Numerical Traps" for another example of this new feature.

    この新しい仕様に関しては "Numerical Traps" も参照してください。

  • s`lhs`rhs` is now a normal substitution

    s`lhs`rhs` (using backticks) is now a normal substitution, with no backtick expansion

    s`lhs`rhs` (バッククォートの使用)は通常の置換となり、 バッククォートの展開は行われなくなりました。

        $string = "";
        $string =~ s`^`hostname`;
        print $string, "\n";
    
        # perl4 prints: <the local hostname>
        # perl5 prints: hostname
  • Stricter parsing of variables in regular expressions

    Stricter parsing of variables used in regular expressions

    正規表現中の変数の使用に関する構文解析がより厳密になりました。

        s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
    
        # perl4: compiles w/o error
        # perl5: with Scalar found where operator expected ..., near "$opt$plus"

    an added component of this example, apparently from the same script, is the actual value of the s'd string after the substitution. [$opt] is a character class in perl4 and an array subscript in perl5

    同じスクリプトでこの例に付け加えことは、置換後の文字列の実際の値です。 [$opt] は perl4 ではキャラクタクラスであり、perl5 では配列の 添え字となります。

        $grpc = 'a';
        $opt  = 'r';
        $_ = 'bar';
        s/^([^$grpc]*$grpc[$opt]?)/foo/;
        print;
    
        # perl4 prints: foo
        # perl5 prints: foobar
  • m?x? matches only once

    Under perl5, m?x? matches only once, like ?x?. Under perl4, it matched repeatedly, like /x/ or m!x!.

    perl5 では、m?x??x? と同様に一回だけマッチします。 perl4 では、/x/m!x! と同じように何度でもマッチします。

        $test = "once";
        sub match { $test =~ m?once?; }
        &match();
        if( &match() ) {
            # m?x? matches more then once
            print "perl4\n";
        } else {
            # m?x? matches only once
            print "perl5\n";
        }
    
        # perl4 prints: perl4
        # perl5 prints: perl5
  • Failed matches don't reset the match variables

    Unlike in Ruby, failed matches in Perl do not reset the match variables ($1, $2, ..., $`, ...).

    Ruby と違って、Perl ではマッチングに失敗してもマッチング変数 ($1, $2, ..., $`, ...) はリセットされません。

サブルーチン、シグナル、ソートの罠

The general group of Perl4-to-Perl5 traps having to do with Signals, Sorting, and their related subroutines, as well as general subroutine traps. Includes some OS-Specific traps.

Perl4 と Perl5 の違いの罠に分類される一般的なものは シグナル、ソート、そしてそれらに関連する サブルーチンで、いくつかの OS 固有の罠を含めた サブルーチンの罠と同じ様なものです。

  • Barewords that used to look like strings look like subroutine calls

    Barewords that used to look like strings to Perl will now look like subroutine calls if a subroutine by that name is defined before the compiler sees them.

    文字列のように見える裸の単語は、その名前が使うよりも前に サブルーチンの名前として定義されている場合にはサブルーチンとして みなされます。

        sub SeeYa { warn"Hasta la vista, baby!" }
        $SIG{'TERM'} = SeeYa;
        print "SIGTERM is now $SIG{'TERM'}\n";
    
        # perl4 prints: SIGTERM is now main'SeeYa
        # perl5 prints: SIGTERM is now main::1 (and warns "Hasta la vista, baby!")

    Use -w to catch this one

    -w を使って、これを発見できます。

  • Reverse is no longer allowed as the name of a sort subroutine

    reverse is no longer allowed as the name of a sort subroutine.

    reverse はもはやソートのサブルーチンの名前としては 使えなくなりました。

        sub reverse{ print "yup "; $a <=> $b }
        print sort reverse (2,1,3);
    
        # perl4 prints: yup yup 123
        # perl5 prints: 123
        # perl5 warns (if using -w): Ambiguous call resolved as CORE::reverse()
  • warn() won't let you specify a filehandle.

    Although it _always_ printed to STDERR, warn() would let you specify a filehandle in perl4. With perl5 it does not.

    常に STDERR に出力していたにもかかわらず、perl4 では warn() はファイルハンドルの 指定を必要としていましたが、perl5 では必要なくなりました。

        warn STDERR "Foo!";
    
        # perl4 prints: Foo!
        # perl5 prints: String found where operator expected

OS の罠

  • SysV resets signal handler correctly

    Under HPUX, and some other SysV OSes, one had to reset any signal handler, within the signal handler function, each time a signal was handled with perl4. With perl5, the reset is now done correctly. Any code relying on the handler _not_ being reset will have to be reworked.

    HPUX 及び一部の SysV OS では、perl4 のときには シグナルが発生する度にそのシグナルハンドラ関数の中で シグナルハンドラを再設定しなければなりませんでした。 perl5 では、この再設定を正しく行うようになりました。 ハンドラを再設定しないということに依存したプログラムは 作業しなおす必要があります。

    Since version 5.002, Perl uses sigaction() under SysV.

    5.002 以降の perl では、SysV のときには sigaction() を使います。

        sub gotit {
            print "Got @_... ";
        }
        $SIG{'INT'} = 'gotit';
    
        $| = 1;
        $pid = fork;
        if ($pid) {
            kill('INT', $pid);
            sleep(1);
            kill('INT', $pid);
        } else {
            while (1) {sleep(10);}
        }
    
        # perl4 (HPUX) prints: Got INT...
        # perl5 (HPUX) prints: Got INT... Got INT...
  • SysV seek() appends correctly

    Under SysV OSes, seek() on a file opened to append >> now does the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened for append, it is impossible to overwrite information already in the file.

    SysV OS では、追記モード (>>) でオープンしたファイルに対する seek() は fopen() マニュアルページにあるように正しく動作するように なりました。 例えば、追記モードでファイルをオープンした場合には既にファイルにある情報を 上書きすることはできません。

        open(TEST,">>seek.test");
        $start = tell TEST;
        foreach(1 .. 9){
            print TEST "$_ ";
        }
        $end = tell TEST;
        seek(TEST,$start,0);
        print TEST "18 characters here";
    
        # perl4 (solaris) seek.test has: 18 characters here
        # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here

展開の罠

Perl4-to-Perl5 traps having to do with how things get interpolated within certain expressions, statements, contexts, or whatever.

Perl4 と Perl5 の違いの罠には、式や文、コンテキストなどにおける 展開に関するものがあります。

  • @ always interpolates an array in double-quotish strings

    @ now always interpolates an array in double-quotish strings.

    ダブルクォートで囲まれた文字列にある @ は常に配列に展開されます。

        print "To: someone@somewhere.com\n";
    
        # perl4 prints: To:someone@somewhere.com
        # perl < 5.6.1, error : In string, @somewhere now must be written as \@somewhere
        # perl >= 5.6.1, warning : Possible unintended interpolation of @somewhere in string
  • Double-quoted strings may no longer end with an unescaped $

    Double-quoted strings may no longer end with an unescaped $.

    ダブルクォートで括られた文字列がエスケープされていない $ で 終了することがなくなりました。

        $foo = "foo$";
        print "foo is $foo\n";
    
        # perl4 prints: foo is foo$
        # perl5 errors: Final $ should be \$ or $name

    Note: perl5 DOES NOT error on the terminating @ in $bar

    注意: perl5 は、$bar の終端にある @ については“エラーにしません”

  • Arbitrary expressions are evaluated inside braces within double quotes

    Perl now sometimes evaluates arbitrary expressions inside braces that occur within double quotes (usually when the opening brace is preceded by $ or @).

    Perl はダブルクォート中にあるブレースの内側の任意の式を 評価するようになりました(一般的には、$@ に続いて 開きのブレースがきたときです)。

        @www = "buz";
        $foo = "foo";
        $bar = "bar";
        sub foo { return "bar" };
        print "|@{w.w.w}|${main'foo}|";
    
        # perl4 prints: |@{w.w.w}|foo|
        # perl5 prints: |buz|bar|

    Note that you can use strict; to ward off such trappiness under perl5.

    use strict; を使って、perl5 におけるこのような罠を避けることが できることに注意してください。

  • $$x now tries to dereference $x

    The construct "this is $$x" used to interpolate the pid at that point, but now tries to dereference $x. $$ by itself still works fine, however.

    "this is $$x" はプロセス ID を展開するようになっていましたが、 今は $x の参照外し(dereference)を試みます。 それでも $$ 自身は今でもきちんと動作します。

        $s = "a reference";
        $x = *s;
        print "this is $$x\n";
    
        # perl4 prints: this is XXXx   (XXX is the current pid)
        # perl5 prints: this is a reference
  • Creation of hashes on the fly with eval "EXPR" requires protection

    Creation of hashes on the fly with eval "EXPR" now requires either both $'s to be protected in the specification of the hash name, or both curlies to be protected. If both curlies are protected, the result will be compatible with perl4 and perl5. This is a very common practice, and should be changed to use the block form of eval{} if possible.

    eval "EXPR" を使ったその場(on the fly)でのハッシュの生成は ハッシュの名前を指定する $ がプロテクトされているか、もしくは 両方の中かっこがプロテクトされていることを要求します。 両方の中かっこがプロテクトされている場合には、perl4 と perl5 の結果は同じです。

        $hashname = "foobar";
        $key = "baz";
        $value = 1234;
        eval "\$$hashname{'$key'} = q|$value|";
        (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
    
        # perl4 prints: Yup
        # perl5 prints: Nope

    Changing

    以下のものを変更します:

        eval "\$$hashname{'$key'} = q|$value|";

    to

    このように:

        eval "\$\$hashname{'$key'} = q|$value|";

    causes the following result:

    結果はこうなります:

        # perl4 prints: Nope
        # perl5 prints: Yup

    or, changing to

    以下のように変更した場合には

        eval "\$$hashname\{'$key'\} = q|$value|";

    causes the following result:

    結果はこうなります:

        # perl4 prints: Yup
        # perl5 prints: Yup
        # and is compatible for both versions
  • Bugs in earlier perl versions

    perl4 programs which unconsciously rely on the bugs in earlier perl versions.

    以前のバージョンにあったバグに依存しているような perl4 プログラム。

        perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
    
        # perl4 prints: This is not perl5
        # perl5 prints: This is perl5
  • Array and hash brackets during interpolation

    You also have to be careful about array and hash brackets during interpolation.

    展開中の配列とハッシュの大かっこについても注意する必要があります。

        print "$foo["
    
        perl 4 prints: [
        perl 5 prints: syntax error
    
        print "$foo{"
    
        perl 4 prints: {
        perl 5 prints: syntax error

    Perl 5 is expecting to find an index or key name following the respective brackets, as well as an ending bracket of the appropriate type. In order to mimic the behavior of Perl 4, you must escape the bracket like so.

    Perl 5 は、個々のかっこには添え字かキー名が続き、さらに適切な種類の 閉じかっこが続くと仮定しています。 Perl 4 の振る舞いを模倣するためには、そのようなかっこを エスケープしなければなりません。

        print "$foo\[";
        print "$foo\{";
  • Interpolation of \$$foo{bar}

    Similarly, watch out for: \$$foo{bar}

    同様に、\$$foo{bar} にも注意してください:

        $foo = "baz";
        print "\$$foo{bar}\n";
    
        # perl4 prints: $baz{bar}
        # perl5 prints: $

    Perl 5 is looking for $foo{bar} which doesn't exist, but perl 4 is happy just to expand $foo to "baz" by itself. Watch out for this especially in eval's.

    perl5 は存在しない $foo{bar} を探しに行きますが、perl4 は $foo を“baz”に展開しただけで満足します。 eval でもこの事に注意してください。

  • qq() string passed to eval will not find string terminator

    qq() string passed to eval

    evalqq() された文字列を渡した場合

        eval qq(
            foreach \$y (keys %\$x\) {
                \$count++;
            }
        );
    
        # perl4 runs this ok
        # perl5 prints: Can't find string terminator ")"

DBM の罠

General DBM traps.

DBMに関する一般的な罠。

  • Perl5 must have been linked with same dbm/ndbm as the default for dbmopen()

    Existing dbm databases created under perl4 (or any other dbm/ndbm tool) may cause the same script, run under perl5, to fail. The build of perl5 must have been linked with the same dbm/ndbm as the default for dbmopen() to function properly without tie'ing to an extension dbm implementation.

    perl4 で(もしくは他の dbm/ndbm ツールで)作成した dbm データベースを、 perl5 の元で同じスクリプトで扱おうとすると失敗します。 perl5 の作成において、拡張 dbm の実装を tie しないときに dbmopen() がデフォルトで使用する関数のために (perl4 のときと同じ)同じ dbm/ndbm をリンクしていなければなりません。

        dbmopen (%dbm, "file", undef);
        print "ok\n";
    
        # perl4 prints: ok
        # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
  • DBM exceeding limit on the key/value size will cause perl5 to exit immediately

    Existing dbm databases created under perl4 (or any other dbm/ndbm tool) may cause the same script, run under perl5, to fail. The error generated when exceeding the limit on the key/value size will cause perl5 to exit immediately.

    perl4 (またはその他の dbm/ndbm ツール)で作成された dbm は、perl5 で このスクリプトの実行に失敗することがあります。 key/value のサイズに関する制限を超えたときに発生するエラーにより、 perl5 では即座にプログラムから exit します。

        dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
        $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
        print "YUP\n";
    
        # perl4 prints:
        dbm store returned -1, errno 28, key "trap" at - line 3.
        YUP
    
        # perl5 prints:
        dbm store returned -1, errno 28, key "trap" at - line 3.

未分類の罠

Everything else.

その他の罠。

  • require/do trap using returned value

    (require/do の戻り値を使ったときの罠)

    If the file doit.pl has:

    doit.pl というファイルが

        sub foo {
            $rc = do "./do.pl";
            return 8;
        }
        print &foo, "\n";

    And the do.pl file has the following single line:

    であって、do.pl が以下のような内容だったとすると、

        return 3;

    Running doit.pl gives the following:

    doit.pl の実行結果はこうなります。

        # perl 4 prints: 3 (aborts the subroutine early)
        # perl 5 prints: 8

    Same behavior if you replace do with require.

    dorequire に置き換えても同じ振る舞いとなります。

  • split on empty string with LIMIT specified

    (空文字列に LIMIT を指定して split を使った場合)

        $string = '';
        @list = split(/foo/, $string, 2)

    Perl4 returns a one element list containing the empty string but Perl5 returns an empty list.

    Perl4 は空文字列を持った一要素のリストを返しますが、Perl5 は 空リストを返します。

As always, if any of these are ever officially declared as bugs, they'll be fixed and removed.

いつものように、バグとして公式に宣言されたものがあれば、 それは修正されて取り除かれるでしょう。