Mojolicious::Guides::Cookbook - Cooking with Mojolicious

This document contains many fun recipes for cooking with Mojolicious.

Essentials every Mojolicious developer should know.

A blocking operation is a subroutine that blocks the execution of the calling subroutine until the subroutine is finished.

A non-blocking operation on the other hand lets the calling subroutine continue execution even though the subroutine is not yet finished. Instead of waiting, the calling subroutine passes along a callback to be executed once the subroutine is finished, this is called continuation-passing style.

While Mojolicious has been designed from the ground up for non-blocking I/O and event loops, it is not possible to magically make Perl code non-blocking. You have to use specialized non-blocking code available through modules like Mojo::IOLoop and Mojo::UserAgent, or third-party event loops. You can wrap your blocking code in subprocesses though to prevent it from interfering with your non-blocking code.

An event loop is basically a loop that continually tests for external events and executes the appropriate callbacks to handle them, it is often the main loop in a program. Non-blocking tests for readability/writability of file descriptors and timers are commonly used events for highly scalable network servers, because they allow a single process to handle thousands of client connections concurrently.

In Mojolicious this event loop is Mojo::IOLoop.

A reverse proxy architecture is a deployment technique used in many production environments, where a reverse proxy server is put in front of your application to act as the endpoint accessible by external clients. It can provide a lot of benefits, like terminating SSL connections from the outside, limiting the number of concurrent open sockets towards the Mojolicious application (or even using Unix sockets), balancing load across multiple instances, or supporting several applications through the same IP/port.

                   ..........................................
                   :                                        :
   +--------+      :  +-----------+      +---------------+  :
   |        |-------->|           |      |               |  :
   | client |      :  |  reverse  |----->|  Mojolicious  |  :
   |        |<--------|   proxy   |      |  application  |  :
   +--------+      :  |           |<-----|               |  :
                   :  +-----------+      +---------------+  :
                   :                                        :
                   .. system boundary (e.g. same host) ......

This setup introduces some problems, though: the application will receive requests from the reverse proxy instead of the original client; the address/hostname where your application lives internally will be different from the one visible from the outside; and if terminating SSL, the reverse proxy exposes services via HTTPS while using HTTP towards the Mojolicious application.

As an example, compare a sample request from the client and what the Mojolicious application receives:

   client                       reverse proxy                Mojolicious app
    __|__              _______________|______________             ____|____
   /     \            /                              \           /         \
   1.2.3.4 --HTTPS--> api.example.com      10.20.30.39 --HTTP--> 10.20.30.40

However, now the client address is no longer available (which might be useful for analytics, or Geo-IP) and URLs generated via "url_for" in Mojolicious::Controller will look like this:

instead of something meaningful for the client, like this:

To solve these problems, you can configure your reverse proxy to send the missing data (see "Nginx" and "Apache/mod_proxy") and tell your application about it by setting the environment variable MOJO_REVERSE_PROXY. For finer control, "Rewriting" includes examples of how the changes could be implemented manually.

Getting Mojolicious and Mojolicious::Lite applications running on different platforms. Note that many real-time web features are based on the Mojo::IOLoop event loop, and therefore require one of the built-in web servers to be able to use them to their full potential.

Mojolicious contains a very portable non-blocking I/O HTTP and WebSocket server with Mojo::Server::Daemon. It is usually used during development and in the construction of more advanced web servers, but is solid and fast enough for small to mid sized applications.

It is available to every application through the command Mojolicious::Command::daemon, which has many configuration options and is known to work on every platform Perl works on with its single-process architecture.

  $ ./script/my_app daemon -h
  ...List of available options...

Another huge advantage is that it supports TLS and WebSockets out of the box, a development certificate for testing purposes is built right in, so it just works, but you can specify all listen locations supported by "listen" in Mojo::Server::Daemon.

To manage the web server with systemd, you can use a unit configuration file like this.

On UNIX platforms you can also add pre-forking to the built-in web server and switch to a multi-process architecture with Mojolicious::Command::prefork, to take advantage of multiple CPU cores and copy-on-write memory management.

Since all built-in web servers are based on the Mojo::IOLoop event loop, they scale best with non-blocking operations. But if your application for some reason needs to perform many blocking operations, you can improve performance by increasing the number of worker processes and decreasing the number of concurrent connections each worker is allowed to handle (often as low as 1).

During startup your application is preloaded in the manager process, which does not run an event loop, so you can use "next_tick" in Mojo::IOLoop to run code whenever a new worker process has been forked and its event loop gets started.

And to manage the pre-forking web server with systemd, you can use a unit configuration file like this.

After reading the Mojolicious::Guides::Tutorial, you should already be familiar with Mojo::Server::Morbo.

It is basically a restarter that forks a new Mojo::Server::Daemon web server whenever a file in your project changes, and should therefore only be used during development. To start applications with it you can use the morbo script.

For bigger applications Mojolicious contains the UNIX optimized pre-forking web server Hypnotoad, which can take advantage of multiple CPU cores and copy-on-write memory management to scale up to thousands of concurrent client connections.

