名前¶

perlfaq7 - Perl 言語一般に関することがら

説明¶

このセクションでは、他のセクションにはきっちりとあてはまらないような Perl 言語に関する一般的な事柄を扱います。

Perl のための BNF/yacc/RE は入手できますか?¶

BNFはありませんが、もし多少の勇気を持ちあわせているのであれば 配布ソースに含まれている perly.y にある yacc 文法をいじくりまわすことが できます。 その文法は非常に賢い字句解析ルーチンに依存したものなので、 toke.c を眺める準備もしておきましょう。

reduce Chaim Frenkel の言葉を借りればこうです: 「Perl の文法は BNF まで縮小することができない。 perl の構文解析の作業は yacc、字句解析器、煙と鏡とに分配される。」

$@%&* のマークはなんですか? これらをいつ使えばいいのかを知るにはどうすればいいですか?¶

これらは型指定子(type specifiers)で、perldata で説明されています:

        $ for scalar values (number, string or reference)
        @ for arrays
        % for hashes (associative arrays)
        & for subroutines (aka functions, procedures, methods)
        * for all types of that symbol name.  In version 4 you used them like
          pointers, but in modern perls you can just use references.

        $ スカラ値(数値、文字列、リファレンス)に対するもの
        @ 配列に対するもの
        % ハッシュ(連想配列)に対するもの
        & サブルーチン(またの名を関数、手続き、メソッド)に対するもの
        * シンボル名に対する全ての型。バージョン 4 ではポインタのように
          使われていましたが、新しい perl ではリファレンスが使えます。

実際には型指定子として見ることはないであろう二つのものが この他にもあります:

        <> are used for inputting a record from a filehandle.
        \  takes a reference to something.

        <> あるファイルハンドルからレコードを入力するのに使われます。
        \  なにかのリファレンスを取ります。

<FILE> は、ファイルに対する型指定子にもハンドルの名前の どちらでもない ということに注意してください。 これはハンドル FILE に対する <> 演算子です。 一行(そう、レコードですね。"$/" in perlvar を参照してください) を FILE というハンドルからスカラコンテキストで読み出します。 リストコンテキストの場合は 全ての 行を読み出します。 ファイルの <> に関係する open、close などの操作を行うときには、 ハンドルについて行っている場合であっても アングルブラケットを使っては いけません。 eof(FH), seek(FH, 0,2) や "copying from STDIN to FILE" は 正しいものなのです。

文字列では常にクォートする/決してクォートしない必要があるのでしょうか? また、セミコロンやカンマについては?¶

通常は、裸の単語(barewords)はクォートする必要はありませんが、 ほとんど場合はクォートすべきでしょう(そして、use strcit しているときは しなければなりません)。 しかし、単純な単語から 構成されるハッシュと、=> 演算子の左側にあるオペランドは 両方ともクォートされているとみなされます:

        This                    is like this
        ------------            ---------------
        $foo{line}              $foo{'line'}
        bar => stuff            'bar' => stuff

ブロックの最後にあるセミコロンは、リストの最後にあるカンマと同じく 省略可能です。 良いスタイル(perlstyle を参照)は一行野郎(one-liners)でなければ それらを使うようにしましょうと言っています。

        if ($whoops) { exit 1 }
        @nums = (1, 2, 3);

        if ($whoops) {
                exit 1;
        }

        @lines = (
        "There Beren came from mountains cold",
        "And lost he wandered under leaves",
        );

戻り値の一部をスキップするには?¶

方法の一つは、戻り値をリストとみなして、それに添え字づけするというものです:

        $dir = (getpwnam($user))[7];

もう一つのやりかたは、左辺の要素として undef を使うというものです:

        ($dev, $ino, undef, undef, $uid, $gid) = stat($file);

必要な要素だけを選択するために、リストスライスも使えます:

        ($dev, $ino, $uid, $gid) = ( stat($file) )[0,1,4,5];

一時的に警告をブロックするには?¶

Perl 5.6.0 以降を使っているなら、use warnings プラグマで どんな警告を生成するかをうまく制御できます。 詳細については perllexwarn を参照してください。

        {
        no warnings;          # temporarily turn off warnings
        $a = $b + $c;         # I know these might be undef
        }

さらに、警告の分野毎に警告を有効または無効にできます。 無視したいカテゴリを無効にしても、残りのカテゴリの警告は受けられます。 カテゴリ名と階層を含む、完全な詳細については perllexwarn を 参照してください。

        {
        no warnings 'uninitialized';
        $a = $b + $c;
        }

より古いバージョンの場合は、変数 $^W(perlvar に説明があります)は 実行時の警告のブロックを制御します:

        {
        local $^W = 0;        # temporarily turn off warnings
        $a = $b + $c;         # I know these might be undef
        }

    {
        local $^W = 0;        # 一時的に警告をオフにする
        $a = $b + $c;         # これらが undef かもしれないことを知っている
    }

全ての句読点変数(punctuation variable)と同様、現時点では $^W に対して my() を使うことはできず、local() だけしか使えないということに 注意してください。

エクステンションてなんですか?¶

エクステンションとは、Perl からコンパイル済みの C コードを呼び出すための 方法です。 エクステンションについて知るには perlxstut を読むのが良いでしょう。

