libwww-perl-6.04

名前

LWP - The World-Wide Web library for Perl

LWP - Perl での WWW アクセスのためのライブラリ

概要

  use LWP;
  print "This is libwww-perl-$LWP::VERSION\n";

説明

The libwww-perl collection is a set of Perl modules which provides a simple and consistent application programming interface (API) to the World-Wide Web. The main focus of the library is to provide classes and functions that allow you to write WWW clients. The library also contain modules that are of more general use and even classes that help you implement simple HTTP servers.

libwww-perl は World-Wide Web への簡単で一貫性のあるプログラミング インターフェース (API) を提供する Perl モジュールの集まりです。 WWW クライアントを書くことが出来るクラスと関数を提供することを 目標にしています。 ライブラリはもっと汎用的に使われるモジュールも入っていますし、簡単な HTTP サーバを実装する助けになるクラスすらあります。

Most modules in this library provide an object oriented API. The user agent, requests sent and responses received from the WWW server are all represented by objects. This makes a simple and powerful interface to these services. The interface is easy to extend and customize for your own needs.

このライブラリのほとんどのモジュールはオブジェクト指向 API を提供しています。 リクエストを送信し、WWW サーバからレスポンスを受信する ユーザーエージェント(user agent)は、すべてオブジェクトによって表されます。 これによりこれらのサービスへの単純で強力なインターフェースを実現します。 このインターフェースはあなた自身の必要のために拡張したり カスタマイズすることが簡単です。

The main features of the library are:

このライブラリの主な機能を以下に示します:

  • Contains various reusable components (modules) that can be used separately or together.

    個別にも一緒にも使うことができる各種の再利用可能なコンポーネント (モジュール) が入っています。

  • Provides an object oriented model of HTTP-style communication. Within this framework we currently support access to http, https, gopher, ftp, news, file, and mailto resources.

    HTTP 式通信のオブジェクト指向モデルを提供します。 このフレームワークで現在、http, https, gopher, ftp, news, file, mailto リソースへのアクセスを提供しています。

  • Provides a full object oriented interface or a very simple procedural interface.

    完全なオブジェクト指向インタフェース、またはとても単純な手続き型 インターフェースを提供します。

  • Supports the basic and digest authorization schemes.

    基本認証およびダイジェスト認証機能をサポートしています。

  • Supports transparent redirect handling.

    透過的なリダイレクトハンドリングをサポートします。

  • Supports access through proxy servers.

    プロキシサーバを通したアクセスをサポートします。

  • Provides parser for robots.txt files and a framework for constructing robots.

    robots.txt のためのパーサーとロボットを構築するための フレームワークを提供します。

  • Supports parsing of HTML forms.

    HTML フォームのパースを助けます。

  • Implements HTTP content negotiation algorithm that can be used both in protocol modules and in server scripts (like CGI scripts).

    プロトコルモジュールと (CGI スクリプトのような) サーバスクリプトの 両方で使うことが出来るHTTPコンテントネゴシエーションアルゴリズムを 実装します。

  • Supports HTTP cookies.

    HTTP クッキーをサポートします。

  • Some simple command line clients, for instance lwp-request and lwp-download.

    lwp-requestlwp-download のような単純なコマンドライン クライアントアプリケーション。

HTTP 式通信

The libwww-perl library is based on HTTP style communication. This section tries to describe what that means.

libwww-perl は HTTP 式通信をベースにしています。 このセクションでは、それがどういう意味かを説明します。

Let us start with this quote from the HTTP specification document <URL:http://www.w3.org/Protocols/>:

まずは HTTP 仕様の文書 <URL:http://www.w3.org/Protocols/> からの引用から始めましょう:

  • The HTTP protocol is based on a request/response paradigm. A client establishes a connection with a server and sends a request to the server in the form of a request method, URI, and protocol version, followed by a MIME-like message containing request modifiers, client information, and possible body content. The server responds with a status line, including the message's protocol version and a success or error code, followed by a MIME-like message containing server information, entity meta-information, and possible body content.

    HTTP プロトコルはリクエスト/レスポンスパラダイムをベースにしています。 クライアントはサーバと接続を確立し、リクエストメソッド、URI そして プロトコルバージョン、その後にリクエスト修飾子、クライアント情報、 もしあればボディ内容が入った MIME ライクなメッセージといった形式で サーバにリクエストを送信します。 サーバはメッセージのプロトコルバージョン、成功あるいはエラーコードが 入ったステータス行、その後ろにサーバ情報、エンティティメタ情報、 もしあればボディ内容が入った MIME 風のメッセージでレスポンスします。

What this means to libwww-perl is that communication always take place through these steps: First a request object is created and configured. This object is then passed to a server and we get a response object in return that we can examine. A request is always independent of any previous requests, i.e. the service is stateless. The same simple model is used for any kind of service we want to access.