It is based on the Mojo::Server::Prefork web server, which adds pre-forking to Mojo::Server::Daemon, but optimized specifically for production environments out of the box. To start applications with it you can use the hypnotoad script, which listens on port 8080, automatically daemonizes the server process and defaults to production mode for Mojolicious and Mojolicious::Lite applications.

Many configuration settings can be tweaked right from within your application with "config" in Mojolicious, for a full list see "SETTINGS" in Mojo::Server::Hypnotoad.

Or just add a hypnotoad section to your Mojolicious::Plugin::Config or Mojolicious::Plugin::JSONConfig configuration file.

But one of its biggest advantages is the support for effortless zero downtime software upgrades (hot deployment). That means you can upgrade Mojolicious, Perl or even system libraries at runtime without ever stopping the server or losing a single incoming connection, just by running the command above again.

  $ hypnotoad ./script/my_app
  Starting hot deployment for Hypnotoad server 31841.

You might also want to enable proxy support if you're using Hypnotoad behind a reverse proxy. This allows Mojolicious to automatically pick up the X-Forwarded-For and X-Forwarded-Proto headers.

To manage Hypnotoad with systemd, you can use a unit configuration file like this.

Hypnotoad makes zero downtime software upgrades (hot deployment) very simple, as you can see above, but on modern operating systems that support the SO_REUSEPORT socket option, there is also another method available that works with all built-in web servers.

All you have to do, is to start a second web server listening to the same port, and stop the first web server gracefully afterwards.

Just remember that both web servers need to be started with the reuse parameter.

One of the most popular setups these days is Hypnotoad behind an Nginx reverse proxy, which even supports WebSockets in newer versions.

Another good reverse proxy is Apache with mod_proxy, the configuration looks quite similar to the Nginx one above. And if you need WebSocket support, newer versions come with mod_proxy_wstunnel.

CGI is supported out of the box and your Mojolicious application will automatically detect that it is executed as a CGI script. Its use in production environments is discouraged though, because as a result of how CGI works, it is very slow and many web servers are making it exceptionally hard to configure properly. Additionally, many real-time web features, such as WebSockets, are not available.

PSGI is an interface between Perl web frameworks and web servers, and Plack is a Perl module and toolkit that contains PSGI middleware, helpers and adapters to web servers. PSGI and Plack are inspired by Python's WSGI and Ruby's Rack. Mojolicious applications are ridiculously simple to deploy with Plack, but be aware that many real-time web features, such as WebSockets, are not available.

Plack provides many server and protocol adapters for you to choose from, such as FCGI, uWSGI and mod_perl.

The MOJO_REVERSE_PROXY environment variable can be used to enable proxy support, this allows Mojolicious to automatically pick up the X-Forwarded-For and X-Forwarded-Proto headers.

If an older server adapter is unable to correctly detect the application home directory, you can simply use the MOJO_HOME environment variable.

There is no need for a .psgi file, just point the server adapter at your application script, it will automatically act like one if it detects the presence of a PLACK_ENV environment variable.

Wrapper scripts like myapp.fcgi are a great way to separate deployment and application logic.

Mojo::Server::PSGI can be used directly to load and customize applications in the wrapper script.

But you could even use middleware right in your application.

Sometimes you might have to deploy your application in a blackbox environment where you can't just change the server configuration or behind a reverse proxy that passes along additional information with X-Forwarded-* headers. In such cases you can use the hook "before_dispatch" in Mojolicious to rewrite incoming requests.

  # Change scheme if "X-Forwarded-HTTPS" header is set
  $app->hook(before_dispatch => sub {
    my $c = shift;
    $c->req->url->base->scheme('https')
      if $c->req->headers->header('X-Forwarded-HTTPS');
  });

Since reverse proxies generally don't pass along information about path prefixes your application might be deployed under, rewriting the base path of incoming requests is also quite common. This allows "url_for" in Mojolicious::Controller for example, to generate portable URLs based on the current environment.

  # Move first part and slash from path to base path in production mode
  $app->hook(before_dispatch => sub {
    my $c = shift;
    push @{$c->req->url->base->path->trailing_slash(1)},
      shift @{$c->req->url->path->leading_slash(0)};
  }) if $app->mode eq 'production';

