名前¶

perlclass - Perl クラス構文リファレンス

概要¶

    use v5.38;
    use feature 'class';

    class My::Example 1.234 {
        field $x;

        ADJUST {
            $x = "Hello, world";
        }

        method print_message {
            say $x;
        }
    }

    My::Example->new->print_message;

説明¶

この文書では、オブジェクト指向プログラミングをサポートする ネイティブなキーワードを提供する Perl の class 機能の構文について 説明します。

歴史¶

Perl 5 以降、オブジェクトのサポートは、パッケージ名によって bless された リファレンスの概念に基づいて拡張されました ("bless REF,CLASSNAME" in perlfunc 参照)。 このようなリファレンスは、bless されたパッケージ(またはその親のいずれか)から サブルーチンを呼び出すために使えます。 このシステムは、必要最小限のものではありますが、オブジェクト指向のための 複数のより高度な、コミュニティ駆動システムの作成を可能にするのに 十分な柔軟性を備えていました。 さらなる情報については、perlmod と perlobj を参照してください。

class 機能は、他のプログラミング言語で見られるものに似ている、 クラス構文のコア実装です。 これは bless へのラッパーではなく、perl インタプリタに直接組み込まれた 全く新しいシステムです。

キーワード¶

class 機能を有効にすると、現在のレキシカルスコープ内で次の新しい キーワードを使えます。

class¶

    class NAME BLOCK

    class NAME VERSION BLOCK

    class NAME VERSION : ATTRIBUTES... BLOCK

    class NAME;

    class NAME VERSION;

    class NAME VERSION : ATTRIBUTES...;

class キーワードは、クラスとして意図された新しいパッケージを宣言します ("Packages" in perlmod 参照)。 class機能からの他のすべてのキーワードは、この宣言のスコープ内で 使われる必要があります。

    class WithVersion 1.000 {
        # class definition goes here
    }

クラスは、ブロック構文または文構文のいずれかで宣言できます。 ブロックを使う場合、ブロックの本体にはクラスの実装が含まれます。 文形式を使用する場合、ファイルの残りの部分は、次の class または package ステートメントまで使い切られます。

package キーワードと同様に、class 宣言にはオプションでバージョン番号を 持ちます。 また、オプションの属性も持ちます。 両方が指定された場合、バージョン番号は属性の前、先頭でなければなりません。

class と package の宣言は似ていますが、クラスは自動的に new という 名前のコンストラクタを取得します - あなたはこれを書く必要はありません(書くべきではありません)。 さらに、class の BLOCK の中では、フィールドとメソッドを宣言できます。

field¶

    field VARIABLE_NAME;

    field VARIABLE_NAME = EXPR;

    field VARIABLE_NAME : ATTRIBUTES;

    field VARIABLE_NAME : ATTRIBUTES = EXPR;

フィールドは、クラスのスコープ内(より具体的には "method" および ADJUST ブロック内)で見える変数です。 各クラス実体は、フィールドのための他の実態と独立した独自の保管場所を 取得します。

フィールドは、通常のレキシカルスコープの変数のように振る舞います。 それには印(sigil)があり、クラスに対してプライベートです(ただし、 アクセサメソッドを作成すると、外部からアクセスできるようになります)。 主な違いは、異なる実体は同じスコープ内の異なる値にアクセスすることです。

    class WithFields {
        field $scalar = 42;
        field @array  = qw(this is just an array);
        field %hash   = (species => 'Martian', planet => 'Mars');
    }

フィールドは、オプションで初期化式を持つことができます。 存在する場合、式は各オブジェクト実体のコンストラクタ内で評価されます。 それぞれの評価中に、式はスコープ内の他の変数と同様、 それまでに設定されたフィールドの値を使用できます。

    class WithACounter {
        my $next_count = 1;
        field $count = $next_count++;
    }

:param フィールド属性と組み合わせた場合、デフォルト式では、 =, //=, ||$= 演算子のいずれかを使えます。 = を使った式は、呼び出し側がコンストラクタに対応する引数を まったく渡さなかった場合に適用されます。 //= を使った式は、呼び出し側が引数を渡したが値が 未定義であった場合にも適用され、 ||= を使った式は、値が偽であった場合に適用されます。

フィールド初期化式の間、実体はまだ構築されていないので、 $self レキシカル変数は利用できません。 しかし、例えばフィールドのための値の構築を助けるための クラスメソッドを呼び出すために、 構築中のクラスの名前を得るために __CLASS__ トークンが使えます。

    class WithCustomField {
        use constant DEFAULT_X => 10;
        field $x = __CLASS__->DEFAULT_X;
    }

これにより、サブクラスが異なった振る舞いを持つメソッドを オーバーライドできます。

    class DifferentCustomField :isa(WithCustomField) {
        sub DEFAULT_X { rand > 0.5 ? 20 : 30 }
    }