これが libwww-perl に意味することは、通信はこれらのステップで 行われるということです: まず request オブジェクトが生成され、 構成設定されます。 そしてこのオブジェクトはサーバに渡され、戻りで検査することが出来る response オブジェクトを取得します。 リクエストは常に前のリクエストとは独立しています。 つまりサービスはステートレスです。 同じ単純なモデルがアクセスしたいすべての種類のサービスに使われます。

For example, if we want to fetch a document from a remote file server, then we send it a request that contains a name for that document and the response will contain the document itself. If we access a search engine, then the content of the request will contain the query parameters and the response will contain the query result. If we want to send a mail message to somebody then we send a request object which contains our message to the mail server and the response object will contain an acknowledgment that tells us that the message has been accepted and will be forwarded to the recipient(s).

例えば、リモートのファイルサーバから文書を取り出したいならば、 その文書の名前が入ったリクエストを送信すると、レスポンスに その文書そのものが入っているでしょう。 もし検索エンジンにアクセスすれば、リクエストの内容には問い合わせ パラメータが入り、レスポンスには問い合わせ結果が入るでしょう。 ある人にメールメッセージを送信したければ、メッセージが入った リクエストオブジェクトをメールサーバに送信すると、レスポンス オブジェクトにはそのメッセージが受信され受取人に転送されたことを 教えてくれる受取通知が入るでしょう。

It is as simple as that!

それくらい単純なのです!

Request(リクエスト)オブジェクト

The libwww-perl request object has the class name HTTP::Request. The fact that the class name uses HTTP:: as a prefix only implies that we use the HTTP model of communication. It does not limit the kind of services we can try to pass this request to. For instance, we will send HTTP::Requests both to ftp and gopher servers, as well as to the local file system.

libwww-perl リクエスト (request) オブジェクトは HTTP::Request という クラスを持ちます。 クラス名の前に HTTP:: がついているということは、通信の HTTP モデルを 使っているということを暗示しているだけです。 それは、このリクエストを渡そうそするサービスの種類を制限しません。 例えば ftp や gopher サービスにも、そしてローカルなファイルシステムにも HTTP::Request を送信します。

The main attributes of the request objects are:

Request オブジェクトの主な属性は以下の通りです:

  • method is a short string that tells what kind of request this is. The most common methods are GET, PUT, POST and HEAD.

    method は、これが何の種類のリクエストかを伝える短い文字列です。 もっとも一般的なメソッドは GET, PUT, POST, HEAD です。

  • uri is a string denoting the protocol, server and the name of the "document" we want to access. The uri might also encode various other parameters.

    uri はアクセスしたいプロトコル、サーバそして「文書」の名前を 示す文字列です。 uri には他のさまざまなパラメータも組み込まれることもあります。

  • headers contains additional information about the request and can also used to describe the content. The headers are a set of keyword/value pairs.

    headers にはリクエストについての追加の情報が入ります。 そして内容の説明するためにも使われます。 ヘッダはキーワード/値の組み合わせのセットです。

  • content is an arbitrary amount of data.

    content は任意のデータの固まりです。

Response(レスポンス)オブジェクト

The libwww-perl response object has the class name HTTP::Response. The main attributes of objects of this class are:

ibwww-perl レスポンス(response)オブジェクトは HTTP::Response という クラス名を持ちます。 このクラスのオブジェクト主な属性は以下の通りです:

  • code is a numerical value that indicates the overall outcome of the request.

    code はリクエストの全体の結果を示す数値です。

  • message is a short, human readable string that corresponds to the code.

    message は、code に対応する人間が読める短い文字列です。

  • headers contains additional information about the response and describe the content.

    headers にはレスポンスについての追加の情報が入り、 内容 (content) について説明します。

  • content is an arbitrary amount of data.

    content は任意のデータの固まりです。

Since we don't want to handle all possible code values directly in our programs, a libwww-perl response object has methods that can be used to query what kind of response this is. The most commonly used response classification methods are:

すべてのありうる code 値を直接我々のプログラムで扱いたくないので、 libwww-perl のレスポンスオブジェクトは、これがどんな種類のレスポンスかを 問い合わせるために使うことが出来るメソッドを持っています。 最もよく使われるレスポンス分類メソッドは以下の通りです:

is_success()

The request was successfully received, understood or accepted.

リクエストは正常に受信され、理解されあるいは受け取られました。

is_error()

The request failed. The server or the resource might not be available, access to the resource might be denied or other things might have failed for some reason.

リクエストは失敗しました。 サーバまたはリソースが利用可能でないか、リソースへのアクセスが拒否されたか、 他のことが何らかの理由により失敗しました。

ユーザエージェント(User Agent)

Let us assume that we have created a request object. What do we actually do with it in order to receive a response?

リクエスト (request)オブジェクトを作成したとします。 レスポンス(response)を受信するため実際には何をするでしょうか?

The answer is that you pass it to a user agent object and this object takes care of all the things that need to be done (like low-level communication and error handling) and returns a response object. The user agent represents your application on the network and provides you with an interface that can accept requests and return responses.