Mojo::URL objects are very easy to manipulate, just make sure that the URL (foo/bar?baz=yada), which represents the routing destination, is always relative to the base URL (http://example.com/myapp/), which represents the deployment location of your application.

From time to time you might want to reuse parts of Mojolicious applications like configuration files, database connection or helpers for other scripts, with this little Mojo::Server based mock server you can just embed them.

  # Load application with mock server
  my $server = Mojo::Server->new;
  my $app = $server->load_app('./myapp.pl');

  # Access fully initialized application
  say for @{$app->static->paths};
  say $app->config->{secret_identity};
  say $app->dumper({just => 'a helper test'});
  say $app->build_controller->render_to_string(template => 'foo');

The plugin Mojolicious::Plugin::Mount uses this functionality to allow you to combine multiple applications into one and deploy them together.

You can also use "one_tick" in Mojo::IOLoop to embed the built-in web server Mojo::Server::Daemon into alien environments like foreign event loops that for some reason can't just be integrated with a new reactor backend.

  # Normal action
  get '/' => {text => 'Hello World!'};

  # Connect application with web server and start accepting connections
  my $daemon
    = Mojo::Server::Daemon->new(app => app, listen => ['http://*:8080']);
  $daemon->start;

  # Call "one_tick" repeatedly from the alien environment
  Mojo::IOLoop->one_tick while 1;

The real-time web is a collection of technologies that include Comet (long polling), EventSource and WebSockets, which allow content to be pushed to consumers with long-lived connections as soon as it is generated, instead of relying on the more traditional pull model. All built-in web servers use non-blocking I/O and are based on the Mojo::IOLoop event loop, which provides many very powerful features that allow real-time web applications to scale up to thousands of concurrent client connections.

Since Mojo::UserAgent is also based on the Mojo::IOLoop event loop, it won't block the built-in web servers when used non-blocking, even for high latency backend web services.

  # Search MetaCPAN for "mojolicious"
  get '/' => sub {
    my $c = shift;
    $c->ua->get('fastapi.metacpan.org/v1/module/_search?q=mojolicious' => sub {
      my ($ua, $tx) = @_;
      $c->render('metacpan', hits => $tx->result->json->{hits}{hits});
    });
  };

The callback passed to "get" in Mojo::UserAgent will be executed once the request to the backend web service has been finished, this is called continuation-passing style.

Multiple non-blocking operations, such as concurrent requests, can be easily synchronized with promises and "all" in Mojo::Promise. You create Mojo::Promise objects manually or use methods like "get_p" in Mojo::UserAgent that create them for you.

  # Search MetaCPAN for "mojo" and "minion"
  get '/' => sub {
    my $c = shift;

    # Create two promises
    my $url   = Mojo::URL->new('fastapi.metacpan.org/v1/module/_search');
    my $mojo   = $c->ua->get_p($url->clone->query({q => 'mojo'}));
    my $minion = $c->ua->get_p($url->clone->query({q => 'minion'}));

    # Render a response once both promises have been resolved
    Mojo::Promise->all($mojo, $minion)->then(sub {
      my ($mojo, $minion) = @_;
      $c->render(json => {
        mojo   => $mojo->[0]->result->json('/hits/hits/0/_source/release'),
        minion => $minion->[0]->result->json('/hits/hits/0/_source/release')
      });
    })->catch(sub {
      my $err = shift;
      $c->reply->exception($err);
    })->wait;
  };

To create promises manually you just wrap your continuation-passing style APIs in functions that return promises. Here's an example for how "get_p" in Mojo::UserAgent works internally.

  # Wrap a user agent method with a promise
  my $ua = Mojo::UserAgent->new;
  sub get_p {
    my $promise = Mojo::Promise->new;
    $ua->get(@_ => sub {
      my ($ua, $tx) = @_;
      my $err = $tx->error;
      $promise->resolve($tx) if !$err || $err->{code};
      $promise->reject($err->{message});
    });
    return $promise;
  }

  # Use our new promise generating function
  get_p('https://mojolicious.org')->then(sub {
    my $tx = shift;
    say $tx->result->dom->at('title')->text;
  })->wait;

Promises have three states, they start out as pending and you call "resolve" in Mojo::Promise to transition them to fulfilled, or "reject" in Mojo::Promise to transition them to rejected.

Timers, another primary feature of the event loop, are created with "timer" in Mojo::IOLoop and can, for example, be used to delay rendering of a response, and unlike sleep, won't block any other requests that might be processed concurrently.

  # Wait 3 seconds before rendering a response
  get '/' => sub {
    my $c = shift;
    Mojo::IOLoop->timer(3 => sub {
      $c->render(text => 'Delayed by 3 seconds!');
    });
  };

Recurring timers created with "recurring" in Mojo::IOLoop are slightly more powerful, but need to be stopped manually, or they would just keep getting emitted.

  # Count to 5 in 1 second steps
  get '/' => sub {
    my $c = shift;

    # Start recurring timer
    my $i = 1;
    my $id = Mojo::IOLoop->recurring(1 => sub {
      $c->write_chunk($i);
      $c->finish if $i++ == 5;
    });

    # Stop recurring timer
    $c->on(finish => sub { Mojo::IOLoop->remove($id) });
  };

Timers are not tied to a specific request or connection, and can even be created at startup time.

  # Check title in the background every 10 seconds
  my $title = 'Got no title yet.';
  Mojo::IOLoop->recurring(10 => sub {
    app->ua->get('https://mojolicious.org' => sub {
      my ($ua, $tx) = @_;
      $title = $tx->result->dom->at('title')->text;
    });
  });

  # Show current title
  get '/' => sub {
    my $c = shift;
    $c->render(json => {title => $title});
  };

Just remember that all these non-blocking operations are processed cooperatively, so your callbacks shouldn't block for too long.

You can also use subprocesses, created with "subprocess" in Mojo::IOLoop, to perform computationally expensive operations without blocking the event loop.

  # Operation that would block the event loop for 5 seconds
  get '/' => sub {
    my $c = shift;
    Mojo::IOLoop->subprocess(
      sub {
        my $subprocess = shift;
        sleep 5;
        return '♥', 'Mojolicious';
      },
      sub {
        my ($subprocess, $err, @results) = @_;
        $c->reply->exception($err) and return if $err;
        $c->render(text => "I $results[0] $results[1]!");
      }
    );
  };

The first callback will be executed in a child process, without blocking the event loop of the parent process. The results of the first callback will then be shared between both processes, and the second callback executed in the parent process.

Since timers and other non-blocking operations are running solely in the event loop, outside of the application, exceptions that get thrown in callbacks can't get caught and handled automatically. But you can handle them manually by subscribing to the event "error" in Mojo::Reactor or catching them inside the callback.

  # Forward error messages to the application log
  Mojo::IOLoop->singleton->reactor->on(error => sub {
    my ($reactor, $err) = @_;
    app->log->error($err);
  });

  # Exception only gets logged (and connection times out)
  get '/connection_times_out' => sub {
    my $c = shift;
    Mojo::IOLoop->timer(2 => sub {
      die 'This request will not be getting a response';
    });
  };

  # Exception gets caught and handled
  get '/catch_exception' => sub {
    my $c = shift;
    Mojo::IOLoop->timer(2 => sub {
      eval { die 'This request will be getting a response' };
      $c->reply->exception($@) if $@;
    });
  };

A default subscriber that turns all errors into warnings will usually be added by Mojo::IOLoop as a fallback.

During development or for applications where crashing is simply preferable, you can also make every exception that gets thrown in a callback fatal by removing all of its subscribers.

The WebSocket protocol offers full bi-directional low-latency communication channels between clients and servers. Receive messages just by subscribing to events such as "message" in Mojo::Transaction::WebSocket with "on" in Mojolicious::Controller and return them with "send" in Mojolicious::Controller.

  # Template with browser-side code
  get '/' => 'index';

  # WebSocket echo service
  websocket '/echo' => sub {
    my $c = shift;

    # Opened
    $c->app->log->debug('WebSocket opened');

    # Increase inactivity timeout for connection a bit
    $c->inactivity_timeout(300);

    # Incoming message
    $c->on(message => sub {
      my ($c, $msg) = @_;
      $c->send("echo: $msg");
    });

    # Closed
    $c->on(finish => sub {
      my ($c, $code, $reason) = @_;
      $c->app->log->debug("WebSocket closed with status $code");
    });
  };

        // Incoming messages
        ws.onmessage = function (event) {
          document.body.innerHTML += event.data + '<br/>';
        };

        // Outgoing messages
        ws.onopen = function (event) {
          window.setInterval(function () { ws.send('Hello Mojo!') }, 1000);
        };
      </script>
    </body>
  </html>

The event "finish" in Mojo::Transaction::WebSocket will be emitted right after the WebSocket connection has been closed.

You can activate permessage-deflate compression with "with_compression" in Mojo::Transaction::WebSocket, this can result in much better performance, but also increases memory usage by up to 300KiB per connection.

You can also use "with_protocols" in Mojo::Transaction::WebSocket to negotiate a subprotocol.

EventSource is a special form of long polling where you can use "write" in Mojolicious::Controller to directly send DOM events from servers to clients. It is uni-directional, that means you will have to use Ajax requests for sending data from clients to servers, the advantage however is low infrastructure requirements, since it reuses the HTTP protocol for transport.

  # Template with browser-side code
  get '/' => 'index';

  # EventSource for log messages
  get '/events' => sub {
    my $c = shift;

    # Increase inactivity timeout for connection a bit
    $c->inactivity_timeout(300);

    # Change content type and finalize response headers
    $c->res->headers->content_type('text/event-stream');
    $c->write;

    # Subscribe to "message" event and forward "log" events to browser
    my $cb = $c->app->log->on(message => sub {
      my ($log, $level, @lines) = @_;
      $c->write("event:log\ndata: [$level] @lines\n\n");
    });

    # Unsubscribe from "message" event again once we are done
    $c->on(finish => sub {
      my $c = shift;
      $c->app->log->unsubscribe(message => $cb);
    });
  };

        // Subscribe to "log" event
        events.addEventListener('log', function (event) {
          document.body.innerHTML += event.data + '<br/>';
        }, false);
      </script>
    </body>
  </html>

The event "message" in Mojo::Log will be emitted for every new log message and the event "finish" in Mojo::Transaction right after the transaction has been finished.

Mojolicious contains a very sophisticated event system based on Mojo::EventEmitter, with ready-to-use events on almost all layers, and which can be combined to solve some of the hardest problems in web development.

  # Intercept multipart uploads and log each chunk received
  hook after_build_tx => sub {
    my $tx = shift;

    # Subscribe to "upgrade" event to identify multipart uploads
    weaken $tx;
    $tx->req->content->on(upgrade => sub {
      my ($single, $multi) = @_;
      return unless $tx->req->url->path->contains('/upload');

      # Subscribe to "part" event to find the right one
      $multi->on(part => sub {
        my ($multi, $single) = @_;

        # Subscribe to "body" event of part to make sure we have all headers
        $single->on(body => sub {
          my $single = shift;

          # Make sure we have the right part and replace "read" event
          return unless $single->headers->content_disposition =~ /example/;
          $single->unsubscribe('read')->on(read => sub {
            my ($single, $bytes) = @_;

            # Log size of every chunk we receive
            app->log->debug(length($bytes) . ' bytes uploaded');
          });
        });
      });
    });
  };

  # Upload form in DATA section
  get '/' => 'index';

  # Streaming multipart upload
  post '/upload' => {text => 'Upload was successful.'};

Internally, the Mojo::IOLoop event loop can use multiple reactor backends, EV for example, will be automatically used if possible. Which in turn allows other event loops like AnyEvent to just work.

  # Wait 3 seconds before rendering a response
  get '/' => sub {
    my $c = shift;
    my $w;
    $w = AE::timer 3, 0, sub {
      $c->render(text => 'Delayed by 3 seconds!');
      undef $w;
    };
  };

Who actually controls the event loop backend is not important.

  # Search MetaCPAN for "mojolicious"
  my $cv = AE::cv;
  my $ua = Mojo::UserAgent->new;
  $ua->get('fastapi.metacpan.org/v1/module/_search?q=mojolicious' => sub {
    my ($ua, $tx) = @_;
    $cv->send($tx->result->json('/hits/hits/0/_source/release'));
  });
  say $cv->recv;

You could, for example, just embed the built-in web server into an AnyEvent application.

  # Normal action
  get '/' => {text => 'Hello World!'};

  # Connect application with web server and start accepting connections
  my $daemon
    = Mojo::Server::Daemon->new(app => app, listen => ['http://*:8080']);
  $daemon->start;

  # Let AnyEvent take control
  AE::cv->recv;

When we say Mojolicious is a web framework we actually mean it, with Mojo::UserAgent there's a full featured HTTP and WebSocket user agent built right in.

Requests can be performed very comfortably with methods like "get" in Mojo::UserAgent, and always result in a Mojo::Transaction::HTTP object, which has many useful attributes and methods. You can check for connection errors with "result" in Mojo::Transaction, or access HTTP request and response information directly through "req" in Mojo::Transaction and "res" in Mojo::Transaction.

  # Request a resource and make sure there were no connection errors
  my $ua = Mojo::UserAgent->new;
  my $tx = $ua->get('mojolicious.org/perldoc/Mojo' => {Accept => 'text/plain'});
  my $res = $tx->result;

  # Decide what to do with its representation
  if    ($res->is_success)  { say $res->body }
  elsif ($res->is_error)    { say $res->message }
  elsif ($res->code == 301) { say $res->headers->location }
  else                      { say 'Whatever...' }

While methods like "is_success" in Mojo::Message::Response and "is_error" in Mojo::Message::Response serve as building blocks for more sophisticated REST clients.

Scraping information from websites has never been this much fun before. The built-in HTML/XML parser Mojo::DOM is accessible through "dom" in Mojo::Message and supports all CSS selectors that make sense for a standalone parser, it can be a very powerful tool especially for testing web application.

  # Fetch website
  my $ua = Mojo::UserAgent->new;
  my $res = $ua->get('mojolicious.org/perldoc')->result;

  # Extract title
  say 'Title: ', $res->dom->at('head > title')->text;

  # Extract headings
  $res->dom('h1, h2, h3')->each(sub { say 'Heading: ', shift->all_text });

  # Visit all nodes recursively to extract more than just text
  for my $n ($res->dom->descendant_nodes->each) {

    # Text or CDATA node
    print $n->content if $n->type eq 'text' || $n->type eq 'cdata';

    # Also include alternate text for images
    print $n->{alt} if $n->type eq 'tag' && $n->tag eq 'img';
  }

For a full list of available CSS selectors see "SELECTORS" in Mojo::DOM::CSS.

Most web services these days are based on the JSON data-interchange format. That's why Mojolicious comes with the possibly fastest pure-Perl implementation Mojo::JSON built right in, which is accessible through "json" in Mojo::Message.

  # Fresh user agent
  my $ua = Mojo::UserAgent->new;

  # Search MetaCPAN for "mojolicious" and list latest releases
  my $url = Mojo::URL->new('http://fastapi.metacpan.org/v1/release/_search');
  $url->query({q => 'mojolicious', sort => 'date:desc'});
  for my $hit (@{$ua->get($url)->result->json->{hits}{hits}}) {
    say "$hit->{_source}{name} ($hit->{_source}{author})";
  }

You can just add username and password to the URL, an Authorization header will be automatically generated.

Mojo::UserAgent can automatically follow redirects, the event "start" in Mojo::UserAgent allows you direct access to each transaction right after they have been initialized and before a connection gets associated with them.

  # User agent following up to 10 redirects
  my $ua = Mojo::UserAgent->new(max_redirects => 10);

  # Add a witty header to every request
  $ua->on(start => sub {
    my ($ua, $tx) = @_;
    $tx->req->headers->header('X-Bender' => 'Bite my shiny metal ass!');
    say 'Request: ', $tx->req->url->clone->to_abs;
  });

  # Request that will most likely get redirected
  say 'Title: ', $ua->get('google.com')->result->dom->at('head > title')->text;

This even works for proxy CONNECT requests.

Content generators can be registered with "add_generator" in Mojo::UserAgent::Transactor to generate the same type of content repeatedly for multiple requests.

  # Add "stream" generator
  my $ua = Mojo::UserAgent->new;
  $ua->transactor->add_generator(stream => sub {
    my ($transactor, $tx, $path) = @_;
    $tx->req->content->asset(Mojo::Asset::File->new(path => $path));
  });

  # Send multiple files streaming via PUT and POST
  $ua->put('http://example.com/upload'  => stream => '/home/sri/mojo.png');
  $ua->post('http://example.com/upload' => stream => '/home/sri/minion.png');

The json, form and multipart content generators are always available.

  # Send "application/json" content via PATCH
  my $ua = Mojo::UserAgent->new;
  my $tx = $ua->patch('http://api.example.com' => json => {foo => 'bar'});

  # Send query parameters via GET
  my $tx2 = $ua->get('search.example.com' => form => {q => 'test'});

  # Send "application/x-www-form-urlencoded" content via POST
  my $tx3 = $ua->post('http://search.example.com' => form => {q => 'test'});

  # Send "multipart/form-data" content via PUT
  my $tx4 = $ua->put(
    'upload.example.com' => form => {test => {content => 'Hello World!'}});

  # Send custom multipart content via PUT
  my $tx5 = $ua->put('api.example.com' => multipart => ['Hello', 'World!']);

For more information about available content generators see also "tx" in Mojo::UserAgent::Transactor.

When downloading large files with Mojo::UserAgent you don't have to worry about memory usage at all, because it will automatically stream everything above 250KiB into a temporary file, which can then be moved into a permanent file with "save_to" in Mojo::Message.

  # Fetch the latest Mojolicious tarball
  my $ua = Mojo::UserAgent->new(max_redirects => 5);
  my $tx = $ua->get('https://www.github.com/mojolicious/mojo/tarball/master');
  $tx->result->save_to('mojo.tar.gz');

To protect you from excessively large files there is also a limit of 2GiB by default, which you can tweak with the attribute "max_response_size" in Mojo::UserAgent.

  # Increase limit to 10GiB
  $ua->max_response_size(10737418240);

Uploading a large file is even easier.

  # Upload file via POST and "multipart/form-data"
  my $ua = Mojo::UserAgent->new;
  $ua->post('example.com/upload' =>
    form => {image => {file => '/home/sri/hello.png'}});

And once again you don't have to worry about memory usage, all data will be streamed directly from the file.

Receiving a streaming response can be really tricky in most HTTP clients, but Mojo::UserAgent makes it actually easy.

  # Accept responses of indefinite size
  my $ua = Mojo::UserAgent->new(max_response_size => 0);

  # Build a normal transaction
  my $tx = $ua->build_tx(GET => 'http://example.com');

  # Replace "read" events to disable default content parser
  $tx->res->content->unsubscribe('read')->on(read => sub {
    my ($content, $bytes) = @_;
    say "Streaming: $bytes";
  });

  # Process transaction
  $tx = $ua->start($tx);

The event "read" in Mojo::Content will be emitted for every chunk of data that is received, even chunked transfer encoding and gzip content encoding will be handled transparently if necessary.

Sending a streaming request is almost just as easy.

  # Build a normal transaction
  my $ua = Mojo::UserAgent->new;
  my $tx = $ua->build_tx(GET => 'http://example.com');

  # Prepare body
  my $body = 'Hello World!';
  $tx->req->headers->content_length(length $body);

  # Start writing directly with a drain callback
  my $drain;
  $drain = sub {
    my $content = shift;
    my $chunk = substr $body, 0, 1, '';
    $drain = undef unless length $body;
    $content->write($chunk, $drain);
  };
  $tx->req->content->$drain;

  # Process transaction
  $tx = $ua->start($tx);

The drain callback passed to "write" in Mojo::Content will be executed whenever the entire previous chunk of data has actually been written.

Mojo::UserAgent has been designed from the ground up to be non-blocking, the whole blocking API is just a simple convenience wrapper. Especially for high latency tasks like web crawling this can be extremely useful, because you can keep many concurrent connections active at the same time.

  # Concurrent non-blocking requests
  my $ua = Mojo::UserAgent->new;
  $ua->get('https://metacpan.org/search?q=mojo' => sub {
    my ($ua, $mojo) = @_;
    say $mojo->result->dom->at('title')->text;
  });
  $ua->get('https://metacpan.org/search?q=minion' => sub {
    my ($ua, $minion) = @_;
    say $minion->result->dom->at('title')->text;
  });

  # Start event loop if necessary
  Mojo::IOLoop->start unless Mojo::IOLoop->is_running;

But don't try to open too many connections to one server at the same time, it might get overwhelmed. Better use a queue to process requests in smaller batches.

  # User agent with a custom name, following up to 5 redirects
  my $ua = Mojo::UserAgent->new(max_redirects => 5);
  $ua->transactor->name('MyParallelCrawler 1.0');

  # Use a delay to keep the event loop running until we are done
  my $delay = Mojo::IOLoop->delay;
  my $fetch;
  $fetch = sub {

    # Stop if there are no more URLs
    return unless my $url = shift @urls;

    # Fetch the next title
    my $end = $delay->begin;
    $ua->get($url => sub {
      my ($ua, $tx) = @_;
      say "$url: ", $tx->result->dom->at('title')->text;

      # Next request
      $fetch->();
      $end->();
    });
  };

  # Process two requests at a time
  $fetch->() for 1 .. 2;
  $delay->wait;

It is also strongly recommended to respect every sites robots.txt file as well as terms of service, and to wait a little before reopening connections to the same host, or the operators might be forced to block your access.

You might have seen "wait" in Mojo::Promise already in some examples above. It is used to make non-blocking operations portable, allowing them to work inside an already running event loop or start one on demand.

  # Synchronize non-blocking requests with promises
  my $ua = Mojo::UserAgent->new;
  my $mojo   = $ua->get_p('https://metacpan.org/search?q=mojo');
  my $minion = $ua->get_p('https://metacpan.org/search?q=minion');
  Mojo::Promise->all($mojo, $minion)->then(sub {
    my ($mojo, $minion) = @_;
    say $mojo->[0]->result->dom->at('title')->text;
    say $minion->[0]->result->dom->at('title')->text;
  })->wait;

WebSockets are not just for the server-side, you can use "websocket_p" in Mojo::UserAgent to open new connections, which are always non-blocking. The WebSocket handshake uses HTTP, and is a normal GET request with a few additional headers. It can even contain cookies, and is followed by a 101 response from the server, notifying our user agent that the connection has been established and it can start using the bi-directional WebSocket protocol.

  # Open WebSocket to echo service
  my $ua = Mojo::UserAgent->new;
  $ua->websocket_p('ws://echo.websocket.org')->then(sub {
    my $tx = shift;

    # Prepare a followup promise so we can wait for messages
    my $promise = Mojo::Promise->new;

    # Wait for WebSocket to be closed
    $tx->on(finish => sub {
      my ($tx, $code, $reason) = @_;
      say "WebSocket closed with status $code.";
      $promise->resolve;
    });

    # Close WebSocket after receiving one message
    $tx->on(message => sub {
      my ($tx, $msg) = @_;
      say "WebSocket message: $msg";
      $tx->finish;
    });

    # Send a message to the server
    $tx->send('Hi!');

    # Insert a new promise into the promise chain
    return $promise;
  })->catch(sub {
    my $err = shift;

    # Handle failed WebSocket handshakes and other exceptions
    warn "WebSocket error: $err";
  })->wait;

Not just TCP/IP sockets are supported, but also UNIX domain sockets, which can have significant security and performance benefits when used for inter-process communication. Instead of http:// and ws:// you can use the http+unix:// and ws+unix:// schemes, and pass along a percent encoded path (/ becomes %2F) instead of a hostname.

  # GET request via UNIX domain socket "/tmp/foo.sock"
  my $ua = Mojo::UserAgent->new;
  say $ua->get('http+unix://%2Ftmp%2Ffoo.sock/index.html')->result->body;

  # GET request with HOST header via UNIX domain socket "/tmp/bar.sock"
  my $tx = $ua->get('http+unix://%2Ftmp%2Fbar.sock' => {Host => 'example.com'});
  say $tx->result->body;

  # WebSocket connection via UNIX domain socket "/tmp/baz.sock"
  $ua->websocket_p('ws+unix://%2Ftmp%2Fbaz.sock/echo')->then(sub {
    my $tx = shift;

You can set the Host header manually to pass along a hostname.

Don't you hate checking huge HTML files from the command line? Thanks to the command Mojolicious::Command::get that is about to change. You can just pick the parts that actually matter with the CSS selectors from Mojo::DOM and JSON Pointers from Mojo::JSON::Pointer.

How about a list of all id attributes?

Or the text content of all heading tags?

Maybe just the text of the third heading?

You can also extract all text from nested child elements.

The request can be customized as well.

Store response data by redirecting STDOUT.

Pass request data by redirecting STDIN.

Or use the output of another program.

Submit forms as application/x-www-form-urlencoded content.

And upload files as multipart/form-data content.

You can follow redirects and view the headers for all messages.

Extract just the information you really need from JSON data structures.

This can be an invaluable tool for testing your applications.

For quick hacks and especially testing, ojo one-liners are also a great choice.

Fun Mojolicious application hacks for all occasions.

Basic authentication data will be automatically extracted from the Authorization header.

    # Check for username "Bender" and password "rocks"
    return $c->render(text => 'Hello Bender!')
      if secure_compare $c->req->url->to_abs->userinfo, 'Bender:rocks';

    # Require authentication
    $c->res->headers->www_authenticate('Basic');
    $c->render(text => 'Authentication required!', status => 401);
  };

This can be combined with TLS for a secure authentication mechanism.

Adding a configuration file to your application is as easy as adding a file to its home directory and loading the plugin Mojolicious::Plugin::Config. The default name is based on the value of "moniker" in Mojolicious (myapp), appended with a .conf extension (myapp.conf).

Configuration files themselves are just Perl scripts that return a hash reference with configuration settings of your choice. All those settings are then available through the method "config" in Mojolicious and the helper "config" in Mojolicious::Plugin::DefaultHelpers.

Alternatively you can also use configuration files in the JSON format with Mojolicious::Plugin::JSONConfig.

To organize your code better and to prevent helpers from cluttering your application, you can use application specific plugins.

They work just like normal plugins and are also subclasses of Mojolicious::Plugin. Nested helpers with a prefix based on the plugin name are an easy way to avoid conflicts.

You can have as many application specific plugins as you like, the only difference to normal plugins is that you load them using their full class name.

Of course these plugins can contain more than just helpers, take a look at "PLUGINS" in Mojolicious::Plugins for a few ideas.

By now you've probably used many of the built-in commands described in Mojolicious::Commands, but did you know that you can just add new ones and that they will be picked up automatically by the command line interface if they are placed in a directory from @INC?

    # Leak secret passphrases
    if ($args[0] eq 'secrets') { say for @{$self->app->secrets} }

    # Leak mode
    elsif ($args[0] eq 'mode') { say $self->app->mode }
  }

Command line arguments are passed right through and there are many useful attributes and methods in Mojolicious::Command that you can use or overload.

And to make your commands application specific, just add a custom namespace to "namespaces" in Mojolicious::Commands and use a class name like MyApp::Command::spy instead of Mojolicious::Command::spy.

  # Application
  package MyApp;
  use Mojo::Base 'Mojolicious';

    # Add another namespace to load commands from
    push @{$self->commands->namespaces}, 'MyApp::Command';
  }