なぜ Perl の演算子は C の演算子とは異なった優先順位を持っているのでしょうか?¶

実際はそうではありません。Perl に持ち込まれたCの演算子はすべて、 C と Perl とで同じ優先順位を持っています。 問題は、C にはない演算子、特にその右辺に対してつねにリストコンテキストを 与える関数、例えば print、chmod、exec などです。 そういった関数は「リスト演算子」と呼ばれ、 perlop にある優先順位テーブルにあります。

ありがちな間違いは以下のようにのように書いてしまうことです:

        unlink $file || die "snafu";

これは以下のように解釈されます:

        unlink ($file || die "snafu");

この問題を避けるためには、余計な括弧をつけるかより優先順位の低い or 演算子を使うようにします:

        (unlink $file) || die "snafu";
        unlink $file or die "snafu";

"English" 演算子(and, or, xor, not) は先に説明している 同じ働きをするリスト演算子よりも低い優先順位を故意に持たされています。

もう一つの、びっくりするような優先順位を持っている演算子は べき乗(exponentiation)です。 これは単項のマイナスよりも強く結び付くので、-2**2 はプラス 4 ではなく、 マイナス 4 を生成します。 この演算子は右結合するので、2**3**2 は 8 の 2 乗ではなく、 2 の 9 乗です。

C と同じ優先順位を持っているにも関らず、Perl では ?: 演算子は 左辺値を作り出します。 以下の代入では、$maybe の値に応じて、$a か $b のいずれかに $x の値を代入します:

        ($maybe ? $a : $b) = $x;

構造体を宣言したり生成するには?¶

一般的には、構造体を“宣言”することはありません。 単に(おそらくは無名の)ハッシュリファレンスを使うだけです。 詳しくは perlrefと perldsc を参照してください。 例を挙げましょう:

        $person = {};                   # new anonymous hash
        $person->{AGE}  = 24;           # set field AGE to 24
        $person->{NAME} = "Nat";        # set field NAME to "Nat"

もうちょっと正確ななにかを求めているのなら、 perltoot に挑戦してみてください。

モジュールを作成するには?¶

(brian d foy によって寄贈されました)

perlmod, perlmodlib, perlmodstyle はモジュールに関する全ての 不愉快な詳細について説明しています。 perlnewmod にはこのプロセスに関する大まかな概要と、スタイルに関する いくつかの忠告があります。

もしモジュールに C コードや C ライブラリインターフェースを含めたいなら、 h2xs が必要です。 h2xs は必要になるモジュール配布構造と初期インターフェースファイルを 作成します。 perlxs と perlxstut は詳細を説明しています。

C のコードを使う必要がないのなら、ExtUtils::ModuleMaker や Module::Starter といったツールが、モジュール配布の骨格を作るのを 助けてくれます。