答えは、それを ユーザーエージェント (user agent) オブジェクトに渡します。 このオブジェクトは (下位レベルの通信やエラーの取り扱いなど) しなけれならないすべてのことに注意し、 レスポンス (response) オブジェクトを返します。 ユーザーエージェントはネットワークでのアプリケーションを表し、 リクエスト (request) を受け付け、レスポンス (response) を 返すことができるインタフェースを提供します。

The user agent is an interface layer between your application code and the network. Through this interface you are able to access the various servers on the network.

ユーザーエージェントはあなたのアプリケーションコードとネットワークの間の インターフェース層です。 このインタフェースを通して、ネットワーク上のさまざまなサービスに アクセスすることができます。

The class name for the user agent is LWP::UserAgent. Every libwww-perl application that wants to communicate should create at least one object of this class. The main method provided by this object is request(). This method takes an HTTP::Request object as argument and (eventually) returns a HTTP::Response object.

ユーザーエージェントのクラス名は LWP::UserAgent です。 通信したいすべての libwww-perl アプリケーションは、このクラスの オブジェクトを少なくとも一つ作成しなければなりません。 このオブジェクトにより提供される主なメソッドは request() です。 このメソッドは HTTP::Request オブジェクトを引数として取り、 (最終的に) HTTP::Response オブジェクトを返します。

The user agent has many other attributes that let you configure how it will interact with the network and with your application.

ユーザーエージェントは他に、ネットワークやアプリケーションと どのように相互に影響しあうかを構成設定させる多くの属性を持っています。

  • timeout specifies how much time we give remote servers to respond before the library disconnects and creates an internal timeout response.

    timeout はライブラリが切断し、内部の timeout レスポンスを作成する前に、 リモートサーバに返答するための時間をどれくらい与えるかを指定します。

  • agent specifies the name that your application uses when it presents itself on the network.

    agent はネットワーク上でそれ自身を表すときにアプリケーションが 使う名前を指定します。

  • from can be set to the e-mail address of the person responsible for running the application. If this is set, then the address will be sent to the servers with every request.

    from はそのアプリケーションを実行することに責任を持つ人の e-mail アドレスに設定されることができます。 もしこれが設定されると、そのアドレスは要求のたびにサーバに送信されます。

  • parse_head specifies whether we should initialize response headers from the <head> section of HTML documents.

    parse_head は HTML 文書の <head> セクションから レスポンスヘッダを初期化するべきかどうかを指定します。

  • proxy and no_proxy specify if and when to go through a proxy server. <URL:http://www.w3.org/History/1994/WWW/Proxies/>

    proxyno_proxy はプロキシサーバを通っていくか、そしていつかを 指定します。 <URL:http://www.w3.org/History/1994/WWW/Proxies/>

  • credentials provides a way to set up user names and passwords needed to access certain services.

    credentials はあるサービスにアクセスするために必要とされるユーザ名と パスワードを設定する方法を提供します。

Many applications want even more control over how they interact with the network and they get this by sub-classing LWP::UserAgent. The library includes a sub-class, LWP::RobotUA, for robot applications.

多くのアプリケーションは、ネットワークとどのようにやりとりするかを、 さらに制御することを望みます。 そしてこれは LWP::UserAgent をサブクラス化することによって実現します。 ライブラリにはサブクラスとして、ロボットアプリケーションのために LWP::RobotUA が入っています。

An Example

This example shows how the user agent, a request and a response are represented in actual perl code:

この例は、ユーザーエージェント(user agent)、リクエスト(request)、 そしてレスポンス(response)が、実際の perl コードではどのように 表されるかを示します:

  # Create a user agent object
  use LWP::UserAgent;
  my $ua = LWP::UserAgent->new;
  $ua->agent("MyApp/0.1 ");

  # Create a request
  my $req = HTTP::Request->new(POST => 'http://search.cpan.org/search');
  $req->content_type('application/x-www-form-urlencoded');
  $req->content('query=libwww-perl&mode=dist');

  # Pass request to the user agent and get a response back
  my $res = $ua->request($req);

  # Check the outcome of the response
  if ($res->is_success) {
      print $res->content;
  }
  else {
      print $res->status_line, "\n";
  }

The $ua is created once when the application starts up. New request objects should normally created for each request sent.

アプリケーションが起動されたとき、$ua が一度作られます。 新しいリクエストオブジェクトは通常リクエストを送信するたびに作成されます。

ネットワークサポート

This section discusses the various protocol schemes and the HTTP style methods that headers may be used for each.

このセクションでは各種のプロトコル機構とそれぞれにヘッダが 使われるかもしれない HTTP 式メソッドについて説明します。

For all requests, a "User-Agent" header is added and initialized from the $ua->agent attribute before the request is handed to the network layer. In the same way, a "From" header is initialized from the $ua->from attribute.

すべてのリクエストに、リクエストがネットワーク層に渡される前に、 "User-Agent" ヘッダが追加され、$ua->agent 属性から初期化されます。 同じ方法で、"From" ヘッダは $ua->from 属性から初期化されます。