The options -h/--help, --home and -m/--mode are handled automatically by Mojolicious::Commands and are shared by all commands.

For a full list of shared options see "SYNOPSIS" in Mojolicious::Commands.

Ever thought about running a quick one-liner against your Mojolicious application to test something? Thanks to the command Mojolicious::Command::eval you can do just that, the application object itself can be accessed via app.

The verbose options will automatically print the return value or returned data structure to STDOUT.

Ever thought about releasing your Mojolicious application to CPAN? It's actually much easier than you might think.

The trick is to move the public and templates directories so they can get automatically installed with the modules. Additionally author commands from the Mojolicious::Command::Author namespace are not usually wanted by an installed application so they can be excluded.

  # Application
  package MyApp;
  use Mojo::Base 'Mojolicious';

  # Every CPAN module needs a version
  our $VERSION = '1.0';

    # Switch to installable home directory
    $self->home(Mojo::Home->new(path(__FILE__)->sibling('MyApp')));

    # Switch to installable "public" directory
    $self->static->paths->[0] = $self->home->child('public');

    # Switch to installable "templates" directory
    $self->renderer->paths->[0] = $self->home->child('templates');

    # Exclude author commands
    $self->commands->namespaces(['Mojolicious::Commands']);

Finally there is just one small change to be made to the application script. The shebang line becomes the recommended #!perl, which the toolchain can rewrite to the proper shebang during installation.

  # Start command line interface for application
  Mojolicious::Commands->start_app('MyApp');

That's really everything, now you can package your application like any other CPAN module.

And if you have a PAUSE account (which can be requested at http://pause.perl.org) even upload it.

If every byte matters this is the smallest Hello World application you can write with Mojolicious::Lite.

It works because all routes without a pattern default to / and automatic rendering kicks in even if no actual code gets executed by the router. The renderer just picks up the text value from the stash and generates a response.

The Hello World example above can get even a little bit shorter in an ojo one-liner.

And you can use all the commands from Mojolicious::Commands.

You can continue with Mojolicious::Guides now or take a look at the Mojolicious wiki, which contains a lot more documentation and examples by many different authors.

If you have any questions the documentation might not yet answer, don't hesitate to ask on the mailing list or the official IRC channel #mojo on irc.freenode.net (chat now!).