モジュール配布を作成するための最良の実践型ガイドである、Sam Tregar による "Writing Perl Modules for CPAN" ( http://apress.com/book/bookDisplay.html?bID=14 ) を見るのもよいでしょう。

すでに CPAN にあるモジュールを引き継ぐには?¶

(brian d foy によって寄贈されました)

モジュールを引き継ぐのに一番簡単な方法は、現在のモジュールのメンテナに 連絡して、共同メンテナにしてもらうか、モジュールを引き渡してもらう ことです。

もし何らかの理由(メールが返ってきたなど)で作者と連絡が取れない場合、 PAUSE 管理者である modules@perl.org が助けになるかもしれません。 PAUSE 管理者はそれぞれの場合を個別に扱います。

• Get a login for the Perl Authors Upload Server (PAUSE) if you don't already have one: http://pause.perl.org

  まだ持っていないなら、the Perl Authors Upload Server (PAUSE) のアカウントを 取ります: http://pause.perl.org

• Write to modules@perl.org explaining what you did to contact the current maintainer. The PAUSE admins will also try to reach the maintainer.

  現在のメンテナに連絡するためにしたことの説明を modules@perl.org に書きます。 PAUSE 管理者もメンテナに連絡を試みます。

• Post a public message in a heavily trafficked site announcing your intention to take over the module.

  モジュールを引き継ぎたいという意思を表明するために、トラフィックの多い サイトに公的なメッセージを投稿します。

• Wait a bit. The PAUSE admins don't want to act too quickly in case the current maintainer is on holiday. If there's no response to private communication or the public post, a PAUSE admin can transfer it to you.

  しばらく待ちます。 PAUSE 管理者は、現在のメンテナが休暇中の場合に、あまりに性急に行動したいとは 思いません。 もし私的な通信や公的な投稿に反応がない場合、PAUSE 管理者はモジュールを あなたに移行できます。

クラスを作るには?¶

(brian d foy によって寄贈されました)

Perl では、クラスは単なるパッケージで、メソッドは単なるサブルーチンです。 Perl はそれ以上に形式的なことはしませんし、あなたの好きな方法でパッケージを 設定できるようにします (つまり、Perl はあなたのために何の設定もしません)。

Perl の文書には、 perlboot (Barnyard Object Oriented Tutorial), perltoot (Tom's Object Oriented Tutorial), perlbot (Bag o' Object Tricks), perlobj といった、クラス生成に対応する いくつかのチュートリアルがあります。

変数が汚染されているかどうかを確かめるには?¶

CPAN にある (リリース 5.8.0 からは Perl に含まれている) Scalar::Util モジュールの tainted() 関数が使えます。 "Laundering and Detecting Tainted Data" in perlsec も参照してください。

クロージャ(closure)ってなんですか?¶

クロージャは perlref に説明があります。

クロージャ は、きちんとした定義を持ったコンピュータ科学の用語ですが その意味を説明するのはとても難しいのです。 クロージャは Perl では、そのスコープの外側でもレキシカル変数に対する リファレンスを保持しつづける無名サブルーチンとして実装されています。 これらのレキシカルは、サブルーチンが定義されたときの変数に対して、 魔法のような参照(magically refer)を行います(深い束縛、deep binding)。

クロージャは、Perl ができるような関数の戻り値として関数それ自身を返す関数を 持つことができるプログラミング言語でもっともよく使われます。 一部の言語では、無名関数を提供しているけれども適切なクロージャを提供する 能力はないということに注意してください。 たとえば Python がそうです。 クロージャに関するより詳しいことは、関数言語に関するなんらかの教科書を みてください。 Scheme はクロージャをサポートするだけでなく、それを推奨している言語です。

以下は、古典的な、クロージャではない関数を生成する関数です:

        sub add_function_generator {
                return sub { shift() + shift() };
                }

        $add_sub = add_function_generator();
        $sum = $add_sub->(4,5);                # $sum is 9 now.

add_function_generator() が返した無名サブルーチンは技術的には クロージャではありません。 なぜなら、あれはスコープの外側で参照するようなレキシカルがないからです。 クロージャを使うことによって、後で埋めることのできるカスタマイズ可能な 幾つかのスロットを持つ 関数テンプレート のように働きます。

それとは対照的に、次の関数 make_adder() では、関数自身のスコープの外側で レキシカル変数に対するリファレンスを持つ無名関数を返します。 そのようなリファレンスは Perl が適切なクロージャを返すように要求するので、 その変数を参照するときはいつでも関数が生成されたときの レキシカルが参照されます。

        sub make_adder {
                my $addpiece = shift;
                return sub { shift() + $addpiece };
        }

        $f1 = make_adder(20);
        $f2 = make_adder(555);

これで、&$f1($n) は それに渡した $n に対して常に 20 を加え、 &$f2($n) は渡された $n に常に 555 を加えます。 クロージャの中にある $addpiece が仕事をしています。

クロージャは、それほど難しくない状況でよく使われます。 たとえば、関数にちょっとしたコードを押しこみたいときがそうです:

        my $line;
        timeout( 30, sub { $line = <STDIN> } );

もし実行すべきコードが文字列として渡されていたのであれば、 '$line = <STDIN>' としているところは、仮想的な timeout() 関数が アクセスするレキシカル変数 $line を呼び出し元のスコープのものに戻す 手段がなくなってしまいます。

もう一つのクロージャの使用法は、ある変数を名前つきサブルーチンで プライベート にすることです; 例えば、サブルーチンの作成時に初期化され、 サブルーチン内でのみ変更可能なカウンタです。 これは、パッケージの生存期間中に変数が干渉されることがないように、とき毒 パッケージファイルの BEGIN ブロックで使われます:

        BEGIN {
                my $id = 0;
                sub next_id { ++$id }
        }

これは perlsub でより詳しく議論されています; Persistent Private Variables のエントリを参照してください。

変数の自殺(variable suicide)って何で、それをどうすれば防げますか?¶

この問題は 5.004_05 で修正されたので、防ぐためには perl を バージョンアップします :)

変数の自殺とは、(一時的にしろ、恒久的にしろ)変数の値を失ったときのことを 指します。 これは、クロージャ、もしくは別名つけされた foreach イテレータ変数や サブルーチンの引数と相互作用している my() や local() を通した スコープによって引き起こされます。 以前はこのやり方で変数の値をうっかりとなくしてしまうように 使われがちでしたが、現在は非常に難しくなっています。 以下のコードを考えてみましょう:

        my $f = 'foo';
        sub T {
                while ($i++ < 3) { my $f = $f; $f .= "bar"; print $f, "\n" }
                }

        T;
        print "Finally $f\n";

もし変数の自殺に遭遇したら、サブルーチン内の my $f は、値が foo である $f の最新のコピーをではありません。 この出力は、漏れてはいけないサブルーチン内の $f の値が漏れていることを 示し、以下のようになります:

        foobar
        foobarbar
        foobarbarbar
        Finally foo

"bar" を保持している $f は三回 new $f されるべきものです (my $f は、 ループが通る度に新たなレキシカル変数を生成すべきなのです)。 予想される出力は以下のものです:

        foobar
        foobar
        foobar
        Finally foo

{関数, ファイルハンドル, 配列, ハッシュ, メソッド, 正規表現} を渡したり返したりするには?¶

これらのオブジェクトのリファレンスを渡す必要があります。 "Pass by Reference" in perlsub にある関連した質問と、 perlref にあるリファレンスに関する情報を参照してください。

Passing Variables and Functions

(変数や関数を渡す)

Regular variables and functions are quite easy to pass: just pass in a reference to an existing or anonymous variable or function:

普通の変数や関数はとても簡単に渡せます: 既に存在している変数や関数に対する リファレンスか、無名変数や無名関数に対するリファレンスを渡せばよいのです。

        func( \$some_scalar );

        func( \@some_array  );
        func( [ 1 .. 10 ]   );

        func( \%some_hash   );
        func( { this => 10, that => 20 }   );

        func( \&some_func   );
        func( sub { $_[0] ** $_[1] }   );

Passing Filehandles

As of Perl 5.6, you can represent filehandles with scalar variables which you treat as any other scalar.

Perl 5.6 から、他のスカラと同様にファイルハンドルもスカラ変数で扱えます。

        open my $fh, $filename or die "Cannot open $filename! $!";
        func( $fh );

        sub func {
                my $passed_fh = shift;

                my $line = <$passed_fh>;
                }

Before Perl 5.6, you had to use the *FH or \*FH notations. These are "typeglobs"--see "Typeglobs and Filehandles" in perldata and especially "Pass by Reference" in perlsub for more information.

Perl 5.6 より前では、*FH や \*FH といった記法を使う必要があります。 これらは“型グロブ”(typeglob)です。 "Typeglobs and Filehandles" in perldata) と "Pass by Reference" in perlsub に 詳しい説明があります。

Passing Regexes

(正規表現を渡す)

Here's an example of how to pass in a string and a regular expression for it to match against. You construct the pattern with the qr// operator:

以下の例は、文字列とマッチングする正規表現を渡す方法です。 パターンを qr// 演算子で構築します:

        sub compare($$) {
                my ($val1, $regex) = @_;
                my $retval = $val1 =~ /$regex/;
        return $retval;
        }
        $match = compare("old McDonald", qr/d.*D/i);

Passing Methods

(メソッドを渡す)

To pass an object method into a subroutine, you can do this:

サブルーチンにオブジェクトメソッドを渡すには、以下のようにできます:

        call_a_lot(10, $some_obj, "methname")
        sub call_a_lot {
                my ($count, $widget, $trick) = @_;
                for (my $i = 0; $i < $count; $i++) {
                        $widget->$trick();
                }
        }

Or, you can use a closure to bundle up the object, its method call, and arguments:

オブジェクトとそのメソッド呼び出しと引数とをまとめるために クロージャを使うこともできます:

        my $whatnot =  sub { $some_obj->obfuscate(@args) };
        func($whatnot);
        sub func {
                my $code = shift;
                &$code();
        }

You could also investigate the can() method in the UNIVERSAL class (part of the standard perl distribution).

UNIVERSAL クラスにある can() メソッドを試すこともできます (これは標準の perl 配布キットの一部です)。

静的変数を作るには?¶

(brian d foy によって寄贈されました)

Perl 5.10 では、state で変数を宣言します。 state 宣言は、サブルーチンの呼び出しの間で永続するレキシカル変数を 作成します:

        sub counter { state $count = 1; $counter++ }

スコープ外でレキシカル変数を使うことでスタティック変数を でっち上げることができます。 この例では、サブルーチン counter を定義し、そこでレキシカル変数 $count を使います。 これを BEGIN ブロックで囲っているので、$count はコンパイル時に 定義されますが、BEGIN ブロックの終わりでスコープから外れます。 BEGIN ブロックはまた、サブルーチンとそこで使われている値はコンパイル時に 定義されるので、このサブルーチンはその他のどのサブルーチンからも 使える準備が出来ていて、このコードをプログラムテキスト中の他のサブルーチンと 同様に同じ場所(典型的には、コードの最後)にこのコードを置けることを保証します。 サブルーチン counter は未だにデータへのリファレンスを持っていて、 これが値にアクセスできる唯一の方法です(そしてそうする度に、値が インクリメントされます)。 $count で定義されたメモリの塊にあるデータは counter に プライベートです。

        BEGIN {
                my $count = 1;
                sub counter { $count++ }
        }

        my $start = counter();

        .... # code that calls counter();

        my $end = counter();

前述の例では、関数でプライベートな変数を作っています; ただ一つの関数だけがこのリファレンスを覚えているからです。 変数がスコープ内にある間に複数の関数を定義でき、各関数は「プライベート」 変数を共有できます。 レキシカル変数がスコープ内ではあるけれども関数の外側から変数にアクセスでき、 それに対するリファレンスすら作成できるため、これは実際には 「静的」変数ではありません。 この例では、increment_count と return_count は変数を共有しています。 片方の関数が値を加え、もう片方は単に値を返します。 これらは両方とも $count にアクセスでき、スコープ外から離れるため、 これにアクセスするその他の方法はありません。

        BEGIN {
                my $count = 1;
                sub increment_count { $count++ }
                sub return_count    { $count }
        }

ファイルプライベートな変数を宣言するには、やはりレキシカル変数が使えます。 ファイルもスコープとなるので、あるファイルで定義されたレキシカル変数は その他のファイルからは見えません。

さらなる情報については "Persistent Private Variables" in perlsub を 参照してください。 perlref でのクロージャに関する議論は、この答えには無名サブルーチンは 使っていないですが、助けになるかもしれません。 詳細については "Persistent Private Variables" in perlsub を参照してください。

動的スコープとレキシカル(または静的)スコープとの間の違いは? local() と my() との違いは?¶