For all responses, the library adds a header called "Client-Date". This header holds the time when the response was received by your application. The format and semantics of the header are the same as the server created "Date" header. You may also encounter other "Client-XXX" headers. They are all generated by the library internally and are not received from the servers.

すべてのレスポンスに、ライブラリは "Client-Date" と呼ばれるヘッダを 追加します。 このヘッダはレスポンスがアプリケーションにより受信された時刻を保持します。 ヘッダの形式と意味はサーバにより作成される "Date" ヘッダと同じです。 他にも "Client-XXX" というヘッダに出会うかもしれません。 それらはライブラリにより内部で生成され、サーバから受信されていません。

HTTPリクエスト

HTTP requests are just handed off to an HTTP server and it decides what happens. Few servers implement methods beside the usual "GET", "HEAD", "POST" and "PUT", but CGI-scripts may implement any method they like.

HTTP リクエストは単純に HTTP サーバに渡され、それが何をするかを判断します。 ほとんどのサーバは通常の"GET", "HEAD", "POST", "PUT" の他にメソッドを 実装しませんが、CGI スクリプトが好きなメソッドを実装するかもしれません。

If the server is not available then the library will generate an internal error response.

サーバが利用できなければ、ライブラリは内部でエラーレスポンスを生成します。

The library automatically adds a "Host" and a "Content-Length" header to the HTTP request before it is sent over the network.

このライブラリは自動的にネットワークを越えて送信する前に、HTTP リクエストに "Host" と "Content-Length" ヘッダを追加します。

For a GET request you might want to add a "If-Modified-Since" or "If-None-Match" header to make the request conditional.

GET リクエストでは、条件をつけたリクエストを行うために "If-Modified-Since" や "If-None-Match" ヘッダを追加した方がよいでしょう。

For a POST request you should add the "Content-Type" header. When you try to emulate HTML <FORM> handling you should usually let the value of the "Content-Type" header be "application/x-www-form-urlencoded". See lwpcook for examples of this.

POST リクエストでは、"Content-Type" ヘッダを追加しなければなりません。 HTML <FORM> の扱いをエミュレートしようとするとき、 "Content-Type" ヘッダの値は "application/x-www-form-urlencoded" に しなければなりません。 この例については lwpcook をご覧下さい。

The libwww-perl HTTP implementation currently support the HTTP/1.1 and HTTP/1.0 protocol.

libwww-perl HTTP 実装は現在 HTTP/1.1 と HTTP/1.0 プロトコルを サポートしています。

The library allows you to access proxy server through HTTP. This means that you can set up the library to forward all types of request through the HTTP protocol module. See LWP::UserAgent for documentation of this.

このライブラリは HTTP を通してプロキシサーバにアクセスすることも 可能にしています。 つまり HTTP プロトコルモジュールを通してすべてのタイプのリクエストを フォワードするために設定できるということです。 これの文書については LWP::UserAgent をご覧下さい。

HTTPS リクエスト

HTTPS requests are HTTP requests over an encrypted network connection using the SSL protocol developed by Netscape. Everything about HTTP requests above also apply to HTTPS requests. In addition the library will add the headers "Client-SSL-Cipher", "Client-SSL-Cert-Subject" and "Client-SSL-Cert-Issuer" to the response. These headers denote the encryption method used and the name of the server owner.

HTTPS リクエストは、ネットスケープにより開発された SSL プロトコルを 使った暗号化されたネットワーク接続による HTTP リクエストです。 HTTP リクエストについての上記のすべてが HTTPS リクエストにも当てはまります。 さらにライブラリはレスポンスにヘッダ "Client-SSL-Cipher", "Client-SSL-Cert-Subject", "Client-SSL-Cert-Issuer" を追加します。 これらのヘッダは使われた暗号化方法とサーバ所有者の名前を表します。

The request can contain the header "If-SSL-Cert-Subject" in order to make the request conditional on the content of the server certificate. If the certificate subject does not match, no request is sent to the server and an internally generated error response is returned. The value of the "If-SSL-Cert-Subject" header is interpreted as a Perl regular expression.

リクエストにはサーバ認証の内容による条件付のリクエストを行うために ヘッダ "If-SSL-Cert-Subject" を入れることが出来ます。 認証サブジェクト(cerificate subject) が合わなければ、サーバには リクエストが送られず、内部的に作成されたエラーレスポンスが返されます。 "If-SSL-Cert-Subject" ヘッダの値は Perl の正規表現として解釈されます。

FTP リクエスト

The library currently supports GET, HEAD and PUT requests. GET retrieves a file or a directory listing from an FTP server. PUT stores a file on a ftp server.

このライブラリは現在 GET, HEAD, PUT リクエストをサポートします。 GET は FTP サーバからファイルやディレクトリ一覧を取り出します。 PUT はファイルを ftp サーバに格納します。

You can specify a ftp account for servers that want this in addition to user name and password. This is specified by including an "Account" header in the request.