DifferentCustomField の実体が構築されるとき、 基底クラスの __CLASS__ 式は正しいクラス名をもたらし、 オーバーライドされたメソッドを起動します。

method¶

    method METHOD_NAME SIGNATURE BLOCK

    method METHOD_NAME BLOCK

    method SIGNATURE BLOCK

    method BLOCK

メソッドは、クラスオブジェクトのコンテキスト内で呼び出されることを目的とした サブルーチンです。

現在のオブジェクト実体が設定された $self という名前の変数が、 method のレキシカルスコープに自動的に作成されます。

メソッドは常に use feature 'signatures' が有効であるかのように 動作しますが、$self はシグニチャに関する限り引数リストには表示されません。

    class WithMethods {
        field $greetings;

        ADJUST {
            $greetings = "Hello";
        }

        method greet($name = "someone") {
            say "$greetings, $name";
        }
    }

通常のサブルーチンと同じように、メソッドは匿名にすることが できます。

    class AnonMethodFactory {

        method get_anon_method {
            return method {
                return 'this is an anonymous method';
            };
        }
    }

属性¶

上述のキーワードの特定の様相は、属性 を使って管理されます。 属性はすべてコロンで始まり、一つまたは複数の属性をアイテム名の後に スペースで区切って追加できます。

クラス属性¶

:isa¶

クラスは、:isa クラス属性を使用して、一つの スーパークラスから 継承できます。

    class Example::Base { ... }

    class Example::Subclass :isa(Example::Base) { ... }

継承されたメソッドはアクセス可能で、呼び出すことができます。 フィールドは常にレキシカルであるため、継承によってアクセス可能にはなりません。

:isa 属性は、基本クラスの最小バージョンを要求する場合があります。 use MODULE VERSION が使われている場合、基底クラスの実際のバージョンが 低すぎる場合、コンパイルは失敗します。

    class Example::Subclass :isa(Example::Base 2.345) { ... }

:isa 属性は、指定されたモジュールがまだロードされていない場合、 そのモジュールを require しようとします。

フィールド属性¶

:param¶

:param 属性を持つスカラーフィールドは、コンストラクタに渡された 名前付き引数から値を取得します。 デフォルトでは、引数はフィールドと同じ名前 (先頭の $ 印を除く) を 持ちますが、属性で別の名前を指定できます。

    field $x :param;
    field $y :param(the_y_value);

デフォルトの式がない場合、コンストラクタには引数が必要です; 呼び出し元はパラメータを渡す必要があり、渡さない場合は例外が投げられます。 デフォルトの式を使用すると、これはオプションになります。

:reader¶

A field with a :reader 属性を持つフィールドは、読み込みアクセサメソッドを 自動的に生成します。 生成されたメソッドは空の(つまり 0 引数の)シグネチャを持ち、 その本体は単にフィールド変数の値を返します。

    field $s :reader;

    # Equivalent to
    field $s;
    method s () { return $s; }

デフォルトでは、アクセサメソッドはフィールドと同じ名前(から戦闘の印を 引いたもの)ですが、属性の値で違う名前を指定できます。

    field $x :reader(get_x);

    # Generates a method
    method get_x () { return $x; }

読み込みメソッドは非スカラフィールドに適用できます。 リストコンテキストで起動された場合、 これらはフィールドの内容を返します; スカラコンテキストでは、 フィールド変数がスカラコンテキストに置かれたかのように、 要素の数を返します。

    field @users :reader;
    ...

    scalar $instance->users;

メソッド属性¶

まだありません。

オブジェクトのライフサイクル¶

構築¶

各オブジェクトは、コンストラクタ呼び出しから始まります。 コンストラクタは常に new という名前で、クラス名に対する メソッド呼び出しのように呼び出されます。

    my $object = My::Class->new(%arguments);

オブジェクト構築中に、クラスフィールドは %arguments ハッシュ内を 検索され、可能な場所では値が伝搬されます。

調整¶

オブジェクトの調整は、オブジェクト定義中に任意のユーザ定義コードを実行する 方法です。 これは、ADJUST ブロックにあるコードによって行われます。 オブジェクトが構築されると毎回、その ADJUST ブロックが (宣言された順番に)実行されます。

    class WellAdjusted {
        field $x :param;
        ADJUST {
            say "Hello!";
        }
        ADJUST {
            say "x = $x";
        }
    }

    my $object = WellAdjusted->new(x => 42);
    # Output:
    #   Hello!
    #   x = 42

ADJUST ブロックは、一度だけ実行される BEGIN や INIT ブロック に似ています。 しかし、ADJUST ブロックはメソッドと同様、この時点で作られている 全てのオブジェクトフィールドと同様、$self (構築されたオブジェクトを 保持しているレキシカル変数) にアクセスできます。