local($x) は、グローバル変数 $x の古い値を保存して、 そのサブルーチンから呼び出された関数から参照できる サブルーチンの 存在する間の新たな値を代入します。 これはコンパイル時ではなく、実行時に行われるので、動的スコープと呼ばれます。 local() は常にグローバル変数に対して作用し、 パッケージ変数とか動的変数と呼ばれることもあります。

my($x) は、現在のサブルーチンにおいてのみ参照できる変数を新たに 生成します。 これはコンパイル時に行われるので、レキシカルスコープだとか 静的スコープと呼ばれます。 my() はプライベート変数に作用し、レキシカル変数とか、(間違って)静的 (スコープを持った)変数と呼ばれることもあります。

例を挙げましょう:

        sub visible {
                print "var has value $var\n";
                }

        sub dynamic {
                local $var = 'local';   # new temporary value for the still-global
                visible();              #   variable called $var
                }

        sub lexical {
                my $var = 'private';    # new private variable, $var
                visible();              # (invisible outside of sub scope)
                }

        $var = 'global';

        visible();                      # prints global
        dynamic();                      # prints local
        lexical();                      # prints global

"private"という値を出力させる方法がないということに注目してください。 これは、$var が関数の lexical() なブロックの内側でのみその値を持っていて、 そこから呼び出されたサブルーチンからは隠されてしまうからです。

まとめると、local() はあなたがプライベートと考えるようなことをローカルな 変数に対して行うようなことはありません。 これはグローバル変数に一時的な値を与えるだけです。 あなたがプライベート変数を必要としている場合、my() があなたが 探し求めているものです。

このことをより詳しく説明している "Private Variables via my()" in perlsub と "Temporary Values via local()" in perlsub を参照してください。

どうやれば同じ名前のレキシカル変数がスコープにあるときに動的変数にアクセスできますか?¶

自分のパッケージを知っているのなら、これを $Some_Pack::var と明示的に 記述できます。 $::var という記法はカレントパッケージにおける動的な $var ではなく、 "main" パッケージの中にあるそれなのだということに注意してください。

        use vars '$var';
        local $var = "global";
        my    $var = "lexical";

        print "lexical is $var\n";
        print "global  is $main::var\n";

あるいは、動的変数を現在のレキシカルスコープにもたらすために、コンパイラ 指示子 our() を使えます。

        require 5.006; # our() did not exist before 5.6
        use vars '$var';

        local $var = "global";
        my $var    = "lexical";

        print "lexical is $var\n";

        {
                our $var;
                print "global  is $var\n";
        }

深い束縛(deep binding)と浅い束縛(shallow binding)との間の違いとは?¶

深い束縛では、無名サブルーチンに置かれているレキシカル変数は そのサブルーチンが生成されたときのものと同一のものになります。 浅い束縛では、これはそのサブルーチンが呼び出されたときのスコープに 存在している同じ名前を持った変数のどれか、になります。 Perl はレキシカル変数(つまり、my() によって作られるもの)に対しては 常に深い束縛を使います。 それに対し動的変数(つまりグローバル変数か、ローカル変数か、 パッケージ変数)では、浅い束縛がなされます。 こういったものを使わない理由がもう一つあります。 その答えは "What's a closure?" を参照してください。

なぜ "my($foo) = ;" が正しく動作しないのでしょうか?¶

my() と local() は = の右辺に対してリストコンテキストを与えます。 読み込み操作 <FH> は Perlの関数や演算子の多くと同じくそれが呼び出されたときの コンテキストを見分けることができて、それに応じて適切に振る舞います。 一般的には、scalar() 関数が助けになるでしょう。 その関数は(一般的な神話とは反して)引数となるデータに対して 何も行いませんが、引数がスカラとして振る舞うように指示します。 関数のスカラ時の振る舞いが定義されていないのであれば、 当然ながらこれはあなたの助けにはなりません(sort() がそうです)。

しかしながら特定のケースにおいては、スカラコンテキストを強制するために 単に括弧を取り除く必要があります:

        local($foo) = <FILE>;       # WRONG
        local($foo) = scalar(<FILE>);   # ok
        local $foo  = <FILE>;       # right

これと同じ問題があるものの、なんにしろレキシカル変数を使うべきでしょう。

        my($foo) = <FILE>;      # WRONG
        my $foo  = <FILE>;      # right

組み込みの関数や演算子、メソッドを再定義するには?¶

なんだってそんなことをしたがるのですか? :-)

open() のようなあらかじめ定義されている関数をオーバーライドしたいのであれば、 異なるモジュールから新しい定義をインポートする必要があります。 "Overriding Built-in Functions" in perlsub を参照してください。

+ や ** のような Perl の演算子をオーバーロードしたいのであれば overload で説明されているような use overload プラグマを 使いたくなるでしょう。

親クラスにおける不明瞭なメソッド呼び出しについて考えているのなら、 "Overridden Methods" in perltoot を参照してください。

関数呼び出しを &foo で行ったときと foo() で行ったときとの違いはなんですか?¶

(brian d foy によって寄贈されました)