加えてユーザ名、パスワードを要求するサーバのために ftp アカウントを 指定することが出来ます。 これはリクエストに "Account" ヘッダが入ることによって指定されます。

User name/password can be specified using basic authorization or be encoded in the URL. Failed logins return an UNAUTHORIZED response with "WWW-Authenticate: Basic" and can be treated like basic authorization for HTTP.

ユーザ名/パスワードは基本認証を使って指定したり、URL で エンコードされたりします。 ログインが失敗すると "WWW-Authenticate: Basic" で UNAUTHORIZED レスポンスを 返し、HTTP のための基本認証のように扱うことが出来ます。

The library supports ftp ASCII transfer mode by specifying the "type=a" parameter in the URL. It also supports transfer of ranges for FTP transfers using the "Range" header.

ライブラリは URL で "type=a" パラメータを指定することにより、ftp ASCII 転送モードをサポートします。 また、"Range" ヘッダを使った FTP 転送による範囲転送も対応しています。

Directory listings are by default returned unprocessed (as returned from the ftp server) with the content media type reported to be "text/ftp-dir-listing". The File::Listing module provides methods for parsing of these directory listing.

ディレクトリ一覧はデフォルトでは内容メディア型が "text/ftp-dir-listing" としてレポートさながら、返され、 (ftpサーバから返されたまま) 処理されません。 File::Listring モジュールはこれらのディレクトリ一覧の解析のための メソッドを提供します。

The ftp module is also able to convert directory listings to HTML and this can be requested via the standard HTTP content negotiation mechanisms (add an "Accept: text/html" header in the request if you want this).

ftp モジュールはディレクトリ一覧を HTML に変換することも出来ます。 そしてこれは標準の HTTP コンテントネゴシエーション機構を通して 要求されることも出来ます。 (こうしたければリクエストに"Accept: text/html" ヘッダを追加してください)

For normal file retrievals, the "Content-Type" is guessed based on the file name suffix. See LWP::MediaTypes.

通常のファイル取り出しでは、"Content-Type" はファイル名の拡張子に基づいて 推測します。 LWP::MediaTypes をご覧下さい。

The "If-Modified-Since" request header works for servers that implement the MDTM command. It will probably not work for directory listings though.

"If-Modified-Since" リクエストヘッダが MDTM コマンドを実装している サーバのために動作します。 しかしこれはおそらくディレクトリ一覧には動作しないでしょう。

Example:

例:

  $req = HTTP::Request->new(GET => 'ftp://me:passwd@ftp.some.where.com/');
  $req->header(Accept => "text/html, */*;q=0.1");

News リクエスト

Access to the USENET News system is implemented through the NNTP protocol. The name of the news server is obtained from the NNTP_SERVER environment variable and defaults to "news". It is not possible to specify the hostname of the NNTP server in news: URLs.

USENET News システムへのアクセスは NNTP プロトコルを通して実装されます。 news サーバの名前は NNTP_SERVER 環境変数から取得され、 デフォルトは "news" です。 news:URL で NNTP サーバのホスト名を指定することは出来ません。

The library supports GET and HEAD to retrieve news articles through the NNTP protocol. You can also post articles to newsgroups by using (surprise!) the POST method.

このライブラリは NNTP プロトコルを通して news 記事を取り出すための GET と HEAD をサポートします。 (驚くべきことに!) POST メソッドを使って newsgroup に記事を ポストすることもできます。

GET on newsgroups is not implemented yet.

ニュースグループに対する GET はまだ実装されていません。

Examples:

例:

  $req = HTTP::Request->new(GET => 'news:abc1234@a.sn.no');

  $req = HTTP::Request->new(POST => 'news:comp.lang.perl.test');
  $req->header(Subject => 'This is a test',
               From    => 'me@some.where.org');
  $req->content(<<EOT);
  This is the content of the message that we are sending to
  the world.
  EOT

Gopher リクエスト

The library supports the GET and HEAD methods for gopher requests. All request header values are ignored. HEAD cheats and returns a response without even talking to server.

このライブラリは gopher リクエストのための GET と HEAD メソッドを サポートします。 すべてのリクエストヘッダの値は無視されます。 HEAD はごまかして、サーバと話することすらなくレスポンスを返します。

Gopher menus are always converted to HTML.

Gopher メニューは常に HTML に変換されます。

The response "Content-Type" is generated from the document type encoded (as the first letter) in the request URL path itself.

レスポンスの "Content-Type" はリクエスト URL パスそれ自身にエンコードされた 文書タイプから生成されます。

Example:

例:

  $req = HTTP::Request->new(GET => 'gopher://gopher.sn.no/');

File リクエスト

The library supports GET and HEAD methods for file requests. The "If-Modified-Since" header is supported. All other headers are ignored. The host component of the file URL must be empty or set to "localhost". Any other host value will be treated as an error.