生存期間¶

構築フェーズの後、オブジェクトは使用可能な状態になります。

オブジェクトに対して blessed (Scalar::Util::blessed または builtin::blessed) を使うと、クラスの名前が返されます; 一方、reftype(Scalar::Util::reftype または builtin::reftype) を 使うと、文字列 'OBJECT' が返されます。

破棄¶

Perl の他のデータ構造と同様に、オブジェクトも最後の参照がなくなると、 破棄されます。

TODO¶

この機能はまだ実験的であり、非常に不完全です。 次のリストは、追加または変更される機能の概要を示しています。

• Roles

  (ロール)

  Some syntax for declaring a role (likely a role keyword), and for consuming a role into a class (likely a :does() attribute).

  (role キーワードのような) ロールを宣言するための構文と、 (:does() 属性のような) ロールをクラスに取り込むための構文。

• Parameters to ADJUST blocks

  (ADJUST ブロックへの引数)

  Some syntax for declaring that an ADJUST block can consume named parameters, which become part of the class constructor's API. This might be inspired by a similar plan to add named arguments to subroutine signatures.

  ADJUST ブロックがクラスコンストラクタの API の一部となる 名前付き引数を消費できることを宣言するためのいくつかの構文。 これは、名前付き引数をサブルーチンシグネチャに追加する 同様の計画に触発された可能性があります。

      class X {
          ADJUST (:$alpha, :$beta = 123) {
             ...
          }
      }
  
      my $obj = X->new(alpha => 456);

• ADJUST blocks as true blocks

  (真のブロックとしての ADJUST ブロック)

  Currently, every ADJUST block is wrapped in its own CV (subroutine) that gets invoked with the full ENTERSUB overhead. It should be possible to use the same mechanism that makes all field initializer expressions appear within the same CV on ADJUST blocks as well, merging them all into a single CV per class. This will make it faster to invoke if a class has more than one of them.

  現在、すべての ADJUST ブロックは、完全な ENTERSUB オーバーヘッドで 呼び出される独自の CV (サブルーチン)にラップされています。 すべてのフィールド初期化式を ADJUST ブロックの同じ CV 内に表示する 同じ機構を使って、クラスごとにすべてを 単一の CV にマージすることも可能です。 これにより、クラスに複数の CV がある場合の呼び出しが高速になります。

• More accessor generator attributes

  (さらなるアクセサ生成属性)

  Attributes to request that other kinds of accessor methods be generated for fields. Likely :writer.

  フィールドに対して他の種類のアクセサメソッドの生成を要求する属性。 :writer が考えられます。

      class X {
          field $name :writer;
      }

  Equivalent to

  次と同等です:

      class X {
          field $name;
          method set_name ($new) { $name = $new; return $self; }
      }

• Metaprogramming

  (メタプログラミング)

  An extension of the metaprogramming API (currently proposed by PPC0022) which adds knowledge of classes, methods, fields, ADJUST blocks, and other such class-related details.

  (現在 PPC0022 によって 提案されている) メタプログラミング API の拡張で、クラス、メソッド、 フィールド、ADJUST ブロック、およびその他のクラス関連の 詳細に関する知識を追加します。

• Extension Customisation

  (拡張のカスタマイズ)

  Ways in which out-of-core modules can interact with the class system, including an ability for them to provide new class or field attributes.

  コア外モジュールがクラスシステムと相互作用する方法; これには、新しいクラスまたはフィールド属性を提供する機能が含まれます。

KNOWN BUGS¶

実験的な class 機能には、次のバグが発見されています:

• Since Perl v5.38, inheriting from a parent class which is declared in the same file and which hadn't already been sealed can cause a segmentation fault. [GH #20890]

  Perl v5.38 から、同じファイルにあってすでに閉じていない親クラスから 継承すると、セグメンテーションフォルトを起こすことがあります。 [GH #20890]

• Since Perl v5.38 and with the experimental refaliasing feature, trying to replace a field variable causes a segmentation fault. [GH #20947]

  Perl v5.38 から、実験的な refaliasing 機能が有効の場合、 フィールド変数を置き換えようとするとセグメンテーションフォルトを 引き起こします。 [GH #20947]

• Since Perl v5.38, it's possible to craft a class with leaky encapsulation, which can cause a segmentation fault. [GH #20956]

  Perl v5.38 から、細工して、 セグメンテーションフォルトを引き起こすことがある、 リークのあるクラスを作ることができます。 [GH #20956]

• In Perl v5.38, inheriting from a class would not always attempt to load the parent class (fixed in Perl v5.40). [GH #21332]

  Perl v5.38 で、クラスからの継承が、常に親クラスを 読み込もうとしませんでした(Perl 5.40 で修正されました)。 [GH #21332]

作者¶

Paul Evans

Bartosz Jarzyna