perl-5.20.1
map BLOCK LIST
map EXPR,LIST

Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each element) and returns the list value composed of the results of each such evaluation. In scalar context, returns the total number of elements so generated. Evaluates BLOCK or EXPR in list context, so each element of LIST may produce zero, one, or more elements in the returned value.

LIST の個々の要素に対して、BLOCK か EXPR を評価し ($_ は、ローカルに個々の要素が設定されます) 、 それぞれの評価結果からなるリスト値が返されます。 スカラコンテキストでは、生成された要素の数を返します。 BLOCK や EXPR をリストコンテキストで評価しますので、LIST の 個々の要素によって作られる、返り値であるリストの要素数は、 0 個の場合もあれば、複数の場合もあります。

    @chars = map(chr, @numbers);

translates a list of numbers to the corresponding characters.

は、数のリストを対応する文字に変換します。

    my @squares = map { $_ * $_ } @numbers;

translates a list of numbers to their squared values.

これは数値のリストを、その 2 乗に変換します。

    my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;

shows that number of returned elements can differ from the number of input elements. To omit an element, return an empty list (). This could also be achieved by writing

とすると、入力要素の数と異なる返された要素の数を示します。 要素を省略すると、空リスト () を返します。 これは以下のように書くことでも達成できて

    my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;

which makes the intention more clear.

この方が目的がよりはっきりします。

Map always returns a list, which can be assigned to a hash such that the elements become key/value pairs. See perldata for more details.

map は常にリストを返し、要素がキー/値の組になるようなハッシュに 代入できます。 さらなる詳細については perldata を参照してください。

    %hash = map { get_a_key_for($_) => $_ } @array;

is just a funny way to write

は以下のものをちょっと変わった書き方で書いたものです。

    %hash = ();
    foreach (@array) {
        $hash{get_a_key_for($_)} = $_;
    }

Note that $_ is an alias to the list value, so it can be used to modify the elements of the LIST. While this is useful and supported, it can cause bizarre results if the elements of LIST are not variables. Using a regular foreach loop for this purpose would be clearer in most cases. See also grep for an array composed of those items of the original list for which the BLOCK or EXPR evaluates to true.

$_ は、LIST の値へのエイリアスですので、LIST の要素を 変更するために使うことができます。 これは、便利でサポートされていますが、 LIST の要素が変数でないと、おかしな結果になります。 この目的には通常の foreach ループを使うことで、ほとんどの場合は より明確になります。 BLOCK や EXPR が真になる元のリストの要素からなる配列については、 grep も参照してください。

If $_ is lexical in the scope where the map appears (because it has been declared with the deprecated my $_ construct), then, in addition to being locally aliased to the list elements, $_ keeps being lexical inside the block; that is, it can't be seen from the outside, avoiding any potential side-effects.

(廃止予定の my $_ 構文で宣言されることによって) $_map が現れる スコープ内でレキシカルな場合は、ローカルではリスト要素への エイリアスであることに加えて、$_ はブロック内でレキシカルでありつづけます; つまり、外側からは見えず、起こりうる副作用を回避します。

{ starts both hash references and blocks, so map { ... could be either the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look ahead for the closing } it has to take a guess at which it's dealing with based on what it finds just after the {. Usually it gets it right, but if it doesn't it won't realize something is wrong until it gets to the } and encounters the missing (or unexpected) comma. The syntax error will be reported close to the }, but you'll need to change something near the { such as using a unary + to give Perl some help:

{ はハッシュリファレンスとブロックの両方の開始文字なので、 map { ... は map BLOCK LIST の場合と map EXPR, LIST の場合があります。 Perl は終了文字の } を先読みしないので、{ の直後の文字を見て どちらとして扱うかを推測します。 通常この推測は正しいですが、もし間違った場合は、} まで読み込んで カンマが足りない(または多い)ことがわかるまで、何かがおかしいことに 気付きません。 } の近くで文法エラーが出ますが、Perl を助けるために単項の + を 使うというように、{ の近くの何かを変更する必要があります。

    %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
    %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
    %hash = map { ("\L$_" => 1) } @array # this also works
    %hash = map {  lc($_) => 1  } @array # as does this.
    %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!

    %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)

or to force an anon hash constructor use +{:

または +{ を使って無名ハッシュコンストラクタを強制します:

    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
                                           # comma at end

to get a list of anonymous hashes each with only one entry apiece.

こうするとそれぞれ 1 要素だけの無名ハッシュのリストを得られます。