このライブラリは file リクエストのために GET とHEAD メソッドを サポートしています。 "If-Modified-Since" ヘッダがサポートされています。 他のすべてのヘッダは無視されます。 file URL の host コンポーネントは空であるか "localhost" に 設定されていなければなりません。 他の host はすべてエラーとして扱われます。

Directories are always converted to an HTML document. For normal files, the "Content-Type" and "Content-Encoding" in the response are guessed based on the file suffix.

ディレクトリは常に HTML 文書に変換されます。 通常のファイルでは、レスポンスの中の "Content-Type" と "Content-Encoding" は ファイル拡張子を元に推測します。

Example:

例:

  $req = HTTP::Request->new(GET => 'file:/etc/passwd');

Mailto リクエスト

You can send (aka "POST") mail messages using the library. All headers specified for the request are passed on to the mail system. The "To" header is initialized from the mail address in the URL.

このライブラリを使って、メールメッセージを送信 (つまり "POST") することができます。 リクエストに指定されたすべてのヘッダはメールシステムに渡されます。 "To" ヘッダは URL でのメールアドレスで初期化されます。

Example:

例:

  $req = HTTP::Request->new(POST => 'mailto:libwww@perl.org');
  $req->header(Subject => "subscribe");
  $req->content("Please subscribe me to the libwww-perl mailing list!\n");

CPAN リクエスト

URLs with scheme cpan: are redirected to the a suitable CPAN mirror. If you have your own local mirror of CPAN you might tell LWP to use it for cpan: URLs by an assignment like this:

cpan: スキームの URLは適切な CPAN ミラーへリダイレクトされます。 もしローカルに自分自身の CPAN ミラーを持っているなら、以下のように cpan: URL を代入することによって LWP に知らせることができます:

  $LWP::Protocol::cpan::CPAN = "file:/local/CPAN/";

Suitable CPAN mirrors are also picked up from the configuration for the CPAN.pm, so if you have used that module a suitable mirror should be picked automatically. If neither of these apply, then a redirect to the generic CPAN http location is issued.

適切な CPAN ミラーは CPAN.pm の設定からも選択されるので、このモジュールを 使っていれば適切なミラーは自動的に選択されるはずです。 もしどちらも適用されない場合、一般的な http による CPAN の位置へと リダイレクトされます。

Example request to download the newest perl:

最新の perl のダウンロードを要求する例です:

  $req = HTTP::Request->new(GET => "cpan:src/latest.tar.gz");

クラスとパッケージの概要

This table should give you a quick overview of the classes provided by the library. Indentation shows class inheritance.

以下の表はこのライブラリによって提供されるクラスの簡単な概略を示します。 インデントはクラスの継承を示します。

 LWP::MemberMixin   -- Access to member variables of Perl5 classes
   LWP::UserAgent   -- WWW user agent class
     LWP::RobotUA   -- When developing a robot applications
   LWP::Protocol          -- Interface to various protocol schemes
     LWP::Protocol::http  -- http:// access
     LWP::Protocol::file  -- file:// access
     LWP::Protocol::ftp   -- ftp:// access
     ...
 LWP::MemberMixin   -- Perl5クラスのメンバー変数へのアクセス
   LWP::UserAgent   -- WWW ユーザエージェントクラス
     LWP::RobotUA   -- ロボット(robot)アプリケーションを開発するとき
   LWP::Protocol          -- 様々なプロトコル機能へのインターフェース
     LWP::Protocol::http  -- http:// アクセス
     LWP::Protocol::file  -- file:// アクセス
     LWP::Protocol::ftp   -- ftp:// アクセス
     ...
 LWP::Authen::Basic -- Handle 401 and 407 responses
 LWP::Authen::Digest
 LWP::Authen::Basic -- 401と407レスポンスの取り扱い
 LWP::Authen::Digest
 HTTP::Headers      -- MIME/RFC822 style header (used by HTTP::Message)
 HTTP::Message      -- HTTP style message
   HTTP::Request    -- HTTP request
   HTTP::Response   -- HTTP response
 HTTP::Daemon       -- A HTTP server class
 HTTP::Headers      -- MIME/RFC822 形式ヘッダ (HTTP::Messageによって使われる)
 HTTP::Message      -- HTTP 形式メッセージ
   HTTP::Request    -- HTTP リクエスト
   HTTP::Response   -- HTTP レスポンス
 HTTP::Daemon       -- HTTP サーバクラス
 WWW::RobotRules    -- Parse robots.txt files
   WWW::RobotRules::AnyDBM_File -- Persistent RobotRules
 WWW::RobotRules    -- robots.txt ファイルの解析
   WWW::RobotRules::AnyDBM_File -- 永続化 RobotRules

 Net::HTTP          -- Low level HTTP client

The following modules provide various functions and definitions.