&foo の形で、引き続くかっこなしでサブルーチンを呼び出すと、 foo のプロトタイプを無視して、引数リスト @_ の現在の値を渡します。 以下は例です: bar サブルーチンは、引数リストを表示する &foo を 呼び出します:

        sub bar { &foo }

        sub foo { print "Args in foo are: @_\n" }

        bar( qw( a b c ) );

bar を引数付きで呼び出した場合、foo も同じ @_ を得ます:

        Args in foo are: a b c

サブルーチンをかっこ付きで呼び出した場合、引数のありなしに関わらず、 現在の @_ は使わずに、サブルーチンのプロトタイプに従います。 foo を呼び出すときにかっこをつけるように例を変更します:

        sub bar { &foo() }

        sub foo { print "Args in foo are: @_\n" }

        bar( qw( a b c ) );

今度は、foo が呼び出し元から @_ を得ていないことが分かります:

        Args in foo are:

@_ パススルー機能の主な利用法は、他のサブルーチンを呼び出すのが 主な仕事であるサブルーチンを書くためです。 更なる詳細については、perlsub を参照してください。

switch 文や case 文を作るには?¶

Perl 5.10 では、perlsyn に記述されている given-when 構造を 使ってください:

        use 5.010;

        given ( $string ) {
                when( 'Fred' )        { say "I found Fred!" }
                when( 'Barney' )      { say "I found Barney!" }
                when( /Bamm-?Bamm/ )  { say "I found Bamm-Bamm!" }
                default               { say "I don't recognize the name!" }
                };

もしピュア Perl を使って、バージョン 5.10 より前と互換性を持たせたいなら、 構造文を書くための一般的な答えは if-elsif-else を使うことです:

        for ($variable_to_test) {
                if    (/pat1/)  { }     # do something
                elsif (/pat2/)  { }     # do something else
                elsif (/pat3/)  { }     # do something else
                else            { }     # default
                }

以下の例は、パターンマッチングに基づいた単純な switch の例です。 $whatchamacallit に格納されたリファレンスの型に基づいて多様なやり方の 条件判断を行っています:

    SWITCH: for (ref $whatchamacallit) {

        /^$/            && die "not a reference";

        /SCALAR/        && do {
                                print_scalar($$ref);
                                last SWITCH;
                        };

        /ARRAY/         && do {
                                print_array(@$ref);
                                last SWITCH;
                        };

        /HASH/          && do {
                                print_hash(%$ref);
                                last SWITCH;
                        };

        /CODE/          && do {
                                warn "can't print function ref";
                                last SWITCH;
                        };

        # DEFAULT

        warn "User defined type skipped";

    }

このスタイルに関するその他の例については perlsyn を参照してください。

定数や変数の位置を変えた方が良いことがあるかもしれません。 たとえば、与えられたたくさんの答についてテストを行いたいとしましょう。 この場合大小文字を無視することもできますし、 略記することもあります。もし全て文字列が異なるキャラクターで始まっていたり、 "SEND" が "STOP" より高い優先順位を持つように調整したくいのなら マッチの順序をアレンジしたいのであれば以下に示すようなテクニックを 使うことができます。

        chomp($answer = <>);
        if    ("SEND"  =~ /^\Q$answer/i) { print "Action is send\n"  }
        elsif ("STOP"  =~ /^\Q$answer/i) { print "Action is stop\n"  }
        elsif ("ABORT" =~ /^\Q$answer/i) { print "Action is abort\n" }
        elsif ("LIST"  =~ /^\Q$answer/i) { print "Action is list\n"  }
        elsif ("EDIT"  =~ /^\Q$answer/i) { print "Action is edit\n"  }

まったく異なるアプローチに、関数のリファレンスのハッシュを作成するという やり方があります。

        my %commands = (
                "happy" => \&joy,
                "sad",  => \&sullen,
                "done"  => sub { die "See ya!" },
                "mad"   => \&angry,
        );

        print "How are you? ";
        chomp($string = <STDIN>);
        if ($commands{$string}) {
                $commands{$string}->();
        } else {
                print "No such command: $string\n";
        }

Perl 5.8 から、ソースフィルタモジュール Switch も switch と case を 使うために使えます。 Perl 5.10 には完全互換のネイティブな switch があり、また、これはソース フィルタとして実装されているので、複雑な文法の場合はいつも想定通りに 動くとは限らないからです。

どうすれば未定義な変数, 関数, メソッドに対するアクセスを捕捉できますか?¶

"Autoloading" in perlsub と "AUTOLOAD: Proxy Methods" in perltoot で 言及されている AUTOLOAD メソッドは、未定義な関数やメソッドに対する 呼び出しを捕捉させてくれます。

use warnings が有効なときに警告の引き金になるような未定義変数への アクセスがあったとき、警告をエラーに昇格させることができます。

        use warnings FATAL => qw(uninitialized);

なぜ同じファイルにあるメソッドが見つけられないのでしょうか?¶

幾つかの理由が考えられます: あなたが継承したものが混乱していているか、 メソッド名を間違えたか、あるいはオブジェクトの型が間違っていたか。 上記の場合に関する詳細は perltoot をチェックしてみてください。 $object が bless されているクラスは print ref($object) として 見分けることができます。