以下のモジュールは様々な関数と定義を提供します。

 LWP                -- This file.  Library version number and documentation.
 LWP::MediaTypes    -- MIME types configuration (text/html etc.)
 LWP::Simple        -- Simplified procedural interface for common functions
 HTTP::Status       -- HTTP status code (200 OK etc)
 HTTP::Date         -- Date parsing module for HTTP date formats
 HTTP::Negotiate    -- HTTP content negotiation calculation
 File::Listing      -- Parse directory listings
 HTML::Form         -- Processing for <form>s in HTML documents
 LWP                -- このファイル。ライブラリ・バージョン番号と文書
 LWP::MediaTypes    -- MIME タイプ設定(text/html など)
 LWP::Simple        -- 一般的な機能のための簡略化された手続き型インターフェース
 HTTP::Status       -- HTTP ステータスコード (200 OK など)
 HTTP::Date         -- HTTP日付フォーマットのための日付解析モジュール
 HTTP::Negotiate    -- HTTPコンテントネゴシエーション計算
 File::Listing      -- ディレクトリ一覧の解析
 HTML::Form         -- HTML 文書の <form> を処理する

さらなる文書

All modules contain detailed information on the interfaces they provide. The lwpcook manpage is the libwww-perl cookbook that contain examples of typical usage of the library. You might want to take a look at how the scripts lwp-request, lwp-download, lwp-dump and lwp-mirror are implemented.

すべてのモジュールにはそれが提供しているインターフェースについての 詳細な情報がはいっています。 lwpcook マニュアルページはライブラリの典型的な利用法の例が入った libwww-perl レシピ集 です。 スクリプト lwp-request, lwp-download, lwp-dump, lwp-mirror が どのように実行されているかを見るのもよいでしょう。

環境変数

The following environment variables are used by LWP:

以下の環境変数が LWP で使われます:

HOME

The LWP::MediaTypes functions will look for the .media.types and .mime.types files relative to you home directory.

LWP::MediaTypes 関数は、ホームディレクトリにある .media.types.mime.types ファイルを参照します。

http_proxy
ftp_proxy
xxx_proxy
no_proxy

These environment variables can be set to enable communication through a proxy server. See the description of the env_proxy method in LWP::UserAgent.

これらの環境変数はプロキシサーバを通して通信するために使われます。 LWP::UserAgentenv_proxy メソッドの記述を参照してください。

PERL_LWP_ENV_PROXY

If set to a TRUE value, then the LWP::UserAgent will by default call env_proxy during initialization. This makes LWP honor the proxy variables described above.

真の値に設定すると、LWP::UserAgent デフォルトで初期化時に env_proxy を呼び出します。 これにより、LWP は前述のプロキシ変数を尊重します。

PERL_LWP_SSL_VERIFY_HOSTNAME