もう一つありうる理由は、Perl がパッケージを見いだす前にクラス名を使った 間接オブジェクト構文(find Guru "Samy" のようなもの)を使ったためでしょう。 パッケージは、それを使うよりも前に全てが定義されているようにします。 これは require 文ではなく use 文を使えば考慮されます。 あるいは、代わりに矢印記法(arrow notation、 Guru->find("Samy") のようなもの)を使うようにしてください。 オブジェクトの記法は perlobj で説明されています。

モジュールの作り方については perlmod を、間接オブジェクトの問題点に ついては "WARNING" in perlobj を確認してください。

カレントのパッケージや呼び出しパッケージはどうすればわかりますか?¶

(brian d foy によって寄贈されました)

今いるパッケージを知るには、perldata に記述されている特殊リテラル __PACKAGE__ を使ってください。 特殊リテラルは独立したトークンとしてのみ使えるので、変数のように 文字列に展開できません:

        my $current_package = __PACKAGE__;
        print "I am in package $current_package\n";

あるコードを呼び出したパッケージを知りたい場合 (おそらく Carp のように よりよい診断メッセージのためでしょう) caller 組み込み関数を 使ってください:

        sub foo {
                my @args = ...;
                my( $package, $filename, $line ) = caller;

                print "I was called from package $package\n";
                );

デフォルトでは、プログラムはパッケージ main で開始されるので、 いつもなんらかのパッケージ内にいるはずです。

これはオブジェクトが bless されているパッケージを知ることとは違います; これは現在のパッケージではないかもしれません。 この目的のためには、Perl 5.8 から標準ライブラリの一部となっている Scalar::Util の blessed を使ってください:

        use Scalar::Util qw(blessed);
        my $object_package = blessed( $object );

しかし、ほとんどの場合では、オブジェクトがそのクラスから継承していると 主張している限りは、どのパッケージが bless したかを 気にするべきではありません:

        my $is_right_class = eval { $object->isa( $package ) }; # true or false

また、Perl 5.10 以降では、オブジェクトがロールを扱うかどうかを見るために 継承をチェックする必要はありません。 このために、UNIVERSAL にある DOES を使えます:

        my $class_does_it = eval { $object->DOES( $role ) }; # true or false

安全に isa を DOES に置き換えられます (しかし逆は真ではありません)。

Perl プログラムの大きなブロックをコメントアウトするには?¶

(brian d foy によって寄贈されました)