The default verify_hostname setting for LWP::UserAgent. If not set the default will be 1. Set it as 0 to disable hostname verification (the default prior to libwww-perl 5.840.

LWP::UserAgent のための デフォルトの verify_hostname 設定。 設定されてない場合、デフォルトは 1 です。 0 に設定すると、ホスト名認証を無効にします (libwww-perl 5.840 より前のデフォルトです)。

PERL_LWP_SSL_CA_FILE
PERL_LWP_SSL_CA_PATH

The file and/or directory where the trusted Certificate Authority certificates is located. See LWP::UserAgent for details.

信頼できる Certificate Authority 証明書が置かれているファイルまたは ディレクトリ。 詳しくは LWP::UserAgent を参照してください。

PERL_HTTP_URI_CLASS

Used to decide what URI objects to instantiate. The default is URI. You might want to set it to URI::URL for compatibility with old times.

どの URI オブジェクトを実体化するかを決定するために使われます。 デフォルトは URI です。 昔との互換性のために URI::URL を設定したくなるかもしれません。

作者

LWP was made possible by contributions from Adam Newby, Albert Dvornik, Alexandre Duret-Lutz, Andreas Gustafsson, Andreas König, Andrew Pimlott, Andy Lester, Ben Coleman, Benjamin Low, Ben Low, Ben Tilly, Blair Zajac, Bob Dalgleish, BooK, Brad Hughes, Brian J. Murrell, Brian McCauley, Charles C. Fu, Charles Lane, Chris Nandor, Christian Gilmore, Chris W. Unger, Craig Macdonald, Dale Couch, Dan Kubb, Dave Dunkin, Dave W. Smith, David Coppit, David Dick, David D. Kilzer, Doug MacEachern, Edward Avis, erik, Gary Shea, Gisle Aas, Graham Barr, Gurusamy Sarathy, Hans de Graaff, Harald Joerg, Harry Bochner, Hugo, Ilya Zakharevich, INOUE Yoshinari, Ivan Panchenko, Jack Shirazi, James Tillman, Jan Dubois, Jared Rhine, Jim Stern, Joao Lopes, John Klar, Johnny Lee, Josh Kronengold, Josh Rai, Joshua Chamas, Joshua Hoblitt, Kartik Subbarao, Keiichiro Nagano, Ken Williams, KONISHI Katsuhiro, Lee T Lindley, Liam Quinn, Marc Hedlund, Marc Langheinrich, Mark D. Anderson, Marko Asplund, Mark Stosberg, Markus B Krüger, Markus Laker, Martijn Koster, Martin Thurn, Matthew Eldridge, Matthew.van.Eerde, Matt Sergeant, Michael A. Chase, Michael Quaranta, Michael Thompson, Mike Schilli, Moshe Kaminsky, Nathan Torkington, Nicolai Langfeldt, Norton Allen, Olly Betts, Paul J. Schinder, peterm, Philip GuentherDaniel Buenzli, Pon Hwa Lin, Radoslaw Zielinski, Radu Greab, Randal L. Schwartz, Richard Chen, Robin Barker, Roy Fielding, Sander van Zoest, Sean M. Burke, shildreth, Slaven Rezic, Steve A Fink, Steve Hay, Steven Butler, Steve_Kilbane, Takanori Ugai, Thomas Lotterer, Tim Bunce, Tom Hughes, Tony Finch, Ville Skyttä, Ward Vandewege, William York, Yale Huang, and Yitzchak Scott-Thoennes.

LWP は以下の人々の貢献によって実現可能になりました: Adam Newby, Albert Dvornik, Alexandre Duret-Lutz, Andreas Gustafsson, Andreas König, Andrew Pimlott, Andy Lester, Ben Coleman, Benjamin Low, Ben Low, Ben Tilly, Blair Zajac, Bob Dalgleish, BooK, Brad Hughes, Brian J. Murrell, Brian McCauley, Charles C. Fu, Charles Lane, Chris Nandor, Christian Gilmore, Chris W. Unger, Craig Macdonald, Dale Couch, Dan Kubb, Dave Dunkin, Dave W. Smith, David Coppit, David Dick, David D. Kilzer, Doug MacEachern, Edward Avis, erik, Gary Shea, Gisle Aas, Graham Barr, Gurusamy Sarathy, Hans de Graaff, Harald Joerg, Harry Bochner, Hugo, Ilya Zakharevich, INOUE Yoshinari, Ivan Panchenko, Jack Shirazi, James Tillman, Jan Dubois, Jared Rhine, Jim Stern, Joao Lopes, John Klar, Johnny Lee, Josh Kronengold, Josh Rai, Joshua Chamas, Joshua Hoblitt, Kartik Subbarao, Keiichiro Nagano, Ken Williams, KONISHI Katsuhiro, Lee T Lindley, Liam Quinn, Marc Hedlund, Marc Langheinrich, Mark D. Anderson, Marko Asplund, Mark Stosberg, Markus B Krüger, Markus Laker, Martijn Koster, Martin Thurn, Matthew Eldridge, Matthew.van.Eerde, Matt Sergeant, Michael A. Chase, Michael Quaranta, Michael Thompson, Mike Schilli, Moshe Kaminsky, Nathan Torkington, Nicolai Langfeldt, Norton Allen, Olly Betts, Paul J. Schinder, peterm, Philip GuentherDaniel Buenzli, Pon Hwa Lin, Radoslaw Zielinski, Radu Greab, Randal L. Schwartz, Richard Chen, Robin Barker, Roy Fielding, Sander van Zoest, Sean M. Burke, shildreth, Slaven Rezic, Steve A Fink, Steve Hay, Steven Butler, Steve_Kilbane, Takanori Ugai, Thomas Lotterer, Tim Bunce, Tom Hughes, Tony Finch, Ville Skyttä, Ward Vandewege, William York, Yale Huang, and Yitzchak Scott-Thoennes.

LWP owes a lot in motivation, design, and code, to the libwww-perl library for Perl4 by Roy Fielding, which included work from Alberto Accomazzi, James Casey, Brooks Cutter, Martijn Koster, Oscar Nierstrasz, Mel Melchner, Gertjan van Oosten, Jared Rhine, Jack Shirazi, Gene Spafford, Marc VanHeyningen, Steven E. Brenner, Marion Hakanson, Waldemar Kebsch, Tony Sanders, and Larry Wall; see the libwww-perl-0.40 library for details.

LWP は、動機、設計、コードの多くを、Roy Fielding による Perl 4 用の libwww-perl ライブラリを基にしており、これは Alberto Accomazzi, James Casey, Brooks Cutter, Martijn Koster, Oscar Nierstrasz, Mel Melchner, Gertjan van Oosten, Jared Rhine, Jack Shirazi, Gene Spafford, Marc VanHeyningen, Steven E. Brenner, Marion Hakanson, Waldemar Kebsch, Tony Sanders, Larry Wall と共に作業したものです; 詳細については libwww-perl-0.40 ライブラリを参照してください。

コピーライト

  Copyright 1995-2009, Gisle Aas
  Copyright 1995, Martijn Koster

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

AVAILABILITY

The latest version of this library is likely to be available from CPAN as well as:

このライブラリの最新バージョンは以下の場所の他に CPAN からも利用できます:

  http://github.com/gisle/libwww-perl

The best place to discuss this code is on the <libwww@perl.org> mailing list.

このプログラムについて議論する一番よい場所は <libwww@perl.org> メーリングリストです。