Perl の複数行をコメントアウトするための、汚いけれども簡単な方法は、 コメントアウトしたい部分を Pod 指示子で囲むことです。 これらの指示子は、行の先頭、かつ、Perl が新しい文が始まると 想定する場所に置く必要があります(従って、# コメントのように文の途中には 置けません)。 Pod セクションの終了を示す =cut でコメントを終了します:

        =pod

        my $object = NotGonnaHappen->new();

        ignored_sub();

        $wont_be_assigned = 37;

        =cut

汚いけれども簡単な方法は、ソースにコメントされたコードを残す予定が ない(つまりいずれ消す)場合にのみうまく働きます。 もし Pod パーサを使うと、複数行コメントは Pod によって表示されます。 よりよい方法は、Pod パーサからも隠すことです。

=begin 指示子で、段落を特定の目的のためにマークできます。 Pod パーサがこれを扱えない場合、単に無視されます。 コメントは comment でラベル付けします。 コメントの終了は同じラベルで =end を使います。 Pod コメントから Perl コードに戻るにはやはり =cut が必要です:

        =begin comment

        my $object = NotGonnaHappen->new();

        ignored_sub();

        $wont_be_assigned = 37;

        =end comment

        =cut

Pod に関するさらなる情報については、perlpod と perlpodspec を 調べてください。

パッケージをクリアするには?¶

Mark-Jason Dominus による以下のコードを使います:

        sub scrub_package {
                no strict 'refs';
                my $pack = shift;
                die "Shouldn't delete main package"
                        if $pack eq "" || $pack eq "main";
                my $stash = *{$pack . '::'}{HASH};
                my $name;
                foreach $name (keys %$stash) {
                        my $fullname = $pack . '::' . $name;
                        # Get rid of everything with that name.
                        undef $$fullname;
                        undef @$fullname;
                        undef %$fullname;
                        undef &$fullname;
                        undef *$fullname;
        }
        }

あるいは、あなたが使っている Perl が最近のリリースのものであれば、 単に Symbol::delete_package() という関数を代わりに使うことができます。

変数を変数名として使うには?¶

初心者はしばしば変数名が入った変数を使いたいと考えます。

        $fred    = 23;
        $varname = "fred";
        ++$$varname;         # $fred now 24

これは 時には 動作します。 しかしこれは二つの理由により悪いアイデアです。

一つ目の理由は、このテクニックは グローバル変数でのみ動作する からです。 つまり、もし上記の例において $fred が my() で作成されたレキシカル変数の場合、 このコードは全く動作しません。 プライベートなレキシカル変数を飛ばして、思いがけずグローバル変数に アクセスすることになります。 グローバル変数は、簡単に衝突し、一般に拡張性がなく、混乱するコードを 作ることになるので、よくないものです。

シンボリックリファレンスは use strict プラグマの元では禁止されます。 これは真のリファレンスではないので、リファレンスカウントに含まれず、 ガベージゴレクションもされません。

変数に他の変数の名前を記録するというのがよくない考えであるという 別の理由としては、このような疑問はしばしば Perl のデータ構造、 特にハッシュに関する理解の不足から発生するからです。 シンボリックリファレンスを使うことによって、ユーザー定義のハッシュの代わりに パッケージのシンボルテーブルハッシュ(%main:: など)を使うことができます。 解決法は、代わりに自分自身のハッシュや真のリファレンスを使うことです。

        $USER_VARS{"fred"} = 23;
        $varname = "fred";
        $USER_VARS{$varname}++;  # not $$varname++

ここではシンボリックリファレンスの代わりに %USER_VARS ハッシュを 使っています。 時々これはユーザーから文字列を変数へのリファレンスとして読み込んで、 それを perl プログラムの変数の値として拡張することがあります。 これもよくない考えです。 なぜなら、プログラムが指定する名前空間とユーザーが指定する名前空間を 融合させることになるからです。 以下のように文字列を読み込んであなたのプログラムの変数の実際の内容の ために拡張するのではなく:

        $str = 'this has a $fred and $barney in it';
        $str =~ s/(\$\w+)/$1/eeg;                 # need double eval

%USER_VARS のようなハッシュを保存し、このハッシュのエントリを参照する 変数リファレンスを持つよりよい方法です:

        $str =~ s/\$(\w+)/$USER_VARS{$1}/g;   # no /e here at all

これは前述の手法よりも、より高速で、より明快で、より安全です。 もちろん、ドル記号を使う必要はありません。 パーセント記号で囲むなどのより混乱しにくい独自のスキームを使えます。

        $str = 'this has a %fred% and %barney% in it';
        $str =~ s/%(\w+)%/$USER_VARS{$1}/g;   # no /e here at all

人々が時々変数名が入った変数を欲しがるもう一つの理由は、 ハッシュを使った適切なデータ構造を構築する方法を知らないからです。 例えば、プログラムで %fred と %barney が必要で、 さらにこれらを名前で参照するスカラへ変数が必要だとします。

        $name = "fred";
        $$name{WIFE} = "wilma";     # set %fred

        $name = "barney";
        $$name{WIFE} = "betty"; # set %barney

これはやはりシンボリックリファレンスで、やはり上記の問題を抱えたままです。 以下のように書けば遥かに改善します:

        $folks{"fred"}{WIFE}   = "wilma";
        $folks{"barney"}{WIFE} = "betty";

そして始めるのに単に多段ハッシュを使います。

唯一あなたが完全にシンボリックリファレンスを 使わなければならない 場合は、 シンボルテーブルに対するリファレンスが必要なときだけです。 これは、フォーマット名といったものに対する真のリファレンスを得ることが できないからです。 そうすることはメソッド呼び出しのためにも重要です。 なぜなら名前解決のためにシンボルテーブルを使うからです。

これらの場合、一時的に strict 'refs' にして シンボルテーブルを使うようにできます。 例えば:

        @colors = qw(red blue green yellow orange purple violet);
        for my $name (@colors) {
                no strict 'refs';  # renege for the block
                *$name = sub { "<FONT COLOR='$name'>@_</FONT>" };
        }

これら(red(), blue(), green() など)の関数全ては別々に現れますが、 クロージャの中の実際のコードは一回だけコンパイルされます。

シンボルテーブルを直接操作するためにシンボリックリファレンスを 使いたくなることがあるかもしれません。 これには、フォーマット、ハンドル、サブルーチンには関係ありません。 これらは常にグローバルだからです--これらに my() を使うことはできません。 おそらく、スカラ、配列、ハッシュのために--そして普通はサブルーチンの ために--だけ、ハードリファレンスが必要でしょう。

"bad interpreter" とはどういう意味ですか?¶

(brian d foy によって寄贈されました)

"bad interpreter" というメッセージは perl ではなく、シェルが出力しています。 実際のメッセージはプラットフォーム、シェル、ロケール設定によって 様々です。

"bad interpreter - no such file or directory" と表示されたら、perl スクリプトの最初の行 ("#!" 行) に perl (あるいはスクリプトを実行する 機能のあるその他のプログラム) への正しいパスが含まれていません。 スクリプトをあるマシンから、perl のパスが異なる -- 例えば /usr/bin/perl と /usr/local/bin/perl -- 他のマシンに移動させた場合に時々起こります。 これはまた、元のマシンの行終端が CRLF で、移動先のマシンが LF のみの場合にも 起こります; シェルが /usr/bin/perl<CR> を探そうとしますが、失敗します。

"bad interpreter: Permission denied" と表示されたら、スクリプトを 実行可能にする必要があります。

どちらの場合でも、明示的に perl でスクリプトを実行できるようにするべきです:

        % perl script.pl

"perl: command not found" のようなメッセージが出た場合、perl が PATH に ありません; つまりおそらくは perl の位置があなたの想定している 場所ではないことも意味しているので、#! 行を調整する必要があります。

AUTHOR AND COPYRIGHT¶

Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and other authors as noted. All rights reserved.

This documentation is free; you can redistribute it and/or modify it under the same terms as Perl itself.

Irrespective of its distribution, all code examples in this file are hereby placed into the public domain. You are permitted and encouraged to use this code in your own programs for fun or for profit as you see fit. A simple comment in the code giving credit would be courteous but is not required.