- NAME
- 説明
- 演算子の優先順位と結合性
- 項とリスト演算子 (左方向)
- 矢印演算子
- インクリメントとデクリメント
- 指数演算子
- 単項演算子
- 拘束演算子
- 乗法演算子
- 加法演算子
- シフト演算子
- 名前付き単項演算子
- 比較演算子
- 等価演算子
- クラスインスタンス演算子
- スマートマッチング演算子
- ビットごとの AND
- ビットごとの OR と XOR
- C スタイルの論理積
- C スタイルの論理和
- C スタイルの排他的論理和
- 論理定義性和
- 範囲演算子
- 条件演算子
- 代入演算子
- コンマ演算子
- リスト演算子 (右方向)
- 論理否定
- 論理積
- 論理和と排他論理和
- Perl にない C の演算子
- クォートとクォート風の演算子
- 正規表現のクォート風の演算子
- クォート風演算子
- クォートされた構造のパースに関する詳細
- I/O 演算子
- 定数の畳み込み
- 無実行
- ビット列演算子
- 整数演算
- 浮動小数点数演算
- より大きな数
- APPENDIX
NAME ¶
perlop - Perl expressions: operators, precedence, string literals
perlop - Perl の式: 演算子、優先順位、文字列リテラル
説明¶
In Perl, the operator determines what operation is performed, independent of the type of the operands. For example $x + $y is always a numeric addition, and if $x or $y do not contain numbers, an attempt is made to convert them to numbers first.
Perl では、演算子はどんな演算を行うかをオペランドの型と独立して決定します。 例えば $x + $y は常に数値加算で、$x や $y に数値でないものが 含まれている場合、まずそれらを数値に変換しようとします。
This is in contrast to many other dynamic languages, where the operation is determined by the type of the first argument. It also means that Perl has two versions of some operators, one for numeric and one for string comparison. For example $x == $y compares two numbers for equality, and $x eq $y compares two strings.
これは、最初の引数の型によって演算が決定されるその他の多くの動的言語と 対照的です。 これはまた、数値比較用と文字列比較用の 2 種類の演算子があるということです。 例えば $x == $y は二つの数値の等価性を比較し、$x eq $y は二つの 文字列を比較します。
There are a few exceptions though: x can be either string repetition or list repetition, depending on the type of the left operand, and &, |, ^ and ~ can be either string or numeric bit operations.
しかし、いくつかの例外があります: x は左オペランドの型によって、 文字列の繰り返しの場合とリストの繰り返しの場合があります; また &, |, ^, ~ は文字列としてのビット演算と数値としてのビット演算の 場合があります。
演算子の優先順位と結合性¶
Operator precedence and associativity work in Perl more or less like they do in mathematics.
Perl での演算子の優先順位と結合性は多かれ少なかれ数学のものと似ています。
Operator precedence means some operators group more tightly than others. For example, in 2 + 4 * 5, the multiplication has higher precedence, so 4 * 5 is grouped together as the right-hand operand of the addition, rather than 2 + 4 being grouped together as the left-hand operand of the multiplication. It is as if the expression were written 2 + (4 * 5), not (2 + 4) * 5. So the expression yields 2 + 20 == 22, rather than 6 * 5 == 30.
演算子の優先順位 とは、他の演算子グループよりもしっかりと 結びついている演算子グループがあるということです。 例えば、2 + 4 * 5 の場合、乗算が高い優先順位を持っているので、 2 + 4 が乗算の左オペランドとしてまとめられるのではなく、 4 * 5 が加法の右オペランドとしてまとめられます。 これは、(2 + 4) * 5 ではなく、2 + (4 * 5) と 書かれたかのようなものです。 従って、この式は 6 * 5 == 30 ではなく 2 + 20 == 22 になります。
Operator associativity defines what happens if a sequence of the same operators is used one after another: usually that they will be grouped at the left or the right. For example, in 9 - 3 - 2, subtraction is left associative, so 9 - 3 is grouped together as the left-hand operand of the second subtraction, rather than 3 - 2 being grouped together as the right-hand operand of the first subtraction. It is as if the expression were written (9 - 3) - 2, not 9 - (3 - 2). So the expression yields 6 - 2 == 4, rather than 9 - 1 == 8.
演算子の結合性 は、同じ演算子が連続して現れた場合に何が起こるかを 定義します: 通常はそれらが左側と結びつくか右側と結びつくかです。 例えば 9 - 3 - 2で、減法は左結合なので、 3 - 2 が最初の減法の右オペランドとしてまとめられるのではなく、 9 - 3 が 2 番目の減法の左オペランドとしてまとめられます。 これは、9 - (3 - 2) ではなく (9 - 3) - 2 と書かれたかのようなものです。 従って、この式は 9 - 1 == 8 ではなく 6 - 2 == 4 になります。
For simple operators that evaluate all their operands and then combine the values in some way, precedence and associativity (and parentheses) imply some ordering requirements on those combining operations. For example, in 2 + 4 * 5, the grouping implied by precedence means that the multiplication of 4 and 5 must be performed before the addition of 2 and 20, simply because the result of that multiplication is required as one of the operands of the addition. But the order of operations is not fully determined by this: in 2 * 2 + 4 * 5 both multiplications must be performed before the addition, but the grouping does not say anything about the order in which the two multiplications are performed. In fact Perl has a general rule that the operands of an operator are evaluated in left-to-right order. A few operators such as &&= have special evaluation rules that can result in an operand not being evaluated at all; in general, the top-level operator in an expression has control of operand evaluation.
全てのオペランドを評価してから何らかの形で値を結合する 単純な演算子の場合、優先順位と結合性(とかっこ)はそれらの結合操作で ある種の順序要求を暗示します。 例えば 2 + 4 * 5 では、 優先順位が暗示するグループ化によって、 4 と 5 の乗算は 2 と 20 の加算の前に行われる必要があります; 単にこの乗法の結果が加法のオペランドの一つとして必要だからです。 しかし、演算の順序はこれによって完全に決定されるわけではありません: 2 * 2 + 4 * 5 では、両方の乗算は加算の前に行われなければなりませんが、 グループ化は二つの乗算が行われる順序については何も言っていません。 実際の所、Perl には、演算子のオペランドは左から右の順で 評価されるという一般的な規則があります。 &&= のようないくつかの演算子は、 全く評価されないオペランドとなる特別な評価規則を持ちます; 一般的に、式の中の最上位の演算子がオペランド評価を制御します。
Some comparison operators, as their associativity, chain with some operators of the same precedence (but never with operators of different precedence). This chaining means that each comparison is performed on the two arguments surrounding it, with each interior argument taking part in two comparisons, and the comparison results are implicitly ANDed. Thus "$x < $y <= $z" behaves exactly like "$x < $y && $y <= $z", assuming that "$y" is as simple a scalar as it looks. The ANDing short-circuits just like "&&" does, stopping the sequence of comparisons as soon as one yields false.
一部の比較演算子は、それらの優先順位と、 同じ優先順位を持つ一部の演算子と 連鎖 させることができます (異なる優先順位を持つ演算子とはできません)。 連鎖というのは、それぞれの比較はそれらの周りの二つの引数に対して 行われ、それぞれの内部引数は二つの比較の一部となり、比較結果は 暗黙に AND されるということです。 従って "$x < $y <= $z" は、"$y" が見た目単純な スカラだと仮定すると、 "$x < $y && $y <= $z" と正確に同じように振る舞います。 AND の短絡は "&&" と同様に行われ、一つが偽となった時点で一連の連鎖は 停止します。
In a chained comparison, each argument expression is evaluated at most once, even if it takes part in two comparisons, but the result of the evaluation is fetched for each comparison. (It is not evaluated at all if the short-circuiting means that it's not required for any comparisons.) This matters if the computation of an interior argument is expensive or non-deterministic. For example,
連鎖比較において、それぞれの引数式は、例え二つの比較の一部となったとしても、 評価されるのは最大 1 回ですが、評価の結果はそれぞれの比較毎に取得されます。 (短絡によって比較が必要でない場合は、まったく評価されません。) これは、内側の引数の計算が高価だったり非決定的だったりする場合に 問題になります。 例えば:
if($x < expensive_sub() <= $z) { ...is not entirely like
これは全体的に次のようなものではなく:
if($x < expensive_sub() && expensive_sub() <= $z) { ...but instead closer to
しかし次のものに近いです:
my $tmp = expensive_sub();
if($x < $tmp && $tmp <= $z) { ...in that the subroutine is only called once. However, it's not exactly like this latter code either, because the chained comparison doesn't actually involve any temporary variable (named or otherwise): there is no assignment. This doesn't make much difference where the expression is a call to an ordinary subroutine, but matters more with an lvalue subroutine, or if the argument expression yields some unusual kind of scalar by other means. For example, if the argument expression yields a tied scalar, then the expression is evaluated to produce that scalar at most once, but the value of that scalar may be fetched up to twice, once for each comparison in which it is actually used.
ここでサブルーチンは 1 回だけ呼び出されます。 しかし、正確に後者のコードのようなものでもありません; なぜなら 連鎖比較は実際には(名前付きかどうかにかかわらず)一時変数を使わないからです; 代入はありません。 これは、式が通常のサブルーチンとして呼び出されるときにはあまり違いは ありませんが、左辺値サブルーチンの呼び出しの場合や、引数式が 他の手段によって何らかの普通でない種類のスカラになった場合には より問題になります。 例えば、引数式が tie されたスカラになった場合、式はスカラを作るために 最大 1 回評価されますが、スカラの値は、実際に使われる比較毎に 1 回、 合計 2 回読み込まれます。
In this example, the expression is evaluated only once, and the tied scalar (the result of the expression) is fetched for each comparison that uses it.
この例で、式は 1 回だけ評価され、tie されたスカラ (式の結果) は、 これら使われる比較毎に取得されます。
if ($x < $tied_scalar < $z) { ...In the next example, the expression is evaluated only once, and the tied scalar is fetched once as part of the operation within the expression. The result of that operation is fetched for each comparison, which normally doesn't matter unless that expression result is also magical due to operator overloading.
次の例では、式は 1 回だけ評価され、 tie されたスカラは式の中の演算の 一部として 1 回だけ取得されます。 この演算の結果は比較毎に取得されます; 通常これは、式の結果も演算子オーバーロードによってマジカルでない限り、 関係ありません。
if ($x < $tied_scalar + 42 < $z) { ...Some operators are instead non-associative, meaning that it is a syntax error to use a sequence of those operators of the same precedence. For example, "$x .. $y .. $z" is an error.
一部の演算子は非結合です; 同じ優先順位の演算子の並びを使うと 文法エラーになります。 例えば、"$x .. $y .. $z" はエラーです。
Perl operators have the following associativity and precedence, listed from highest precedence to lowest. Operators borrowed from C keep the same precedence relationship with each other, even where C's precedence is slightly screwy. (This makes learning Perl easier for C folks.) With very few exceptions, these all operate on scalar values only, not array values.
Perl の演算子には、以下のような結合性と優先順位 (高い優先順位から 低いものへ並べている) があります。 C から持ってきた演算子の優先順位は、C での優先順位が多少おかしくても、 そのままにしてあります。 (これによって、C を使っている方が Perl に移りやすくなっています。) ごく僅かな例外を別として、全ての演算子はスカラ値のみを持ち、 配列値を持ちません。
left terms and list operators (leftward)
left ->
nonassoc ++ --
right **
right ! ~ ~. \ and unary + and -
left =~ !~
left * / % x
left + - .
left << >>
nonassoc named unary operators
nonassoc isa
chained < > <= >= lt gt le ge
chain/na == != eq ne <=> cmp ~~
left & &.
left | |. ^ ^.
left &&
left || ^^ //
nonassoc .. ...
right ?:
right = += -= *= etc. goto last next redo dump
left , =>
nonassoc list operators (rightward)
right not
left and
left or xor 左結合 項 リスト演算子 (左方向に対して)
左結合 ->
非結合 ++ --
右結合 **
右結合 ! ~ ~. \ 単項の+ 単項の-
左結合 =~ !~
左結合 * / % x
左結合 + - .
左結合 << >>
非結合 名前付き単項演算子
連鎖 < > <= >= lt gt le ge
連鎖/なし == != eq ne <=> cmp ~~
非結合 isa
左結合 & &.
左結合 | |. ^ ^.
左結合 &&
左結合 || ^^ //
非結合 .. ...
右結合 ?:
右結合 = += -= *= など; goto last next redo dump
左結合 , =>
非結合 リスト演算子 (右方向に対して)
右結合 not
左結合 and
左結合 or xorIn the following sections, these operators are covered in detail, in the same order in which they appear in the table above.
以下の章では、前述の表の順に、これらの演算子に関して詳述します。
Many operators can be overloaded for objects. See overload.
多くの演算子はオブジェクトでオーバーロードできます。 overload を参照して下さい。
項とリスト演算子 (左方向)¶
A TERM has the highest precedence in Perl. They include variables, quote and quote-like operators, any expression in parentheses, and any function whose arguments are parenthesized. Actually, there aren't really functions in this sense, just list operators and unary operators behaving as functions because you put parentheses around the arguments. These are all documented in perlfunc.
「項」は Perl でもっとも優先順位が高いものです。 これには、変数、クォートとクォート的な演算子、括弧で括った任意の式、 引数を括弧で括った任意の関数が含まれます。 実際には、この意味では本当の関数はなく、リスト演算子と関数のように働く 単項演算子が、引数を括弧で括るためそのように見えます。 これらはすべて perlfunc に記述しています。
If any list operator (print(), etc.) or any unary operator (chdir(), etc.) is followed by a left parenthesis as the next token, the operator and arguments within parentheses are taken to be of highest precedence, just like a normal function call.
リスト演算子 (print() など) や単項演算子 (chdir() など) は、 すべて次のトークンとして開き括弧が続くと、その演算子と括弧内の引数は、 通常の関数呼び出しのようにもっとも高い優先順位として扱われます。
In the absence of parentheses, the precedence of list operators such as print, sort, or chmod is either very high or very low depending on whether you are looking at the left side or the right side of the operator. For example, in
括弧が無い場合には、print、sort、chmod のようなリスト演算子の 優先順位は、演算子の左側をからすると非常に高く、右側からすると 非常に低く見えます。たとえば、
@ary = (1, 3, sort 4, 2);
print @ary; # prints 1324the commas on the right of the sort are evaluated before the sort, but the commas on the left are evaluated after. In other words, list operators tend to gobble up all arguments that follow, and then act like a simple TERM with regard to the preceding expression. Be careful with parentheses:
では、sort の右のコンマは sort よりも前に評価されますが、左側のコンマは 後から評価されます。 言い方を変えると、リスト演算子は自分の後にある引数をすべて使って処理を行ない、 その結果を自分の前の式に対する「項」であるかのように見せるということです。 ただし、括弧には気を付けないといけません:
# These evaluate exit before doing the print:
print($foo, exit); # Obviously not what you want.
print $foo, exit; # Nor is this. # 以下は print を行なう前に exit を評価します:
print($foo, exit); # 明らかにやりたいことではないでしょう。
print $foo, exit; # これでもない。 # These do the print before evaluating exit:
(print $foo), exit; # This is what you want.
print($foo), exit; # Or this.
print ($foo), exit; # Or even this. # 以下は exit を評価する前に print を行ないます:
(print $foo), exit; # これがしたかった。
print($foo), exit; # これでもいい。
print ($foo), exit; # これも OK。Also note that
また、
print ($foo & 255) + 1, "\n";probably doesn't do what you expect at first glance. The parentheses enclose the argument list for print which is evaluated (printing the result of $foo & 255). Then one is added to the return value of print (usually 1). The result is something like this:
の動作を一目見ただけで判断するのは、難しいでしょう。 かっこは print のために評価される引数リストを囲っています ($foo & 255 の結果が表示されます)。 それから print の返り値 (通常は 1) に 1 が加えられます。 結果は以下のようになります:
1 + 1, "\n"; # Obviously not what you meant. 1 + 1, "\n"; # 明らかにやりたいことではないでしょう。To do what you meant properly, you must write:
意味したいことを適切に行うには、以下のように書く必要があります:
print(($foo & 255) + 1, "\n");See "Named Unary Operators" for more discussion of this.
詳しくは、"Named Unary Operators" を参照してください。
Also parsed as terms are the do {} and eval {} constructs, as well as subroutine and method calls, and the anonymous constructors [] and {}.
この他に「項」として解析されるものには、do {} や eval {} の 構成、サブルーティンやメソッドの呼び出し、無名のコンストラクタ [] と {} があります。
See also "Quote and Quote-like Operators" toward the end of this section, as well as "I/O Operators".
後の方の "Quote and Quote-like Operators" や "I/O Operators" も参照してください。
矢印演算子¶
"->" is an infix dereference operator, just as it is in C and C++. If the right side is either a [...], {...}, or a (...) subscript, then the left side must be either a hard or symbolic reference to an array, a hash, or a subroutine respectively. (Or technically speaking, a location capable of holding a hard reference, if it's an array or hash reference being used for assignment.) See perlreftut and perlref.
C や C++ と同じように "->" は中置の被参照演算子です。 右側が [...], {...}, (...) のいずれかの形の添字であれば、左側は配列、 ハッシュ、サブルーチンへのハードリファレンスか シンボリックリファレンスでなければなりません。 (あるいは技術的には、配列またはハードリファレンスが代入可能であれば ハードリファレンスを保持できる場所です。) perlreftut と perlref を参照してください。
Otherwise, the right side is a method name or a simple scalar variable containing either the method name or a subroutine reference, and (if it is a method name) the left side must be either an object (a blessed reference) or a class name (that is, a package name). See perlobj.
そうでなければ、右側はメソッド名かサブルーチンのリファレンスを持った 単純スカラ変数で、 (メソッド名なら) 左側はオブジェクト (bless されたリファレンス) か クラス名でなければなりません。 perlobj を参照してください。
The dereferencing cases (as opposed to method-calling cases) are somewhat extended by the postderef feature. For the details of that feature, consult "Postfix Dereference Syntax" in perlref.
(メソッド呼び出しの場合ではなく) デリファレンスの場合、 後置デリファレンス (postderef) 機能によっていくらか拡張されます。 この機能の詳細については、"Postfix Dereference Syntax" in perlref を 参照してください。
インクリメントとデクリメント¶
"++" and "--" work as in C. That is, if placed before a variable, they increment or decrement the variable by one before returning the value, and if placed after, increment or decrement after returning the value.
"++" と "--" は、C の場合と同じように動作します。 つまり、変数の前に置かれれば、値を返す前に変数を 1 インクリメントまたは デクリメントし、後に置かれれば、値を返した後で変数を インクリメントまたはデクリメントします。
$i = 0; $j = 0;
print $i++; # prints 0
print ++$j; # prints 1Note that just as in C, Perl doesn't define when the variable is incremented or decremented. You just know it will be done sometime before or after the value is returned. This also means that modifying a variable twice in the same statement will lead to undefined behavior. Avoid statements like:
C と同様、Perl は いつ 変数がインクリメントまたはデクリメントされるかは 定義されません。 値が返される前か後のどこかで行われる、ということだけがわかります。 これは、同じ文である変数を 2 回修正すると、振る舞いが未定義になることを 意味します。 以下のような文は避けてください:
$i = $i ++;
print ++ $i + $i ++;Perl will not guarantee what the result of the above statements is.
Perl は上記の文の結果について保障しません。
The auto-increment operator has a little extra builtin magic to it. If you increment a variable that is numeric, or that has ever been used in a numeric context, you get a normal increment. If, however, the variable has been used in only string contexts since it was set, and has a value that is not the empty string and matches the pattern /^[a-zA-Z]*[0-9]*\z/, the increment is done as a string, preserving each character within its range, with carry:
インクリメント演算子には、ちょっと風変わりな機能が組み込まれています。 数値が入った変数や、数値の文脈で使われてきた変数を インクリメントする場合には、通常のインクリメントとして動作します。 しかし、その変数が設定されてからずっと文字列の文脈でしか使われていなくて、 空文字列でなく、 /^[a-zA-Z]*[0-9]*\z/ にマッチする値を持っているときには、 個々の文字の範囲を保ちながら桁あげを行なって、文字列としてインクリメントが 行なわれます (マジカルインクリメントと呼ばれます):
print ++($foo = "99"); # prints "100"
print ++($foo = "a0"); # prints "a1"
print ++($foo = "Az"); # prints "Ba"
print ++($foo = "zz"); # prints "aaa"undef is always treated as numeric, and in particular is changed to 0 before incrementing (so that a post-increment of an undef value will return 0 rather than undef).
undef は常に数値として扱われ、特にインクリメントされる前には 0 に 変換されます(従って、undef のポストインクリメント値は undef ではなく 0 になります)。
The auto-decrement operator is not magical.
デクリメント演算子には、マジカルなものはありません。
指数演算子¶
Binary "**" is the exponentiation operator. It binds even more tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is implemented using C's pow(3) function, which actually works on doubles internally.)
二項演算子の "**" は指数演算子です。 この演算子は、単項のマイナスよりも結合が強い演算子で、 -2**4 は (-2)**4 ではなく、-(2**4) と解釈されます。 (これは C の pow(3) を使って実装されていますので、 内部的には double で動作します。)
Note that certain exponentiation expressions are ill-defined: these include 0**0, 1**Inf, and Inf**0. Do not expect any particular results from these special cases, the results are platform-dependent.
一部の指数表現は明確に定義されていません: これは 0**0, 1**Inf, Inf**0 などです。 これらの特殊な場合に関して特定の結果を想定しないでください; 結果はプラットフォーム依存です。
単項演算子¶
Unary "!" performs logical negation, that is, "not". See also not for a lower precedence version of this.
単項演算子の "!" は論理否定を行ないます; つまり「not」ということです。 この演算子の優先順位を低くしたものとして、 not が用意されています。
Unary "-" performs arithmetic negation if the operand is numeric, including any string that looks like a number. If the operand is an identifier, a string consisting of a minus sign concatenated with the identifier is returned. Otherwise, if the string starts with a plus or minus, a string starting with the opposite sign is returned. One effect of these rules is that -bareword is equivalent to the string "-bareword". If, however, the string begins with a non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert the string to a numeric, and the arithmetic negation is performed. If the string cannot be cleanly converted to a numeric, Perl will give the warning Argument "the string" isn't numeric in negation (-) at ....
単項演算子の "-" は被演算子が数値または数値に見える文字列であれば、 算術否定を行ないます。 被演算子が識別子ならば、マイナス記号にその識別子をつなげた文字列が返されます。 これ以外で被演算子の最初の文字がプラスかマイナスのときには、 その記号を逆のものに置き換えた文字列を返します。 この規則の結果、-bareword が文字列 "-bareword" に等価となります。 しかし、文字列が英字以外("+" と "-" を除く)で始まっていると、 Perl は文字列を数値に変換しようとし、それから算術否定が実行されます。 もし文字列が明確に数値に変換できない場合、Perl は Argument "the string" isn't numeric in negation (-) at ... という 警告を出します。
Unary "~" performs bitwise negation, that is, 1's complement. For example, 0666 & ~027 is 0640. (See also "Integer Arithmetic" and "Bitwise String Operators".) Note that the width of the result is platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64 bits wide on a 64-bit platform, so if you are expecting a certain bit width, remember to use the "&" operator to mask off the excess bits.
単項演算子の "~" はビットごとの否定を行ないます; つまり、1 の補数を返します。 例えば、0666 & ~027 は 0640 です。 ("Integer Arithmetic" と "Bitwise String Operators" も参照して下さい。) 結果の幅はプラットホーム依存であることに注意してください: ~0 は 32 ビットプラットホームでは 32 ビット幅ですが、64 ビットプラットホームでは 64 ビット幅なので、特定のビット幅を仮定する場合は、 余分なビットをマスクするために "&" 演算子を使うことを忘れないでください。
Starting in Perl 5.28, it is a fatal error to try to complement a string containing a character with an ordinal value above 255.
Perl 5.28 から、値が 255 を超える文字を含む文字列の 補数を求めようとすると致命的エラーになります。
If the "bitwise" feature is enabled via use feature 'bitwise' or use v5.28, then unary "~" always treats its argument as a number, and an alternate form of the operator, "~.", always treats its argument as a string. So ~0 and ~"0" will both give 2**32-1 on 32-bit platforms, whereas ~.0 and ~."0" will both yield "\xff". Until Perl 5.28, this feature produced a warning in the "experimental::bitwise" category.
"bitwise" 機能が use feature 'bitwise' か use v5.28 で有効にされると、 単項の "~" は常にその引数を数値として扱い、その代替形式である "~." はその引数を常に文字列として扱います。 従って 32 ビットプラットフォームでは ~0 と ~"0" はどちらも 2**32-1 を意味しますが、~.0 と ~."0" はどちらも "\xff" になります。 Perl 5.28 まで、この機能は "experimental::bitwise" カテゴリの警告を 発生させていました。
Unary "+" has no effect whatsoever, even on strings. It is useful syntactically for separating a function name from a parenthesized expression that would otherwise be interpreted as the complete list of function arguments. (See examples above under "Terms and List Operators (Leftward)".)
単項演算子の "+" は、たとえ文字列に対して用いられた場合にも、何もしません。 関数名に続けて括弧付きの式を書く場合に、関数の引数リストと 解釈されないようにするために用いることができます。 (下記 "Terms and List Operators (Leftward)" の例を参照してください。)
Unary "\" creates references. If its operand is a single sigilled thing, it creates a reference to that object. If its operand is a parenthesised list, then it creates references to the things mentioned in the list. Otherwise it puts its operand in list context, and creates a list of references to the scalars in the list provided by the operand. See perlreftut and perlref. Do not confuse this behavior with the behavior of backslash within a string, although both forms do convey the notion of protecting the next thing from interpolation.
単項演算子の "\" はリファレンスを生成します。 オペランドが一つの印付きのものの場合、それへのリファレンスを作ります。 オペランドがかっこでくくられたリストの場合、 リストで言及されているものへのリファレンスを作ります。 さもなければオペランドをリストコンテキストとし、 オペランドによって提供されたリストのスカラへのリファレンスのリストを作ります。 perlreftut と perlref を参照してください。 この用法も文字列中のバックスラッシュも、後に続くものが展開されるのを 防ぐことになりますが、動作を混同しないでください。
拘束演算子¶
Binary "=~" binds a scalar expression to a pattern match. Certain operations search or modify the string $_ by default. This operator makes that kind of operation work on some other string. The right argument is a search pattern, substitution, or transliteration. The left argument is what is supposed to be searched, substituted, or transliterated instead of the default $_. When used in scalar context, the return value generally indicates the success of the operation. The exceptions are substitution (s///) and transliteration (y///) with the /r (non-destructive) option, which cause the return value to be the result of the substitution. Behavior in list context depends on the particular operator. See "Regexp Quote-Like Operators" for details and perlretut for examples using these operators.
二項演算子の "=~" は、スカラ式をパターンマッチに拘束します。 デフォルトで $_ の文字列を検索したり、変更したりする演算があります。 この演算子は、そのような演算を他の文字列に対して行なわせるようにするものです。 右引数は、検索パターン、置換、文字変換のいずれかです。 左引数は、デフォルトの $_ の代わりに検索、置換、文字変換の 対象となるものです。 スカラコンテキストで使うと、返り値は一般的に演算の結果が成功したか否かです。 例外は、/r (非破壊) オプション付きの置換 (s///) と 文字変換 (y///) です; この場合は変換した結果を返します。 リストコンテキストでの振る舞いは演算子に依存します。 詳しくは "Regexp Quote-Like Operators" を、これらの演算子を使った 例については perlretut を参照して下さい。
If the right argument is an expression rather than a search pattern, substitution, or transliteration, it is interpreted as a search pattern at run time. Note that this means that its contents will be interpolated twice, so
右引数が検索パターン、置換、文字変換ではなく、式であれば、 それは実行時に決まる検索パターンと解釈されます。 これは、内容が 2 回展開されることを意味することに注意してください; つまり:
'\\' =~ q'\\';is not ok, as the regex engine will end up trying to compile the pattern \, which it will consider a syntax error.
は正しくありません; 正規表現エンジンは最終的にパターン \ を コンパイルしようとして、これは文法エラーと考えるからです。
Binary "!~" is just like "=~" except the return value is negated in the logical sense.
二項演算子の "!~" は、返される値が論理否定されることを除いて "=~" と同じです。
Binary "!~" with a non-destructive substitution (s///r) or transliteration (y///r) is a syntax error.
二項演算子の "!~" を非破壊置換 (s///r) や変換 (y///r) で使うと 文法エラーとなります。
乗法演算子¶
Binary "*" multiplies two numbers.
二項演算子の "*" は 2 つの数値の積を返します。
Binary "/" divides two numbers.
二項演算子の "/" は 2 つの数値の商を返します。
Binary "%" is the modulo operator, which computes the division remainder of its first argument with respect to its second argument. Given integer operands $m and $n: If $n is positive, then $m % $n is $m minus the largest multiple of $n less than or equal to $m. If $n is negative, then $m % $n is $m minus the smallest multiple of $n that is not less than $m (that is, the result will be less than or equal to zero). If the operands $m and $n are floating point values and the absolute value of $n (that is abs($n)) is less than (UV_MAX + 1), only the integer portion of $m and $n will be used in the operation (Note: here UV_MAX means the maximum of the unsigned integer type). If the absolute value of the right operand (abs($n)) is greater than or equal to (UV_MAX + 1), "%" computes the floating-point remainder $r in the equation ($r = $m - $i*$n) where $i is a certain integer that makes $r have the same sign as the right operand $n (not as the left operand $m like C function fmod()) and the absolute value less than that of $n. Note that when use integer is in scope, "%" gives you direct access to the modulo operator as implemented by your C compiler. This operator is not as well defined for negative operands, but it will execute faster.
二項演算子の "%" は剰余演算子で、一つ目の引数を二つ目の引数で割ったときの 余りを返します。 $m と $n の二つの整数の被演算子を取ったとすると: $n が正の場合、$m % $n は、$m から $m 以下の最大の $n の倍数を引いた値です。 $n が負の場合、$m % $n は、$m から $m を下回らない 最小の $n の倍数を引いた値です(従って結果はゼロ以下になります)。 オペランド $m と $n が浮動小数点数で、$n の絶対値 (つまり abs($n)) が (UV_MAX + 1) より小さい場合、 $m と $n の整数部のみが操作で使われます (注意: ここで UV_MAX は符号なし整数の最大値を意味します)。 右オペランドの絶対値 (abs($n)) が (UV_MAX + 1) 以上の場合、 "%" は、($r = $m - $i*$n) となる浮動小数点剰余 $r を計算します; ここで $i は、$r が右オペランド $n と同じ符号 (C の 関数 fmod() のように左オペランド $m ではありません) で、 絶対値が $n より小さいものになるような、ある整数です。 use integer がスコープ内にある場合、 "%" は C コンパイラで実装された剰余演算子を使います。 この演算子は被演算子が負の場合の挙動が不確実ですが、 より高速です。
Binary x is the repetition operator. In scalar context, or if the left operand is neither enclosed in parentheses nor a qw// list, it performs a string repetition. In that case it supplies scalar context to the left operand, and returns a string consisting of the left operand string repeated the number of times specified by the right operand. If the x is in list context, and the left operand is either enclosed in parentheses or a qw// list, it performs a list repetition. In that case it supplies list context to the left operand, and returns a list consisting of the left operand list repeated the number of times specified by the right operand. If the right operand is zero or negative (raising a warning on negative), it returns an empty string or an empty list, depending on the context.
二項演算子の "x" は繰り返し演算子です。 スカラコンテキストまたは左辺値がかっこで囲まれたり qw// リストであったりしない場合は、文字列の繰り返しを実行します。 この場合、左オペランドにスカラコンテキストを提供し、 右オペランドによって指定された回数繰り返された左オペランド文字列からなる 文字列を返します。 x がリストコンテキストで、 左オペランドがかっこでくくられているか qw// リストの場合、 リスト繰り返しを実行します。 この場合、これは左オペランドへリストコンテキストを提供し、 右オペランドによって指定された回数繰り返された 左オペランドのリストからなるリストを返します。 右オペランドが 0 か負数の場合(負数の場合は警告が出ます)、 コンテキストによって空文字列か空リストを返します。
print '-' x 80; # print row of dashes
print "\t" x ($tab/8), ' ' x ($tab%8); # tab over
@ones = (1) x 80; # a list of 80 1's
@ones = (5) x @ones; # set all elements to 5加法演算子¶
Binary "+" returns the sum of two numbers.
二項演算子の "+" は 2 つの数値の和を返します。
Binary "-" returns the difference of two numbers.
二項演算子の "-" は 2 つの数値の差を返します。
Binary "." concatenates two strings.
二項演算子の "." は 2 つの文字列を連結します。
シフト演算子¶
Binary "<<" returns the value of its left argument shifted left by the number of bits specified by the right argument. Arguments should be integers. (See also "Integer Arithmetic".)
二項演算子の "<<" は左引数の値を、右引数で示すビット数だけ、 左にシフトした値を返します。 引数は整数でなければなりません。 ("Integer Arithmetic" も参照して下さい。)
Binary ">>" returns the value of its left argument shifted right by the number of bits specified by the right argument. Arguments should be integers. (See also "Integer Arithmetic".)
二項演算子の ">>" は左引数の値を、右引数で示すビット数だけ、 右にシフトした値を返します。 引数は整数でなければなりません。 ("Integer Arithmetic" も参照して下さい。)
If use integer (see "Integer Arithmetic") is in force then signed C integers are used (arithmetic shift), otherwise unsigned C integers are used (logical shift), even for negative shiftees. In arithmetic right shift the sign bit is replicated on the left, in logical shift zero bits come in from the left.
use integer ("Integer Arithmetic" を参照してください)が有効な場合、 C の符号付き整数が使われ(算術シフト)、そうでない場合は(例え負のシフトでも) C の符号なし整数が使われます(論理シフト)。 算術右シフトでは符号ビットは左側に複製され、論理シフトでは 0 ビットが 左側から来ます。
Either way, the implementation isn't going to generate results larger than the size of the integer type Perl was built with (32 bits or 64 bits).
どちらの場合も、この実装は Perl がビルドされた整数型のサイズ(32 ビットか 64 ビット)よりも大きい結果を生成することはありません。
Shifting by negative number of bits means the reverse shift: left shift becomes right shift, right shift becomes left shift. This is unlike in C, where negative shift is undefined.
負数のビットシフトは逆シフトを意味します: 左シフトは右シフトに鳴り、 右シフトは左シフトになります。 これは、負のシフトが未定義である C とは異なります。
Shifting by more bits than the size of the integers means most of the time zero (all bits fall off), except that under use integer right overshifting a negative shiftee results in -1. This is unlike in C, where shifting by too many bits is undefined. A common C behavior is "shift by modulo wordbits", so that for example
整数のサイズ以上のビット数のシフトは、ほとんどの場合 0 (全てのビットが落ちる) になります; 例外として、use integer の基で、負の値を超過シフトすると -1 になります。 これは、多すぎるビット数のシフトは未定義である C とは異なります。 一般的な C の振る舞いは「ワードビット数を法としてシフトする」なので、 例えば次のようになります
1 >> 64 == 1 >> (64 % 64) == 1 >> 0 == 1 # Common C behavior.but that is completely accidental.
しかしこれは完全に偶然です。
If you get tired of being subject to your platform's native integers, the use bigint pragma neatly sidesteps the issue altogether:
プラットフォームのネイティブな整数の影響に疲れたなら、use bigint プラグマは問題を完全にうまく回避します:
print 20 << 20; # 20971520
print 20 << 40; # 5120 on 32-bit machines,
# 21990232555520 on 64-bit machines
use bigint;
print 20 << 100; # 25353012004564588029934064107520名前付き単項演算子¶
The various named unary operators are treated as functions with one argument, with optional parentheses.
さまざまな名前付き単項演算子が、引数を 1 つ持ち、括弧が省略可能な、 関数として扱われます。
If any list operator (print(), etc.) or any unary operator (chdir(), etc.) is followed by a left parenthesis as the next token, the operator and arguments within parentheses are taken to be of highest precedence, just like a normal function call. For example, because named unary operators are higher precedence than ||:
リスト演算子 (print() など) や単項演算子 (chdir() など) は、 すべて次のトークンとして開き括弧が続くと、その演算子と括弧内の引数は、 通常の関数呼び出しのようにもっとも高い優先順位として扱われます。 たとえば、名前つき単項演算子は || より優先順位が高いので、 以下のようになります:
chdir $foo || die; # (chdir $foo) || die
chdir($foo) || die; # (chdir $foo) || die
chdir ($foo) || die; # (chdir $foo) || die
chdir +($foo) || die; # (chdir $foo) || diebut, because "*" is higher precedence than named operators:
しかし "*" は名前つき演算子より優先順位が高いので、以下のようになります:
chdir $foo * 20; # chdir ($foo * 20)
chdir($foo) * 20; # (chdir $foo) * 20
chdir ($foo) * 20; # (chdir $foo) * 20
chdir +($foo) * 20; # chdir ($foo * 20)
rand 10 * 20; # rand (10 * 20)
rand(10) * 20; # (rand 10) * 20
rand (10) * 20; # (rand 10) * 20
rand +(10) * 20; # rand (10 * 20)Regarding precedence, the filetest operators, like -f, -M, etc. are treated like named unary operators, but they don't follow this functional parenthesis rule. That means, for example, that -f($file).".bak" is equivalent to -f "$file.bak".
優先順位に関して、-f や -M のようなファイルテスト演算子は、名前付き 単項演算子として扱われますが、この関数のかっこルールは適用されません。 これは、例えば -f($file).".bak" は -f "$file.bak" と等価であることを 意味します。
See also "Terms and List Operators (Leftward)".
"Terms and List Operators (Leftward)" も参照して下さい。
比較演算子¶
Perl operators that return true or false generally return values that can be safely used as numbers. For example, the relational operators in this section and the equality operators in the next one return 1 for true and a special version of the defined empty string, "", which counts as a zero but is exempt from warnings about improper numeric conversions, just as "0 but true" is.
真か偽の値を返す Perl 演算子は一般的に安全に数値として使える値を返します。 例えば、この節の関係演算子と次の節の等価演算子は、真および、 "0 but true" と同様、ゼロとカウントされるけれども不適切な数値変換に 関する警告の出ない、定義された空文字列 "" の特別版に対して 1 を 返します。
Binary "<" returns true if the left argument is numerically less than the right argument.
二項演算子の "<" は左引数が数値的に右引数よりも小さければ、 真を返します。
Binary ">" returns true if the left argument is numerically greater than the right argument.
二項演算子の ">" は左引数が数値的に右引数よりも大きければ、 真を返します。
Binary "<=" returns true if the left argument is numerically less than or equal to the right argument.
二項演算子の "<=" は左引数が数値的に右引数よりも小さいか等しければ、 真を返します。
Binary ">=" returns true if the left argument is numerically greater than or equal to the right argument.
二項演算子の ">=" は左引数が数値的に右引数よりも大きいか等しければ、 真を返します。
Binary "lt" returns true if the left argument is stringwise less than the right argument.
二項演算子の "lt" は左引数が文字列的に右引数よりも小さければ、真を返します。
Binary "gt" returns true if the left argument is stringwise greater than the right argument.
二項演算子の "gt" は左引数が文字列的に右引数よりも大きければ、真を返します。
Binary "le" returns true if the left argument is stringwise less than or equal to the right argument.
二項演算子の "le" は左引数が文字列的に右引数よりも小さいか等しければ、 真を返します。
Binary "ge" returns true if the left argument is stringwise greater than or equal to the right argument.
二項演算子の "ge" は左引数が文字列的に右引数よりも大きいか等しければ、 真を返します。
A sequence of relational operators, such as "$x < $y <= $z", performs chained comparisons, in the manner described above in the section "Operator Precedence and Associativity". Beware that they do not chain with equality operators, which have lower precedence.
"$x < $y <= $z" のような比較演算子の並びは、 "Operator Precedence and Associativity" 節で述べたような形で 連鎖比較を実行します。 より低い優先順位を持つ等価演算子とは連鎖しないことに注意してください。
等価演算子¶
Binary "==" returns true if the left argument is numerically equal to the right argument.
二項演算子の "==" は左引数が数値的に右引数と等しければ、真を返します。
Binary "!=" returns true if the left argument is numerically not equal to the right argument.
二項演算子の "!=" は左引数が数値的に右引数と等しくなければ、真を 返します。
Binary "eq" returns true if the left argument is stringwise equal to the right argument.
二項演算子の "eq" は左引数が文字列的に右引数と等しければ、真を返します。
Binary "ne" returns true if the left argument is stringwise not equal to the right argument.
二項演算子の "ne" は左引数が文字列的に右引数と等しくなければ、真を 返します。
A sequence of the above equality operators, such as "$x == $y == $z", performs chained comparisons, in the manner described above in the section "Operator Precedence and Associativity". Beware that they do not chain with relational operators, which have higher precedence.
"$x == $y == $z" のような上述の等価演算子の並びは、 "Operator Precedence and Associativity" 節で述べたような形で 連鎖比較を実行します。 より高い優先順位を持つ比較演算子とは連鎖しないことに注意してください。
Binary "<=>" returns -1, 0, or 1 depending on whether the left argument is numerically less than, equal to, or greater than the right argument. If your platform supports NaN's (not-a-numbers) as numeric values, using them with "<=>" returns undef. NaN is not "<", "==", ">", "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN returns true, as does NaN != anything else. If your platform doesn't support NaN's then NaN is just a string with numeric value 0.
二項演算子の "<=>" は左引数が数値的に右引数より小さいか、等しいか、 大きいかに従って、-1, 0, 1 を返します。 数値として NaN (非数) に対応しているプラットフォームでは、 それに対して "<=>" を使うと undef を返します。 NaN はどの値に対しても(NaN に対してでさえも) "<", "==", ">", "<=", ">=" のいずれも成立しないので、これらは全て 偽となります。 NaN != NaN は真を返しますが、 NaN != その他のどの値でも です。 NaN に対応していないプラットフォームでは、NaN は単に数としての値 0 を 持つ文字列です。
$ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
$ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'(bigint, bigrat, bignum プラグマは全て "NaN" に対応していることに 注意してください。)
Binary "cmp" returns -1, 0, or 1 depending on whether the left argument is stringwise less than, equal to, or greater than the right argument.
二項演算子の "cmp" は左引数が文字列的に右引数より小さいか、 等しいか、大きいかに従って、-1, 0, 1 を返します。
Here we can see the difference between <=> and cmp,
ここで、<=> と cmp の違いを示します:
print 10 <=> 2 #prints 1
print 10 cmp 2 #prints -1(likewise between gt and >, lt and <, etc.)
(gt と >, lt と <, なども同様です)
Binary "~~" does a smartmatch between its arguments. Smart matching is described in the next section.
二項演算子の "~~" はその引数に対してスマートマッチングを行います。 スマートマッチングについては次の節で述べられています。
The two-sided ordering operators "<=>" and "cmp", and the smartmatch operator "~~", are non-associative with respect to each other and with respect to the equality operators of the same precedence.
両面順序演算子 "<=>", "cmp" および、 スマートマッチング演算子 "~~" は、互いに、および同じ優先順位の 演算子に対しては非結合です。
"lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified by the current LC_COLLATE locale if a use locale form that includes collation is in effect. See perllocale. Do not mix these with Unicode, only use them with legacy 8-bit locale encodings. The standard Unicode::Collate and Unicode::Collate::Locale modules offer much more powerful solutions to collation issues.
"lt", "le", "ge", "gt", "cmp" は照合を含む use locale 型式が有効な場合は、現在の LC_COLLATE ロケールで 指定された照合(ソート)順が使われます。 perllocale を参照して下さい。 これらを Unicode と混ぜないでください; 伝統的な 8 ビットロケールコーディングでのみ使ってください。 標準の Unicode::Collate と Unicode::Collate::Locale モジュールは、 照合問題に関する遥かに強力な解決法を提供します。
For case-insensitive comparisons, look at the "fc" in perlfunc case-folding function, available in Perl v5.16 or later:
大文字小文字を無視した比較に関しては、Perl v5.16 以降で利用可能な "fc" in perlfunc 大文字小文字畳み込み関数を参照してください:
if ( fc($x) eq fc($y) ) { ... }クラスインスタンス演算子¶
Binary isa evaluates to true when the left argument is an object instance of the class (or a subclass derived from that class) given by the right argument. If the left argument is not defined, not a blessed object instance, nor does not derive from the class given by the right argument, the operator evaluates as false. The right argument may give the class either as a bareword or a scalar expression that yields a string class name:
二項演算子の isa は、左側の引数が右側の引数で与えられた クラス(またはこのクラスから派生した下位クラス)の オブジェクトインスタンスである場合に真と評価されます。 左側の引数が、未定義、bless されたオブジェクトインスタンスではない、 右側の引数で与えられたクラスから派生していない、のいずれかの場合、 この演算子は偽として評価されます。 右側の引数は、裸の単語か、クラス名の文字列となるスカラ式を与えます:
if( $obj isa Some::Class ) { ... }
if( $obj isa "Different::Class" ) { ... }
if( $obj isa $name_of_class ) { ... }This feature is available from Perl 5.31.6 onwards when enabled by use feature 'isa'. This feature is enabled automatically by a use v5.36 (or higher) declaration in the current scope.
これは Perl 5.31.6 からの機能で、use feature 'isa' によって 有効化されると利用可能になります。 この機能は、現在のスコープで use v5.36 (またはそれ以上の) 宣言をすることで 自動的に有効になります。
スマートマッチング演算子¶
First available in Perl 5.10.1 (the 5.10.0 version behaved differently), binary ~~ does a "smartmatch" between its arguments. This is mostly used implicitly in the when construct described in perlsyn, although not all when clauses call the smartmatch operator. Unique among all of Perl's operators, the smartmatch operator can recurse. The smartmatch operator is experimental and its behavior is subject to change.
Perl 5.10.1 で最初に現れた (5.10.0 版は異なった振る舞いでした)、2 項 ~~ は 引数に対する「スマートマッチング」を行います。 これはほとんど perlsyn で記述されている when 構文で暗黙に使われますが、 when 節だけがスマートマッチング演算子を呼び出すわけではありません。 全ての Perl の演算子の中で唯一、スマートマッチング演算子は再帰できます。 スマートマッチング演算子は 実験的 で、その振る舞いは 変更されることがあります。
It is also unique in that all other Perl operators impose a context (usually string or numeric context) on their operands, autoconverting those operands to those imposed contexts. In contrast, smartmatch infers contexts from the actual types of its operands and uses that type information to select a suitable comparison mechanism.
また、その他全ての Perl 演算子はそのオペランドにコンテキスト(通常は 文字列または数値コンテキスト)を割り当てて、オペランドを割り当てた コンテキストに自動変換します。 一方、スマートマッチングはそのオペランドの実際の型からコンテキストを 推論 して、適切な比較機構を選択するためにその型情報を使います。
The ~~ operator compares its operands "polymorphically", determining how to compare them according to their actual types (numeric, string, array, hash, etc.). Like the equality operators with which it shares the same precedence, ~~ returns 1 for true and "" for false. It is often best read aloud as "in", "inside of", or "is contained in", because the left operand is often looked for inside the right operand. That makes the order of the operands to the smartmatch operand often opposite that of the regular match operator. In other words, the "smaller" thing is usually placed in the left operand and the larger one in the right.
~~ 演算子はオペランドを「多態的に」比較します; どのように比較するかの 決定は、実際の型 (数値、文字列、配列、ハッシュなど) に基づきます。 同じ優先順位を共有する等価演算子のように、 ~~ は真では 1 を、偽では "" を返します。 これはしばしば "in", "inside of", "is contained in" と呼ぶのが最良です; なぜなら左オペランドはしばしば右オペランドの 内側 を探すからです。 これにより、スマートマッチングオペランドへのオペランドの順序はしばしば 正規表現演算子のものと逆になります。 言い換えると、「より小さい」ものが普通は左オペランドに置かれ、より 大きいものが右側に置かれます。
The behavior of a smartmatch depends on what type of things its arguments are, as determined by the following table. The first row of the table whose types apply determines the smartmatch behavior. Because what actually happens is mostly determined by the type of the second operand, the table is sorted on the right operand instead of on the left.
スマートマッチングの振る舞いは、次の表で決定されるように、引数がどんな 型かに依存します。 型が適用される表の最初の行は、スマートマッチングの振る舞いを決定します。 実際に何が起こるかはほとんどの場合 2 番目のオペランドの型で決定されるので、 表は左ではなく右オペランドでソートされています。
Left Right Description and pseudocode
===============================================================
Any undef check whether Any is undefined
like: !defined Any 左 右 説明と擬似コード
===============================================================
Any undef Any が未定義かどうか調べる
like: !defined Any Any Object invoke ~~ overloading on Object, or die Any Object Object に対する ~~ オーバーロードを起動するか die Right operand is an ARRAY: 右被演算子が 配列: Left Right Description and pseudocode
===============================================================
ARRAY1 ARRAY2 recurse on paired elements of ARRAY1 and ARRAY2[2]
like: (ARRAY1[0] ~~ ARRAY2[0])
&& (ARRAY1[1] ~~ ARRAY2[1]) && ...
HASH ARRAY any ARRAY elements exist as HASH keys
like: grep { exists HASH->{$_} } ARRAY
Regexp ARRAY any ARRAY elements pattern match Regexp
like: grep { /Regexp/ } ARRAY
undef ARRAY undef in ARRAY
like: grep { !defined } ARRAY
Any ARRAY smartmatch each ARRAY element[3]
like: grep { Any ~~ $_ } ARRAY 左 右 説明と擬似コード
===============================================================
ARRAY1 ARRAY2 ARRAY1 と ARRAY2 の組の要素に対して再帰 [2]
like: (ARRAY1[0] ~~ ARRAY2[0])
&& (ARRAY1[1] ~~ ARRAY2[1]) && ...
HASH ARRAY いずれかの ARRAY 要素が HASH キーに存在するか
like: grep { exists HASH->{$_} } ARRAY
Regexp ARRAY いずれかの ARRAY 要素が Regexp でマッチングするか
like: grep { /Regexp/ } ARRAY
undef ARRAY ARRAY 内の undef
like: grep { !defined } ARRAY
Any ARRAY それぞれの ARRAY 要素に対してスマートマッチング [3]
like: grep { Any ~~ $_ } ARRAY Right operand is a HASH: 右被演算子がハッシュ: Left Right Description and pseudocode
===============================================================
HASH1 HASH2 all same keys in both HASHes
like: keys HASH1 ==
grep { exists HASH2->{$_} } keys HASH1
ARRAY HASH any ARRAY elements exist as HASH keys
like: grep { exists HASH->{$_} } ARRAY
Regexp HASH any HASH keys pattern match Regexp
like: grep { /Regexp/ } keys HASH
undef HASH always false (undef cannot be a key)
like: 0 == 1
Any HASH HASH key existence
like: exists HASH->{Any} 左 右 説明と擬似コード
===============================================================
HASH1 HASH2 HASH1 と HASH2 両方が全て同じキー
like: keys HASH1 ==
grep { exists HASH2->{$_} } keys HASH1
ARRAY HASH いずれかの ARRAY 要素が HASH キーに存在するか
like: grep { exists HASH->{$_} } ARRAY
Regexp HASH いずれかの HASH キーが Regexp でマッチングするか
like: grep { /Regexp/ } keys HASH
undef HASH 常に偽 (undef はキーになれない)
like: 0 == 1
Any HASH HASH キーが存在するか
like: exists HASH->{Any} Right operand is CODE: 右被演算子がコードリファレンス: Left Right Description and pseudocode
===============================================================
ARRAY CODE sub returns true on all ARRAY elements[1]
like: !grep { !CODE->($_) } ARRAY
HASH CODE sub returns true on all HASH keys[1]
like: !grep { !CODE->($_) } keys HASH
Any CODE sub passed Any returns true
like: CODE->(Any) 左 右 説明と擬似コード
===============================================================
ARRAY CODE 全ての ARRAY 要素に対してサブルーチンが真を返す [1]
like: !grep { !CODE->($_) } ARRAY
HASH CODE 全ての HASH キーに対してサブルーチンが真を返す [1]
like: !grep { !CODE->($_) } keys HASH
Any CODE サブルーチンに Any を渡して真を返す
like: CODE->(Any) Right operand is a Regexp: 右被演算子が正規表現: Left Right Description and pseudocode
===============================================================
ARRAY Regexp any ARRAY elements match Regexp
like: grep { /Regexp/ } ARRAY
HASH Regexp any HASH keys match Regexp
like: grep { /Regexp/ } keys HASH
Any Regexp pattern match
like: Any =~ /Regexp/ 左 右 説明と擬似コード
===============================================================
ARRAY Regexp いずれかの ARRAY 要素が Regexp にマッチングするか
like: grep { /Regexp/ } ARRAY
HASH Regexp いずれかの HASH キーが Regexp にマッチングするか
like: grep { /Regexp/ } keys HASH
Any Regexp パターンマッチング
like: Any =~ /Regexp/ Other: その他: Left Right Description and pseudocode
===============================================================
Object Any invoke ~~ overloading on Object,
or fall back to... 左 右 説明と擬似コード
===============================================================
Object Any Object に対して ~~ のオーバーロードを起動、
あるいは次にフォールバック… Any Num numeric equality
like: Any == Num
Num nummy[4] numeric equality
like: Num == nummy
undef Any check whether undefined
like: !defined(Any)
Any Any string equality
like: Any eq Any Any Num 数値の等価性
like: Any == Num
Num nummy[4] 数値の等価性
like: Num == nummy
undef Any 未定義かどうかを調べる
like: !defined(Any)
Any Any 文字列の等価性
like: Any eq AnyNotes:
注意:
- 1. Empty hashes or arrays match.
-
(1. 空ハッシュや配列はマッチングします。)
- 2. That is, each element smartmatches the element of the same index in the other array.[3]
-
(2. つまり、それぞれの要素は他の配列の同じインデックスの要素とスマートマッチングします。[3])
- 3. If a circular reference is found, fall back to referential equality.
-
(3. 循環参照が見つかると、参照の等価性にフォールバックします。)
- 4. Either an actual number, or a string that looks like one.
-
(4. 実際の数値か、数値に見える文字列のどちらかです。)
The smartmatch implicitly dereferences any non-blessed hash or array reference, so the HASH and ARRAY entries apply in those cases. For blessed references, the Object entries apply. Smartmatches involving hashes only consider hash keys, never hash values.
スマートマッチングは bless されていないハッシュや配列のリファレンスを暗黙に デリファレンスするので、それらの場合では HASH と ARRAY の エントリが適用されます。 bless されたリファレンスでは、Object エントリが適用されます。 ハッシュに関連するスマートマッチングはキーのみを考慮し、ハッシュの値は 考慮しません。
The "like" code entry is not always an exact rendition. For example, the smartmatch operator short-circuits whenever possible, but grep does not. Also, grep in scalar context returns the number of matches, but ~~ returns only true or false.
"like" コードエントリは常に正確な処理を行うわけではありません。 例えば、スマートマッチング演算子は可能なら短絡しますが、grep はしません。 また、スカラコンテキストでは grep はマッチングした数を返しますが、 ~~ は真か偽かのみを返します。
Unlike most operators, the smartmatch operator knows to treat undef specially:
ほとんどの演算子と異なり、スマートマッチング演算子は undef を特別に 扱う方法を知っています:
use v5.10.1;
@array = (1, 2, 3, undef, 4, 5);
say "some elements undefined" if undef ~~ @array;Each operand is considered in a modified scalar context, the modification being that array and hash variables are passed by reference to the operator, which implicitly dereferences them. Both elements of each pair are the same:
それぞれのオペランドは修正されたスカラコンテキストと考えられます; 修正というのは、配列とハッシュの変数は演算子にリファレンスが渡され、 暗黙にデリファレンスされます。 それぞれの組のどちらの要素も同じです:
use v5.10.1;
my %hash = (red => 1, blue => 2, green => 3,
orange => 4, yellow => 5, purple => 6,
black => 7, grey => 8, white => 9);
my @array = qw(red blue green);
say "some array elements in hash keys" if @array ~~ %hash;
say "some array elements in hash keys" if \@array ~~ \%hash;
say "red in array" if "red" ~~ @array;
say "red in array" if "red" ~~ \@array;
say "some keys end in e" if /e$/ ~~ %hash;
say "some keys end in e" if /e$/ ~~ \%hash;Two arrays smartmatch if each element in the first array smartmatches (that is, is "in") the corresponding element in the second array, recursively.
二つの配列は、最初の配列のそれぞれの要素が、二つ目の配列の対応する要素に (つまり "in") 再帰的にスマートマッチングするときに、スマートマッチングします。
use v5.10.1;
my @little = qw(red blue green);
my @bigger = ("red", "blue", [ "orange", "green" ] );
if (@little ~~ @bigger) { # true!
say "little is contained in bigger";
}Because the smartmatch operator recurses on nested arrays, this will still report that "red" is in the array.
スマートマッチング演算子はネストした配列を再帰するので、これは "red" が 配列にいると報告するままです。
use v5.10.1;
my @array = qw(red blue green);
my $nested_array = [[[[[[[ @array ]]]]]]];
say "red in array" if "red" ~~ $nested_array;If two arrays smartmatch each other, then they are deep copies of each others' values, as this example reports:
二つの配列が互いにスマートマッチングすると、次の例が報告しているように、 互いの値のディープコピーになります:
use v5.12.0;
my @a = (0, 1, 2, [3, [4, 5], 6], 7);
my @b = (0, 1, 2, [3, [4, 5], 6], 7);
if (@a ~~ @b && @b ~~ @a) {
say "a and b are deep copies of each other";
}
elsif (@a ~~ @b) {
say "a smartmatches in b";
}
elsif (@b ~~ @a) {
say "b smartmatches in a";
}
else {
say "a and b don't smartmatch each other at all";
}If you were to set $b[3] = 4, then instead of reporting that "a and b are deep copies of each other", it now reports that "b smartmatches in a". That's because the corresponding position in @a contains an array that (eventually) has a 4 in it.
$b[3] = 4 に設定すると、"a and b are deep copies of each other" と 報告されるのではなく、"b smartmatches in a" と報告されます。 これは、@a の対応する位置には(最終的に)中に 4 がある配列を 含んでいるからです。
Smartmatching one hash against another reports whether both contain the same keys, no more and no less. This could be used to see whether two records have the same field names, without caring what values those fields might have. For example:
あるハッシュを他のものとスマートマッチングすると、両方に同じキーが 含まれているかどうかを報告し、それ以上でもそれ以下でもありません。 これは、値を気にせずに、二つのレコードが同じフィールド名を持っているか どうかを見るのに使えるかもしれません。 例えば:
use v5.10.1;
sub make_dogtag {
state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
my ($class, $init_fields) = @_;
die "Must supply (only) name, rank, and serial number"
unless $init_fields ~~ $REQUIRED_FIELDS;
...
}However, this only does what you mean if $init_fields is indeed a hash reference. The condition $init_fields ~~ $REQUIRED_FIELDS also allows the strings "name", "rank", "serial_num" as well as any array reference that contains "name" or "rank" or "serial_num" anywhere to pass through.
しかし、これは $init_fields が確かにハッシュリファレンスである場合にのみ 考えている通りに動作します。 $init_fields ~~ $REQUIRED_FIELDS という条件は、文字列 "name", "rank", "serial_num" および、 "name", "rank", "serial_num" のいずれかを含むような 配列リファレンスでも成立します。
The smartmatch operator is most often used as the implicit operator of a when clause. See the section on "Switch Statements" in perlsyn.
スマートマッチング演算子は when 節の暗黙の演算子としてもっともよく 使われます。 perlsyn の "Switch Statements" の節を参照してください。
オブジェクトのスマートマッチング¶
To avoid relying on an object's underlying representation, if the smartmatch's right operand is an object that doesn't overload ~~, it raises the exception "Smartmatching a non-overloaded object breaks encapsulation". That's because one has no business digging around to see whether something is "in" an object. These are all illegal on objects without a ~~ overload:
オブジェクトの基となる表現に依存することを避けるために、スマートマッチングの 右オペランドが ~~ をオーバーロードしないオブジェクトなら、例外 "Smartmatching a non-overloaded object breaks encapsulation" が発生します。 これは、何かがオブジェクトに「含まれている」かどうかを知るために 調べる筋合いではないからです。 次のものは ~~ のオーバーロードがなければ全て不正です:
%hash ~~ $object
42 ~~ $object
"fred" ~~ $objectHowever, you can change the way an object is smartmatched by overloading the ~~ operator. This is allowed to extend the usual smartmatch semantics. For objects that do have an ~~ overload, see overload.
しかし、~~ 演算子をオーバーロードすることにオブジェクトが スマートマッチングする方法を変更できます。 これにより通常のスマートマッチングの意味論を拡張できます。 ~~ のオーバーロードを持つオブジェクトについては、overload を 参照してください。
Using an object as the left operand is allowed, although not very useful. Smartmatching rules take precedence over overloading, so even if the object in the left operand has smartmatch overloading, this will be ignored. A left operand that is a non-overloaded object falls back on a string or numeric comparison of whatever the ref operator returns. That means that
左オペランドにオブジェクトを使うことは許されていますが、あまり 有用ではありません。 スマートマッチングの規則はオーバーロードより優先順位が高いので、例え 左オペランドのオブジェクトがスマートマッチングのオーバーロードを 持っていても、無視されます。 左オペランドがオーバーロードされていないオブジェクトなら、ref 演算子が 返したものに従って、文字または数値比較にフォールバックします。 これは、
$object ~~ Xdoes not invoke the overload method with X as an argument. Instead the above table is consulted as normal, and based on the type of X, overloading may or may not be invoked. For simple strings or numbers, "in" becomes equivalent to this:
は X を引数としてオーバーロードメソッドを起動 しない ということです。 通常通り前述の表を見て X の型に依存するのではなく、オーバーロードは 起動されるかもしれませんし、されないかもしれません。 単純な文字列や数値については、"in" は以下と等価になります:
$object ~~ $number ref($object) == $number
$object ~~ $string ref($object) eq $stringFor example, this reports that the handle smells IOish (but please don't really do this!):
例えば、これは "handle smells IOish" と報告します (しかし実際にこれを しないでください!):
use IO::Handle;
my $fh = IO::Handle->new();
if ($fh ~~ /\bIO\b/) {
say "handle smells IOish";
}That's because it treats $fh as a string like "IO::Handle=GLOB(0x8039e0)", then pattern matches against that.
これは、$fh を "IO::Handle=GLOB(0x8039e0)" のような文字列として扱い、 それからパターンはこれに対してマッチングするからです。
ビットごとの AND¶
Binary "&" returns its operands ANDed together bit by bit. Although no warning is currently raised, the result is not well defined when this operation is performed on operands that aren't either numbers (see "Integer Arithmetic") nor bitstrings (see "Bitwise String Operators").
二項演算子の "&" は、両オペランドのビットごとに論理積をとって、 その結果を返します。 数値 ("Integer Arithmetic") 参照) でもビット文字列 ("Bitwise String Operators" 参照) でもないオペランドに対してこの演算を 実行した場合、現在のところ警告は出ませんが、結果は未定義です。
Note that "&" has lower priority than relational operators, so for example the parentheses are essential in a test like
"&" は関係演算子より優先順位が低いので、例えば以下のようなテストでは、 かっこが重要です:
print "Even\n" if ($x & 1) == 0;If the "bitwise" feature is enabled via use feature 'bitwise' or use v5.28, then this operator always treats its operands as numbers. Before Perl 5.28 this feature produced a warning in the "experimental::bitwise" category.
use feature 'bitwise' か use v5.28 によって "bitwise" 機能が 有効になっている場合、この演算子はオペランドを常に数値として扱います。 Perl 5.28 より前ではこの機能は "experimental::bitwise" カテゴリの 警告が出力されていました。
ビットごとの OR と XOR¶
Binary "|" returns its operands ORed together bit by bit.
二項演算子の "|" は、両オペランドのビットごとに論理和をとって、 その結果を返します。
Binary "^" returns its operands XORed together bit by bit.
二項演算子の "^" は、両オペランドのビットごとに排他論理和をとって、 その結果を返します。
Although no warning is currently raised, the results are not well defined when these operations are performed on operands that aren't either numbers (see "Integer Arithmetic") nor bitstrings (see "Bitwise String Operators").
数値 ("Integer Arithmetic") 参照) でもビット文字列 ("Bitwise String Operators" 参照) でもないオペランドに対してこれらの演算を 実行した場合、現在のところ警告は出ませんが、結果は未定義です。
Note that "|" and "^" have lower priority than relational operators, so for example the parentheses are essential in a test like
"|" と "^" は関係演算子より優先順位が低いので、例えば以下のような テストでは、かっこが重要です:
print "false\n" if (8 | 2) != 10;If the "bitwise" feature is enabled via use feature 'bitwise' or use v5.28, then this operator always treats its operands as numbers. Before Perl 5.28. this feature produced a warning in the "experimental::bitwise" category.
use feature 'bitwise' か use v5.28 によって "bitwise" 機能が 有効になっている場合、この演算子はオペランドを常に数値として扱います。 Perl 5.28 より前ではこの機能は "experimental::bitwise" カテゴリの 警告が出力されていました。
C スタイルの論理積¶
Binary "&&" performs a short-circuit logical AND operation. That is, if the left operand is false, the right operand is not even evaluated. Scalar or list context propagates down to the right operand if it is evaluated.
二項演算子の "&&" は、短絡の論理積演算を行ないます。 つまり、左被演算子が偽であれば、右被演算子は評価さえ 行なわれないということです。 評価される場合には、スカラかリストかというコンテキストは、 右被演算子に及びます。
C スタイルの論理和¶
Binary "||" performs a short-circuit logical OR operation. That is, if the left operand is true, the right operand is not even evaluated. Scalar or list context propagates down to the right operand if it is evaluated.
二項演算子の "||" は、短絡の論理和演算を行ないます。 つまり、左被演算子が真であれば、右被演算子は評価さえ 行なわれないということです。 評価される場合には、スカラかリストかというコンテキストは、 右被演算子に及びます。
C スタイルの排他的論理和¶
Binary "^^" performs a logical XOR operation. Both operands are evaluated and the result is true only if exactly one of the operands is true. Scalar or list context propagates down to the right operand.
二項演算子の "^^" は、短絡の排他的論理和演算を行ないます。 両方の被演算子が評価され、被演算子の一つだけが真の時にだけ真になります。 スカラかリストかというコンテキストは、右被演算子に及びます。
論理定義性和¶
Although it has no direct equivalent in C, Perl's // operator is related to its C-style "or". In fact, it's exactly the same as ||, except that it tests the left hand side's definedness instead of its truth. Thus, EXPR1 // EXPR2 returns the value of EXPR1 if it's defined, otherwise, the value of EXPR2 is returned. (EXPR1 is evaluated in scalar context, EXPR2 in the context of // itself). Usually, this is the same result as defined(EXPR1) ? EXPR1 : EXPR2 (except that the ternary-operator form can be used as a lvalue, while EXPR1 // EXPR2 cannot). This is very useful for providing default values for variables. If you actually want to test if at least one of $x and $y is defined, use defined($x // $y).
C では直接等価なものはありませんが、Perl の // 演算子は C スタイル 論理和に関連しています。 実際、左辺の真偽ではなく定義されているかを判定することを除けば || と同じです。 従って EXPR1 // EXPR2 は、EXPR1 が定義されていればその値を 返し、さもなければ、EXPR2 の値を返します。 (EXPR1 はスカラコンテキストで、EXPR2 は // 自身の コンテキストで評価されます。) 普通はこれは defined(EXPR1) ? EXPR1 : EXPR2 と同じ結果になり 完全に等価です (例外は 3 項演算子形式は左辺値として使えますが、 EXPR1 // EXPR2 は使えません)。 これは、変数に対するデフォルト値を設定するのにとても有用です。 実際に、$x と $y の少なくとも片方が定義されているかを判定したいなら、 defined($x // $y) を使ってください。
The ||, // and && operators return the last value evaluated (unlike C's || and &&, which return 0 or 1). Thus, a reasonably portable way to find out the home directory might be:
||, //, && 演算子は、(C のように 単に 0 や 1 を返すのではなく) 最後に評価された値を返します。 これにより、かなり一般的に使えるホームディレクトリを探す方法は:
$home = $ENV{HOME}
// $ENV{LOGDIR}
// (getpwuid($<))[7]
// die "You're homeless!\n";In particular, this means that you shouldn't use this for selecting between two aggregates for assignment:
特に、これは代入のために二つの集合を選択するためには 使うべきではないことを意味します。
@a = @b || @c; # This doesn't do the right thing
@a = scalar(@b) || @c; # because it really means this.
@a = @b ? @b : @c; # This works fine, though.As alternatives to && and || when used for control flow, Perl provides the and and or operators (see below). The short-circuit behavior is identical. The precedence of "and" and "or" is much lower, however, so that you can safely use them after a list operator without the need for parentheses:
Perl では、フロー制御に使う場合の && と || の同義語として、 and 演算子と or 演算子が用意されています (下記参照)。 短絡の動作は全く同じです。 しかし、"and" と "or" の優先順位はかなり低くしてあるので、引数に括弧を 使っていないリスト演算子のあとに続けて使う場合にも、 安心して使うことができます:
unlink "alpha", "beta", "gamma"
or gripe(), next LINE;With the C-style operators that would have been written like this:
C スタイルの演算子では以下のように書く必要があります。
unlink("alpha", "beta", "gamma")
|| (gripe(), next LINE);It would be even more readable to write that this way:
次のようにして書き込みをより読みやすくすることもできます:
unless(unlink("alpha", "beta", "gamma")) {
gripe();
next LINE;
}Using "or" for assignment is unlikely to do what you want; see below.
代入で "or" を使うと、したいことと違うことになります; 以下を 参照して下さい。
範囲演算子¶
Binary ".." is the range operator, which is really two different operators depending on the context. In list context, it returns a list of values counting (up by ones) from the left value to the right value. If the left value is greater than the right value then it returns the empty list. The range operator is useful for writing foreach (1..10) loops and for doing slice operations on arrays. In the current implementation, no temporary array is created when the range operator is used as the expression in foreach loops, but older versions of Perl might burn a lot of memory when you write something like this:
二項演算子の ".." は範囲演算子で、使われるコンテキストによって 異なる動作をする 2 つの演算子を合わせたものです。 リストコンテキストでは、左の値から右の値まで (1 づつ昇順で) 数えあげた値から なるリストを返します。 左側の値が右側の値より大きい場合は、空リストを返します。 範囲演算子は、foreach (1..10) のようなループを書くときや、 配列のスライス演算を行なうときに便利です。 現状の実装では、foreach ループの式の中で範囲演算子を使っても 一時配列は作りませんが、古い Perl は以下のようなことを書くと、 大量のメモリを消費することになります:
for (1 .. 1_000_000) {
# code
}The range operator also works on strings, using the magical auto-increment, see below.
範囲演算子は、マジカル自動インクリメントを使うことで文字列でも動作します; 以下を参照してください。
In scalar context, ".." returns a boolean value. The operator is bistable, like a flip-flop, and emulates the line-range (comma) operator of sed, awk, and various editors. Each ".." operator maintains its own boolean state, even across calls to a subroutine that contains it. It is false as long as its left operand is false. Once the left operand is true, the range operator stays true until the right operand is true, AFTER which the range operator becomes false again. It doesn't become false till the next time the range operator is evaluated. It can test the right operand and become false on the same evaluation it became true (as in awk), but it still returns true once. If you don't want it to test the right operand until the next evaluation, as in sed, just use three dots ("...") instead of two. In all other regards, "..." behaves just like ".." does.
スカラコンテキストで使われたときには、".." は真偽値を返します。 この演算子は、フリップフロップのように 2 値安定で、 sed や awk や多くのエディタでの行範囲 (コンマ) 演算子を エミュレートするものとなります。 各々の ".." 演算子は、例えそれを含むサブルーチンの呼び出しを またいでも、それぞれに独立して自分の真偽状態を管理します。 はじめは、左被演算子が偽である間、演算全体も偽となっています。 いったん左被演算子が真になると、範囲演算子は、右被演算子が真である間、 真を返すようになります; 範囲演算子が再び偽になった 後 です。 次に範囲演算子が評価されるまでは、偽とはなりません。 (awk でのように) 真となった、その評価の中で右被演算子をテストし、 偽とすることができますが、1 度は真を返すことになります。 sed でのように、次に評価されるまで右被演算子をテストしたくなければ、 2 個のドットの代わりに 3 つのドット ("...") を使ってください。 その他の点では、"..." は ".." と同様に振舞います．
The right operand is not evaluated while the operator is in the "false" state, and the left operand is not evaluated while the operator is in the "true" state. The precedence is a little lower than || and &&. The value returned is either the empty string for false, or a sequence number (beginning with 1) for true. The sequence number is reset for each range encountered. The final sequence number in a range has the string "E0" appended to it, which doesn't affect its numeric value, but gives you something to search for if you want to exclude the endpoint. You can exclude the beginning point by waiting for the sequence number to be greater than 1.
右被演算子は、演算子の状態が「偽」である間は評価されることがなく、 左被演算子は、演算子の状態が「真」である間は評価されることがありません。 優先順位は、|| と && の少し下です。 偽としては空文字列が返され、 真としては (1 から始まる) 通し番号が返されます。 この通し番号は、新たに範囲が始まるごとにリセットされます。 範囲の最後の通し番号には、文字列 "E0" が末尾につけられます; これは、 数値としては何の影響もありませんが、範囲の終わりで何か特別なことをしたい 場合に、目印として使うことができます。 範囲の始まりを除きたい場合には、通し番号が 1 よりも大きくなるのを 待てばよいでしょう。
If either operand of scalar ".." is a constant expression, that operand is considered true if it is equal (==) to the current input line number (the $. variable).
スカラの ".." の被演算子が定数表現であるときは、その被演算子は暗黙に、 現在の入力行番号(変数 $.) と等しい(==) 場合に真となります。
To be pedantic, the comparison is actually int(EXPR) == int(EXPR), but that is only an issue if you use a floating point expression; when implicitly using $. as described in the previous paragraph, the comparison is int(EXPR) == int($.) which is only an issue when $. is set to a floating point value and you are not reading from a file. Furthermore, "span" .. "spat" or 2.18 .. 3.14 will not do what you want in scalar context because each of the operands are evaluated using their integer representation.
とても細かい話をすると、比較は実際には int(EXPR) == int(EXPR) ですが、 これは浮動小数点数を使うときにだけ問題になります; 前の段落で記述したように 明示的に $. を使ったとき、比較は int(EXPR) == int($.) となり、 $. に浮動小数点数がセットされ、ファイルから読み込みを行わない場合にのみ 問題になります。 さらに、"span" .. "spat" や 2.18 .. 3.14 は、それぞれの オペランドが整数表現を使って評価されるため、スカラコンテキストでは 望みどおりの結果になりません。
Examples:
例:
As a scalar operator:
スカラ演算子として:
if (101 .. 200) { print; } # print 2nd hundred lines, short for
# if ($. == 101 .. $. == 200) { print; }
next LINE if (1 .. /^$/); # skip header lines, short for
# next LINE if ($. == 1 .. /^$/);
# (typically in a loop labeled LINE)
s/^/> / if (/^$/ .. eof()); # quote body
# parse mail messages
while (<>) {
$in_header = 1 .. /^$/;
$in_body = /^$/ .. eof;
if ($in_header) {
# do something
} else { # in body
# do something else
}
} continue {
close ARGV if eof; # reset $. each file
}Here's a simple example to illustrate the difference between the two range operators:
以下は二つの範囲演算子の違いを示す単純な例です:
@lines = (" - Foo",
"01 - Bar",
"1 - Baz",
" - Quux");
foreach (@lines) {
if (/0/ .. /1/) {
print "$_\n";
}
}This program will print only the line containing "Bar". If the range operator is changed to ..., it will also print the "Baz" line.
このプログラムは "Bar" を含む行だけを表示します。 範囲演算子を ... に変更すると、"Baz" の行も表示します。
And now some examples as a list operator:
これはリスト演算子の例です:
for (101 .. 200) { print } # print $_ 100 times
@foo = @foo[0 .. $#foo]; # an expensive no-op
@foo = @foo[$#foo-4 .. $#foo]; # slice last 5 items for (101 .. 200) { print } # $_ を 100 回出力
@foo = @foo[0 .. $#foo]; # 高価な no-op
@foo = @foo[$#foo-4 .. $#foo]; # 末尾の 5 アイテムをスライスBecause each operand is evaluated in integer form, 2.18 .. 3.14 will return two elements in list context.
それぞれのオペランドは整数の形で評価されるので、2.18 .. 3.14 は リストコンテキストでは二つの要素を返します。
@list = (2.18 .. 3.14); # same as @list = (2 .. 3); @list = (2.18 .. 3.14); # @list = (2 .. 3); と同じThe range operator in list context can make use of the magical auto-increment algorithm if both operands are strings, subject to the following rules:
リストコンテキストでの範囲演算子は、両方のオペランドが 文字列であるときには、次の規則に従って、マジカルインクリメントの 機能が使えます。
-
With one exception (below), if both strings look like numbers to Perl, the magic increment will not be applied, and the strings will be treated as numbers (more specifically, integers) instead.
一つの例外(後述)を除いて、 両側の文字列が Perl にとって数値に見える場合、 マジカルインクリメントは適用されず、代わりにその文字列は数値として (より正確には、整数として)扱われます。
For example,
"-2".."2"is the same as-2..2, and"2.18".."3.14"produces2, 3.例えば、
"-2".."2"は-2..2と同じで、"2.18".."3.14"は2, 3を生成します。 -
The exception to the above rule is when the left-hand string begins with
0and is longer than one character, in this case the magic increment will be applied, even though strings like"01"would normally look like a number to Perl.前述の規則の例外として、 左側の文字列が
0で始まっていて 2 文字以上の場合、"01"のような文字列は通常 Perl にとって数値に見えるにも関わらず、 この場合はマジカルインクリメントは 適用されます 。For example,
"01".."04"produces"01", "02", "03", "04", and"00".."-1"produces"00"through"99"- this may seem surprising, but see the following rules for why it works this way. To get dates with leading zeros, you can say:例えば、
"01".."04"は"01", "02", "03", "04"を生成し、"00".."-1"は"00"から"99"を生成します - これは驚きがあるかも しれませんが、なぜこれがこのように動作するのかについては 次の規則を見てください。 先頭に 0 があるものから日付を取り出すために、次のようにできます:@z2 = ("01" .. "31"); print $z2[$mday];If you want to force strings to be interpreted as numbers, you could say
文字列が数値として解釈することを強制したいなら、次のようにできます:
@numbers = ( 0+$first .. 0+$last );Note: In Perl versions 5.30 and below, any string on the left-hand side beginning with
"0", including the string"0"itself, would cause the magic string increment behavior. This means that on these Perl versions,"0".."-1"would produce"0"through"99", which was inconsistent with0..-1, which produces the empty list. This also means that"0".."9"now produces a list of integers instead of a list of strings.注意: Perl バージョン 5.30 以下では、左側が
"0"で始まる 任意の 文字列 (文字列"0"自体を含む)は、マジカル文字列 インクリメントを引き起こします。 つまり、これらの Perl バージョンでは、"0".."-1"は"0"から"99"までを生成しますが、これは空のリストを生成する0..-1と 矛盾していました。 また、"0".."9"では、文字列のリストではなく整数のリストが 生成されるということです。 -
If the initial value specified isn't part of a magical increment sequence (that is, a non-empty string matching
/^[a-zA-Z]*[0-9]*\z/), only the initial value will be returned.指定された初期値がマジカルインクリメント処理の一部でない場合 (つまり、
/^[a-zA-Z]*[0-9]*\z/にマッチングする、空でない文字列の場合)、 初期値のみが返されます。For example,
"ax".."az"produces"ax", "ay", "az", but"*x".."az"produces only"*x".例えば、
"ax".."az"は"ax", "ay", "az"を生成しますが、"*x".."az"は"*x"だけを生成します。 -
For other initial values that are strings that do follow the rules of the magical increment, the corresponding sequence will be returned.
マジカルインクリメントの規則に従う文字列がもう片方の初期値の場合、 対応する並びが返されます。
For example, you can say
例えば以下のように書くと:
@alphabet = ("A" .. "Z");to get all normal letters of the English alphabet, or
英語の大文字すべてを得られますし:
$hexdigit = (0 .. 9, "a" .. "f")[$num & 15];to get a hexadecimal digit.
と書けば、16 進の数字が得られます。
-
If the final value specified is not in the sequence that the magical increment would produce, the sequence goes until the next value would be longer than the final value specified. If the length of the final string is shorter than the first, the empty list is returned.
マジカルインクリメントによって得られる値の中に指定した最終値に ちょうど一致するものが見つからないような場合には、 マジカルインクリメントによって得られる次の値の文字列長が、 最終値として指定した値のものより長くなるまでインクリメントが続けられます。 最終値の文字列の長さが最初のものより短い場合、 空リストが返されます。
For example,
"a".."--"is the same as"a".."zz","0".."xx"produces"0"through"99", and"aaa".."--"returns the empty list.例えば、
"a".."--"は"a".."zz"と同じで、"0".."xx"は"0"から"99"を出力し、"aaa".."--"は空リストを返します。
As of Perl 5.26, the list-context range operator on strings works as expected in the scope of "use feature 'unicode_strings". In previous versions, and outside the scope of that feature, it exhibits "The "Unicode Bug"" in perlunicode: its behavior depends on the internal encoding of the range endpoint.
Perl 5.26 から、文字列に対するリストコンテキスト範囲演算子は、 "use feature 'unicode_strings" のスコープの中で想定通りに 動作するようになりました。 以前のバージョン、およびこの機能のスコープの外側では、 これは "The "Unicode Bug"" in perlunicode を起こしていました: その振る舞いは範囲の両端の内部エンコーディングに依存していました。
Because the magical increment only works on non-empty strings matching /^[a-zA-Z]*[0-9]*\z/, the following will only return an alpha:
マジカルインクリメントは /^[a-zA-Z]*[0-9]*\z/ にマッチングする 空でない文字列でのみ動作するので、 以下はαのみを返します:
use charnames "greek";
my @greek_small = ("\N{alpha}" .. "\N{omega}");To get the 25 traditional lowercase Greek letters, including both sigmas, you could use this instead:
両方のシグマを含む、25 文字の伝統的な小文字のギリシャ文字を得るためには、 代わりに以下のようにしてください:
use charnames "greek";
my @greek_small = map { chr } ( ord("\N{alpha}")
..
ord("\N{omega}")
);However, because there are many other lowercase Greek characters than just those, to match lowercase Greek characters in a regular expression, you could use the pattern /(?:(?=\p{Greek})\p{Lower})+/ (or the experimental feature /(?[ \p{Greek} & \p{Lower} ])+/).
しかし、小文字のギリシャ文字はここに書いたものよりも たくさん あるので、 正規表現で小文字のギリシャ文字にマッチングさせるためには、 /(?:(?=\p{Greek})\p{Lower})+/ というパターン (または 実験的機能 である /(?[ \p{Greek} & \p{Lower} ])+/) を使います。
条件演算子¶
Ternary "?:" is the conditional operator, just as in C. It works much like an if-then-else. If the argument before the ? is true, the argument before the : is returned, otherwise the argument after the : is returned. For example:
三項演算子の "?:" は、C の場合と同じ条件演算子です。 これは、if-then-else のように働きます。 "?" の前の引数が真であれば ":" の前の引数が返されますが、 真でなければ、":" の後の引数が返されます。 例えば:
printf "I have %d dog%s.\n", $n,
($n == 1) ? "" : "s";Scalar or list context propagates downward into the 2nd or 3rd argument, whichever is selected.
スカラコンテキストかリストコンテキストかという状況は、 選択された 2 番目もしくは 3 番目の引数にまで伝わります。
$x = $ok ? $y : $z; # get a scalar
@x = $ok ? @y : @z; # get an array
$x = $ok ? @y : @z; # oops, that's just a count! $x = $ok ? $y : $z; # スカラを取る
@x = $ok ? @y : @z; # 配列を取る
$x = $ok ? @y : @z; # うわ、これは単なる数です!The operator may be assigned to if both the 2nd and 3rd arguments are legal lvalues (meaning that you can assign to them):
2 番目と 3 番目の引数双方が左辺値 (代入可能ということ)であれば、 この演算子に代入を行なうこともできます:
($x_or_y ? $x : $y) = $z;Because this operator produces an assignable result, using assignments without parentheses will get you in trouble. For example, this:
この演算子は代入可能な結果を生み出すので、 括弧なしで代入を行うとおかしくなるかもしれません。 例えばこれは:
$x % 2 ? $x += 10 : $x += 2Really means this:
以下を意味し:
(($x % 2) ? ($x += 10) : $x) += 2Rather than this:
以下のようにはなりません:
($x % 2) ? ($x += 10) : ($x += 2)That should probably be written more simply as:
恐らく以下のようにもっと単純に書くべきでしょう:
$x += ($x % 2) ? 10 : 2;代入演算子¶
"=" is the ordinary assignment operator.
"=" は通常の代入演算子です。
Assignment operators work as in C. That is,
代入演算子は C の場合と同様の働きをします。 つまり、
$x += 2;is equivalent to
は以下と等価です:
$x = $x + 2;although without duplicating any side effects that dereferencing the lvalue might trigger, such as from tie(). Other assignment operators work similarly. The following are recognized:
しかし、tie() のようなもので起こる左辺値の被参照による 副作用が 2 回起こることはありません。 他の代入演算も同様に働きます。 以下のものが認識されます:
**= += *= &= &.= <<= &&=
-= /= |= |.= >>= ||=
.= %= ^= ^.= //=
x=Although these are grouped by family, they all have the precedence of assignment. These combined assignment operators can only operate on scalars, whereas the ordinary assignment operator can assign to arrays, hashes, lists and even references. (See "Context" and "List value constructors" in perldata, and "Assigning to References" in perlref.)
グループ分けしてありますが、これらはいずれも代入演算子として 同じ優先順位となっています。 これらの複合代入演算子はスカラとしてのみ動作しますが、一方 通常の代入演算子は配列、スカラ、リスト、リファレンスに代入できます。 ("Context", "List value constructors" in perldata, "Assigning to References" in perlref を参照してください。)
Unlike in C, the scalar assignment operator produces a valid lvalue. Modifying an assignment is equivalent to doing the assignment and then modifying the variable that was assigned to. This is useful for modifying a copy of something, like this:
C と違って、スカラ代入演算子は有効な左辺値を作り出します。 代入を修正することは、代入を行なってから、その代入された変数を修正するのと 同じことになります。 これは、以下のように何かのコピーを変更したいときに便利です:
($tmp = $global) =~ tr/13579/24680/;Although as of 5.14, that can be also be accomplished this way:
しかし 5.14 現在、これは次のようにしてもできるようになりました:
use v5.14;
$tmp = ($global =~ tr/13579/24680/r);Likewise,
同様に、
($x += 2) *= 3;is equivalent to
は以下と等価です:
$x += 2;
$x *= 3;Similarly, a list assignment in list context produces the list of lvalues assigned to, and a list assignment in scalar context returns the number of elements produced by the expression on the right hand side of the assignment.
同様に、リストコンテキストでのリストへの代入は代入可能な左辺値のリストとなり、 スカラコンテキストでのリストへの代入は代入の右側の式で作成された 要素の数を返します。
The three dotted bitwise assignment operators (&.= |.= ^.=) are new in Perl 5.22. See "Bitwise String Operators".
三つのドット付きビット単位代入演算子 (&.= |.= ^.=) は Perl 5.22 からの新しいものです。 "Bitwise String Operators" を参照してください。
コンマ演算子¶
Binary "," is the comma operator. In scalar context it evaluates its left argument, throws that value away, then evaluates its right argument and returns that value. This is just like C's comma operator.
二項演算子の "," はコンマ演算子です。 スカラコンテキストではその左引数を評価し、その値を捨てて、 それから右引数を評価し、その値を返します。 これはちょうど、C のコンマ演算子と同じです。
In list context, it's just the list argument separator, and inserts both its arguments into the list. These arguments are also evaluated from left to right.
リストコンテキストでは、これは単にリスト引数の区切り文字で、 双方の引数をそのリストに挿入する働きがあります。 これらの引数も左から右に評価されます。
The => operator (sometimes pronounced "fat comma") is a synonym for the comma except that it causes a word on its left to be interpreted as a string if it begins with a letter or underscore and is composed only of letters, digits and underscores. This includes operands that might otherwise be interpreted as operators, constants, single number v-strings or function calls. If in doubt about this behavior, the left operand can be quoted explicitly.
=> 演算子(時々「ファットコンマ」と発音されます)はコンマ演算子の 同義語ですが、もし左側の単語が文字か下線で始まっていて、かつ文字、数字、 下線でのみ構成されている場合、これを文字列として扱うという効果もあります。 これには他の場所では演算子、定数、v-文字列、関数呼び出しとして扱われる オペランドを含みます。 この振る舞いについて迷うことがあるなら、左オペランドを明示的に クォートすることも出来ます。
Otherwise, the => operator behaves exactly as the comma operator or list argument separator, according to context.
さもなければ、=> 演算子はコンテキストによって、 カンマ演算子かリスト引数の区切り文字と全く同様に振る舞います。
For example:
例えば:
use constant FOO => "something";
my %h = ( FOO => 23 );is equivalent to:
は、以下と等価です:
my %h = ("FOO", 23);It is NOT:
これは 違います:
my %h = ("something", 23);The => operator is helpful in documenting the correspondence between keys and values in hashes, and other paired elements in lists.
=> 演算子は、ハッシュのキーと値や、その他のリスト中の組となる 要素の関係を表現するのに便利です。
%hash = ( $key => $value );
login( $username => $password );The special quoting behavior ignores precedence, and hence may apply to part of the left operand:
特殊なクォートの振る舞いは優先順位を無視し、従って左オペランドの 一部 に 適用されることがあります:
print time.shift => "bbb";That example prints something like "1314363215shiftbbb", because the => implicitly quotes the shift immediately on its left, ignoring the fact that time.shift is the entire left operand.
この例は "1314363215shiftbbb" のようなものを表示します; なぜなら => は暗黙にすぐ左にある shift をクォートし、 time.shift 全体が 左オペランドであるという事実を無視するからです。
リスト演算子 (右方向)¶
On the right side of a list operator, the comma has very low precedence, such that it controls all comma-separated expressions found there. The only operators with lower precedence are the logical operators "and", "or", and "not", which may be used to evaluate calls to list operators without the need for parentheses:
リスト演算子の右側のものにとって、カンマはとても低い優先順位になります; これによってコンマで区切った式をリスト演算子の引数として 置くことができます。 これよりも優先順位が低いものは、論理演算子の "and", "or", "not" のみで、括弧を付けないリスト演算子の呼び出しを評価するために使えます:
open HANDLE, "< :encoding(UTF-8)", "filename"
or die "Can't open: $!\n";However, some people find that code harder to read than writing it with parentheses:
しかし、かっこ付きで書くよりもコードが読みにくいという人もいます:
open(HANDLE, "< :encoding(UTF-8)", "filename")
or die "Can't open: $!\n";in which case you might as well just use the more customary "||" operator:
この場合、より慣習的な "||" 演算子も使えます:
open(HANDLE, "< :encoding(UTF-8)", "filename")
|| die "Can't open: $!\n";See also discussion of list operators in "Terms and List Operators (Leftward)".
"Terms and List Operators (Leftward)" のリスト演算子の議論も参照して下さい。
論理否定¶
Unary "not" returns the logical negation of the expression to its right. It's the equivalent of "!" except for the very low precedence.
単項演算子の "not" は右側に来る式の否定を返します。 これは、優先順位がずっと低いことを除いては "!" と等価です。
論理積¶
Binary "and" returns the logical conjunction of the two surrounding expressions. It's equivalent to && except for the very low precedence. This means that it short-circuits: the right expression is evaluated only if the left expression is true.
二項演算子の "and" は両側の式の論理積を返します。 これは、優先順位がずっと低いことを除けば && と等価です。 つまり、これも短絡演算を行ない、右側の式は左側の式が 「真」であった場合にのみ評価されます。
論理和と排他論理和¶
Binary "or" returns the logical disjunction of the two surrounding expressions. It's equivalent to || except for the very low precedence. This makes it useful for control flow:
二項演算子の "or" は両側の式の論理和を返します。 これは、優先順位がずっと低いことを除いて || と等価です。 これはフローを制御するのに有用です:
print FH $data or die "Can't write to FH: $!";This means that it short-circuits: the right expression is evaluated only if the left expression is false. Due to its precedence, you must be careful to avoid using it as replacement for the || operator. It usually works out better for flow control than in assignments:
つまり、これも短絡演算を行ない、右側の式は左側の式が 「偽」であった場合にのみ評価されます。 優先度の関係で、これを || 演算子の置き換えに使うのは慎重に 避けなければなりません。 これは普通代入よりも、フローの制御でうまく動作します:
$x = $y or $z; # bug: this is wrong
($x = $y) or $z; # really means this
$x = $y || $z; # better written this way $x = $y or $z; # バグ: これは間違い
($x = $y) or $z; # 本当にしたいこと
$x = $y || $z; # こう書いた方がいいHowever, when it's a list-context assignment and you're trying to use || for control flow, you probably need "or" so that the assignment takes higher precedence.
しかし、代入がリストコンテキストの時に || をフロー制御に使おうとする場合、 代入により大きな優先順位を持たせるために "or" が必要かもしれません。
@info = stat($file) || die; # oops, scalar sense of stat!
@info = stat($file) or die; # better, now @info gets its due @info = stat($file) || die; # うわ、stat がスカラの意味だ!
@info = stat($file) or die; # よりよい; @info はその目的を果たすThen again, you could always use parentheses.
もちろん、常に括弧をつけてもよいです。
Binary "xor" returns the exclusive-OR of the two surrounding expressions. It cannot short-circuit (of course).
二項演算子の "xor" は両側の式の排他論理和を返します。 これは (もちろん) 短絡できません。
There is no low precedence operator for defined-OR.
定義性論理和の低優先順位版はありません。
Perl にない C の演算子¶
Here is what C has that Perl doesn't:
C にあって Perl に無いものは以下の通りです:
- unary &
-
Address-of operator. (But see the
"\"operator for taking a reference.)アドレス演算子。 (しかし
"\"演算子がリファレンスのために用いられます。) - unary *
-
Dereference-address operator. (Perl's prefix dereferencing operators are typed:
$,@,%, and&.)被アドレス参照演算子。 (Perl の被参照プリフィクス演算子が型づけを行ないます:
$,@,%,&。) - (TYPE)
-
Type-casting operator.
型のキャスト演算子。
クォートとクォート風の演算子¶
While we usually think of quotes as literal values, in Perl they function as operators, providing various kinds of interpolating and pattern matching capabilities. Perl provides customary quote characters for these behaviors, but also provides a way for you to choose your quote character for any of them. In the following table, a {} represents any pair of delimiters you choose.
クォートはリテラル値であると考えるのが普通ですが、Perl において、 クォートは演算子として働き、さまざまな展開やパターンマッチの機能を 持っています。 そのような動作をさせるのに、Perl は慣習的にクォート文字を使っていますが、 どの種類のクォートも、自分でクォート文字を選べるようになっています。 以下の表では、{} がその選んだ区切文字のペアを示しています。
Customary Generic Meaning Interpolates
'' q{} Literal no
"" qq{} Literal yes
`` qx{} Command yes*
qw{} Word list no
// m{} Pattern match yes*
qr{} Pattern yes*
s{}{} Substitution yes*
tr{}{} Transliteration no (but see below)
y{}{} Transliteration no (but see below)
<<EOF here-doc yes* 通常記法 汎用記法 意味 展開
=================================================
'' q{} リテラル 不可
"" qq{} リテラル 可
`` qx{} コマンド 可 *
qw{} 単語リスト 不可
// m{} パターンマッチ 可 *
qr{} パターン 可 *
s{}{} 置換 可 *
tr{}{} 変換 不可 (但し以下を参照のこと)
y{}{} 変換 不可 (但し以下を参照のこと)
<<EOF ヒアドキュメント 可 * * unless the delimiter is ''. * '' がデリミタでない場合のみNon-bracketing delimiters use the same character fore and aft, but the four sorts of ASCII brackets (round, angle, square, curly) all nest, which means that
選んだ区切文字が括弧の類でない場合には、前後の文字として同一のものを 使いますが、4 つの ASCII のかっこ ((), <>, [], {}) の場合にはネストできます; つまり、以下のものは、
q{foo{bar}baz}is the same as
以下と同じです。
'foo{bar}baz'Note, however, that this does not always work for quoting Perl code:
しかし、以下のコードはクォートされた Perl コードでは いつも正しく動くわけではないことに注意してください:
$s = q{ if($x eq "}") ... }; # WRONGis a syntax error. The Text::Balanced module (standard as of v5.8, and from CPAN before then) is able to do this properly.
これは文法エラーとなります。 Text::Balanced モジュール(Perl 5.8 からは標準配布、それ以前は CPAN に あります)はこれを適切に行います。
If the extra_paired_delimiters feature is enabled, then Perl will additionally recognise a variety of Unicode characters as being paired. For a full list, see the "List of Extra Paired Delimiters" at the end of this document.
extra_paired_delimiters 機能が有効の場合、 Perl は追加で多くの Unicode 文字を組として認識します。 完全な一覧については、この末尾にある "List of Extra Paired Delimiters" を参照してください。
There can (and in some cases, must) be whitespace between the operator and the quoting characters, except when # is being used as the quoting character. q#foo# is parsed as the string foo, while q #foo# is the operator q followed by a comment. Its argument will be taken from the next line. This allows you to write:
演算子とクォート文字の間に空白を置くことも出来ます (そして場合によっては 必須です); ただし、# をクォート文字として使う場合は例外です。 q#foo# は文字列 foo としてパースされますが、 q #foo# は q 演算子の後にコメントがあるとみなされます。 この引数は次の行から取られます。つまり、以下のように書けます:
s {foo} # Replace foo
{bar} # with bar. s {foo} # foo を
{bar} # bar で置き換えるThe cases where whitespace must be used are when the quoting character is a word character (meaning it matches /\w/):
空白が使われなければならないのは、クォート文字が単語文字 (つまり /\w/ にマッチングする)の場合です:
q XfooX # Works: means the string 'foo'
qXfooX # WRONG!The following escape sequences are available in constructs that interpolate, and in transliterations whose delimiters aren't single quotes ("'"). In all the ones with braces, any number of blanks and/or tabs adjoining and within the braces are allowed (and ignored).
以下のエスケープシーケンスが、 区切り文字がシングルクォート ("'") でない展開と文字変換の構文で 利用可能です。 中かっこつきのもの全ては、中かっこの中で隣接している任意の数の空白や タブが許されます(そして無視されます)。
Sequence Note Description
\t tab (HT, TAB)
\n newline (NL)
\r return (CR)
\f form feed (FF)
\b backspace (BS)
\a alarm (bell) (BEL)
\e escape (ESC)
\x{263A} [1,8] hex char (example shown: SMILEY)
\x{ 263A } Same, but shows optional blanks inside and
adjoining the braces
\x1b [2,8] restricted range hex char (example: ESC)
\N{name} [3] named Unicode character or character sequence
\N{U+263D} [4,8] Unicode character (example: FIRST QUARTER MOON)
\c[ [5] control char (example: chr(27))
\o{23072} [6,8] octal char (example: SMILEY)
\033 [7,8] restricted range octal char (example: ESC) シーケンス 注意 説明
\t タブ (HT, TAB)
\n 改行 (NL)
\r 復帰 (CR)
\f 改ページ (FF)
\b バックスペース (BS)
\a アラーム (BEL)
\e エスケープ (ESC)
\x{263a} [1,8] 16 進文字 (例: SMILEY)
\x{ 263A } 同様、しかし中かっこの内側に隣接している
オプションの空白を示している
\x1b [2,8] 範囲制限された 16 進数で表した文字 (例: ESC)
\N{name} [3] 名前つき Unicode 文字または文字シーケンス
\N{U+263D} [4,8] Unicode 文字 (例: FIRST QUARTER MOON)
\c[ [5] 制御文字 (例: chr(27))
\o{23072} [6,8] 8 進文字 (例: SMILEY)
\033 [7,8] 範囲制限された 8 進文字 (例: ESC)Note that any escape sequence using braces inside interpolated constructs may have optional blanks (tab or space characters) adjoining with and inside of the braces, as illustrated above by the second \x{ } example.
変数置換構文の中の中かっこを使ったエスケープシーケンスは、 前述の 2 番目の \x{ } の例で図示したように、中かっこの内側隣接の 位置にオプションの空白(タブまたはスペース文字)を置くことができます。
- [1]
-
The result is the character specified by the hexadecimal number between the braces. See "[8]" below for details on which character.
結果は中かっこで囲まれた 16 進数で指定された文字です。 その文字に関する詳細については以下の "[8]" を参照してください。
Blanks (tab or space characters) may separate the number from either or both of the braces.
空白 (タブまたはスペース文字) は、片方または両方の中かっこから数字を 分離します。
Otherwise, only hexadecimal digits are valid between the braces. If an invalid character is encountered, a warning will be issued and the invalid character and all subsequent characters (valid or invalid) within the braces will be discarded.
さもなければ、中かっこの中には 16 進数字のみが妥当です。 不正な文字に遭遇すると、警告が発生し、中かっこの内側の不正な文字と それ以降の文字(妥当でも不正でも)は捨てられます。
If there are no valid digits between the braces, the generated character is the NULL character (
\x{00}). However, an explicit empty brace (\x{}) will not cause a warning (currently).中かっこの中に妥当な文字がなければ、生成される文字は NULL 文字 (
\x{00}) です。 しかし、明示的な空の中かっこ (\x{}) は(今のところ)警告を出しません。 - [2]
-
The result is the character specified by the hexadecimal number in the range 0x00 to 0xFF. See "[8]" below for details on which character.
結果は 0x00 から 0xFF の範囲の 16 進数で指定された文字です。 その文字に関する詳細については以下の "[8]" を参照してください。
Only hexadecimal digits are valid following
\x. When\xis followed by fewer than two valid digits, any valid digits will be zero-padded. This means that\x7will be interpreted as\x07, and a lone"\x"will be interpreted as\x00. Except at the end of a string, having fewer than two valid digits will result in a warning. Note that although the warning says the illegal character is ignored, it is only ignored as part of the escape and will still be used as the subsequent character in the string. For example:\xに引き続くのは 16 進数字のみが妥当です。\xに引き続く妥当な数字が 2 桁ない場合、妥当な数字はゼロで パッディングされます。 これは、\x7は\x07と解釈され、単独の"\x"は\x00と 解釈されるということです。 文字列の末尾を例外として、妥当な数字が 2 桁ない場合は警告が発生します。 警告は不正な文字が無視されると言うにも関わらず、エスケープの一部のみが 無視され、文字列中の引き続く文字は使われるままであることに注意してください。 例えば:Original Result Warns? "\x7" "\x07" no "\x" "\x00" no "\x7q" "\x07q" yes "\xq" "\x00q" yes - [3]
-
The result is the Unicode character or character sequence given by name. See charnames.
結果は name で指定される Unicode 文字または文字の並びです。 charnames を参照してください。
- [4]
-
\N{U+hexadecimal number}means the Unicode character whose Unicode code point is hexadecimal number.\N{U+hexadecimal number}は、Unicode 符号位置が hexadecimal number の Unicode 文字を意味します。 - [5]
-
The character following
\cis mapped to some other character as shown in the table:\cに引き続く文字は以下の表に示すように他の文字にマッピングされます:Sequence Value \c@ chr(0) \cA chr(1) \ca chr(1) \cB chr(2) \cb chr(2) ... \cZ chr(26) \cz chr(26) \c[ chr(27) # See below for chr(28) \c] chr(29) \c^ chr(30) \c_ chr(31) \c? chr(127) # (on ASCII platforms; see below for link to # EBCDIC discussion)In other words, it's the character whose code point has had 64 xor'd with its uppercase.
\c?is DELETE on ASCII platforms becauseord("?") ^ 64is 127, and\c@is NULL because the ord of"@"is 64, so xor'ing 64 itself produces 0.言い換えると、符号位置を 64 で xor して大文字にした文字です。
ord("?") ^ 64は 127 なので\c?は ASCII プラットフォームでは DELETE で、"@"は 64 のために 64 で xor すると 0 になるので\c@は NUL です。Also,
\c\Xyieldschr(28) . "X"for any X, but cannot come at the end of a string, because the backslash would be parsed as escaping the end quote.また、
\c\Xは任意の X についてchr(28) . "X"となりますが、 文字列の末尾には来ません; 逆スラッシュは末尾のクォートをエスケープするように パースされるからです。On ASCII platforms, the resulting characters from the list above are the complete set of ASCII controls. This isn't the case on EBCDIC platforms; see "OPERATOR DIFFERENCES" in perlebcdic for a full discussion of the differences between these for ASCII versus EBCDIC platforms.
ASCII プラットフォームでは、上述の一覧からの結果の文字は ASCII 制御文字の 完全な集合です。 これは EBCDIC プラットフォームには当てはまりません; これに関する ASCII プラットフォームと EBCDIC プラットフォームとの違いの完全な議論については "OPERATOR DIFFERENCES" in perlebcdic を参照してください。
Use of any other character following the
"c"besides those listed above is discouraged, and as of Perl v5.20, the only characters actually allowed are the printable ASCII ones, minus the left brace"{". What happens for any of the allowed other characters is that the value is derived by xor'ing with the seventh bit, which is 64, and a warning raised if enabled. Using the non-allowed characters generates a fatal error."c"に引き続いて上述した以外の文字を使うことは非推奨であり、 as of Perl v5.20, the only characters actually allowed are the printable ASCII ones, minus the left brace"{". 許されている他の文字を置いたときに起こることは、値が第 7 ビット; つまり 64 で xor を取ったものになり、 有効の場合は警告が発生します。 許されていない文字を使うと致命的エラーが発生します。To get platform independent controls, you can use
\N{...}.プラットフォーム非依存の制御文字を得るには、
\N{...}を使ってください。 - [6]
-
The result is the character specified by the octal number between the braces. See "[8]" below for details on which character.
結果は中かっこで囲まれた 8 進数で指定された文字です。 その文字に関する詳細については以下の "[8]" を参照してください。
Blanks (tab or space characters) may separate the number from either or both of the braces.
空白 (タブまたはスペース文字) は、片方または両方の中かっこから数字を 分離します。
Otherwise, if a character that isn't an octal digit is encountered, a warning is raised, and the value is based on the octal digits before it, discarding it and all following characters up to the closing brace. It is a fatal error if there are no octal digits at all.
さもなければ、8 進数でない文字に遭遇すると、警告が発生し、値はそこまでの 8 進数字を基として、それ以降閉じ中かっこまでの全ての文字を捨てます。 8 進数字がまったくないと致命的エラーになります。
- [7]
-
The result is the character specified by the three-digit octal number in the range 000 to 777 (but best to not use above 077, see next paragraph). See "[8]" below for details on which character.
結果は範囲 000 から 777 までの 3 桁の 8 進数で指定される文字です (しかし 077 より上は使わないのが最良です; 次の段落を参照してください)。 その文字に関する詳細については以下の "[8]" を参照してください。
Some contexts allow 2 or even 1 digit, but any usage without exactly three digits, the first being a zero, may give unintended results. (For example, in a regular expression it may be confused with a backreference; see "Octal escapes" in perlrebackslash.) Starting in Perl 5.14, you may use
\o{}instead, which avoids all these problems. Otherwise, it is best to use this construct only for ordinals\077and below, remembering to pad to the left with zeros to make three digits. For larger ordinals, either use\o{}, or convert to something else, such as to hex and use\N{U+}(which is portable between platforms with different character sets) or\x{}instead.一部のコンテキストでは 2 桁や、1 桁ですら許されますが、正確に 3 桁かつ 先頭が 0、以外の使い方は意図していない結果をもたらすかもしれません。 (例えば、正規表現中では後方参照で混乱するかもしれません; "Octal escapes" in perlrebackslash を参照してください。) Perl 5.14 から、代わりに
\o{}を使えます; これはこれらすべての問題を 避けられます。 さもなければ、この構文を値\077以下でのみ使用するのが最良です; 3 桁にするために左側にゼロをパッディングするのを忘れないでください。 より大きな値では、\o{}を使うか、代わりに 16 進数にして\N{U+}(これは異なった文字集合のプラットフォーム間で移植性があります) を使うか、 または\x{}を 使うような、他のものに変換してください。 - [8]
-
Several constructs above specify a character by a number. That number gives the character's position in the character set encoding (indexed from 0). This is called synonymously its ordinal, code position, or code point. Perl works on platforms that have a native encoding currently of either ASCII/Latin1 or EBCDIC, each of which allow specification of 256 characters. In general, if the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's native encoding. If the number is 256 (0x100, 0400) or above, Perl interprets it as a Unicode code point and the result is the corresponding Unicode character. For example
\x{50}and\o{120}both are the number 80 in decimal, which is less than 256, so the number is interpreted in the native character set encoding. In ASCII the character in the 80th position (indexed from 0) is the letter"P", and in EBCDIC it is the ampersand symbol"&".\x{100}and\o{400}are both 256 in decimal, so the number is interpreted as a Unicode code point no matter what the native encoding is. The name of the character in the 256th position (indexed by 0) in Unicode isLATIN CAPITAL LETTER A WITH MACRON.上述のいくつかの構造は文字を数値で指定しています。 この値は文字集合エンコーディングで (0 から始めた) 文字の位置を指定します。 これは同意語として序数(ordinal)、コード位置(code position)、 符号位置(code point)と呼ばれます。 Perl は現在のところ、それぞれ 256 文字を定義している ASCII/Latin1 または EBCDIC のどちらかのネイティブエンコーディングを持つプラットフォームで 動作します。 一般的に、数値が 255 (0xFF, 0377) 以下なら、Perl はこれをプラットフォームの ネイティブエンコーディングと解釈します。 数値が 256 (0x100, 0400) 以上なら、Perl はこれを Unicode 符号位置と解釈し、 結果は対応する Unicode 文字となります。 例えば
\x{50}と\o{120}はどちらも 10 進数では 80 で、これは 256 より 小さいので、数値はネイティブ文字集合エンコーディングとして解釈されます。 ASCII では (0 から始めて) 80 番目の位置の文字は"P"で、EBCDIC では アンパサンド記号"&"です。\x{100}と\o{400}はどちらも 10 進数では 256 なので、数値は ネイティブエンコーディングが何かに関わらず Unicode 符号位置として 解釈されます。 Unicode での (0 から始めて) 256 番目の位置の文字の名前はLATIN CAPITAL LETTER A WITH MACRONです。An exception to the above rule is that
\N{U+hex number}is always interpreted as a Unicode code point, so that\N{U+0050}is"P"even on EBCDIC platforms.上述の規則の例外として、
\N{U+16 進数}は常に Unicode 符号位置として 解釈されるので、\N{U+0050}は EBCDIC プラットフォームでも"P"です。
NOTE: Unlike C and other languages, Perl has no \v escape sequence for the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may use \N{VT}, \ck, \N{U+0b}, or \x0b. (\v does have meaning in regular expression patterns in Perl, see perlre.)
注意: C やその他の言語と違って、Perl は垂直タブ (VT - ASCII と EBCDIC の 両方で 11) のための \v エスケープシーケンスはありませんが、\N{VT}, \ck, \N{U+0b}, \x0b が使えます。 (\v は Perl の正規表現パターンでは意味があります; perlre を 参照してください。)
The following escape sequences are available in constructs that interpolate, but not in transliterations.
以下のエスケープシーケンスが展開と文字変換の構文で利用可能です。
\l lowercase next character only
\u titlecase (not uppercase!) next character only
\L lowercase all characters till \E or end of string
\U uppercase all characters till \E or end of string
\F foldcase all characters till \E or end of string
\Q quote (disable) pattern metacharacters till \E or
end of string
\E end either case modification or quoted section
(whichever was last seen) \l 次の文字だけを小文字にする
\u 次の文字だけをタイトル文字(大文字ではありません!)にする
\L \E か文字列の末尾まで小文字にする
\U \E か文字列の末尾まで大文字にする
\F \E か文字列の末尾まで畳み込み文字にする
\Q \E か文字列の末尾までパターンメタ文字をクォート(無効化)する
\E 大文字小文字変換かクォート部分(どちらか最後に現れたもの)を
終了させるSee "quotemeta" in perlfunc for the exact definition of characters that are quoted by \Q.
\Q でクォートされる文字の正確な定義については "quotemeta" in perlfunc を 参照してください。
\L, \U, \F, and \Q can stack, in which case you need one \E for each. For example:
\L, \U, \F, \Q はスタックできます; この場合それぞれに対して \E が必要です。 例えば:
say "This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?If a use locale form that includes LC_CTYPE is in effect (see perllocale), the case map used by \l, \L, \u, and \U is taken from the current locale. If Unicode (for example, \N{} or code points of 0x100 or beyond) is being used, the case map used by \l, \L, \u, and \U is as defined by Unicode. That means that case-mapping a single character can sometimes produce a sequence of several characters. Under use locale, \F produces the same results as \L for all locales but a UTF-8 one, where it instead uses the Unicode definition.
LC_CTYPE を含む use locale 型式が有効の場合(perllocale を 参照して下さい)、\l, \L, \u, \U で使われる 大文字小文字テーブルは現在のロケールのものが使われます。 (例えば、\N{} や、0x100 以上の符号位置の) Unicode が 使われている場合、\l, \L, \u, \U で使われる大文字小文字 テーブルは Unicode で定義されているものになります。 これは、単一の文字の大文字小文字マッピングは複数の文字の並びを生成することが あるということです。 use locale の基では、\F は、Unicode の定義が使われる UTF-8 以外の 全てのロケールにおいて、\L と同じ結果を生成します。
All systems use the virtual "\n" to represent a line terminator, called a "newline". There is no such thing as an unvarying, physical newline character. It is only an illusion that the operating system, device drivers, C libraries, and Perl all conspire to preserve. Not all systems read "\r" as ASCII CR and "\n" as ASCII LF. For example, on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed, and on systems without a line terminator, printing "\n" might emit no actual data. In general, use "\n" when you mean a "newline" for your system, but use the literal ASCII when you need an exact character. For example, most networking protocols expect and prefer a CR+LF ("\015\012" or "\cM\cJ") for line terminators, and although they often accept just "\012", they seldom tolerate just "\015". If you get in the habit of using "\n" for networking, you may be burned some day.
全てのシステムでは "newline" と呼ばれる行端末子を表現するために 仮想的な "\n" が用いられます。 普遍の、物理的な "newline" 文字と言うものはありません。 オペレーティングシステム、デバイスドライバ、C ライブラリ、Perl が全て 協力して保存しようとすると言うのは単なる幻想です。 全てのシステムで "\r" を ASCII CR として、また "\n" を ASCII LF として読み込むわけではありません。 例えば昔の Mac (MacOS X 以前)ではこれらは保存され、行端末子のない システムでは、"\n" を print しても実際のデータは何も出力しません。 一般に、システムで "newline" を意味したいときには "\n" を使いますが、 正確な文字が必要な場合はリテラルな ASCII を使います。 例えば、ほとんどのネットワークプロトコルでは行端末子として CR+LF ("\015\012" または "\cM\cJ") を予想し、また好みますが、 しばしば "\012" だけでも許容し、さらに時々は "\015" だけでも認めます。 もしネットワーク関係で "\n" を使う習慣がついていると、 いつか痛い目を見ることになるでしょう。
For constructs that do interpolate, variables beginning with "$" or "@" are interpolated. Subscripted variables such as $a[3] or $href->{key}[0] are also interpolated, as are array and hash slices. But method calls such as $obj->meth are not.
展開が行なわれる構文では、"$" や "@" で始まる変数が展開されます。 $a[3] や $href->{key}[0] のような添え字付き変数もまた 配列やハッシュのスライスのように展開されます。 しかし、$obj->meth のようなメソッド呼び出しは展開されません。
Interpolating an array or slice interpolates the elements in order, separated by the value of $", so is equivalent to interpolating join $", @array. "Punctuation" arrays such as @* are usually interpolated only if the name is enclosed in braces @{*}, but the arrays @_, @+, and @- are interpolated even without braces.
配列やスライスの展開は、要素を順番に、$" の値で分割して展開されるので、 join $", @array の展開と等価です。 @* のような「句読点」配列は普通は名前が @{*} のように中かっこで 囲われている場合にのみ展開されますが、配列 @_, @+, @- は 中かっこなしでも展開されます。
For double-quoted strings, the quoting from \Q is applied after interpolation and escapes are processed.
ダブルクォートされた文字列では、\Q からのクォートは文字変換と エスケープが処理された後に適用されます。
"abc\Qfoo\tbar$s\Exyz"is equivalent to
は以下と等価です:
"abc" . quotemeta("foo\tbar$s") . "xyz"For the pattern of regex operators (qr//, m// and s///), the quoting from \Q is applied after interpolation is processed, but before escapes are processed. This allows the pattern to match literally (except for $ and @). For example, the following matches:
正規表現演算子 (qr//, m//, s///) のパターンでは、\Q による クォートは変数展開が行われた後、エスケープが処理される前に適用されます。 これによりパターンを ($ と @ 以外は) リテラルにマッチングできます。 例えば、以下はマッチングします:
'\s\t' =~ /\Q\s\t/Because $ or @ trigger interpolation, you'll need to use something like /\Quser\E\@\Qhost/ to match them literally.
$ や @ は変換を引き起こすので、リテラルにマッチングさせるためには m/\Quser\E\@\Qhost/ などという風に書く必要があります。
Patterns are subject to an additional level of interpretation as a regular expression. This is done as a second pass, after variables are interpolated, so that regular expressions may be incorporated into the pattern from the variables. If this is not what you want, use \Q to interpolate a variable literally.
パターンはさらに、正規表現として展開が行なわれます。 これは、変数が展開された後の 2 回目のパスで行なわれるので、変数に正規表現を 含めておき、パターンの中へ展開することができます。 もし、そうしたくないのであれば、\Q を使うと変数の内容を文字通りに 展開することができます。
Apart from the behavior described above, Perl does not expand multiple levels of interpolation. In particular, contrary to the expectations of shell programmers, back-quotes do NOT interpolate within double quotes, nor do single quotes impede evaluation of variables when used within double quotes.
上記の振る舞いを除けば、Perl は 複数の段階を踏んで展開を行ないません。 特に、シェルのプログラマの期待とは裏腹に、バッククォートはダブルクォートの 中では展開されませんし、シングルクォートがダブルクォートの中で使われても、 変数の展開を妨げることは ありません。
正規表現のクォート風の演算子¶
Here are the quote-like operators that apply to pattern matching and related activities.
以下はパターンマッチングと関連する行動に関するクォート風の演算子です。
qr/STRING/msixpodualn-
This operator quotes (and possibly compiles) its STRING as a regular expression. STRING is interpolated the same way as PATTERN in
m/PATTERN/. If"'"is used as the delimiter, no variable interpolation is done. Returns a Perl value which may be used instead of the corresponding/STRING/msixpodualnexpression. The returned value is a normalized version of the original pattern. It magically differs from a string containing the same characters:ref(qr/x/)returns "Regexp"; however, dereferencing it is not well defined (you currently get the normalized version of the original pattern, but this may change).この演算子は STRING を正規表現としてクォートします (そして可能ならコンパイルします)。 STRING は
m/PATTERN/内の PATTERN と同様に文字変換されます。"'"がデリミタとして使用された場合、変数展開は行われません。 対応する/STRING/msixpodualn表現の代わりに使われた Perl の値を返します。 返り値は元のパターンを正規化したものです。 これは不思議なことに、同じ文字を含む文字列とは異なります:ref(qr/x/)は "Regexp" を返します; しかし、これのデリファレンスは 定義されていません (現在の所元のパターンの正規化版を返しますが、これは 変更されるかもしれません)。For example,
例えば:
$rex = qr/my.STRING/is; print $rex; # prints (?si-xm:my.STRING) s/$rex/foo/;is equivalent to
は以下と等価です:
s/my.STRING/foo/is;The result may be used as a subpattern in a match:
結果はマッチのサブパターンとして使えます:
$re = qr/$pattern/; $string =~ /foo${re}bar/; # can be interpolated in other # patterns $string =~ $re; # or used standalone $string =~ /$re/; # or this way$re = qr/$pattern/; $string =~ /foo${re}bar/; # 他のパターンに展開できる $string =~ $re; # または単独で使う $string =~ /$re/; # またはこのようにするSince Perl may compile the pattern at the moment of execution of the
qr()operator, usingqr()may have speed advantages in some situations, notably if the result ofqr()is used standalone:Perl は
qr()演算子を実行する瞬間にパターンをコンパイルするので、qr()を使うことでいくつかの場面で速度的に有利になります; 特にqr()の結果が独立して使われる場合に有利になります。sub match { my $patterns = shift; my @compiled = map qr/$_/i, @$patterns; grep { my $success = 0; foreach my $pat (@compiled) { $success = 1, last if /$pat/; } $success; } @_; }Precompilation of the pattern into an internal representation at the moment of
qr()avoids the need to recompile the pattern every time a match/$pat/is attempted. (Perl has many other internal optimizations, but none would be triggered in the above example if we did not useqr()operator.)qr()の時点でパターンを内部表現にプリコンパイルすることにより、/$pat/を試みる毎に毎回パターンを再コンパイルするのを 避けることができます。 (Perl はその他にも多くの内部最適化を行いますが、上の例でqr()演算子を 使わなかった場合はどの最適化も行われません。)Options (specified by the following modifiers) are:
(以下の修飾子で指定される)オプションは以下の通りです:
m Treat string as multiple lines. s Treat string as single line. (Make . match a newline) i Do case-insensitive pattern matching. x Use extended regular expressions; specifying two x's means \t and the SPACE character are ignored within square-bracketed character classes p When matching preserve a copy of the matched string so that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be defined (ignored starting in v5.20 as these are always defined starting in that release) o Compile pattern only once. a ASCII-restrict: Use ASCII for \d, \s, \w and [[:posix:]] character classes; specifying two a's adds the further restriction that no ASCII character will match a non-ASCII one under /i. l Use the current run-time locale's rules. u Use Unicode rules. d Use Unicode or native charset, as in 5.12 and earlier. n Non-capture mode. Don't let () fill in $1, $2, etc...m 文字列を複数行として扱う。 s 文字列を一行として扱う。 (. が 改行にマッチングするようにする) i パターンマッチにおいて大文字小文字を区別しない。 x 拡張正規表現を使う; x を二つ指定すると、 \t と SPACE 文字は大かっこ文字クラスの中では無視されます p マッチング時にマッチングした文字列を保存するので、 ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} が定義される (このリリースから常に定義されるので、v5.20 から無視される) o 一度だけコンパイルする。 a ASCII 制限: \d, \s, \w, [[:posix:]] 文字クラスに ASCII を使う; a を二つ指定すると、/i で ASCII 文字が非 ASCII 文字に マッチングしないようなさらなる制限を追加する。 l 現在の実行時ロケールの規則を使う。 u Unicode の規則を使う。 d 5.12 以降かどうかで、Unicode かネイティブな文字集合を使う。 n 非捕捉モード。() で $1, $2 などを埋めないIf a precompiled pattern is embedded in a larger pattern then the effect of
"msixpluadn"will be propagated appropriately. The effect that the/omodifier has is not propagated, being restricted to those patterns explicitly using it.プリコンパイルされたパターンがより大きいパターンに組み込まれている場合、
"msixpluadn"の効果は適切に伝播します。/o修飾子の効果は伝播せず、明示的に使われたパターンに制限されます。The
/a,/d,/l, and/umodifiers (added in Perl 5.14) control the character set rules, but/ais the only one you are likely to want to specify explicitly; the other three are selected automatically by various pragmas.(Perl 5.14 で追加された)
/a,/d,/l,/u修飾子は 、 文字集合の規則を制御しますが、明示的に指定したいと思いそうなものは/aだけでしょう; その他の三つはさまざまなプラグマによって自動的に選択されます。See perlre for additional information on valid syntax for STRING, and for a detailed look at the semantics of regular expressions. In particular, all modifiers except the largely obsolete
/oare further explained in "Modifiers" in perlre./ois described in the next section.STRING として有効な文法に関する追加の情報と、正規表現の意味論に関する 詳細については、perlre を参照してください。 特に、かなり古いものである
/o以外の全ての修飾子については "Modifiers" in perlre でさらに説明されています。/oは次の節に記述されています。 m/PATTERN/msixpodualngc/PATTERN/msixpodualngc-
Searches a string for a pattern match, and in scalar context returns true if it succeeds, false if it fails. If no string is specified via the
=~or!~operator, the$_string is searched. (The string specified with=~need not be an lvalue--it may be the result of an expression evaluation, but remember the=~binds rather tightly.) See also perlre.パターンマッチで文字列検索を行ない、スカラコンテキストでは成功したときは真、 失敗したときは偽を返します。
=~演算子か!~演算子で検索対象の文字列を示さなかったときには、$_の文字列が検索対象となります。 (=~で指定される文字列は、左辺値である必要はありません-- 式を評価した結果でもかまいませんが、=~の優先順位がいくぶん高いことに 注意してください。) perlre も参照してください。Options are as described in
qr//above; in addition, the following match process modifiers are available:オプションは上述した
qr//に記述されています; さらに、以下の マッチング処理修飾子が利用可能です:g Match globally, i.e., find all occurrences. c Do not reset search position on a failed match when /g is in effect.g グローバルにマッチング、つまり、すべてを探し出す。 c /g が有効なとき、マッチングに失敗しても検索位置をリセットしない。If
"/"is the delimiter then the initialmis optional. With themyou can use any pair of non-whitespace (ASCII) characters as delimiters. This is particularly useful for matching path names that contain"/", to avoid LTS (leaning toothpick syndrome). If"?"is the delimiter, then a match-only-once rule applies, described inm?PATTERN?below. If"'"(single quote) is the delimiter, no variable interpolation is performed on the PATTERN. When using a delimiter character valid in an identifier, whitespace is required after them.区切文字が
"/"のときには、最初のmは付けても付けなくてもかまいません。mを付けるときには、(ASCII の)空白でもない、任意の文字のペアを 区切文字として使うことができます。 これは特に、"/"を含むパス名にパターンマッチングを行なうときに、 LTS (傾斜楊枝症候群) を避けるために便利でしょう。 "?" がデリミタなら、後述するm?PATTERN?にある「一度だけマッチング」 ルールが適用されます。"'"(シングルクォート) がデリミタの場合、PATTERN に対する変数展開は 行われません。 識別子として有効な区切り文字を使う場合、mの後に空白が必要です。PATTERN may contain variables, which will be interpolated every time the pattern search is evaluated, except for when the delimiter is a single quote. (Note that
$(,$), and$|are not interpolated because they look like end-of-string tests.) Perl will not recompile the pattern unless an interpolated variable that it contains changes. You can force Perl to skip the test and never recompile by adding a/o(which stands for "once") after the trailing delimiter. Once upon a time, Perl would recompile regular expressions unnecessarily, and this modifier was useful to tell it not to do so, in the interests of speed. But now, the only reasons to use/oare one of:PATTERN には、変数が含まれていてもよく、パターンが評価されるごとに、 (デリミタがシングルクォートでない限り)変数は展開され (パターンが再コンパイルされ) ます。 (変数
$(,$),$|は文字列の終わりを調べるパターンであると 解釈されるので、展開されません。) Perl は展開された変数の値が変更されない限りパターンを再コンパイルしません。 デリミタに引き続いて/o("once" を意味します) を追加することで、 テストを飛ばして再コンパイルしないようにすることができます。 昔々、Perl は不必要に正規表現を再コンパイルしていたので、速度に関心が ある場合は再コンパイルしないようにするためにこの修飾子は有用でした。 しかし今では、/oを使う理由は以下のいずれかだけです:-
The variables are thousands of characters long and you know that they don't change, and you need to wring out the last little bit of speed by having Perl skip testing for that. (There is a maintenance penalty for doing this, as mentioning
/oconstitutes a promise that you won't change the variables in the pattern. If you do change them, Perl won't even notice.)変数が数千文字の長さで、これが変更されないことが分かっており、これに対する テストを飛ばすことであともう少しだけ速度を稼ぐ必要がある。 (こうすることには保守上のペナルティがあります; なぜなら
/oと 言及することでパターン内の変数を変更しないことを約束したことになるからです。 変更しても、Perl は気づきもしません。) -
you want the pattern to use the initial values of the variables regardless of whether they change or not. (But there are saner ways of accomplishing this than using
/o.)変数が変更されようが変更されまいが、変数の初期値を使ったパターンがほしい。 (しかしこれを達成するための、
/oを使うよりもまともな方法があります。) -
If the pattern contains embedded code, such as
以下のようにパターンに組み込みコードが含まれている場合
use re 'eval'; $code = 'foo(?{ $x })'; /$code/then perl will recompile each time, even though the pattern string hasn't changed, to ensure that the current value of
$xis seen each time. Use/oif you want to avoid this.$xの現在の値を毎回確認するために、例えパターン文字列が 変更されていなくても、毎回再コンパイルされます。 これを避けたい場合は/oを使ってください。
The bottom line is that using
/ois almost never a good idea.結論としては、
/oを使うことがいい考えであることはほとんどありません。 -
- The empty pattern
// -
(空パターン
//)If the PATTERN evaluates to the empty string, the last successfully matched regular expression in the current dynamic scope is used instead (see also "Scoping Rules of Regex Variables" in perlvar). In this case, only the
gandcflags on the empty pattern are honored; the other flags are taken from the original pattern. If no match has previously succeeded, this will (silently) act instead as a genuine empty pattern (which will always match). Using a user supplied string as a pattern has the risk that if the string is empty that it triggers the "last successful match" behavior, which can be very confusing. In such cases you are recommended to replacem/$pattern/withm/(?:$pattern)/to avoid this behavior.PATTERN を評価した結果が空文字列となった場合には、現在の動的 スコープで最後にマッチングに 成功した 正規表現が、代わりに使われます ("Scoping Rules of Regex Variables" in perlvar も参照)。 この場合、空パターンに対して
gのcフラグだけが有効です; その他のフラグは元のパターンから取られます。 以前に成功したマッチングがない場合、これは(暗黙に)真の空パターンとして 動作します(つまり常にマッチングします)。 ユーザーが提供した文字列をパターンとして使うことは、 文字列が空だった場合に「最後に成功したマッチング」の振る舞いを引き起こし、 とても混乱するというリスクがあります。 このような場合では、この振る舞いを避けるために、m/$pattern/をm/(?:$pattern)/に置き換えることを勧めます。The last successful pattern may be accessed as a variable via
${^LAST_SUCCESSFUL_PATTERN}. Matching against it, or the empty pattern should have the same effect, with the exception that when there is no last successful pattern the empty pattern will silently match, whereas using the${^LAST_SUCCESSFUL_PATTERN}variable will produce undefined warnings (if warnings are enabled). You can checkdefined(${^LAST_SUCCESSFUL_PATTERN})to test if there is a "last successful match" in the current scope.最後に成功したパターンは、
${^LAST_SUCCESSFUL_PATTERN}変数経由で アクセスされます。 これと、空文字列に対するマッチングは同じ効果を持ちますが、 空文字列が暗黙にマッチングする最後に成功したパターンはないけれども、${^LAST_SUCCESSFUL_PATTERN}変数を使うと(警告がが有効なら) 未定義警告発生するという例外があります。 現在のスコープで「最後に成功したマッチング」が あるかどうかをテストにするには、defined(${^LAST_SUCCESSFUL_PATTERN})とします。Note that it's possible to confuse Perl into thinking
//(the empty regex) is really//(the defined-or operator). Perl is usually pretty good about this, but some pathological cases might trigger this, such as$x///(is that($x) / (//)or$x // /?) andprint $fh //(print $fh(//orprint($fh //?). In all of these examples, Perl will assume you meant defined-or. If you meant the empty regex, just use parentheses or spaces to disambiguate, or even prefix the empty regex with anm(so//becomesm//).Perl が
//(空正規表現) と//(定義性和演算子) を混同する 可能性があることに注意してください。 Perl は普通これをかなりうまく処理しますが、$x///(($x) / (//)それとも$x // /?) やprint $fh //(print $fh(//それともprint($fh //?) のような病的な状況ではこれが起こりえます。 これらの例の全てでは、Perl は定義性和を意味していると仮定します。 もし空正規表現を意味したいなら、あいまいさをなくすために単に かっこや空白を使うか、空正規表現に接頭辞mを付けてください (つまり//をm//にします)。 - Matching in list context
-
(リストコンテキストでのマッチング)
If the
/goption is not used,m//in list context returns a list consisting of the subexpressions matched by the parentheses in the pattern, that is, ($1,$2,$3...) (Note that here$1etc. are also set). When there are no parentheses in the pattern, the return value is the list(1)for success. With or without parentheses, an empty list is returned upon failure./gオプションが使われなかった場合、リストコンテキストでのm//は パターンの中の括弧で括られた部分列にマッチしたもので構成されるリストを 返します; これは、($1,$2,$3, ...) ということです (この場合、$1なども設定されます)。 パターンに括弧がない場合は、返り値は成功時はリスト(1)です。 括弧のあるなしに関わらず、失敗時は空リストを返します。Examples:
例:
open(TTY, "+</dev/tty") || die "can't access /dev/tty: $!"; <TTY> =~ /^y/i && foo(); # do foo if desired if (/Version: *([0-9.]*)/) { $version = $1; } next if m#^/usr/spool/uucp#; # poor man's grep $arg = shift; while (<>) { print if /$arg/; } if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))This last example splits
$foointo the first two words and the remainder of the line, and assigns those three fields to$F1,$F2, and$Etc. The conditional is true if any variables were assigned; that is, if the pattern matched.最後の例は、
$fooを最初の 2 つの単語と行の残りに分解し、$F1と$F2と$Etcに代入しています。 変数に代入されれば、すなわちパターンがマッチすれば、 if の条件が真となります。The
/gmodifier specifies global pattern matching--that is, matching as many times as possible within the string. How it behaves depends on the context. In list context, it returns a list of the substrings matched by any capturing parentheses in the regular expression. If there are no parentheses, it returns a list of all the matched strings, as if there were parentheses around the whole pattern./g修飾子は、グローバルなパターンマッチを指定するもので、 文字列の中で可能な限りたくさんマッチを行ないます。 この動作は、コンテキストに依存します。 リストコンテキストでは、正規表現内の括弧付けされたものにマッチした 部分文字列のリストが返されます。 括弧がなければ、パターン全体を括弧で括っていたかのように、 すべてのマッチした文字列のリストが返されます。In scalar context, each execution of
m//gfinds the next match, returning true if it matches, and false if there is no further match. The position after the last match can be read or set using thepos()function; see "pos" in perlfunc. A failed match normally resets the search position to the beginning of the string, but you can avoid that by adding the/cmodifier (for example,m//gc). Modifying the target string also resets the search position.スカラコンテキストでは、
m//gを実行する毎に次のマッチを探します; マッチした場合は真を返し、もうマッチしなくなったら偽を返します。 最後のマッチの位置はpos()関数で読み出しや設定ができます; "pos" in perlfunc を参照して下さい。 マッチに失敗すると通常は検索位置を文字列の先頭にリセットしますが、/c修飾子をつける(例えばm//gc)ことでこれを防ぐことができます。 ターゲットとなる文字列が変更された場合も検索位置はリセットされます。 \G assertion-
(
\G アサート)You can intermix
m//gmatches withm/\G.../g, where\Gis a zero-width assertion that matches the exact position where the previousm//g, if any, left off. Without the/gmodifier, the\Gassertion still anchors atpos()as it was at the start of the operation (see "pos" in perlfunc), but the match is of course only attempted once. Using\Gwithout/gon a target string that has not previously had a/gmatch applied to it is the same as using the\Aassertion to match the beginning of the string. Note also that, currently,\Gis only properly supported when anchored at the very beginning of the pattern.m//gマッチをm/\G.../gと混ぜることもできます;\Gは前回のm//gがあればその同じ位置でマッチするゼロ文字幅のアサートです。/g修飾子なしの場合、\Gアサートは操作の最初としてpos()に 固定しますが、("pos" in perlfunc 参照) マッチはもちろん一度だけ試されます。 以前に/gマッチを適用していないターゲット文字列に対して/gなしで\Gを使うと、文字列の先頭にマッチする\Aアサートを使うのと 同じことになります。\Gは現在のところ、パターンのまさに先頭を示す場合にのみ正しく 対応することにも注意してください。Examples:
例:
# list context ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g); # scalar context local $/ = ""; while ($paragraph = <>) { while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) { $sentences++; } } say $sentences;Here's another way to check for sentences in a paragraph:
以下は段落内の文をチェックするためのもう一つの方法です:
my $sentence_rx = qr{ (?: (?<= ^ ) | (?<= \s ) ) # after start-of-string or # whitespace \p{Lu} # capital letter .*? # a bunch of anything (?<= \S ) # that ends in non- # whitespace (?<! \b [DMS]r ) # but isn't a common abbr. (?<! \b Mrs ) (?<! \b Sra ) (?<! \b St ) [.?!] # followed by a sentence # ender (?= $ | \s ) # in front of end-of-string # or whitespace }sx; local $/ = ""; while (my $paragraph = <>) { say "NEW PARAGRAPH"; my $count = 0; while ($paragraph =~ /($sentence_rx)/g) { printf "\tgot sentence %d: <%s>\n", ++$count, $1; } }my $sentence_rx = qr{ (?: (?<= ^ ) | (?<= \s ) ) # 文字列の先頭か空白の後 \p{Lu} # 大文字 .*? # なんでも (?<= \S ) # 空白以外で終わる (?<! \b [DMS]r ) # しかし一般的な省略形ではない (?<! \b Mrs ) (?<! \b Sra ) (?<! \b St ) [.?!] # 引き続いて文を終わらせるものが (?= $ | \s ) # 文字列の末尾か空白の前に }sx; local $/ = ""; while (my $paragraph = <>) { say "NEW PARAGRAPH"; my $count = 0; while ($paragraph =~ /($sentence_rx)/g) { printf "\tgot sentence %d: <%s>\n", ++$count, $1; } }Here's how to use
m//gcwith\G:以下は
m//gcを\Gで使う方法です:$_ = "ppooqppqq"; while ($i++ < 2) { print "1: '"; print $1 while /(o)/gc; print "', pos=", pos, "\n"; print "2: '"; print $1 if /\G(q)/gc; print "', pos=", pos, "\n"; print "3: '"; print $1 while /(p)/gc; print "', pos=", pos, "\n"; } print "Final: '$1', pos=",pos,"\n" if /\G(.)/;The last example should print:
最後のものは以下のものを表示するはずです:
1: 'oo', pos=4 2: 'q', pos=5 3: 'pp', pos=7 1: '', pos=7 2: 'q', pos=8 3: '', pos=8 Final: 'q', pos=8Notice that the final match matched
qinstead ofp, which a match without the\Ganchor would have done. Also note that the final match did not updatepos.posis only updated on a/gmatch. If the final match did indeed matchp, it's a good bet that you're running an ancient (pre-5.6.0) version of Perl.\Gなしでのマッチが行われたため、最後のマッチではpではなくqがマッチすることに注意してください。 また、最後のマッチはposを更新しないことに注意してください。posは/gマッチでのみ更新されます。 もし最後のマッチでpにマッチした場合、かなりの確率で とても古い (5.6.0 以前の) Perl で実行しているはずです。A useful idiom for
lex-like scanners is/\G.../gc. You can combine several regexps like this to process a string part-by-part, doing different actions depending on which regexp matched. Each regexp tries to match where the previous one leaves off.lex風にスキャンするために便利な指定は/\G.../gcです。 文字列を部分ごとに処理するためにいくつかの正規表現をつなげて、どの正規表現に マッチングしたかによって異なる処理をすることができます。 それぞれの正規表現は前の正規表現が飛ばした部分に対してマッチングを試みます。$_ = <<'EOL'; $url = URI::URL->new( "http://example.com/" ); die if $url eq "xXx"; EOL LOOP: { print(" digits"), redo LOOP if /\G\d+\b[,.;]?\s*/gc; print(" lowercase"), redo LOOP if /\G\p{Ll}+\b[,.;]?\s*/gc; print(" UPPERCASE"), redo LOOP if /\G\p{Lu}+\b[,.;]?\s*/gc; print(" Capitalized"), redo LOOP if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc; print(" MiXeD"), redo LOOP if /\G\pL+\b[,.;]?\s*/gc; print(" alphanumeric"), redo LOOP if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc; print(" line-noise"), redo LOOP if /\G\W+/gc; print ". That's all!\n"; }Here is the output (split into several lines):
出力は以下のようになります(何行かに分割しています):
line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE line-noise lowercase line-noise lowercase line-noise lowercase lowercase line-noise lowercase lowercase line-noise lowercase lowercase line-noise MiXeD line-noise. That's all! m?PATTERN?msixpodualngc-
This is just like the
m/PATTERN/search, except that it matches only once between calls to thereset()operator. This is a useful optimization when you want to see only the first occurrence of something in each file of a set of files, for instance. Onlym??patterns local to the current package are reset.これは、
reset()演算子を呼び出すごとに 1 度だけしかマッチングしないことを 除いてはm/PATTERN/による検索と全く同じです。 たとえば、ファイルの集まりの中で個々のファイルについて、あるものを 探すとき、最初の 1 つだけの存在がわかれば良いのであれば、この機能を 使って最適化をはかることができます。 現在のパッケージにローカルとなっているm??のパターンだけが リセットされます。while (<>) { if (m?^$?) { # blank line between header and body } } continue { reset if eof; # clear m?? status for next file }Another example switched the first "latin1" encoding it finds to "utf8" in a pod file:
次の例は、pod ファイル中の最初の "latin1" エンコーディングを "utf8" に 切り替えます:
s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;The match-once behavior is controlled by the match delimiter being
?; with any other delimiter this is the normalm//operator.一度だけマッチングという振る舞いはマッチングデリミタが
?かどうかで 制御されます: その他のデリミタの場合はこれは通常のm//演算子です。In the past, the leading
minm?PATTERN?was optional, but omitting it would produce a deprecation warning. As of v5.22.0, omitting it produces a syntax error. If you encounter this construct in older code, you can just addm.過去には、
m?PATTERN?の先頭のmは省略可能でしたが、これを省略すると 廃止予定警告が出ていました。 v5.22.0 から、これを省略すると文法エラーが発生します。 もし古いコードでこの構文に遭遇した場合は、単にmを追加してください。 s/PATTERN/REPLACEMENT/msixpodualngcer-
Searches a string for a pattern, and if found, replaces that pattern with the replacement text and returns the number of substitutions made. Otherwise it returns false (a value that is both an empty string (
"") and numeric zero (0) as described in "Relational Operators").文字列中でパターンを検索し、もし見つかれば、置換テキストで置き換え、 置換した数を返します。 見つからなければ、偽 (空文字列 (
"") と数値のゼロ (0の両方) を 返します。If the
/r(non-destructive) option is used then it runs the substitution on a copy of the string and instead of returning the number of substitutions, it returns the copy whether or not a substitution occurred. The original string is never changed when/ris used. The copy will always be a plain string, even if the input is an object or a tied variable./r(非破壊) オプションが使われると、文字列のコピーに対して置換が行われ、 置換された数ではなく、置換が行われたかどうかにかかわらずこのコピーが 返されます。/rが使われた場合、元の文字列は決して変更されません。 コピーは、たとえ入力がオブジェクトや tie された変数でも、常に プレーンな文字列です。If no string is specified via the
=~or!~operator, the$_variable is searched and modified. Unless the/roption is used, the string specified must be a scalar variable, an array element, a hash element, or an assignment to one of those; that is, some sort of scalar lvalue.=~演算子や!~演算子によって文字列が指定されていなければ、 変数$_が検索され、修正されます。/rが指定されていない限り、=~で指定される文字列は、スカラ変数、配列要素、ハッシュ要素、 あるいは、これらへの代入式といったある種の スカラ左辺値でなければなりません。If the delimiter chosen is a single quote, no variable interpolation is done on either the PATTERN or the REPLACEMENT. Otherwise, if the PATTERN contains a
$that looks like a variable rather than an end-of-string test, the variable will be interpolated into the pattern at run-time. If you want the pattern compiled only once the first time the variable is interpolated, use the/ooption. If the pattern evaluates to the empty string, the last successfully executed regular expression is used instead. See perlre for further explanation on these.シングルクォートを区切り文字として使った場合には、 PATTERN にも REPLACEMENT にも変数展開を行ないません。 それ以外の場合、文字列の最後を表わすものには見えない
$が PATTERN に含まれると、実行時に変数がパターン内に展開されます。 最初に変数が展開されるときにだけパターンのコンパイルを行ないたいときには、/oオプションを使ってください。 パターンの評価結果が空文字列になった場合には、最後に成功した正規表現が 代わりに使われます。 これについてさらに詳しくは、perlre を参照してください。Options are as with
m//with the addition of the following replacement specific options:オプションは、
m//のものに加えて、以下の置換固有のものがあります:e Evaluate the right side as an expression. ee Evaluate the right side as a string then eval the result. r Return substitution and leave the original string untouched.e 式の右側の評価を行なう。 ee 右側を文字列として評価して、その結果を評価する。 r 置換した結果を返し、もとの文字列はそのままにする。Any non-whitespace delimiter may replace the slashes. Add space after the
swhen using a character allowed in identifiers. If single quotes are used, no interpretation is done on the replacement string (the/emodifier overrides this, however). Note that Perl treats backticks as normal delimiters; the replacement text is not evaluated as a command. If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own pair of quotes, which may or may not be bracketing quotes, for example,s(foo)(bar)ors<foo>/bar/. A/ewill cause the replacement portion to be treated as a full-fledged Perl expression and evaluated right then and there. It is, however, syntax checked at compile-time. A secondemodifier will cause the replacement portion to beevaled before being run as a Perl expression.空白ではない任意の区切り文字で、スラッシュを置き換えられます。 識別子として許されている文字を使うときには
sの後に空白を 追加してください。 先に述べたように、シングルクォートを使うと置換文字列での展開は されません (/e修飾子を使えば可能です)。 バッククォートを通常のデリミタとして扱うことに注意してください; 置換テキストはコマンドとして評価されません。 PATTERN を括弧類で括った場合には、REPLACEMENT 用にもう一組の区切り文字を 用意します; これは、括弧類であっても、なくてもかまいません;s(foo)(bar)やs<foo>/bar/。/eは置換文字列を完全な Perl の式として扱い、その場所で直ちに解釈します。 しかし、これはコンパイル時に構文チェックされます。 二番目のe修飾子を指定すると、置換部分がまず Perl の式としてevalされます。Examples:
例:
s/\bgreen\b/mauve/g; # don't change wintergreen $path =~ s|/usr/bin|/usr/local/bin|; s/Login: $foo/Login: $bar/; # run-time pattern ($foo = $bar) =~ s/this/that/; # copy first, then # change ($foo = "$bar") =~ s/this/that/; # convert to string, # copy, then change $foo = $bar =~ s/this/that/r; # Same as above using /r $foo = $bar =~ s/this/that/r =~ s/that/the other/r; # Chained substitutes # using /r @foo = map { s/this/that/r } @bar # /r is very useful in # maps $count = ($paragraph =~ s/Mister\b/Mr./g); # get change-cnt $_ = 'abc123xyz'; s/\d+/$&*2/e; # yields 'abc246xyz' s/\d+/sprintf("%5d",$&)/e; # yields 'abc 246xyz' s/\w/$& x 2/eg; # yields 'aabbcc 224466xxyyzz' s/%(.)/$percent{$1}/g; # change percent escapes; no /e s/%(.)/$percent{$1} || $&/ge; # expr now, so /e s/^=(\w+)/pod($1)/ge; # use function call $_ = 'abc123xyz'; $x = s/abc/def/r; # $x is 'def123xyz' and # $_ remains 'abc123xyz'. # expand variables in $_, but dynamics only, using # symbolic dereferencing s/\$(\w+)/${$1}/g; # Add one to the value of any numbers in the string s/(\d+)/1 + $1/eg; # Titlecase words in the last 30 characters only (presuming # that the substring doesn't start in the middle of a word) substr($str, -30) =~ s/\b(\p{Alpha})(\p{Alpha}*)\b/\u$1\L$2/g; # This will expand any embedded scalar variable # (including lexicals) in $_ : First $1 is interpolated # to the variable name, and then evaluated s/(\$\w+)/$1/eeg; # Delete (most) C comments. $program =~ s { /\* # Match the opening delimiter. .*? # Match a minimal number of characters. \*/ # Match the closing delimiter. } []gsx; s/^\s*(.*?)\s*$/$1/; # trim whitespace in $_, # expensively for ($variable) { # trim whitespace in $variable, # cheap s/^\s+//; s/\s+$//; } s/([^ ]*) *([^ ]*)/$2 $1/; # reverse 1st two fields $foo !~ s/A/a/g; # Lowercase all A's in $foo; return # 0 if any were found and changed; # otherwise return 1Note the use of
$instead of\in the last example. Unlike sed, we use the \<digit> form only in the left hand side. Anywhere else it's $<digit>.最後の例で
\の代わりに$を使っているのに注意してください。 sed と違って、\<数字> の形式はパターンの方でのみ使用できます。 その他の場所では、$<数字> を使います。Occasionally, you can't use just a
/gto get all the changes to occur that you might want. Here are two common cases:ときには、
/gを付けるだけでは、あなたが望んでいるような形で すべてを変更することができないことがあります。 良くある例を 2 つ示します:# put commas in the right places in an integer 1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g; # expand tabs to 8-column spacing 1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;While
s///accepts the/cflag, it has no effect beyond producing a warning if warnings are enabled.s///は/cフラグを受け付けますが、 警告が有効の場合に警告を出す以外の効果はありません。
クォート風演算子¶
q/STRING/'STRING'-
A single-quoted, literal string. A backslash represents a backslash unless followed by the delimiter or another backslash, in which case the delimiter or backslash is interpolated.
シングルクォートされた、リテラル文字列です。 バックスラッシュは、後ろに続くものが区切文字か、別のバックスラッシュで ある場合を除いて単なるバックスラッシュです; 区切文字やバックスラッシュが続く場合には、その区切文字自身もしくは バックスラッシュそのものが展開されます。
$foo = q!I said, "You said, 'She said it.'"!; $bar = q('This is it.'); $baz = '\n'; # a two-character string qq/STRING/"STRING"-
A double-quoted, interpolated string.
ダブルクォートされた、リテラル文字列です。
$_ .= qq (*** The previous line contains the naughty word "$1".\n) if /\b(tcl|java|python)\b/i; # :-) $baz = "\n"; # a one-character string qx/STRING/`STRING`-
A string which is (possibly) interpolated and then executed as a system command, via /bin/sh or its equivalent if required. Shell wildcards, pipes, and redirections will be honored. Similarly to
system, if the string contains no shell metacharacters then it will executed directly. The collected standard output of the command is returned; standard error is unaffected. In scalar context, it comes back as a single (potentially multi-line) string, orundefif the shell (or command) could not be started. In list context, returns a list of lines (however you've defined lines with$/or$INPUT_RECORD_SEPARATOR), or an empty list if the shell (or command) could not be started.展開され、必要なら /bin/sh またはそれと等価なものでシステムの コマンドとして実行される(であろう)文字列です。 シェルのワイルドカード、パイプ、リダイレクトが有効です。
systemと同様、文字列にシェルメタ文字が含まれていないときは、 直接実行されます。 そのコマンドの、標準出力を集めたものが返されます; 標準エラーは影響を 与えません。 スカラコンテキストでは、(複数行を含むかもしれない) 1 つの文字列が戻ってきます; シェル (またはコマンド) が開始できなかったときはundefを返します。 リストコンテキストでは、($/もしくは$INPUT_RECORD_SEPARATORを どのように設定していても) 行のリストを返します; シェル (またはコマンド) が開始できなかったときは 空リストを返します。print qx/date/; # prints "Sun Jan 28 06:16:19 CST 2024"Because backticks do not affect standard error, use shell file descriptor syntax (assuming the shell supports this) if you care to address this. To capture a command's STDERR and STDOUT together:
バッククォートは標準エラーには影響を与えないので、標準エラーを 使いたい場合は(シェルが対応しているものとして)シェルのファイル記述子の 文法を使ってください。 コマンドの STDERR と STDOUT を共に取得したい場合は:
$output = `cmd 2>&1`;To capture a command's STDOUT but discard its STDERR:
コマンドの STDOUT は取得するが STDERR は捨てる場合は:
$output = `cmd 2>/dev/null`;To capture a command's STDERR but discard its STDOUT (ordering is important here):
コマンドの STDERR は取得するが STDOUT は捨てる場合は (ここでは順序が重要です):
$output = `cmd 2>&1 1>/dev/null`;To exchange a command's STDOUT and STDERR in order to capture the STDERR but leave its STDOUT to come out the old STDERR:
STDERR を取得するが、STDOUT は古い STDERR のために残しておくために STDOUT と STDERR を交換するには:
$output = `cmd 3>&1 1>&2 2>&3 3>&-`;To read both a command's STDOUT and its STDERR separately, it's easiest to redirect them separately to files, and then read from those files when the program is done:
コマンドの STDOUT と STDERR の両方を別々に読み込みたい場合、 一番簡単な方法は別々のファイルにリダイレクトし、 プログラムが終了してからそのファイルを読むことです:
system("program args 1>program.stdout 2>program.stderr");The STDIN filehandle used by the command is inherited from Perl's STDIN. For example:
コマンドによって使われる STDIN ファイルハンドルは Perl の STDIN を 継承します。 例えば:
open(SPLAT, "stuff") || die "can't open stuff: $!"; open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!"; print STDOUT `sort`;will print the sorted contents of the file named "stuff".
は "stuff" という名前のファイルの内容をソートして表示します。
Using single-quote as a delimiter protects the command from Perl's double-quote interpolation, passing it on to the shell instead:
シングルクォートをデリミタとして使うと Perl のダブルクォート展開から 保護され、そのままシェルに渡されます:
$perl_info = qx(ps $$); # that's Perl's $$ $shell_info = qx'ps $$'; # that's the new shell's $$How that string gets evaluated is entirely subject to the command interpreter on your system. On most platforms, you will have to protect shell metacharacters if you want them treated literally. This is in practice difficult to do, as it's unclear how to escape which characters. See perlsec for a clean and safe example of a manual
fork()andexec()to emulate backticks safely.この文字列がどのように評価されるかは完全にシステムのコマンドインタプリタに 依存します。 ほとんどのプラットフォームでは、シェルのメタ文字をリテラルに 扱ってほしい場合はそれを守る必要があります。 文字をエスケープする方法が明確ではないので、これは理論的には難しいことです。 逆クォートを安全にエミュレートするために手動で
fork()とexec()を 行うためのきれいで安全な例については perlsec を参照してください。On some platforms (notably DOS-like ones), the shell may not be capable of dealing with multiline commands, so putting newlines in the string may not get you what you want. You may be able to evaluate multiple commands in a single line by separating them with the command separator character, if your shell supports that (for example,
;on many Unix shells and&on the Windows NTcmdshell).(特に DOS 風の)プラットフォームには、シェルが複数行のコマンドを扱うことが できないものがあるので、文字列に改行を入れるとあなたの望まない結果に なる場合があります。 シェルが対応していれば、コマンド分割文字で分割することで 1 行に複数のコマンドを入れて解釈させることができます (この文字は、多くの Unix シェルでは
;、Windows NTcmdシェルでは&です)。Perl will attempt to flush all files opened for output before starting the child process, but this may not be supported on some platforms (see perlport). To be safe, you may need to set
$|($AUTOFLUSHinEnglish) or call theautoflush()method ofIO::Handleon any open handles.Perl は子プロセスの実行前に書き込み用に開いている全ての ファイルをフラッシュしようとしますが、これに対応していない プラットフォームもあります(perlport を参照してください)。 安全のためには、
$|(Englishモジュールでは$AUTOFLUSH)を セットするか、開いている全てのハンドルに対してIO::Handleのautoflush()メソッドを呼び出す必要があります。Beware that some command shells may place restrictions on the length of the command line. You must ensure your strings don't exceed this limit after any necessary interpolations. See the platform-specific release notes for more details about your particular environment.
コマンド行の長さに制限があるコマンドシェルがあることに注意してください。 全ての必要な変換が行われた後、コマンド文字列がこの制限を越えないことを 保障する必要があります。 特定の環境に関するさらなる詳細についてはプラットフォーム固有の リリースノートを参照してください。
Using this operator can lead to programs that are difficult to port, because the shell commands called vary between systems, and may in fact not be present at all. As one example, the
typecommand under the POSIX shell is very different from thetypecommand under DOS. That doesn't mean you should go out of your way to avoid backticks when they're the right way to get something done. Perl was made to be a glue language, and one of the things it glues together is commands. Just understand what you're getting yourself into.この演算子を使うと、プログラムの移殖が困難になります; 呼び出されるシェル コマンドはシステムによって異なり、実際全く存在しないこともあるからです。 一つの例としては、POSIX シェルの
typeコマンドは DOS のtypeコマンドと 大きく異なっています。 これは、何かを為すために正しい方法として逆クォートを使うことを 避けるべきであることを意味しません。 Perl は接着剤のような言語として作られ、接着されるべきものの一つは コマンドです。 単にあなたが何をしようとしているかを理解しておいてください。Like
system, backticks put the child process exit code in$?. If you'd like to manually inspect failure, you can check all possible failure modes by inspecting$?like this:systemシフトと同様、逆クォートは子プロセスの終了コードを$?に 設定します。 手動で失敗を調査したい場合、次のように$?を調べることによって 全てのあり得る失敗モードをチェックできます:if ($? == -1) { print "failed to execute: $!\n"; } elsif ($? & 127) { printf "child died with signal %d, %s coredump\n", ($? & 127), ($? & 128) ? 'with' : 'without'; } else { printf "child exited with value %d\n", $? >> 8; }Use the open pragma to control the I/O layers used when reading the output of the command, for example:
コマンドの出力を読み込むのに使われる I/O 層を制御するには open を使います; 例えば:
use open IN => ":encoding(UTF-8)"; my $x = `cmd-producing-utf-8`;qx//can also be called like a function with "readpipe" in perlfunc.qx//はまた、"readpipe" in perlfunc のような関数から呼び出されます。See "I/O Operators" for more discussion.
さらなる議論については "I/O Operators" を参照して下さい。
qw/STRING/-
Evaluates to a list of the words extracted out of STRING, using embedded whitespace as the word delimiters. It can be understood as being roughly equivalent to:
埋め込まれた空白を区切文字として、STRING から抜き出した単語のリストを 評価します。 これは、以下の式と大体同じと考えられます:
split(" ", q/STRING/);the differences being that it only splits on ASCII whitespace, generates a real list at compile time, and in scalar context it returns the last element in the list. So this expression:
違いは、ASCII の空白でのみ分割し、実際のリストをコンパイル時に生成し、 スカラコンテキストではリストの最後の要素を返すことです。 従って、以下の表現は:
qw(foo bar baz)is semantically equivalent to the list:
以下のリストと文法的に等価です。
"foo", "bar", "baz"Some frequently seen examples:
よく行なわれる例としては以下のものです:
use POSIX qw( setlocale localeconv ) @EXPORT = qw( foo bar baz );A common mistake is to try to separate the words with commas or to put comments into a multi-line
qw-string. For this reason, theuse warningspragma and the -w switch (that is, the$^Wvariable) produces warnings if the STRING contains the","or the"#"character.よくある間違いは、単語をカンマで区切ったり、複数行の
qw文字列の中に コメントを書いたりすることです。 このために、usr warningsプラグマと -w スイッチ (つまり、$^W変数) は STRING に","や"#"の文字が入っていると 警告を出します。 tr/SEARCHLIST/REPLACEMENTLIST/cdsry/SEARCHLIST/REPLACEMENTLIST/cdsr-
Transliterates all occurrences of the characters found (or not found if the
/cmodifier is specified) in the search list with the positionally corresponding character in the replacement list, possibly deleting some, depending on the modifiers specified. It returns the number of characters replaced or deleted. If no string is specified via the=~or!~operator, the$_string is transliterated.検索リスト (SEARCHLIST) に含まれる (あるいは
/c修飾子が指定されている場合は含まれない)文字を、 置換リスト (REPLACEMENTLIST) の位置的に対応する文字に変換します (指定された修飾子によっては一部が削除されることもあります)。 置換または削除が行なわれた、文字数を返します。=~演算子や!~演算子で文字列が指定されていなければ、$_の文字列が 変換されます。For sed devotees,
yis provided as a synonym fortr.sed 愛好者のために、
yがtrの同義語として提供されています。If the
/r(non-destructive) option is present, a new copy of the string is made and its characters transliterated, and this copy is returned no matter whether it was modified or not: the original string is always left unchanged. The new copy is always a plain string, even if the input string is an object or a tied variable./r(非破壊) オプションがあると、文字列の新しいコピーが作られてその 文字が変換され、変更されたかどうかに関わらずこのコピーが返されます: 元の文字列は常に無変更で残されます。 新しいコピーは、たとえ入力がオブジェクトや tie された変数でも、常に プレーンな文字列です。Unless the
/roption is used, the string specified with=~must be a scalar variable, an array element, a hash element, or an assignment to one of those; in other words, an lvalue./rオプションが使われない限り、=~で指定される文字列は、スカラ変数、 配列要素、ハッシュ要素、あるいはこれらへの代入式といった左辺値で なければなりません。The characters delimitting SEARCHLIST and REPLACEMENTLIST can be any printable character, not just forward slashes. If they are single quotes (
tr'SEARCHLIST'REPLACEMENTLIST'), the only interpolation is removal of\from pairs of\\; so hyphens are interpreted literally rather than specifying a character range.SEARCHLIST と REPLACEMENTLIST を区切る文字は、 スラッシュだけでなく、任意の表示文字が可能です。 それがシングルクォート (
tr'SEARCHLIST'REPLACEMENTLIST') の場合、\\の組から\を削除する変換のみが行われます; したがって、 ハイフンは文字の範囲ではなく、リテラルに解釈されます。Otherwise, a character range may be specified with a hyphen, so
tr/A-J/0-9/does the same replacement astr/ACEGIBDFHJ/0246813579/.さもなければ、文字の範囲はハイフンを使って指定できます;
tr/A-J/0-9/はtr/ACEGIBDFHJ/0246813579/と同じ置換を行います。If the SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST must have its own pair of quotes, which may or may not be bracketing quotes; for example,
tr(aeiouy)(yuoiea)ortr[+\-*/]"ABCD". This final example shows a way to visually clarify what is going on for people who are more familiar with regular expression patterns than withtr, and who may think forward slash delimiters imply thattris more like a regular expression pattern than it actually is. (Another option might be to usetr[...][...].)SEARCHLIST をかっこ類で括った場合には、REPLACEMENTLIST 用に、 もう一組の区切り文字を用意しなければなりません; これは、括弧類であっても、なくてもかまいません; 例えば、
tr(aeiouy)(yuoiea)やtr[+\-*/]"ABCD"です。 最後の例は、trよりも正規表現パターンに親しんでいる人や、 前のスラッシュ区切り文字は、trが実際以上に正規表現パターンに 似ていることを暗示していると考える人に、何が起きているかを 視覚的に明確化しています。 (もう一つの選択肢はtr[...][...]を使うことかもしれません。)trisn't fully like bracketed character classes, just (significantly) more like them than it is to full patterns. For example, characters appearing more than once in either list behave differently here than in patterns, andtrlists do not allow backslashed character classes such as\dor\pL, nor variable interpolation, so"$"and"@"are always treated as literals.trは完全に大かっこ文字クラスと同様ではなく、 単に完全なパターンよりは(かなり)そちらにより似ていると言うだけです。 例えば、どちらかのリストに複数回文字が現れた場合、パターンと 異なる振る舞いをします; そしてtrの一覧は\dや\pLといった逆スラッシュ文字クラスや 変数展開を許さないので、"$"と"@"は 常にリテラルとして扱われます。The allowed elements are literals plus
\'(meaning a single quote). If the delimiters aren't single quotes, also allowed are any of the escape sequences accepted in double-quoted strings. Escape sequence details are in the table near the beginning of this section.許される要素はリテラルと (シングルクォートを意味する)
\'です。 区切り文字がシングルクォートでない場合 ダブルクォート文字列の中で受け入れられるエスケープシーケンスも 許されます。 エスケープシーケンスの詳細は この節の先頭付近の表 にあります。A hyphen at the beginning or end, or preceded by a backslash is also always considered a literal. Precede a delimiter character with a backslash to allow it.
先頭、末尾、および逆スラッシュが前置されたハイフンもまた常に リテラルとして扱われます。 それをするために逆スラッシュと共に区切り文字を前に置きます。
The
troperator is not equivalent to thetr(1)utility.tr[a-z][A-Z]will uppercase the 26 letters "a" through "z", but for case changing not confined to ASCII, uselc,uc,lcfirst,ucfirst(all documented in perlfunc), or the substitution operators/PATTERN/REPLACEMENT/(with\U,\u,\L, and\lstring-interpolation escapes in the REPLACEMENT portion).tr演算子はtr(1)ユーティリティと等価ではありません。tr[a-z][A-Z]は "a" から "z" までの 26 文字を大文字にしますが、 ASCII の範囲外の大文字小文字を変更する場合は、lc,uc,lcfirst,ucfirst(全て perlfunc に文書化されています), あるいは 置換演算子s/PATTERN/REPLACEMENT/(REPLACEMENT 部での\U,\u,\L,\l文字列変換エスケープ) を 使ってください。Most ranges are unportable between character sets, but certain ones signal Perl to do special handling to make them portable. There are two classes of portable ranges. The first are any subsets of the ranges
A-Z,a-z, and0-9, when expressed as literal characters.ほとんどの範囲は文字集合管で互換性がありませんが、一部のものは互換性を 持たせるために Perl が特別に扱います。 移植性のある範囲には二つのクラスがあります。 一つ目はリテラル文字として記述された
A-Z,a-z,0-9の部分集合です。tr/h-k/H-K/capitalizes the letters
"h","i","j", and"k"and nothing else, no matter what the platform's character set is. In contrast, all ofとすると、プラットフォームの文字集合が何であるかに関わらず、 文字
"h","i","j","k"を大文字にして、それ以外は何もしません。 一方、次のようなもの全てはtr/\x68-\x6B/\x48-\x4B/ tr/h-\x6B/H-\x4B/ tr/\x68-k/\x48-K/do the same capitalizations as the previous example when run on ASCII platforms, but something completely different on EBCDIC ones.
ASCII プラットフォームで実行した場合は前述の例と同じ大文字かを行いますが、 EBCDIC プラットフォームでは全く違うことをします。
The second class of portable ranges is invoked when one or both of the range's end points are expressed as
\N{...}移植性のある範囲の二つ目のクラスは、範囲の片方または両方の端が
\N{...}として記述された場合です$string =~ tr/\N{U+20}-\N{U+7E}//d;removes from
$stringall the platform's characters which are equivalent to any of Unicode U+0020, U+0021, ... U+007D, U+007E. This is a portable range, and has the same effect on every platform it is run on. In this example, these are the ASCII printable characters. So after this is run,$stringhas only controls and characters which have no ASCII equivalents.これは、Unicode での U+0020, U+0021, ... U+007D, U+007E と等価な、 今のプラットフォームでの全ての文字を
$stringから削除します。 これは移植性のある範囲で、実行される全てのプラットフォームで同じ効果が あります。 この例では、これらは ASCII の表示文字です。 従ってこれを実行した後、$stringは制御文字および ASCII で等価なものがない 文字のみとなります。But, even for portable ranges, it is not generally obvious what is included without having to look things up in the manual. A sound principle is to use only ranges that both begin from, and end at, either ASCII alphabetics of equal case (
b-e,B-E), or digits (1-4). Anything else is unclear (and unportable unless\N{...}is used). If in doubt, spell out the character sets in full.しかし、移植性のある範囲であっても、 マニュアルで調べる必要なしには、何が含まれるのかは 一般的に明らかではありません。 健全な原則としては、範囲の最初と最後をどちらも ASCII 英字 (大文字小文字も同じ)(
b-e,B-E)にするか、どちらも数字にする(1-4) ことです。 それ以外は不明確です(そして\N{...}が使われていない限り 移植性はありません)。 疑わしいときは、文字セットを完全に書き出してください。Options:
オプションは以下の通りです:
c Complement the SEARCHLIST. d Delete found but unreplaced characters. r Return the modified string and leave the original string untouched. s Squash duplicate replaced characters.c SEARCHLIST を補集合にする。 d 見つかったが置換されなかった文字を削除する。 r 修正した結果を返し、もとの文字列はそのままにする。 s 置換された文字が重なったときに圧縮する。If the
/dmodifier is specified, any characters specified by SEARCHLIST not found in REPLACEMENTLIST are deleted. (Note that this is slightly more flexible than the behavior of some tr programs, which delete anything they find in the SEARCHLIST, period.)/d修飾子が指定されると、SEARCHLIST に指定されて、 REPLACEMENTLIST に対応するものがない文字が削除されます。 (これは、SEARCHLIST で見つかったものを削除する、ただそれだけの、ある種の tr プログラムの動作よりと比べれば、いく分柔軟なものになっています。)If the
/smodifier is specified, sequences of characters, all in a row, that were transliterated to the same character are squashed down to a single instance of that character./s修飾子が指定されると、同じ文字に文字変換された文字の並びを、 その文字 1 文字だけに圧縮します。my $x = "aaabbbca"; $x =~ tr/ab/dd/s; # $x now is "dcd"If the
/dmodifier is used, the REPLACEMENTLIST is always interpreted exactly as specified. Otherwise, if the REPLACEMENTLIST is shorter than the SEARCHLIST, the final character, if any, is replicated until it is long enough. There won't be a final character if and only if the REPLACEMENTLIST is empty, in which case REPLACEMENTLIST is copied from SEARCHLIST. An empty REPLACEMENTLIST is useful for counting characters in a class, or for squashing character sequences in a class./d修飾子が使われると、REPLACEMENTLIST は、常に指定された通りに 解釈されます。 さもなければ、REPLACEMENTLIST が SEARCHLIST よりも短い場合、 同じ長さになるまで、最後の文字が繰り返されているものとして扱われます。 REPLACEMENTLIST が空文字列のときには最後の文字というものはなく、 その場合は REPLACEMENTLIST は SEARCHLIST からコピーされます。 空の REPLACEMENTLIST は、ある文字クラスに含まれる文字数を数えるときや、 ある文字クラスの文字の並びを圧縮するようなときに便利です。tr/abcd// tr/abcd/abcd/ tr/abcd/AB/ tr/abcd/ABBB/ tr/abcd//d s/[abcd]//g tr/abcd/AB/d (tr/ab/AB/ + s/[cd]//g) - but run togetherIf the
/cmodifier is specified, the characters to be transliterated are the ones NOT in SEARCHLIST, that is, it is complemented. If/dand/or/sare also specified, they apply to the complemented SEARCHLIST. Recall, that if REPLACEMENTLIST is empty (except under/d) a copy of SEARCHLIST is used instead. That copy is made after complementing under/c. SEARCHLIST is sorted by code point order after complementing, and any REPLACEMENTLIST is applied to that sorted result. This means that under/c, the order of the characters specified in SEARCHLIST is irrelevant. This can lead to different results on EBCDIC systems if REPLACEMENTLIST contains more than one character, hence it is generally non-portable to use/cwith such a REPLACEMENTLIST./c修飾子が指定されると、SEARCHLIST に「ない」ものが文字変換されます; つまり、補集合です。/dや/sも指定されている場合、これらは SEARCHLIST の補集合に 適用されます。 REPLACEMENTLIST が空の場合、(/dの下でなければ) 代わりに SEARCHLIST のコピーが使われることを思い出してください。 このコピーは、/cの下の補集合化の後で行われます。 SEARCHLIST は補集合化の後で符号位置の順序でソートされ、 REPLACEMENTLIST はソートされた結果に対して適用されます。 つまり、/cの下では、SEARCHLIST で指定された文字の順序は 無関係です。 REPLACEMENTLIST に複数の文字が含まれている場合、 EBCDIC システムでは異なった結果を引き起こすことがあるので、 そのような REPLACEMENTLIST に対して/cを使うのは一般的に移植性がありません。Another way of describing the operation is this: If
/cis specified, the SEARCHLIST is sorted by code point order, then complemented. If REPLACEMENTLIST is empty and/dis not specified, REPLACEMENTLIST is replaced by a copy of SEARCHLIST (as modified under/c), and these potentially modified lists are used as the basis for what follows. Any character in the target string that isn't in SEARCHLIST is passed through unchanged. Every other character in the target string is replaced by the character in REPLACEMENTLIST that positionally corresponds to its mate in SEARCHLIST, except that under/s, the 2nd and following characters are squeezed out in a sequence of characters in a row that all translate to the same character. If SEARCHLIST is longer than REPLACEMENTLIST, characters in the target string that match a character in SEARCHLIST that doesn't have a correspondence in REPLACEMENTLIST are either deleted from the target string if/dis specified; or replaced by the final character in REPLACEMENTLIST if/disn't specified.この操作を説明するもう一つの方法は次のものです:
/cが指定されると、SEARCHLIST は符号位置順にソートされ、 それから補集合化されます。 REPLACEMENTLIST が空で/dが指定されていないと、 REPLACEMENTLIST は (/cで修正された) SEARCHLIST のコピーに 置き換えられ、この変更されているかも知れないリストは引き続くものに対しての 基礎として使われます。 ターゲット文字列のうち、SEARCHLIST ににない文字は変更されずに そのままになります。 ターゲット文字列のその他のそれぞれの文字は、 SEARCHLIST の中の文字に位置的に対応する、 REPLACEMENTLIST の中の文字に置き換えられます;/sの下では例外で、 連続して同じ文字に変換された文字並びの 2 文字目以降の文字は削除されます。 SEARCHLIST が REPLACEMENTLIST より長い場合、 SEARCHLIST の文字のうち REPLACEMENTLIST に対応するものが ない文字にマッチングしたターゲット文字列の中の文字は、/dが指定されていればターゲット文字列から削除されます;/dが指定されていなければREPLACEMENTLIST の最後の文字に 置き換えられます。Some examples:
いくつかの例:
$ARGV[1] =~ tr/A-Z/a-z/; # canonicalize to lower case ASCII $cnt = tr/*/*/; # count the stars in $_ $cnt = tr/*//; # same thing $cnt = $sky =~ tr/*/*/; # count the stars in $sky $cnt = $sky =~ tr/*//; # same thing $cnt = $sky =~ tr/*//c; # count all the non-stars in $sky $cnt = $sky =~ tr/*/*/c; # same, but transliterate each non-star # into a star, leaving the already-stars # alone. Afterwards, everything in $sky # is a star. $cnt = tr/0-9//; # count the ASCII digits in $_ tr/a-zA-Z//s; # bookkeeper -> bokeper tr/o/o/s; # bookkeeper -> bokkeeper tr/oe/oe/s; # bookkeeper -> bokkeper tr/oe//s; # bookkeeper -> bokkeper tr/oe/o/s; # bookkeeper -> bokkopor ($HOST = $host) =~ tr/a-z/A-Z/; $HOST = $host =~ tr/a-z/A-Z/r; # same thing $HOST = $host =~ tr/a-z/A-Z/r # chained with s///r =~ s/:/ -p/r; tr/a-zA-Z/ /cs; # change non-alphas to single space @stripped = map tr/a-zA-Z/ /csr, @original; # /r with map tr [\200-\377] [\000-\177]; # wickedly delete 8th bit $foo !~ tr/A/a/ # transliterate all the A's in $foo to 'a', # return 0 if any were found and changed. # Otherwise return 1If multiple transliterations are given for a character, only the first one is used:
複数の文字変換が一つの文字について指定されると、最初のものだけが使われます。
tr/AAA/XYZ/will transliterate any A to X.
は A を X に変換します。
Because the transliteration table is built at compile time, neither the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote interpolation. That means that if you want to use variables, you must use an
eval():変換テーブルはコンパイル時に作られるので、SEARCHLIST も REPLACEMENTLIST もダブルクォート展開の対象とはなりません。 変数を使いたい場合には、
eval()を使わなければならないということです:eval "tr/$oldlist/$newlist/"; die $@ if $@; eval "tr/$oldlist/$newlist/, 1" or die $@; <<EOF-
A line-oriented form of quoting is based on the shell "here-document" syntax. Following a
<<you specify a string to terminate the quoted material, and all lines following the current line down to the terminating string are the value of the item.クォートの行指向形式は、シェルの「ヒアドキュメント」構文を基にしています。
<<に引き続いて、クォートされるテキストを終了させる文字列を指定でき、 現在の行の次の行から終端文字列までの全ての行がその項目の値となります。Prefixing the terminating string with a
~specifies that you want to use "Indented Here-docs" (see below).終端文字列に
~を前置することで、"Indented Here-docs" (後述)を 使いたいことを指定します。The terminating string may be either an identifier (a word), or some quoted text. An unquoted identifier works like double quotes. There may not be a space between the
<<and the identifier, unless the identifier is explicitly quoted. The terminating string must appear by itself (unquoted and with no surrounding whitespace) on the terminating line.終端文字列には、識別子(単語) かクォートされたテキストが使えます。 クォートされていない識別子は、ダブルクォートのように扱われます。 識別子がクォートされていない場合は、
<<と識別子の間に 空白を入れてはいけません。 終端文字列は終端行に単体で(クォートされず、前後にも空白なしで) 現れなければなりません。If the terminating string is quoted, the type of quotes used determine the treatment of the text.
終端文字列がクォートされている場合には、そのクォートの種類によって、 クォートされるテキストの扱い決められます。
- Double Quotes
-
(ダブルクォート)
Double quotes indicate that the text will be interpolated using exactly the same rules as normal double quoted strings.
ダブルクォートは、通常のダブルクォートされた文字列と全く同じ規則を使って 変数展開されることを示します。
print <<EOF; The price is $Price. EOF print << "EOF"; # same as above The price is $Price. EOF - Single Quotes
-
(シングルクォート)
Single quotes indicate the text is to be treated literally with no interpolation of its content. This is similar to single quoted strings except that backslashes have no special meaning, with
\\being treated as two backslashes and not one as they would in every other quoting construct.シングルクォートは、内容が展開されずにリテラルに扱われることを意味します。 これはシングルクォート文字列と似ていますが、バックスラッシュは 特別な意味を持たず、他の全てのクォート構造違って、
\\は 二つのバックスラッシュとして扱われることが違います。Just as in the shell, a backslashed bareword following the
<<means the same thing as a single-quoted string does:シェルでの場合と同様、
<<に引き続いてバックスラッシュ付きの 裸の単語があると、シングルクォートされた文字列と同じこととなります:$cost = <<'VISTA'; # hasta la ... That'll be $10 please, ma'am. VISTA $cost = <<\VISTA; # Same thing! That'll be $10 please, ma'am. VISTAThis is the only form of quoting in perl where there is no need to worry about escaping content, something that code generators can and do make good use of.
これは、perl において、内容のエスケープについて心配する必要のない 唯一の形で、コードジェネレータがうまく使えるものです。
- Backticks
-
(逆スラッシュ)
The content of the here doc is treated just as it would be if the string were embedded in backticks. Thus the content is interpolated as though it were double quoted and then executed via the shell, with the results of the execution returned.
ヒアドキュメントのの内容は、文字列がバッククォートで 埋め込まれているかのように扱われます。 したがって、その内容、はダブルクォートされているかのように変数展開され、 その後シェル経由で実行され、実行された結果になります。
print << `EOC`; # execute command and get results echo hi there EOC
- Indented Here-docs
-
The here-doc modifier
~allows you to indent your here-docs to make the code more readable:ヒヤドキュメント修飾子
~は、コードをより読みやすくするために ヒヤドキュメントをインデントできるようにします:if ($some_var) { print <<~EOF; This is a here-doc EOF }This will print...
これは次のものを...
This is a here-doc...with no leading whitespace.
...先頭の空白なしで表示します。
The line containing the delimiter that marks the end of the here-doc determines the indentation template for the whole thing. Compilation croaks if any non-empty line inside the here-doc does not begin with the precise indentation of the terminating line. (An empty line consists of the single character "\n".) For example, suppose the terminating line begins with a tab character followed by 4 space characters. Every non-empty line in the here-doc must begin with a tab followed by 4 spaces. They are stripped from each line, and any leading white space remaining on a line serves as the indentation for that line. Currently, only the TAB and SPACE characters are treated as whitespace for this purpose. Tabs and spaces may be mixed, but are matched exactly; tabs remain tabs and are not expanded.
ヒヤドキュメントの末尾を記す区切り文字を含む行は、 全体のためのインデントテンプレートを決定します。 ヒヤドキュメントの非空行が末尾行と正確に同じインデントで始まっていない場合、 コンパイルは croak します。 (空行は単一の文字 "\n" からなります。) 例えば、終了行がタブ文字と、それに引き続いて四つのスペース文字で 始まっていたとします。 ヒヤドキュメントの全ての非空行はタブとそれに引き続く四つのスペースで 始まっていなければなりません。 それらは各行から取り除かれ、行に残った戦闘の空白は その行のインデントとして動作します。 現在の所、この目的には TAB と SPACE の文字だけが空白として扱われます。 タブとスペースは混ぜることが出来ますが、正確に マッチングしなければなりません; タブはタブのままで、展開はされません。
Additional beginning whitespace (beyond what preceded the delimiter) will be preserved:
(区切り文字で指定された以上の)追加の先頭の空白は保存されます:
print <<~EOF; This text is not indented This text is indented with two spaces This text is indented with two tabs EOFFinally, the modifier may be used with all of the forms mentioned above:
最後に、この修飾子は前述した全ての型式で使うことが出来ます:
<<~\EOF; <<~'EOF' <<~"EOF" <<~`EOF`And whitespace may be used between the
~and quoted delimiters:そして空白は
~とクォートされた区切り文字の間にも使えます:<<~ 'EOF'; # ... "EOF", `EOF`
It is possible to stack multiple here-docs in a row:
複数のヒアドキュメントを連続してスタックすることも可能です:
print <<"foo", <<"bar"; # you can stack them I said foo. foo I said bar. bar myfunc(<< "THIS", 23, <<'THAT'); Here's a line or two. THIS and here's another. THATJust don't forget that you have to put a semicolon on the end to finish the statement, as Perl doesn't know you're not going to try to do this:
以下のようなことをしたいのではないということが Perl にはわからないので、 文を終わらせるためには末尾にセミコロンをつけなければならないことを 忘れないで下さい:
print <<ABC 179231 ABC + 20;If you want to remove the line terminator from your here-docs, use
chomp().ヒアドキュメントから行終端子を除去したい場合は、
chomp()を使ってください。chomp($string = <<'END'); This is a string. ENDIf you want your here-docs to be indented with the rest of the code, use the
<<~FOOconstruct described under "Indented Here-docs":ヒアドキュメントをソースのほかの部分からインデントしたい場合、 "Indented Here-docs" に記述されている
<<~FOO構文を使ってください:$quote = <<~'FINIS'; The Road goes ever on and on, down from the door where it began. FINISIf you use a here-doc within a delimited construct, such as in
s///eg, the quoted material must still come on the line following the<<FOOmarker, which means it may be inside the delimited construct:s///egのようなデリミタ構造の中でヒアドキュメントを使う場合、 クォートされたものは、やはり区切られた構造の内側を意味するかもしれない<<FOOマーカーに引き続くものとして来なければなりません:s/this/<<E . 'that' the other E . 'more '/eg;It works this way as of Perl 5.18. Historically, it was inconsistent, and you would have to write
この方法は Perl 5.18 から動作します。 歴史的には、これは一貫性がなく、以下のように
s/this/<<E . 'that' . 'more '/eg; the other Eoutside of string evals.
文字列 eval の外側で書く必要があります。
Additionally, quoting rules for the end-of-string identifier are unrelated to Perl's quoting rules.
q(),qq(), and the like are not supported in place of''and"", and the only interpolation is for backslashing the quoting character:さらに、文字列終端識別子に対するクォートルールは Perl のクォートルールとは 関係がありません。
q(),qq()および同種のものは''や""の 代わりのなるものには対応しておらず、文字をクォートするための バックスラッシュだけが展開されます:print << "abc\"def"; testing... abc"defFinally, quoted strings cannot span multiple lines. The general rule is that the identifier must be a string literal. Stick with that, and you should be safe.
最後に、クォートされた文字列は複数行にかかることはありません。 識別子に関する一般的なルールは、文字列リテラルでなければならいことです。 これに従っていれば、安全のはずです。
クォートされた構造のパースに関する詳細¶
When presented with something that might have several different interpretations, Perl uses the DWIM (that's "Do What I Mean") principle to pick the most probable interpretation. This strategy is so successful that Perl programmers often do not suspect the ambivalence of what they write. But from time to time, Perl's notions differ substantially from what the author honestly meant.
何か複数の解釈が可能な表現があった場合、Perl は最も確からしい解釈を 選択するために DWIM ("Do What I Mean")原則を使います。 この戦略は非常に成功したので、Perl プログラマはしばしば 自分が書いたものの矛盾を疑いません。 しかし時間がたつにつれて、Perl の概念は作者が本当に意味していたものから かなり変わりました。
This section hopes to clarify how Perl handles quoted constructs. Although the most common reason to learn this is to unravel labyrinthine regular expressions, because the initial steps of parsing are the same for all quoting operators, they are all discussed together.
この章では Perl がどのようにクォートされた構造を扱うかを 明確にしようと思います。 これを学ぼうとする最もよくある理由は正規表現の迷宮をほぐすためですが、 パースの初期ステップは全てのクォート演算子で同じなので、全て同時に扱います。
The most important Perl parsing rule is the first one discussed below: when processing a quoted construct, Perl first finds the end of that construct, then interprets its contents. If you understand this rule, you may skip the rest of this section on the first reading. The other rules are likely to contradict the user's expectations much less frequently than this first one.
Perl のパースに関するルールで最も重要なものは以下で述べているうち 最初のものです: つまり、クォートされた構造を処理するときは、Perl はまずその 構造の最後を探して、それから中身を解釈します。 このルールがわかれば、とりあえずはこの章の残りは読み飛ばしてもかまいません。 その他のルールは最初のルールに比べてユーザーの予想に反する頻度は はるかに少ないです。
Some passes discussed below are performed concurrently, but because their results are the same, we consider them individually. For different quoting constructs, Perl performs different numbers of passes, from one to four, but these passes are always performed in the same order.
以下で議論するパスには同時に実行されるものもありますが、 結果は同じことなので、別々に考えることにします。 クォート構造の種類によって、Perl が実行するパスの数は 1 から 4 まで異なりますが、これらのパスは常に同じ順番で実行されます。
- Finding the end
-
(最後を探す)
The first pass is finding the end of the quoted construct. This results in saving to a safe location a copy of the text (between the starting and ending delimiters), normalized as necessary to avoid needing to know what the original delimiters were.
最初のパスは、クォート構造の末尾を探すことです。 これにより、(開始デリミタと終了デリミタの間の)テキストは安全な場所に コピーされ、元のデリミタが何だったかを知る必要がないように正規化されます。
If the construct is a here-doc, the ending delimiter is a line that has a terminating string as the content. Therefore
<<EOFis terminated byEOFimmediately followed by"\n"and starting from the first column of the terminating line. When searching for the terminating line of a here-doc, nothing is skipped. In other words, lines after the here-doc syntax are compared with the terminating string line by line.構造がヒアドキュメントの場合、終了デリミタは内容として終端文字列を持つ 行です。 従って、
<<EOFは、"\n"の直後の、終端行の最初の列から始まるEOFで 終端します。 ヒアドキュメントの終端行を探すとき、読み飛ばされるものはありません。 言い換えると、ヒアドキュメント文法以降の行は、1 行毎に終端文字列と 比較されます。For the constructs except here-docs, single characters are used as starting and ending delimiters. If the starting delimiter is an opening punctuation (that is
(,[,{, or<), the ending delimiter is the corresponding closing punctuation (that is),],}, or>). If the starting delimiter is an unpaired character like/or a closing punctuation, the ending delimiter is the same as the starting delimiter. Therefore a/terminates aqq//construct, while a]terminates bothqq[]andqq]]constructs.ヒアドキュメント以外の構造では、1 文字が開始デリミタと終了デリミタとして 使われます。 開始デリミタが組の開き文字(
(,[,{,<のいずれか)の場合、 終了デリミタは対応する組の閉じ文字(つまり),],},>) です。 開始デリミタが/組になる文字や、組の閉じ文字の場合、終了デリミタは 開始デリミタと同じです。 従って/はqq//構造を終端し、一方]はqq[]とqq]]の 両方の構文を終端します。When searching for single-character delimiters, escaped delimiters and
\\are skipped. For example, while searching for terminating/, combinations of\\and\/are skipped. If the delimiters are bracketing, nested pairs are also skipped. For example, while searching for a closing]paired with the opening[, combinations of\\,\], and\[are all skipped, and nested[and]are skipped as well. However, when backslashes are used as the delimiters (likeqq\\andtr\\\), nothing is skipped. During the search for the end, backslashes that escape delimiters or other backslashes are removed (exactly speaking, they are not copied to the safe location).1 文字のデリミタを探す場合、エスケープされたデリミタと
\\は 読み飛ばします。 例えば、/を探しているときには、\\と\/の組み合わせを 読み飛ばします。 デリミタがかっこでくくられている場合は、ネストした組も読み飛ばされます。 例えば、開きの[と組になる閉じの]を探しているときには、\\,\],\[の組み合わせをは全て読み飛ばし、 さらにネストした[,]も読み飛ばします。 しかし、(qq\\やtr\\\のように)バックスラッシュがデリミタとして 使われた場合、何も読み飛ばしません。 末尾の検索中、デリミタやその他のバックスラッシュをエスケープする バックスラッシュは除去されます(述べたとおりに正確に、安全な場所に コピーはされません)。For constructs with three-part delimiters (
s///,y///, andtr///), the search is repeated once more. If the first delimiter is not an opening punctuation, the three delimiters must be the same, such ass!!!andtr))), in which case the second delimiter terminates the left part and starts the right part at once. If the left part is delimited by bracketing punctuation (that is(),[],{}, or<>), the right part needs another pair of delimiters such ass(){}andtr[]//. In these cases, whitespace and comments are allowed between the two parts, although the comment must follow at least one whitespace character; otherwise a character expected as the start of the comment may be regarded as the starting delimiter of the right part.3 つのデリミタからなる構造 (
s///,y///,tr///) の場合、 検索はもう一度繰り返されます。 最初のデリミタが開きかっこでない場合、s!!!andtr)))のように 3 つのデリミタは同じでなければなりません; この場合、2 番目のデリミタが左側の終端と右側の開始を同時に行います。 左側のデリミタがかっこを構成するもの (これは(),[],{},<>のいずれか) の場合、右側もs(){}やtr[]//のようなデリミタである必要があります。 これらの場合、右側と左側の間には空白やコメントを置けますが、 コメントは少なくとも一つの空白文字の後である必要があります; さもなければコメントの開始文字が右側の開始デリミタとして扱われてしまいます。During this search no attention is paid to the semantics of the construct. Thus:
検索する間、構造の文脈は考慮しません。 従って:
"$hash{"$foo/$bar"}"or:
または:
m/ bar # NOT a comment, this slash / terminated m//! /xdo not form legal quoted expressions. The quoted part ends on the first
"and/, and the rest happens to be a syntax error. Because the slash that terminatedm//was followed by aSPACE, the example above is notm//x, but ratherm//with no/xmodifier. So the embedded#is interpreted as a literal#.は正しいクォート表現ではありません。 クォートは最初の
"や/で終わりとなり、残りの部分は文法エラーと なります。m//を終わらせているスラッシュの次に来ているのが空白なので、 上の例ではm//xではなく、/xなしのm//となります。 従って、中にある#はリテラルな#として扱われます。Also no attention is paid to
\c\(multichar control char syntax) during this search. Thus the second\inqq/\c\/is interpreted as a part of\/, and the following/is not recognized as a delimiter. Instead, use\034or\x1cat the end of quoted constructs.この検索の間、
\c\(マルチバイト文字制御文法)に注意は払われません。 従って、qq/\c\/の 2 番目の\は\/の一部として扱われ、 引き続く/はデリミタとして認識されません。 代わりに、クォート構造の末尾に\034か\x1cを使ってください。 - Interpolation
-
(展開)
The next step is interpolation in the text obtained, which is now delimiter-independent. There are multiple cases.
次のステップは、得られた(デリミタに依存しない)テキストに対する展開です。 複数のケースがあります。
<<'EOF'-
No interpolation is performed. Note that the combination
\\is left intact, since escaped delimiters are not available for here-docs.展開は行われません。
\\の組み合わせはそのままであることに注意してください; ヒアドキュメントではデリミタのエスケープはできないからです。 m'', the pattern ofs'''-
No interpolation is performed at this stage. Any backslashed sequences including
\\are treated at the stage of "Parsing regular expressions".このステージでは展開は行われません。
\\を含む、バックスラッシュ付きのシーケンスは "Parsing regular expressions" で扱われます。 '',q//,tr''',y''', the replacement ofs'''-
The only interpolation is removal of
\from pairs of\\. Therefore"-"intr'''andy'''is treated literally as a hyphen and no character range is available.\1in the replacement ofs'''does not work as$1.\\の組における\の削除のみが行われます。 従って、tr'''やy'''の中にある"-"は文字通りハイフンとして扱われ、 文字範囲は使えません。s'''の置換文字列での\1は$1としては動作しません。 tr///,y///-
No variable interpolation occurs. String modifying combinations for case and quoting such as
\Q,\U, and\Eare not recognized. The other escape sequences such as\200and\tand backslashed characters such as\\and\-are converted to appropriate literals. The character"-"is treated specially and therefore\-is treated as a literal"-".変数展開は行われません。
\Q,\U,\Eのような、大文字小文字やクォートに関する、文字列を 変更するような組み合わせは認識されません。\200や\tのようなその他のエスケープシーケンスや、\\や\-のようなバックスラッシュ付きの文字は、適切なリテラルに 変換されます。 文字"-"は特別扱いされるので、\-はリテラルな"-"として扱われます。 "",``,qq//,qx//,<file*glob>,<<"EOF"-
\Q,\U,\u,\L,\l,\F(possibly paired with\E) are converted to corresponding Perl constructs. Thus,"$foo\Qbaz$bar"is converted to$foo . (quotemeta("baz" . $bar))internally. The other escape sequences such as\200and\tand backslashed characters such as\\and\-are replaced with appropriate expansions.\Q,\U,\u,\L,\l,\F(おそらくは\Eとの組)は 対応する Perl 構造に変換されます。 従って、"$foo\Qbaz$bar"は内部的に$foo . (quotemeta("baz" . $bar))に変換されます。\200や\tのような、その他のエスケープシーケンスや、\\や\-のような、バックスラッシュがつけられた文字は適切な拡張に 置換されます。Let it be stressed that whatever falls between
\Qand\Eis interpolated in the usual way. Something like"\Q\\E"has no\Einside. Instead, it has\Q,\\, andE, so the result is the same as for"\\\\E". As a general rule, backslashes between\Qand\Emay lead to counterintuitive results. So,"\Q\t\E"is converted toquotemeta("\t"), which is the same as"\\\t"(since TAB is not alphanumeric). Note also that:\Qと\Eの間にある全てのもの が通常の方法で展開されます。"\Q\\E"のようなものは内部にあるのは\Eではありません。\Q,\\,Eであるので、結果は"\\\\E"と同じになります。 一般的なルールとして、\Qと\Eの間にあるバックスラッシュは 直感に反した結果になります。 それで、"\Q\t\E"はquotemeta("\t")に変換され、これは(TAB は 英数字ではないので"\\\t"と同じです。 以下のようなことにも注意してください:$str = '\t'; return "\Q$str";may be closer to the conjectural intention of the writer of
"\Q\t\E".これは
"\Q\t\E"を書いた人の憶測上の 意図 により近いです。Interpolated scalars and arrays are converted internally to the
joinand"."catenation operations. Thus,"$foo XXX '@arr'"becomes:展開されたスカラと配列は内部で
joinと"."の結合操作に変換されます。 従って、"$foo XXX '@arr'"は以下のようになります:$foo . " XXX '" . (join $", @arr) . "'";All operations above are performed simultaneously, left to right.
上記の全ての操作は、左から右に同時に行われます。
Because the result of
"\Q STRING \E"has all metacharacters quoted, there is no way to insert a literal$or@inside a\Q\Epair. If protected by\,$will be quoted to become"\\\$"; if not, it is interpreted as the start of an interpolated scalar."\Q STRING \E"の結果は全てのメタ文字がクォートされているので、\Q\Eの組の内側にリテラルの$や@を挿入する方法はありません。\によって守られている場合、$はクォートされて"\\\$"と なります; そうでない場合、これは展開されるスカラ変数の開始として 解釈されます。Note also that the interpolation code needs to make a decision on where the interpolated scalar ends. For instance, whether
"a $x -> {c}"really means:展開コードは、展開するスカラ変数がどこで終わるかを決定する必要が あることにも注意してください。 例えば、
"a $x -> {c}"が実際には以下のどちらかになります:"a " . $x . " -> {c}";or:
または:
"a " . $x -> {c};Most of the time, the longest possible text that does not include spaces between components and which contains matching braces or brackets. because the outcome may be determined by voting based on heuristic estimators, the result is not strictly predictable. Fortunately, it's usually correct for ambiguous cases.
ほとんどの場合、要素と、マッチする中かっこや大かっこの間に空白を含まない、 最も長いテキストになります。 出力は発見的な推定器をよる投票によって決定されるので、結果は厳密には 予測できません。 幸い、紛らわしい場合でも普通は正しいです。
- The replacement of
s/// -
Processing of
\Q,\U,\u,\L,\l,\Fand interpolation happens as withqq//constructs.\Q,\U,\u,\L,\l,\Fの処理と展開がqq//構造と 同じように起こります。It is at this step that
\1is begrudgingly converted to$1in the replacement text ofs///, in order to correct the incorrigible sed hackers who haven't picked up the saner idiom yet. A warning is emitted if theuse warningspragma or the -w command-line flag (that is, the$^Wvariable) was set.このステップでは、より健全な文法をまだ導入していない、手に負えない sed ハッカーのために、
s///の置換テキストの中にある\1を、しぶしぶながら$1に変換します。use warningsプラグマやコマンドラインオプション -w (これは$^W変数です) がセットされていると警告が生成されます。 REinm?RE?,/RE/,m/RE/,s/RE/foo/,-
Processing of
\Q,\U,\u,\L,\l,\F,\E, and interpolation happens (almost) as withqq//constructs.\Q,\U,\u,\L,\l,\F,\Eの処理と展開がqq//構文と (ほとんど)同じように起こります。Processing of
\N{...}is also done here, and compiled into an intermediate form for the regex compiler. (This is because, as mentioned below, the regex compilation may be done at execution time, and\N{...}is a compile-time construct.)\N{...}の処理もここで行われ、正規表現コンパイラのための中間形式に コンパイルされます。 (これは、後述するように、正規表現のコンパイルは実行時に行われ、\N{...}はコンパイル時の構文だからです。)However any other combinations of
\followed by a character are not substituted but only skipped, in order to parse them as regular expressions at the following step. As\cis skipped at this step,@of\c@in RE is possibly treated as an array symbol (for example@foo), even though the same text inqq//gives interpolation of\c@.しかし、その他の、
\の後に文字が続く組み合わせは置換されず、単に 読み飛ばされます; これは以下のステップで正規表現としてパースするためです。 ここでは\cは読み飛ばされるので、正規表現中の\c@の@は 配列のシンボル(例えば@foo) と扱われる可能性があります; 一方qq//内の同じテキストは\c@と展開されます。Code blocks such as
(?{BLOCK})are handled by temporarily passing control back to the perl parser, in a similar way that an interpolated array subscript expression such as"foo$array[1+f("[xyz")]bar"would be.(?{BLOCK})のようなコードブロックは、一時的に制御を perl パーサに 渡すことで扱われます; これは"foo$array[1+f("[xyz")]bar"のような、 変数展開される配列添え字表現と同様の方法です。Moreover, inside
(?{BLOCK}),(?# comment ), and a#-comment in a/x-regular expression, no processing is performed whatsoever. This is the first step at which the presence of the/xmodifier is relevant.さらに、
(?{BLOCK}),(?# comment ),/x正規表現での#の コメントの中では、どのような処理も行われません。 これは/x修飾子が影響を与える最初のステップです。Interpolation in patterns has several quirks:
$|,$(,$),@+and@-are not interpolated, and constructs$var[SOMETHING]are voted (by several different estimators) to be either an array element or$varfollowed by an RE alternative. This is where the notation${arr[$bar]}comes handy:/${arr[0-9]}/is interpreted as array element-9, not as a regular expression from the variable$arrfollowed by a digit, which would be the interpretation of/$arr[0-9]/. Since voting among different estimators may occur, the result is not predictable.パターン内の展開ではいくつか特殊な動作をします:
$|,$(,$),@+,@-は展開されず、$var[SOMETHING]は(いくつかの異なる推定器によって)配列の要素か$varの後に正規表現が続いているのかが投票されます。 これは${arr[$bar]}が便利になるところです:/${arr[0-9]}/は 配列要素-9として解釈され、/$arr[0-9]/の場合のように$arrの後に 数値が続いているような正規表現としては解釈されません。 異なった推定器によって投票されることがあるので、結果は予測できません。The lack of processing of
\\creates specific restrictions on the post-processed text. If the delimiter is/, one cannot get the combination\/into the result of this step./will finish the regular expression,\/will be stripped to/on the previous step, and\\/will be left as is. Because/is equivalent to\/inside a regular expression, this does not matter unless the delimiter happens to be character special to the RE engine, such as ins*foo*bar*,m[foo], orm?foo?; or an alphanumeric char, as in:\\を処理しないことにより、後処理したテキストに特定の制限があります。 デリミタが/の場合、このステップの結果として\/を得ることは できません。/は正規表現を終わらせ、\/は前のステップで/に展開され、\\/はそのまま残されます。/は正規表現の中では\/と等価なので、これはたまたまデリミタが 正規検索エンジンにとって特別な文字の場合、つまりs*foo*bar*,m[foo],m?foo?のような場合、あるいは以下のように英数字でなければ、 問題にはなりません:m m ^ a \s* b mmx;In the RE above, which is intentionally obfuscated for illustration, the delimiter is
m, the modifier ismx, and after delimiter-removal the RE is the same as form/ ^ a \s* b /mx. There's more than one reason you're encouraged to restrict your delimiters to non-alphanumeric, non-whitespace choices.上記の正規表現では、説明のために意図的にわかりにくくしていますが、 デリミタは
mで、修飾子はmxで、デリミタを取り除いた後の 正規表現はm/ ^ a \s* b /mxと同じです。 デリミタを英数字や空白でないものに制限するべきである理由は複数あります。
This step is the last one for all constructs except regular expressions, which are processed further.
これは正規表現以外の全ての構造にとって最後のステップです; 正規表現は さらに処理が続きます。
- Parsing regular expressions
-
(正規表現のパース)
Previous steps were performed during the compilation of Perl code, but this one happens at run time, although it may be optimized to be calculated at compile time if appropriate. After preprocessing described above, and possibly after evaluation if concatenation, joining, casing translation, or metaquoting are involved, the resulting string is passed to the RE engine for compilation.
以前のステップは Perl コードのコンパイル中に実行されますが、 これは実行時に起こりますが、もし適切ならコンパイル時に 計算できるように最適化されることもあります。 上記の前処理の後、そして必要なら連結、結合、大文字小文字変換、 メタクォート化が行われた後、結果の 文字列 がコンパイルのために 正規表現エンジンに渡されます。
Whatever happens in the RE engine might be better discussed in perlre, but for the sake of continuity, we shall do so here.
正規表現エンジンで起こることについては perlre で議論した方が よいでしょうが、継続性のために、ここでそれを行います。
This is another step where the presence of the
/xmodifier is relevant. The RE engine scans the string from left to right and converts it into a finite automaton.これも
/x修飾子の存在が関連するステップの一つです。 正規表現エンジンは文字列を左から右にスキャンして、有限状態オートマトンに 変換します。Backslashed characters are either replaced with corresponding literal strings (as with
\{), or else they generate special nodes in the finite automaton (as with\b). Characters special to the RE engine (such as|) generate corresponding nodes or groups of nodes.(?#...)comments are ignored. All the rest is either converted to literal strings to match, or else is ignored (as is whitespace and#-style comments if/xis present).バックスラッシュ付きの文字は(
\{のように)対応するリテラル文字列に 置換されるか、あるいは(\bのように)有限状態オートマトンの特別な ノードを生成します。 (|のような)正規表現エンジンにとって特別な文字は対応するノードか ノードのグループを生成します。(?#...)コメントは無視されます。 残りの全てはマッチするリテラル文字列に変換されるか、そうでなければ (/xが指定された時の空白と#スタイルのコメントと同様に) 無視されます。Parsing of the bracketed character class construct,
[...], is rather different than the rule used for the rest of the pattern. The terminator of this construct is found using the same rules as for finding the terminator of a{}-delimited construct, the only exception being that]immediately following[is treated as though preceded by a backslash.文字クラス構造
[...]のパースは他のパターンとはルールが異なります。 この構造の終端は{}でデリミタされた構造の終端を検索するのと同じルールで 検索されます; 唯一の例外は、[の直後の]はバックスラッシュが 先行しているものとして扱われます。The terminator of runtime
(?{...})is found by temporarily switching control to the perl parser, which should stop at the point where the logically balancing terminating}is found.実行時
(?{...})の終端は、一時的に perl パーサに制御を切り替えることで 見つけられ、論理的にバランスした終端}が見つかって場所で停止します。It is possible to inspect both the string given to RE engine and the resulting finite automaton. See the arguments
debug/debugcolorin theuse repragma, as well as Perl's -Dr command-line switch documented in "Command Switches" in perlrun.正規表現に与えられる文字列と、結果としての有限状態オートマトンの両方を 検査できます。
use reプラグマのdebug/debugcolor引数と、 "Command Switches" in perlrun に記述されている -Dr コマンドライン オプションを参照してください。 - Optimization of regular expressions
-
(正規表現の最適化)
This step is listed for completeness only. Since it does not change semantics, details of this step are not documented and are subject to change without notice. This step is performed over the finite automaton that was generated during the previous pass.
このステップは完全性のためだけにリストされています。 これは意味論的には変化がないので、このステップの詳細は文書化されておらず、 将来予告なしに変更されることがあります。 このステップはここまでの処理で生成された有限オートマトンに対して 適用されます。
It is at this stage that
split()silently optimizes/^/to mean/^/m.split()で/^/を暗黙に/^/mに最適化するのもこのステップです。
I/O 演算子¶
There are several I/O operators you should know about.
知っておいた方がよい I/O 演算子もいくつかあります。
A string enclosed by backticks (grave accents) first undergoes double-quote interpolation. It is then interpreted as an external command, and the output of that command is the value of the backtick string, like in a shell. In scalar context, a single string consisting of all output is returned. In list context, a list of values is returned, one per line of output. (You can set $/ to use a different line terminator.) The command is executed each time the pseudo-literal is evaluated. The status value of the command is returned in $? (see perlvar for the interpretation of $?). Unlike in csh, no translation is done on the return data--newlines remain newlines. Unlike in any of the shells, single quotes do not hide variable names in the command from interpretation. To pass a literal dollar-sign through to the shell you need to hide it with a backslash. The generalized form of backticks is qx//, or you can call the "readpipe" in perlfunc function. (Because backticks always undergo shell expansion as well, see perlsec for security concerns.)
バッククォートで括られた文字列は、まず、ダブルクォート補完のように 変数の展開が行なわれます。 その後、シェルでの場合と同じように、外部コマンドとして解釈され、 そのコマンドの出力がこのバッククォート文字列の値となります。 スカラーコンテキストでは、出力すべてを含む一個の文字列が返されます。 リストコンテキストでは、出力の 1 行 1 行が個々の要素となるリストが返されます。 ($/ を設定すれば、行の終わりを示す文字を変えることができます。) コマンドは、この擬似リテラルが評価されるごとに実行されます。 コマンドのステータス値は $? に返されます ($? の解釈については、 perlvar を参照してください)。 csh での場合とは違って、結果のデータに対する変換は行なわれず、 改行は改行のままです。 どのシェルとも違って、シングルクォートがコマンド中の変数名を 解釈させないようにすることはありません。 シェルにリテラルなドル記号を渡すには、バックスラッシュで エスケープしなければなりません。 バッククォートの一般形は、qx// か、 "readpipe" in perlfunc 関数を呼び出せます。 (バッククォートは常にシェル展開されます; セキュリティに関しては perlsec を参照して下さい。)
In scalar context, evaluating a filehandle in angle brackets yields the next line from that file (the newline, if any, included), or undef at end-of-file or on error. When $/ is set to undef (sometimes known as file-slurp mode) and the file is empty, it returns '' the first time, followed by undef subsequently.
スカラーコンテキストで山括弧の中のファイルハンドルを評価すると、 そのファイルから、次の行を読み込むことになります (改行があればそれも含まれます); ファイルの最後またはエラーの場合は undef を返します。 $/ が undef に設定されている場合(ファイル吸い込みモードと呼ばれます) でファイルが空の場合、 最初は '' を返し、次は undef を返します。
Ordinarily you must assign the returned value to a variable, but there is one situation where an automatic assignment happens. If and only if the input symbol is the only thing inside the conditional of a while statement (even if disguised as a for(;;) loop), the value is automatically assigned to the global variable $_, destroying whatever was there previously. (This may seem like an odd thing to you, but you'll use the construct in almost every Perl script you write.) The $_ variable is not implicitly localized. You'll have to put a local $_; before the loop if you want that to happen. Furthermore, if the input symbol or an explicit assignment of the input symbol to a scalar is used as a while/for condition, then the condition actually tests for definedness of the expression's value, not for its regular truth value.
通常は、返された値を変数に代入しなければなりませんが、自動的に 代入される場合が 1 つだけあります。 この入力シンボルが、while 文(for(;;) の形になっていたとしても)の条件式中に 単独で現れた場合だけは、その値が自動的にグローバル変数 $_ に代入されます; 以前の値は破壊されます。 (これは、奇妙に思えるかもしれませんが、ほとんどすべての Perl スクリプトで これが必要になることでしょう。) $_ 変数は暗黙にはローカル化されません。 そうしたい場合はループの前に local $_; と書く必要があります。 さらに、入力シンボルまたは入力シンボルからスカラへの明示的な代入が while/for の条件部として使われた場合、 条件は通常の真の値かどうかではなく、式の値が定義されているかどうかを テストします。
Thus the following lines are equivalent:
従って、以下のものは互いに同値なものです:
while (defined($_ = <STDIN>)) { print; }
while ($_ = <STDIN>) { print; }
while (<STDIN>) { print; }
for (;<STDIN>;) { print; }
print while defined($_ = <STDIN>);
print while ($_ = <STDIN>);
print while <STDIN>;This also behaves similarly, but assigns to a lexical variable instead of to $_:
以下は同様の振る舞いをしますが、$_ おｎ代わりにレキシカル変数に 代入します:
while (my $line = <STDIN>) { print $line }In these loop constructs, the assigned value (whether assignment is automatic or explicit) is then tested to see whether it is defined. The defined test avoids problems where the line has a string value that would be treated as false by Perl; for example a "" or a "0" with no trailing newline. If you really mean for such values to terminate the loop, they should be tested for explicitly:
これらのループ構造の中で、代入された値は (代入が自動か明示的かに関わりなく) 定義されているかどうかを見るためにテストされます。 定義テストは、行が Perl にとって偽となる文字列値を持っているかどうかの 問題を避けます; 例えば newline のついていない "" や "0" です。 もし本当にこのような値でループを終了させたいときは、 以下のように明示的にテストするべきです:
while (($_ = <STDIN>) ne '0') { ... }
while (<STDIN>) { last unless $_; ... }In other boolean contexts, <FILEHANDLE> without an explicit defined test or comparison elicits a warning if the use warnings pragma or the -w command-line switch (the $^W variable) is in effect.
その他の真偽値コンテキストでは、明示的な defined や比較なしに <FILEHANDLE> を使うと、use warnings プラグマや -w コマンドラインスイッチ ($^W 変数) が有効なときには、 警告を発生させます。
The filehandles STDIN, STDOUT, and STDERR are predefined. (The filehandles stdin, stdout, and stderr will also work except in packages, where they would be interpreted as local identifiers rather than global.) Additional filehandles may be created with the open() function, amongst others. See perlopentut and "open" in perlfunc for details on this.
STDIN、STDOUT、STDERR というファイルハンドルは、あらかじめ定義されています。 (stdin、stdout、stderr というファイルハンドルも、 ローカルな名前でこれらのグローバルな名前が見えなくなっている パッケージを除けば、使用することができます。) その他のファイルハンドルは、open() 関数などで作ることができます。 これに関する詳細については perlopentut と "open" in perlfunc を 参照して下さい。
If a <FILEHANDLE> is used in a context that is looking for a list, a list comprising all input lines is returned, one line per list element. It's easy to grow to a rather large data space this way, so use with care.
<FILEHANDLE> がリストを必要とするコンテキストで用いられると、 1 要素に 1 行の入力行すべてからなるリストが返されます。 これを使うと簡単にかなり大きなデータになってしまいますので、 注意を要します。
<FILEHANDLE> may also be spelled readline(*FILEHANDLE). See "readline" in perlfunc.
<FILEHANDLE> は readline(*FILEHANDLE) とも書けます。 "readline" in perlfunc を参照して下さい。
The null filehandle <> (sometimes called the diamond operator) is special: it can be used to emulate the behavior of sed and awk, and any other Unix filter program that takes a list of filenames, doing the same to each line of input from all of them. Input from <> comes either from standard input, or from each file listed on the command line. Here's how it works: the first time <> is evaluated, the @ARGV array is checked, and if it is empty, $ARGV[0] is set to "-", which when opened gives you standard input. The @ARGV array is then processed as a list of filenames. The loop
ヌルファイルハンドル <> (時々ダイヤモンド演算子と呼ばれます) は特別で、 sed や awk および、ファイル名のリストを取って、 それら全てからの入力の各行に同じことをするような その他の Unix フィルタプログラムをエミュレートするために使われます。 <> からの入力は、標準入力からか、コマンドライン上に並べられた個々の ファイルから行なわれます。 動作の概要は、以下のようになります: 最初に <> が評価されると、配列 @ARGV が調べられ、空であれば、$ARGV[0] に "-" を設定します。 これは、open されるとき標準入力となります。 その後、配列 @ARGV がファイル名のリストとして処理されます。
while (<>) {
... # code for each line
}is equivalent to the following Perl-like pseudo code:
は以下ののような Perl の擬似コードと等価です:
unshift(@ARGV, '-') unless @ARGV;
while ($ARGV = shift) {
open(ARGV, $ARGV);
while (<ARGV>) {
... # code for each line
}
}except that it isn't so cumbersome to say, and will actually work. It really does shift the @ARGV array and put the current filename into the $ARGV variable. It also uses filehandle ARGV internally. <> is just a synonym for <ARGV>, which is magical. (The pseudo code above doesn't work because it treats <ARGV> as non-magical.)
但し、わずらわしく書かなくても、動作します。 実際に @ARGV を shift しますし、その時点のファイル名を変数 $ARGV に 入れています。 また、内部的にファイルハンドル ARGV を使っています。 <> は <ARGV> の同義語で、マジカルです。 (上記の擬似コードは、<ARGV> をマジカルではないものとして 扱っているので、うまく動作しません。)
Since the null filehandle uses the two argument form of "open" in perlfunc it interprets special characters, so if you have a script like this:
空ファイルハンドルは 2 引数の "open" in perlfunc を使った特別な文字列なので、 もし以下のようなスクリプトを書いて:
while (<>) {
print;
}and call it with perl dangerous.pl 'rm -rfv *|', it actually opens a pipe, executes the rm command and reads rm's output from that pipe. If you want all items in @ARGV to be interpreted as file names, you can use the module ARGV::readonly from CPAN, or use the double diamond bracket:
これを perl dangerous.pl 'rm -rfv *|' として呼び出すと、実際には パイプを開き、rm コマンドを実行して、 rm の出力をパイプから読みます。 もし @ARGV の全ての要素をファイル名として解釈させたいなら、 CPAN にある ARGV::readonly モジュールか、二重ダイヤモンド山かっこが 使えます。
while (<<>>) {
print;
}Using double angle brackets inside of a while causes the open to use the three argument form (with the second argument being <), so all arguments in ARGV are treated as literal filenames (including "-"). (Note that for convenience, if you use <<>> and if @ARGV is empty, it will still read from the standard input.)
while の中で二重角かっこを使うと、 3 引数型式 (かつ 2 番目の引数が < の) open を引き起こすので、 ARGV の全ての引数は ("-" を含めて) リテラル名ファイル名として 扱われます。 (便宜のため、<<>> を使って @ARGV が空の場合、標準入力から 読み込みます。)
You can modify @ARGV before the first <> as long as the array ends up containing the list of filenames you really want. Line numbers ($.) continue as though the input were one big happy file. See the example in "eof" in perlfunc for how to reset line numbers on each file.
最終的に、@ARGV に扱いたいと思っているファイル名が含まれるのであれば、 最初に <> を評価する前に @ARGV を変更することも可能です。 行番号 ($.) は、入力ファイルがあたかも 1 つの大きなファイルで あるかのように、続けてカウントされます。 個々のファイルごとにリセットする方法は、"eof" in perlfunc の例を 参照してください。
If you want to set @ARGV to your own list of files, go right ahead. This sets @ARGV to all plain text files if no @ARGV was given:
最初から @ARGV に自分でファイルのリストを設定してもかまいません。 以下は @ARGV が与えられなかったときに全てのテキストファイルを @ARGV に設定します。
@ARGV = grep { -f && -T } glob('*') unless @ARGV;You can even set them to pipe commands. For example, this automatically filters compressed arguments through gzip:
ここにパイプコマンドを置くことも出来ます。 例えば、以下は圧縮された引数を自動的に gzip のフィルタに通します:
@ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;If you want to pass switches into your script, you can use one of the Getopts modules or put a loop on the front like this:
スクリプトにスイッチを渡したいのであれば、Getopts モジュールを 使うこともできますし、実際の処理の前にのようなループを置くこともできます。
while ($_ = $ARGV[0], /^-/) {
shift;
last if /^--$/;
if (/^-D(.*)/) { $debug = $1 }
if (/^-v/) { $verbose++ }
# ... # other switches
}
while (<>) {
# ... # code for each line
}The <> symbol will return undef for end-of-file only once. If you call it again after this, it will assume you are processing another @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
シンボル <> がファイルの最後で undef を返すのは一度きりです。 そのあとでもう一度呼び出すと、新たに別の @ARGV を処理するものとみなされ、 その時に @ARGV を設定しなおしていないと、STDIN からの入力を 読み込むことになります。
If what the angle brackets contain is a simple scalar variable (for example, $foo), then that variable contains the name of the filehandle to input from, or its typeglob, or a reference to the same. For example:
山括弧の中の文字列が ($foo のような) 単純スカラ変数であれば、 その変数が入力を行なうファイルハンドルの名前そのもの、名前への型グロブ、 名前へのリファレンスのいずれかを示しているとみなされます。 例えば:
$fh = \*STDIN;
$line = <$fh>;If what's within the angle brackets is neither a filehandle nor a simple scalar variable containing a filehandle name, typeglob, or typeglob reference, it is interpreted as a filename pattern to be globbed, and either a list of filenames or the next filename in the list is returned, depending on context. This distinction is determined on syntactic grounds alone. That means <$x> is always a readline() from an indirect handle, but <$hash{key}> is always a glob(). That's because $x is a simple scalar variable, but $hash{key} is not--it's a hash element. Even <$x > (note the extra space) is treated as glob("$x "), not readline($x).
山括弧の中の文字列がファイルハンドルでもファイルハンドル名、型グロブ、 型グロブリファレンスのいずれかが入った単純スカラ変数でもなければ、 グロブを行なうファイル名のパターンと解釈され、コンテキストによって ファイル名のリストか、そのリストの次のファイル名が返されます。 この区別は単に構文的に行われます。 <$x> は常に間接ハンドルから readline() しますが、 <$hash{key}> は常に glob() します。 $x は単純スカラー変数ですが、$hash{key} は違う(ハッシュ要素)からです。 <$x > (余分な空白に注意) ですら readline($x) ではなく glob("$x ") として扱われます。
One level of double-quote interpretation is done first, but you can't say <$foo> because that's an indirect filehandle as explained in the previous paragraph. (In older versions of Perl, programmers would insert curly brackets to force interpretation as a filename glob: <${foo}>. These days, it's considered cleaner to call the internal function directly as glob($foo), which is probably the right way to have done it in the first place.) For example:
まず、1 段階だけダブルクォート展開が行なわれますが、前の段落に書いた 間接ファイルハンドルと同じになる、<$foo> のようには書けません。 (Perl の古いバージョンでは、ファイル名グロブと解釈させるために <${foo}> のように中括弧を入れていました。 最近ではより明確にするために、glob($foo) と内部関数を呼ぶことも できます; おそらく、まず、こちらの方で試すのが正解でしょう。) 例えば:
while (<*.c>) {
chmod 0644, $_;
}is roughly equivalent to:
はだいたい以下と等価です:
open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
while (<FOO>) {
chomp;
chmod 0644, $_;
}except that the globbing is actually done internally using the standard File::Glob extension. Of course, the shortest way to do the above is:
但し実際のグロブは内部的に標準の File::Glob モジュールを使います。 もちろん、もっと簡単に以下のように書けます:
chmod 0644, <*.c>;A (file)glob evaluates its (embedded) argument only when it is starting a new list. All values must be read before it will start over. In list context, this isn't important because you automatically get them all anyway. However, in scalar context the operator returns the next value each time it's called, or undef when the list has run out. As with filehandle reads, an automatic defined is generated when the glob occurs in the test part of a while, because legal glob returns (for example, a file called 0) would otherwise terminate the loop. Again, undef is returned only once. So if you're expecting a single value from a glob, it is much better to say
(ファイル)グロブは新しいリストを開始するときにだけ(組み込みの)引数を 評価します。 全ての値は開始する前に読み込んでいなければなりません。 これはリストコンテキストでは、とにかく自動的に全てを取り込むので 重要ではありません。 しかし、スカラコンテキストではこの演算子は呼び出された時の 次の値か、リストがなくなったときには undef を返します。 ファイルハンドルを読み込む場合は、グロブが while の条件部にある場合は 自動的な defined が生成されます; なぜならそうしないと、本来の glob の返り値 (例えば、0 というファイル) が ループを終了させるからです。 ここでも、undef は一度だけ返されます。 従って、もしグロブから一つの値だけを想定している場合、 以下のように書くことが:
($file) = <blurch*>;than
以下のように書くよりはるかに良いです:
$file = <blurch*>;because the latter will alternate between returning a filename and returning false.
なぜなら後者はファイル名を返す場合と偽を返す場合があるからです。
If you're trying to do variable interpolation, it's definitely better to use the glob() function, because the older notation can cause people to become confused with the indirect filehandle notation.
変数変換に挑戦する場合、明らかに glob() 関数を使う方が良いです; なぜなら古い表記は間接ファイルハンドル表記と混乱するかも知れないからです。
@files = glob("$dir/*.[ch]");
@files = glob($files[$i]);If an angle-bracket-based globbing expression is used as the condition of a while or for loop, then it will be implicitly assigned to $_. If either a globbing expression or an explicit assignment of a globbing expression to a scalar is used as a while/for condition, then the condition actually tests for definedness of the expression's value, not for its regular truth value.
角かっこグロブ式が while や for ループの条件として使われた場合、 これは暗黙に $_ に代入されます。 さらに、グロブ式またはグロブ式からスカラへの明示的な代入が while/for の条件部として使われた場合、 条件は通常の真の値かどうかではなく、式の値が定義されているかどうかを テストします。
定数の畳み込み¶
Like C, Perl does a certain amount of expression evaluation at compile time whenever it determines that all arguments to an operator are static and have no side effects. In particular, string concatenation happens at compile time between literals that don't do variable substitution. Backslash interpolation also happens at compile time. You can say
C と同じように Perl でも、演算子に対するすべての引数がスタティックで、 副作用がないと判断できれば、コンパイル時に式の評価を行なってしまいます。 特に、変数置換の無いリテラルどうしの文字列連結はコンパイル時に行なわれます。 バックスラッシュの解釈もコンパイル時に行なわれます。 以下のように書けて、
'Now is the time for all'
. "\n"
. 'good men to come to.'and this all reduces to one string internally. Likewise, if you say
内部的に 1 つの文字列になります。同様に
foreach $file (@filenames) {
if (-s $file > 5 + 100 * 2**16) { }
}the compiler precomputes the number which that expression represents so that the interpreter won't have to.
と書くとコンパイラは、式が表わす数値をあらかじめ計算しますので、 インタプリタで計算する必要がなくなっています。
無実行¶
Perl doesn't officially have a no-op operator, but the bare constants 0 and 1 are special-cased not to produce a warning in void context, so you can for example safely do
Perl は公式には無実行演算子はありませんが、裸の定数 0 と 1 は 特別に無効コンテキストでも警告を出さないことになっているので、 例えば安全に以下のように書けます:
1 while foo();ビット列演算子¶
Bitstrings of any size may be manipulated by the bitwise operators (~ | & ^).
任意のサイズのビット列はビット単位演算子(~ | & ^)で操作できます。
If the operands to a binary bitwise op are strings of different sizes, | and ^ ops act as though the shorter operand had additional zero bits on the right, while the & op acts as though the longer operand were truncated to the length of the shorter. The granularity for such extension or truncation is one or more bytes.
二項ビット単位演算子のオペランドが異なった長さの文字列だった場合、 | と ^ の演算子は短い側のオペランドの右側に追加のゼロが ついているとみなします; 一方 & 演算子は長い方のオペランドが短い方に 切り詰められます。 この拡張や短縮の粒度はバイト単位です。
# ASCII-based examples
print "j p \n" ^ " a h"; # prints "JAPH\n"
print "JA" | " ph\n"; # prints "japh\n"
print "japh\nJunk" & '_____'; # prints "JAPH\n";
print 'p N$' ^ " E<H\n"; # prints "Perl\n";If you are intending to manipulate bitstrings, be certain that you're supplying bitstrings: If an operand is a number, that will imply a numeric bitwise operation. You may explicitly show which type of operation you intend by using "" or 0+, as in the examples below.
ビット列を操作したい場合は、確実にビット列が渡されるようにしてください: オペランドが数字の場合、数値 ビット単位演算を仮定します。 明示的に演算の型を指定するときには、以下の例のように "" か 0+ を使ってください。
$foo = 150 | 105; # yields 255 (0x96 | 0x69 is 0xFF)
$foo = '150' | 105; # yields 255
$foo = 150 | '105'; # yields 255
$foo = '150' | '105'; # yields string '155' (under ASCII) $foo = 150 | 105; # 255 になる (0x96 | 0x69 は 0xFF)
$foo = '150' | 105; # 255 になる
$foo = 150 | '105'; # 255 になる
$foo = '150' | '105'; # (ASCII では) 文字列 '155' になる $baz = 0+$foo & 0+$bar; # both ops explicitly numeric
$biz = "$foo" ^ "$bar"; # both ops explicitly stringy $baz = 0+$foo & 0+$bar; # どちらのオペランドも明示的に数値
$biz = "$foo" ^ "$bar"; # どちらのオペランドも明示的に文字列This somewhat unpredictable behavior can be avoided with the "bitwise" feature, new in Perl 5.22. You can enable it via use feature 'bitwise' or use v5.28. Before Perl 5.28, it used to emit a warning in the "experimental::bitwise" category. Under this feature, the four standard bitwise operators (~ | & ^) are always numeric. Adding a dot after each operator (~. |. &. ^.) forces it to treat its operands as strings:
この、いくらか予測の難しい振る舞いは、Perl 5.22 で導入された "bitwise" 機能で避けることができます。 これは use feature 'bitwise' か use v5.28 で有効にできます。 Perl 5.28 より前では、これは "experimental::bitwise" カテゴリの警告を 出力していました。 この機能の基では、四つのビット単位演算子 (~ | & ^) は常に数値です。 それぞれの演算子の後にピリオドを付ける (~. |. &. ^.) ことで、 そのオペランドを文字列として扱うことを強制します:
use feature "bitwise";
$foo = 150 | 105; # yields 255 (0x96 | 0x69 is 0xFF)
$foo = '150' | 105; # yields 255
$foo = 150 | '105'; # yields 255
$foo = '150' | '105'; # yields 255
$foo = 150 |. 105; # yields string '155'
$foo = '150' |. 105; # yields string '155'
$foo = 150 |.'105'; # yields string '155'
$foo = '150' |.'105'; # yields string '155'
$baz = $foo & $bar; # both operands numeric
$biz = $foo ^. $bar; # both operands stringyThe assignment variants of these operators (&= |= ^= &.= |.= ^.=) behave likewise under the feature.
この機能の基では、これらの演算子の亜種 (&= |= ^= &.= |.= ^.=) も 同様に振る舞います。
It is a fatal error if an operand contains a character whose ordinal value is above 0xFF, and hence not expressible except in UTF-8. The operation is performed on a non-UTF-8 copy for other operands encoded in UTF-8. See "Byte and Character Semantics" in perlunicode.
値が 0xFF 以上で、UTF-8 以外で表現できない文字がオペランドに含まれている 場合、これは致命的エラーになります。 他の UTF-8 でエンコードされたオペランドに対して 非 UTF-8 のコピーに対して操作が行われます。 "Byte and Character Semantics" in perlunicode を参照してください。
See "vec" in perlfunc for information on how to manipulate individual bits in a bit vector.
ビットベクタの個々のビットをどのように操作するかの情報については "vec" in perlfunc を参照して下さい。
整数演算¶
By default, Perl assumes that it must do most of its arithmetic in floating point. But by saying
デフォルトでは、Perl は演算を浮動小数で行なわなければならないものと しています。 しかし、(もしそうしたいなら)
use integer;you may tell the compiler to use integer operations (see integer for a detailed explanation) from here to the end of the enclosing BLOCK. An inner BLOCK may countermand this by saying
と書けば、その場所から現在の BLOCK の終わりまでは、整数演算 (詳しい説明は integer を参照してください) を 行なってよいと、コンパイラに指示することができます。 内部の BLOCK で、
no integer;which lasts until the end of that BLOCK. Note that this doesn't mean everything is an integer, merely that Perl will use integer operations for arithmetic, comparison, and bitwise operators. For example, even under use integer, if you take the sqrt(2), you'll still get 1.4142135623731 or so.
と書けば、その BLOCK の終わりまでは、指示を取り消すことになります。 これは全てを整数だけを使って処理することを意味するわけではなく、 単に Perl が算術、比較、ビット単位演算子で整数演算を するというだけであることに注意してください。 例えば、use integer の指定があっても、sqrt(2) とすると、 1.4142135623731 といった結果が返ってきます。
Used on numbers, the bitwise operators (& | ^ ~ << >>) always produce integral results. (But see also "Bitwise String Operators".) However, use integer still has meaning for them. By default, their results are interpreted as unsigned integers, but if use integer is in effect, their results are interpreted as signed integers. For example, ~0 usually evaluates to a large integral value. However, use integer; ~0 is -1 on two's-complement machines.
数値を使う場合、ビット単位演算子 (& | ^ ~ << >>) は 常に整数の結果を生成します。 (但し "Bitwise String Operators" も参照して下さい。) しかし、それでも use integer は意味があります。 デフォルトでは、これらの結果は符号なし整数として解釈されますが、 use integer が有効の場合は、符号付き整数として解釈されます。 例えば、~0 は通常大きな整数の値として評価されます。 しかし、use integer; ~0 は 2 の補数のマシンでは -1 になります。
浮動小数点数演算¶
While use integer provides integer-only arithmetic, there is no analogous mechanism to provide automatic rounding or truncation to a certain number of decimal places. For rounding to a certain number of digits, sprintf() or printf() is usually the easiest route. See perlfaq4.
use integer が整数演算を提供する一方、数を特定の桁で自動的に丸めたり 切り捨てたりする機構はありません。 数を丸めるには、sprintf() や printf() を使うのが一番簡単な方法です。 perlfaq4 を参照して下さい。
Floating-point numbers are only approximations to what a mathematician would call real numbers. There are infinitely more reals than floats, so some corners must be cut. For example:
浮動小数点数は数学者が実数と呼ぶものの近似でしかありません。 実数は浮動小数点より無限に続くので、多少角が丸められます。 例えば:
printf "%.20g\n", 123456789123456789;
# produces 123456789123456784Testing for exact floating-point equality or inequality is not a good idea. Here's a (relatively expensive) work-around to compare whether two floating-point numbers are equal to a particular number of decimal places. See Knuth, volume II, for a more robust treatment of this topic.
浮動小数点数が等しいかどうかをちょうど同じかどうかで比較するのはよい 考えではありません。 以下に、二つの浮動小数点数が指定された桁まで等しいかどうかを 比較する(比較的重い)次善の策を示します。 この問題に関するより厳密な扱いについては Knuth, volume II を参照して下さい。
sub fp_equal {
my ($X, $Y, $POINTS) = @_;
my ($tX, $tY);
$tX = sprintf("%.${POINTS}g", $X);
$tY = sprintf("%.${POINTS}g", $Y);
return $tX eq $tY;
}The POSIX module (part of the standard perl distribution) implements ceil(), floor(), and other mathematical and trigonometric functions. The Math::Complex module (part of the standard perl distribution) defines mathematical functions that work on both the reals and the imaginary numbers. Math::Complex is not as efficient as POSIX, but POSIX can't work with complex numbers.
POSIX モジュール(Perl 標準配布パッケージの一部) は ceil(), floor() 及び その他の数学関数や三角関数を実装しています。 Math::Complex モジュール(Perl 標準配布パッケージの一部)は実数と虚数の 両方で動作する数学関数を定義しています。 Math::Complex は POSIX ほど効率的ではありませんが、POSIX は複素数は 扱えません。
Rounding in financial applications can have serious implications, and the rounding method used should be specified precisely. In these cases, it probably pays not to trust whichever system rounding is being used by Perl, but to instead implement the rounding function you need yourself.
金融アプリケーションにおける丸めは深刻な影響を与える可能性があり、 使用する丸めメソッドは指定された精度で行われるべきです。 このような場合、Perl が使用するシステム丸めを信用せず、 代わりに自分自身で丸め関数を実装するべきです。
より大きな数¶
The standard Math::BigInt, Math::BigRat, and Math::BigFloat modules, along with the bignum, bigint, and bigrat pragmas, provide variable-precision arithmetic and overloaded operators, although they're currently pretty slow. At the cost of some space and considerable speed, they avoid the normal pitfalls associated with limited-precision representations.
標準の Math::BigInt, Math::BigRat, Math::BigFloat モジュールと bignum, bigint, bigrat プラグマは多倍長演算を提供し、 演算子をオーバーロードしますが、これらは現在のところかなり遅いです。 多少の領域とかなりの速度を犠牲にして、桁数が制限されていることによる ありがちな落とし穴を避けることができます。
use 5.010;
use bigint; # easy interface to Math::BigInt
$x = 123456789123456789;
say $x * $x;
+15241578780673678515622620750190521Or with rationals:
あるいは分数を使って:
use 5.010;
use bigrat;
$x = 3/22;
$y = 4/6;
say "x/y is ", $x/$y;
say "x*y is ", $x*$y;
x/y is 9/44
x*y is 1/11Several modules let you calculate with unlimited or fixed precision (bound only by memory and CPU time). There are also some non-standard modules that provide faster implementations via external C libraries.
(メモリと CPU 時間のみに依存する)無制限か固定の精度での計算ができる モジュールがいくつかあります。 さらに外部 C ライブラリを使ってより速い実装を提供する 非標準のモジュールもあります。
Here is a short, but incomplete summary:
以下は短いですが不完全なリストです。
Math::String treat string sequences like numbers
Math::FixedPrecision calculate with a fixed precision
Math::Currency for currency calculations
Bit::Vector manipulate bit vectors fast (uses C)
Math::BigIntFast Bit::Vector wrapper for big numbers
Math::Pari provides access to the Pari C library
Math::Cephes uses the external Cephes C library (no
big numbers)
Math::Cephes::Fraction fractions via the Cephes library
Math::GMP another one using an external C library
Math::GMPz an alternative interface to libgmp's big ints
Math::GMPq an interface to libgmp's fraction numbers
Math::GMPf an interface to libgmp's floating point numbers Math::String 文字列を数値のように扱う
Math::FixedPrecision 固定精度で計算する
Math::Currency 通貨の計算用
Bit::Vector (C を使って)ビットベクタを速く操作する
Math::BigIntFast 大きな数のための Bit::Vector のラッパー
Math::Pari Pari C ライブラリへのアクセスを提供する
Math::Cephes 外部の Cephes C を使う(大きな数はなし)
Math::Cephes::Fraction Cephes ライブラリを使った分数
Math::GMP これも外部 C ライブラリを使う
Math::GMPz libgmp の大きな整数へのもう一つのインターフェース
Math::GMPq libgmp の分数へのインターフェース
Math::GMPf libgmp の浮動小数点のインターフェースChoose wisely.
うまく選んでください。
APPENDIX¶
List of Extra Paired Delimiters¶
The complete list of accepted paired delimiters as of Unicode 14.0 is:
( ) U+0028, U+0029 LEFT/RIGHT PARENTHESIS
< > U+003C, U+003E LESS-THAN/GREATER-THAN SIGN
[ ] U+005B, U+005D LEFT/RIGHT SQUARE BRACKET
{ } U+007B, U+007D LEFT/RIGHT CURLY BRACKET
« » U+00AB, U+00BB LEFT/RIGHT-POINTING DOUBLE ANGLE QUOTATION MARK
» « U+00BB, U+00AB RIGHT/LEFT-POINTING DOUBLE ANGLE QUOTATION MARK
༺ ༻ U+0F3A, U+0F3B TIBETAN MARK GUG RTAGS GYON, TIBETAN MARK GUG
RTAGS GYAS
༼ ༽ U+0F3C, U+0F3D TIBETAN MARK ANG KHANG GYON, TIBETAN MARK ANG
KHANG GYAS
᚛ ᚜ U+169B, U+169C OGHAM FEATHER MARK, OGHAM REVERSED FEATHER MARK
‘ ’ U+2018, U+2019 LEFT/RIGHT SINGLE QUOTATION MARK
’ ‘ U+2019, U+2018 RIGHT/LEFT SINGLE QUOTATION MARK
“ ” U+201C, U+201D LEFT/RIGHT DOUBLE QUOTATION MARK
” “ U+201D, U+201C RIGHT/LEFT DOUBLE QUOTATION MARK
‵ ′ U+2035, U+2032 REVERSED PRIME, PRIME
‶ ″ U+2036, U+2033 REVERSED DOUBLE PRIME, DOUBLE PRIME
‷ ‴ U+2037, U+2034 REVERSED TRIPLE PRIME, TRIPLE PRIME
‹ › U+2039, U+203A SINGLE LEFT/RIGHT-POINTING ANGLE QUOTATION MARK
› ‹ U+203A, U+2039 SINGLE RIGHT/LEFT-POINTING ANGLE QUOTATION MARK
⁅ ⁆ U+2045, U+2046 LEFT/RIGHT SQUARE BRACKET WITH QUILL
⁍ ⁌ U+204D, U+204C BLACK RIGHT/LEFTWARDS BULLET
⁽ ⁾ U+207D, U+207E SUPERSCRIPT LEFT/RIGHT PARENTHESIS
₍ ₎ U+208D, U+208E SUBSCRIPT LEFT/RIGHT PARENTHESIS
→ ← U+2192, U+2190 RIGHT/LEFTWARDS ARROW
↛ ↚ U+219B, U+219A RIGHT/LEFTWARDS ARROW WITH STROKE
↝ ↜ U+219D, U+219C RIGHT/LEFTWARDS WAVE ARROW
↠ ↞ U+21A0, U+219E RIGHT/LEFTWARDS TWO HEADED ARROW
↣ ↢ U+21A3, U+21A2 RIGHT/LEFTWARDS ARROW WITH TAIL
↦ ↤ U+21A6, U+21A4 RIGHT/LEFTWARDS ARROW FROM BAR
↪ ↩ U+21AA, U+21A9 RIGHT/LEFTWARDS ARROW WITH HOOK
↬ ↫ U+21AC, U+21AB RIGHT/LEFTWARDS ARROW WITH LOOP
↱ ↰ U+21B1, U+21B0 UPWARDS ARROW WITH TIP RIGHT/LEFTWARDS
↳ ↲ U+21B3, U+21B2 DOWNWARDS ARROW WITH TIP RIGHT/LEFTWARDS
⇀ ↼ U+21C0, U+21BC RIGHT/LEFTWARDS HARPOON WITH BARB UPWARDS
⇁ ↽ U+21C1, U+21BD RIGHT/LEFTWARDS HARPOON WITH BARB DOWNWARDS
⇉ ⇇ U+21C9, U+21C7 RIGHT/LEFTWARDS PAIRED ARROWS
⇏ ⇍ U+21CF, U+21CD RIGHT/LEFTWARDS DOUBLE ARROW WITH STROKE
⇒ ⇐ U+21D2, U+21D0 RIGHT/LEFTWARDS DOUBLE ARROW
⇛ ⇚ U+21DB, U+21DA RIGHT/LEFTWARDS TRIPLE ARROW
⇝ ⇜ U+21DD, U+21DC RIGHT/LEFTWARDS SQUIGGLE ARROW
⇢ ⇠ U+21E2, U+21E0 RIGHT/LEFTWARDS DASHED ARROW
⇥ ⇤ U+21E5, U+21E4 RIGHT/LEFTWARDS ARROW TO BAR
⇨ ⇦ U+21E8, U+21E6 RIGHT/LEFTWARDS WHITE ARROW
⇴ ⬰ U+21F4, U+2B30 RIGHT/LEFT ARROW WITH SMALL CIRCLE
⇶ ⬱ U+21F6, U+2B31 THREE RIGHT/LEFTWARDS ARROWS
⇸ ⇷ U+21F8, U+21F7 RIGHT/LEFTWARDS ARROW WITH VERTICAL STROKE
⇻ ⇺ U+21FB, U+21FA RIGHT/LEFTWARDS ARROW WITH DOUBLE VERTICAL
STROKE
⇾ ⇽ U+21FE, U+21FD RIGHT/LEFTWARDS OPEN-HEADED ARROW
∈ ∋ U+2208, U+220B ELEMENT OF, CONTAINS AS MEMBER
∉ ∌ U+2209, U+220C NOT AN ELEMENT OF, DOES NOT CONTAIN AS MEMBER
∊ ∍ U+220A, U+220D SMALL ELEMENT OF, SMALL CONTAINS AS MEMBER
≤ ≥ U+2264, U+2265 LESS-THAN/GREATER-THAN OR EQUAL TO
≦ ≧ U+2266, U+2267 LESS-THAN/GREATER-THAN OVER EQUAL TO
≨ ≩ U+2268, U+2269 LESS-THAN/GREATER-THAN BUT NOT EQUAL TO
≪ ≫ U+226A, U+226B MUCH LESS-THAN/GREATER-THAN
≮ ≯ U+226E, U+226F NOT LESS-THAN/GREATER-THAN
≰ ≱ U+2270, U+2271 NEITHER LESS-THAN/GREATER-THAN NOR EQUAL TO
≲ ≳ U+2272, U+2273 LESS-THAN/GREATER-THAN OR EQUIVALENT TO
≴ ≵ U+2274, U+2275 NEITHER LESS-THAN/GREATER-THAN NOR EQUIVALENT TO
≺ ≻ U+227A, U+227B PRECEDES/SUCCEEDS
≼ ≽ U+227C, U+227D PRECEDES/SUCCEEDS OR EQUAL TO
≾ ≿ U+227E, U+227F PRECEDES/SUCCEEDS OR EQUIVALENT TO
⊀ ⊁ U+2280, U+2281 DOES NOT PRECEDE/SUCCEED
⊂ ⊃ U+2282, U+2283 SUBSET/SUPERSET OF
⊄ ⊅ U+2284, U+2285 NOT A SUBSET/SUPERSET OF
⊆ ⊇ U+2286, U+2287 SUBSET/SUPERSET OF OR EQUAL TO
⊈ ⊉ U+2288, U+2289 NEITHER A SUBSET/SUPERSET OF NOR EQUAL TO
⊊ ⊋ U+228A, U+228B SUBSET/SUPERSET OF WITH NOT EQUAL TO
⊣ ⊢ U+22A3, U+22A2 LEFT/RIGHT TACK
⊦ ⫞ U+22A6, U+2ADE ASSERTION, SHORT LEFT TACK
⊨ ⫤ U+22A8, U+2AE4 TRUE, VERTICAL BAR DOUBLE LEFT TURNSTILE
⊩ ⫣ U+22A9, U+2AE3 FORCES, DOUBLE VERTICAL BAR LEFT TURNSTILE
⊰ ⊱ U+22B0, U+22B1 PRECEDES/SUCCEEDS UNDER RELATION
⋐ ⋑ U+22D0, U+22D1 DOUBLE SUBSET/SUPERSET
⋖ ⋗ U+22D6, U+22D7 LESS-THAN/GREATER-THAN WITH DOT
⋘ ⋙ U+22D8, U+22D9 VERY MUCH LESS-THAN/GREATER-THAN
⋜ ⋝ U+22DC, U+22DD EQUAL TO OR LESS-THAN/GREATER-THAN
⋞ ⋟ U+22DE, U+22DF EQUAL TO OR PRECEDES/SUCCEEDS
⋠ ⋡ U+22E0, U+22E1 DOES NOT PRECEDE/SUCCEED OR EQUAL
⋦ ⋧ U+22E6, U+22E7 LESS-THAN/GREATER-THAN BUT NOT EQUIVALENT TO
⋨ ⋩ U+22E8, U+22E9 PRECEDES/SUCCEEDS BUT NOT EQUIVALENT TO
⋲ ⋺ U+22F2, U+22FA ELEMENT OF/CONTAINS WITH LONG HORIZONTAL STROKE
⋳ ⋻ U+22F3, U+22FB ELEMENT OF/CONTAINS WITH VERTICAL BAR AT END OF
HORIZONTAL STROKE
⋴ ⋼ U+22F4, U+22FC SMALL ELEMENT OF/CONTAINS WITH VERTICAL BAR AT
END OF HORIZONTAL STROKE
⋶ ⋽ U+22F6, U+22FD ELEMENT OF/CONTAINS WITH OVERBAR
⋷ ⋾ U+22F7, U+22FE SMALL ELEMENT OF/CONTAINS WITH OVERBAR
⌈ ⌉ U+2308, U+2309 LEFT/RIGHT CEILING
⌊ ⌋ U+230A, U+230B LEFT/RIGHT FLOOR
⌦ ⌫ U+2326, U+232B ERASE TO THE RIGHT/LEFT
〈 〉 U+2329, U+232A LEFT/RIGHT-POINTING ANGLE BRACKET
⍈ ⍇ U+2348, U+2347 APL FUNCTIONAL SYMBOL QUAD RIGHT/LEFTWARDS ARROW
⏩ ⏪ U+23E9, U+23EA BLACK RIGHT/LEFT-POINTING DOUBLE TRIANGLE
⏭ ⏮ U+23ED, U+23EE BLACK RIGHT/LEFT-POINTING DOUBLE TRIANGLE WITH
VERTICAL BAR
☛ ☚ U+261B, U+261A BLACK RIGHT/LEFT POINTING INDEX
☞ ☜ U+261E, U+261C WHITE RIGHT/LEFT POINTING INDEX
⚞ ⚟ U+269E, U+269F THREE LINES CONVERGING RIGHT/LEFT
❨ ❩ U+2768, U+2769 MEDIUM LEFT/RIGHT PARENTHESIS ORNAMENT
❪ ❫ U+276A, U+276B MEDIUM FLATTENED LEFT/RIGHT PARENTHESIS ORNAMENT
❬ ❭ U+276C, U+276D MEDIUM LEFT/RIGHT-POINTING ANGLE BRACKET
ORNAMENT
❮ ❯ U+276E, U+276F HEAVY LEFT/RIGHT-POINTING ANGLE QUOTATION MARK
ORNAMENT
❰ ❱ U+2770, U+2771 HEAVY LEFT/RIGHT-POINTING ANGLE BRACKET ORNAMENT
❲ ❳ U+2772, U+2773 LIGHT LEFT/RIGHT TORTOISE SHELL BRACKET ORNAMENT
❴ ❵ U+2774, U+2775 MEDIUM LEFT/RIGHT CURLY BRACKET ORNAMENT
⟃ ⟄ U+27C3, U+27C4 OPEN SUBSET/SUPERSET
⟅ ⟆ U+27C5, U+27C6 LEFT/RIGHT S-SHAPED BAG DELIMITER
⟈ ⟉ U+27C8, U+27C9 REVERSE SOLIDUS PRECEDING SUBSET, SUPERSET
PRECEDING SOLIDUS
⟞ ⟝ U+27DE, U+27DD LONG LEFT/RIGHT TACK
⟦ ⟧ U+27E6, U+27E7 MATHEMATICAL LEFT/RIGHT WHITE SQUARE BRACKET
⟨ ⟩ U+27E8, U+27E9 MATHEMATICAL LEFT/RIGHT ANGLE BRACKET
⟪ ⟫ U+27EA, U+27EB MATHEMATICAL LEFT/RIGHT DOUBLE ANGLE BRACKET
⟬ ⟭ U+27EC, U+27ED MATHEMATICAL LEFT/RIGHT WHITE TORTOISE SHELL
BRACKET
⟮ ⟯ U+27EE, U+27EF MATHEMATICAL LEFT/RIGHT FLATTENED PARENTHESIS
⟴ ⬲ U+27F4, U+2B32 RIGHT/LEFT ARROW WITH CIRCLED PLUS
⟶ ⟵ U+27F6, U+27F5 LONG RIGHT/LEFTWARDS ARROW
⟹ ⟸ U+27F9, U+27F8 LONG RIGHT/LEFTWARDS DOUBLE ARROW
⟼ ⟻ U+27FC, U+27FB LONG RIGHT/LEFTWARDS ARROW FROM BAR
⟾ ⟽ U+27FE, U+27FD LONG RIGHT/LEFTWARDS DOUBLE ARROW FROM BAR
⟿ ⬳ U+27FF, U+2B33 LONG RIGHT/LEFTWARDS SQUIGGLE ARROW
⤀ ⬴ U+2900, U+2B34 RIGHT/LEFTWARDS TWO-HEADED ARROW WITH VERTICAL
STROKE
⤁ ⬵ U+2901, U+2B35 RIGHT/LEFTWARDS TWO-HEADED ARROW WITH DOUBLE
VERTICAL STROKE
⤃ ⤂ U+2903, U+2902 RIGHT/LEFTWARDS DOUBLE ARROW WITH VERTICAL
STROKE
⤅ ⬶ U+2905, U+2B36 RIGHT/LEFTWARDS TWO-HEADED ARROW FROM BAR
⤇ ⤆ U+2907, U+2906 RIGHT/LEFTWARDS DOUBLE ARROW FROM BAR
⤍ ⤌ U+290D, U+290C RIGHT/LEFTWARDS DOUBLE DASH ARROW
⤏ ⤎ U+290F, U+290E RIGHT/LEFTWARDS TRIPLE DASH ARROW
⤐ ⬷ U+2910, U+2B37 RIGHT/LEFTWARDS TWO-HEADED TRIPLE DASH ARROW
⤑ ⬸ U+2911, U+2B38 RIGHT/LEFTWARDS ARROW WITH DOTTED STEM
⤔ ⬹ U+2914, U+2B39 RIGHT/LEFTWARDS ARROW WITH TAIL WITH VERTICAL
STROKE
⤕ ⬺ U+2915, U+2B3A RIGHT/LEFTWARDS ARROW WITH TAIL WITH DOUBLE
VERTICAL STROKE
⤖ ⬻ U+2916, U+2B3B RIGHT/LEFTWARDS TWO-HEADED ARROW WITH TAIL
⤗ ⬼ U+2917, U+2B3C RIGHT/LEFTWARDS TWO-HEADED ARROW WITH TAIL WITH
VERTICAL STROKE
⤘ ⬽ U+2918, U+2B3D RIGHT/LEFTWARDS TWO-HEADED ARROW WITH TAIL WITH
DOUBLE VERTICAL STROKE
⤚ ⤙ U+291A, U+2919 RIGHT/LEFTWARDS ARROW-TAIL
⤜ ⤛ U+291C, U+291B RIGHT/LEFTWARDS DOUBLE ARROW-TAIL
⤞ ⤝ U+291E, U+291D RIGHT/LEFTWARDS ARROW TO BLACK DIAMOND
⤠ ⤟ U+2920, U+291F RIGHT/LEFTWARDS ARROW FROM BAR TO BLACK DIAMOND
⤳ ⬿ U+2933, U+2B3F WAVE ARROW POINTING DIRECTLY RIGHT/LEFT
⤷ ⤶ U+2937, U+2936 ARROW POINTING DOWNWARDS THEN CURVING RIGHT/
LEFTWARDS
⥅ ⥆ U+2945, U+2946 RIGHT/LEFTWARDS ARROW WITH PLUS BELOW
⥇ ⬾ U+2947, U+2B3E RIGHT/LEFTWARDS ARROW THROUGH X
⥓ ⥒ U+2953, U+2952 RIGHT/LEFTWARDS HARPOON WITH BARB UP TO BAR
⥗ ⥖ U+2957, U+2956 RIGHT/LEFTWARDS HARPOON WITH BARB DOWN TO BAR
⥛ ⥚ U+295B, U+295A RIGHT/LEFTWARDS HARPOON WITH BARB UP FROM BAR
⥟ ⥞ U+295F, U+295E RIGHT/LEFTWARDS HARPOON WITH BARB DOWN FROM BAR
⥤ ⥢ U+2964, U+2962 RIGHT/LEFTWARDS HARPOON WITH BARB UP ABOVE
RIGHT/LEFTWARDS HARPOON WITH BARB DOWN
⥬ ⥪ U+296C, U+296A RIGHT/LEFTWARDS HARPOON WITH BARB UP ABOVE LONG
DASH
⥭ ⥫ U+296D, U+296B RIGHT/LEFTWARDS HARPOON WITH BARB DOWN BELOW
LONG DASH
⥱ ⭀ U+2971, U+2B40 EQUALS SIGN ABOVE RIGHT/LEFTWARDS ARROW
⥲ ⭁ U+2972, U+2B41 TILDE OPERATOR ABOVE RIGHTWARDS ARROW, REVERSE
TILDE OPERATOR ABOVE LEFTWARDS ARROW
⥴ ⭋ U+2974, U+2B4B RIGHTWARDS ARROW ABOVE TILDE OPERATOR,
LEFTWARDS ARROW ABOVE REVERSE TILDE OPERATOR
⥵ ⭂ U+2975, U+2B42 RIGHTWARDS ARROW ABOVE ALMOST EQUAL TO,
LEFTWARDS ARROW ABOVE REVERSE ALMOST EQUAL TO
⥹ ⥻ U+2979, U+297B SUBSET/SUPERSET ABOVE RIGHT/LEFTWARDS ARROW
⦃ ⦄ U+2983, U+2984 LEFT/RIGHT WHITE CURLY BRACKET
⦅ ⦆ U+2985, U+2986 LEFT/RIGHT WHITE PARENTHESIS
⦇ ⦈ U+2987, U+2988 Z NOTATION LEFT/RIGHT IMAGE BRACKET
⦉ ⦊ U+2989, U+298A Z NOTATION LEFT/RIGHT BINDING BRACKET
⦋ ⦌ U+298B, U+298C LEFT/RIGHT SQUARE BRACKET WITH UNDERBAR
⦍ ⦐ U+298D, U+2990 LEFT/RIGHT SQUARE BRACKET WITH TICK IN TOP
CORNER
⦏ ⦎ U+298F, U+298E LEFT/RIGHT SQUARE BRACKET WITH TICK IN BOTTOM
CORNER
⦑ ⦒ U+2991, U+2992 LEFT/RIGHT ANGLE BRACKET WITH DOT
⦓ ⦔ U+2993, U+2994 LEFT/RIGHT ARC LESS-THAN/GREATER-THAN BRACKET
⦕ ⦖ U+2995, U+2996 DOUBLE LEFT/RIGHT ARC GREATER-THAN/LESS-THAN
BRACKET
⦗ ⦘ U+2997, U+2998 LEFT/RIGHT BLACK TORTOISE SHELL BRACKET
⦨ ⦩ U+29A8, U+29A9 MEASURED ANGLE WITH OPEN ARM ENDING IN ARROW
POINTING UP AND RIGHT/LEFT
⦪ ⦫ U+29AA, U+29AB MEASURED ANGLE WITH OPEN ARM ENDING IN ARROW
POINTING DOWN AND RIGHT/LEFT
⦳ ⦴ U+29B3, U+29B4 EMPTY SET WITH RIGHT/LEFT ARROW ABOVE
⧀ ⧁ U+29C0, U+29C1 CIRCLED LESS-THAN/GREATER-THAN
⧘ ⧙ U+29D8, U+29D9 LEFT/RIGHT WIGGLY FENCE
⧚ ⧛ U+29DA, U+29DB LEFT/RIGHT DOUBLE WIGGLY FENCE
⧼ ⧽ U+29FC, U+29FD LEFT/RIGHT-POINTING CURVED ANGLE BRACKET
⩹ ⩺ U+2A79, U+2A7A LESS-THAN/GREATER-THAN WITH CIRCLE INSIDE
⩻ ⩼ U+2A7B, U+2A7C LESS-THAN/GREATER-THAN WITH QUESTION MARK ABOVE
⩽ ⩾ U+2A7D, U+2A7E LESS-THAN/GREATER-THAN OR SLANTED EQUAL TO
⩿ ⪀ U+2A7F, U+2A80 LESS-THAN/GREATER-THAN OR SLANTED EQUAL TO WITH
DOT INSIDE
⪁ ⪂ U+2A81, U+2A82 LESS-THAN/GREATER-THAN OR SLANTED EQUAL TO WITH
DOT ABOVE
⪃ ⪄ U+2A83, U+2A84 LESS-THAN/GREATER-THAN OR SLANTED EQUAL TO WITH
DOT ABOVE RIGHT/LEFT
⪅ ⪆ U+2A85, U+2A86 LESS-THAN/GREATER-THAN OR APPROXIMATE
⪇ ⪈ U+2A87, U+2A88 LESS-THAN/GREATER-THAN AND SINGLE-LINE NOT
EQUAL TO
⪉ ⪊ U+2A89, U+2A8A LESS-THAN/GREATER-THAN AND NOT APPROXIMATE
⪍ ⪎ U+2A8D, U+2A8E LESS-THAN/GREATER-THAN ABOVE SIMILAR OR EQUAL
⪕ ⪖ U+2A95, U+2A96 SLANTED EQUAL TO OR LESS-THAN/GREATER-THAN
⪗ ⪘ U+2A97, U+2A98 SLANTED EQUAL TO OR LESS-THAN/GREATER-THAN WITH
DOT INSIDE
⪙ ⪚ U+2A99, U+2A9A DOUBLE-LINE EQUAL TO OR LESS-THAN/GREATER-THAN
⪛ ⪜ U+2A9B, U+2A9C DOUBLE-LINE SLANTED EQUAL TO OR LESS-THAN/
GREATER-THAN
⪝ ⪞ U+2A9D, U+2A9E SIMILAR OR LESS-THAN/GREATER-THAN
⪟ ⪠ U+2A9F, U+2AA0 SIMILAR ABOVE LESS-THAN/GREATER-THAN ABOVE
EQUALS SIGN
⪡ ⪢ U+2AA1, U+2AA2 DOUBLE NESTED LESS-THAN/GREATER-THAN
⪦ ⪧ U+2AA6, U+2AA7 LESS-THAN/GREATER-THAN CLOSED BY CURVE
⪨ ⪩ U+2AA8, U+2AA9 LESS-THAN/GREATER-THAN CLOSED BY CURVE ABOVE
SLANTED EQUAL
⪪ ⪫ U+2AAA, U+2AAB SMALLER THAN/LARGER THAN
⪬ ⪭ U+2AAC, U+2AAD SMALLER THAN/LARGER THAN OR EQUAL TO
⪯ ⪰ U+2AAF, U+2AB0 PRECEDES/SUCCEEDS ABOVE SINGLE-LINE EQUALS SIGN
⪱ ⪲ U+2AB1, U+2AB2 PRECEDES/SUCCEEDS ABOVE SINGLE-LINE NOT EQUAL TO
⪳ ⪴ U+2AB3, U+2AB4 PRECEDES/SUCCEEDS ABOVE EQUALS SIGN
⪵ ⪶ U+2AB5, U+2AB6 PRECEDES/SUCCEEDS ABOVE NOT EQUAL TO
⪷ ⪸ U+2AB7, U+2AB8 PRECEDES/SUCCEEDS ABOVE ALMOST EQUAL TO
⪹ ⪺ U+2AB9, U+2ABA PRECEDES/SUCCEEDS ABOVE NOT ALMOST EQUAL TO
⪻ ⪼ U+2ABB, U+2ABC DOUBLE PRECEDES/SUCCEEDS
⪽ ⪾ U+2ABD, U+2ABE SUBSET/SUPERSET WITH DOT
⪿ ⫀ U+2ABF, U+2AC0 SUBSET/SUPERSET WITH PLUS SIGN BELOW
⫁ ⫂ U+2AC1, U+2AC2 SUBSET/SUPERSET WITH MULTIPLICATION SIGN BELOW
⫃ ⫄ U+2AC3, U+2AC4 SUBSET/SUPERSET OF OR EQUAL TO WITH DOT ABOVE
⫅ ⫆ U+2AC5, U+2AC6 SUBSET/SUPERSET OF ABOVE EQUALS SIGN
⫇ ⫈ U+2AC7, U+2AC8 SUBSET/SUPERSET OF ABOVE TILDE OPERATOR
⫉ ⫊ U+2AC9, U+2ACA SUBSET/SUPERSET OF ABOVE ALMOST EQUAL TO
⫋ ⫌ U+2ACB, U+2ACC SUBSET/SUPERSET OF ABOVE NOT EQUAL TO
⫏ ⫐ U+2ACF, U+2AD0 CLOSED SUBSET/SUPERSET
⫑ ⫒ U+2AD1, U+2AD2 CLOSED SUBSET/SUPERSET OR EQUAL TO
⫕ ⫖ U+2AD5, U+2AD6 SUBSET/SUPERSET ABOVE SUBSET/SUPERSET
⫥ ⊫ U+2AE5, U+22AB DOUBLE VERTICAL BAR DOUBLE LEFT/RIGHT TURNSTILE
⫷ ⫸ U+2AF7, U+2AF8 TRIPLE NESTED LESS-THAN/GREATER-THAN
⫹ ⫺ U+2AF9, U+2AFA DOUBLE-LINE SLANTED LESS-THAN/GREATER-THAN OR
EQUAL TO
⭆ ⭅ U+2B46, U+2B45 RIGHT/LEFTWARDS QUADRUPLE ARROW
⭇ ⭉ U+2B47, U+2B49 REVERSE TILDE OPERATOR ABOVE RIGHTWARDS ARROW,
TILDE OPERATOR ABOVE LEFTWARDS ARROW
⭈ ⭊ U+2B48, U+2B4A RIGHTWARDS ARROW ABOVE REVERSE ALMOST EQUAL
TO, LEFTWARDS ARROW ABOVE ALMOST EQUAL TO
⭌ ⥳ U+2B4C, U+2973 RIGHTWARDS ARROW ABOVE REVERSE TILDE OPERATOR,
LEFTWARDS ARROW ABOVE TILDE OPERATOR
⭢ ⭠ U+2B62, U+2B60 RIGHT/LEFTWARDS TRIANGLE-HEADED ARROW
⭬ ⭪ U+2B6C, U+2B6A RIGHT/LEFTWARDS TRIANGLE-HEADED DASHED ARROW
⭲ ⭰ U+2B72, U+2B70 RIGHT/LEFTWARDS TRIANGLE-HEADED ARROW TO BAR
⭼ ⭺ U+2B7C, U+2B7A RIGHT/LEFTWARDS TRIANGLE-HEADED ARROW WITH
DOUBLE VERTICAL STROKE
⮆ ⮄ U+2B86, U+2B84 RIGHT/LEFTWARDS TRIANGLE-HEADED PAIRED ARROWS
⮊ ⮈ U+2B8A, U+2B88 RIGHT/LEFTWARDS BLACK CIRCLED WHITE ARROW
⮕ ⬅ U+2B95, U+2B05 RIGHT/LEFTWARDS BLACK ARROW
⮚ ⮘ U+2B9A, U+2B98 THREE-D TOP-LIGHTED RIGHT/LEFTWARDS EQUILATERAL
ARROWHEAD
⮞ ⮜ U+2B9E, U+2B9C BLACK RIGHT/LEFTWARDS EQUILATERAL ARROWHEAD
⮡ ⮠ U+2BA1, U+2BA0 DOWNWARDS TRIANGLE-HEADED ARROW WITH LONG TIP
RIGHT/LEFTWARDS
⮣ ⮢ U+2BA3, U+2BA2 UPWARDS TRIANGLE-HEADED ARROW WITH LONG TIP
RIGHT/LEFTWARDS
⮩ ⮨ U+2BA9, U+2BA8 BLACK CURVED DOWNWARDS AND RIGHT/LEFTWARDS ARROW
⮫ ⮪ U+2BAB, U+2BAA BLACK CURVED UPWARDS AND RIGHT/LEFTWARDS ARROW
⮱ ⮰ U+2BB1, U+2BB0 RIBBON ARROW DOWN RIGHT/LEFT
⮳ ⮲ U+2BB3, U+2BB2 RIBBON ARROW UP RIGHT/LEFT
⯮ ⯬ U+2BEE, U+2BEC RIGHT/LEFTWARDS TWO-HEADED ARROW WITH TRIANGLE
ARROWHEADS
⸂ ⸃ U+2E02, U+2E03 LEFT/RIGHT SUBSTITUTION BRACKET
⸃ ⸂ U+2E03, U+2E02 RIGHT/LEFT SUBSTITUTION BRACKET
⸄ ⸅ U+2E04, U+2E05 LEFT/RIGHT DOTTED SUBSTITUTION BRACKET
⸅ ⸄ U+2E05, U+2E04 RIGHT/LEFT DOTTED SUBSTITUTION BRACKET
⸉ ⸊ U+2E09, U+2E0A LEFT/RIGHT TRANSPOSITION BRACKET
⸊ ⸉ U+2E0A, U+2E09 RIGHT/LEFT TRANSPOSITION BRACKET
⸌ ⸍ U+2E0C, U+2E0D LEFT/RIGHT RAISED OMISSION BRACKET
⸍ ⸌ U+2E0D, U+2E0C RIGHT/LEFT RAISED OMISSION BRACKET
⸑ ⸐ U+2E11, U+2E10 REVERSED FORKED PARAGRAPHOS, FORKED PARAGRAPHOS
⸜ ⸝ U+2E1C, U+2E1D LEFT/RIGHT LOW PARAPHRASE BRACKET
⸝ ⸜ U+2E1D, U+2E1C RIGHT/LEFT LOW PARAPHRASE BRACKET
⸠ ⸡ U+2E20, U+2E21 LEFT/RIGHT VERTICAL BAR WITH QUILL
⸡ ⸠ U+2E21, U+2E20 RIGHT/LEFT VERTICAL BAR WITH QUILL
⸢ ⸣ U+2E22, U+2E23 TOP LEFT/RIGHT HALF BRACKET
⸤ ⸥ U+2E24, U+2E25 BOTTOM LEFT/RIGHT HALF BRACKET
⸦ ⸧ U+2E26, U+2E27 LEFT/RIGHT SIDEWAYS U BRACKET
⸨ ⸩ U+2E28, U+2E29 LEFT/RIGHT DOUBLE PARENTHESIS
⸶ ⸷ U+2E36, U+2E37 DAGGER WITH LEFT/RIGHT GUARD
⹂ „ U+2E42, U+201E DOUBLE LOW-REVERSED-9 QUOTATION MARK, DOUBLE
LOW-9 QUOTATION MARK
⹕ ⹖ U+2E55, U+2E56 LEFT/RIGHT SQUARE BRACKET WITH STROKE
⹗ ⹘ U+2E57, U+2E58 LEFT/RIGHT SQUARE BRACKET WITH DOUBLE STROKE
⹙ ⹚ U+2E59, U+2E5A TOP HALF LEFT/RIGHT PARENTHESIS
⹛ ⹜ U+2E5B, U+2E5C BOTTOM HALF LEFT/RIGHT PARENTHESIS
〈 〉 U+3008, U+3009 LEFT/RIGHT ANGLE BRACKET
《 》 U+300A, U+300B LEFT/RIGHT DOUBLE ANGLE BRACKET
「 」 U+300C, U+300D LEFT/RIGHT CORNER BRACKET
『 』 U+300E, U+300F LEFT/RIGHT WHITE CORNER BRACKET
【 】 U+3010, U+3011 LEFT/RIGHT BLACK LENTICULAR BRACKET
〔 〕 U+3014, U+3015 LEFT/RIGHT TORTOISE SHELL BRACKET
〖 〗 U+3016, U+3017 LEFT/RIGHT WHITE LENTICULAR BRACKET
〘 〙 U+3018, U+3019 LEFT/RIGHT WHITE TORTOISE SHELL BRACKET
〚 〛 U+301A, U+301B LEFT/RIGHT WHITE SQUARE BRACKET
〝 〞 U+301D, U+301E REVERSED DOUBLE PRIME QUOTATION MARK, DOUBLE
PRIME QUOTATION MARK
꧁ ꧂ U+A9C1, U+A9C2 JAVANESE LEFT/RIGHT RERENGGAN
﴾ ﴿ U+FD3E, U+FD3F ORNATE LEFT/RIGHT PARENTHESIS
﹙ ﹚ U+FE59, U+FE5A SMALL LEFT/RIGHT PARENTHESIS
﹛ ﹜ U+FE5B, U+FE5C SMALL LEFT/RIGHT CURLY BRACKET
﹝ ﹞ U+FE5D, U+FE5E SMALL LEFT/RIGHT TORTOISE SHELL BRACKET
﹤ ﹥ U+FE64, U+FE65 SMALL LESS-THAN/GREATER-THAN SIGN
（ ） U+FF08, U+FF09 FULLWIDTH LEFT/RIGHT PARENTHESIS
＜ ＞ U+FF1C, U+FF1E FULLWIDTH LESS-THAN/GREATER-THAN SIGN
［ ］ U+FF3B, U+FF3D FULLWIDTH LEFT/RIGHT SQUARE BRACKET
｛ ｝ U+FF5B, U+FF5D FULLWIDTH LEFT/RIGHT CURLY BRACKET
｟ ｠ U+FF5F, U+FF60 FULLWIDTH LEFT/RIGHT WHITE PARENTHESIS
｢ ｣ U+FF62, U+FF63 HALFWIDTH LEFT/RIGHT CORNER BRACKET
￫ ￩ U+FFEB, U+FFE9 HALFWIDTH RIGHT/LEFTWARDS ARROW
𝄃 𝄂 U+1D103, U+1D102 MUSICAL SYMBOL REVERSE FINAL BARLINE, MUSICAL
SYMBOL FINAL BARLINE
𝄆 𝄇 U+1D106, U+1D107 MUSICAL SYMBOL LEFT/RIGHT REPEAT SIGN
👉 👈 U+1F449, U+1F448 WHITE RIGHT/LEFT POINTING BACKHAND INDEX
🔈 🕨 U+1F508, U+1F568 SPEAKER, RIGHT SPEAKER
🔉 🕩 U+1F509, U+1F569 SPEAKER WITH ONE SOUND WAVE, RIGHT SPEAKER WITH
ONE SOUND WAVE
🔊 🕪 U+1F50A, U+1F56A SPEAKER WITH THREE SOUND WAVES, RIGHT SPEAKER
WITH THREE SOUND WAVES
🕻 🕽 U+1F57B, U+1F57D LEFT/RIGHT HAND TELEPHONE RECEIVER
🖙 🖘 U+1F599, U+1F598 SIDEWAYS WHITE RIGHT/LEFT POINTING INDEX
🖛 🖚 U+1F59B, U+1F59A SIDEWAYS BLACK RIGHT/LEFT POINTING INDEX
🖝 🖜 U+1F59D, U+1F59C BLACK RIGHT/LEFT POINTING BACKHAND INDEX
🗦 🗧 U+1F5E6, U+1F5E7 THREE RAYS LEFT/RIGHT
🠂 🠀 U+1F802, U+1F800 RIGHT/LEFTWARDS ARROW WITH SMALL TRIANGLE
ARROWHEAD
🠆 🠄 U+1F806, U+1F804 RIGHT/LEFTWARDS ARROW WITH MEDIUM TRIANGLE
ARROWHEAD
🠊 🠈 U+1F80A, U+1F808 RIGHT/LEFTWARDS ARROW WITH LARGE TRIANGLE
ARROWHEAD
🠒 🠐 U+1F812, U+1F810 RIGHT/LEFTWARDS ARROW WITH SMALL EQUILATERAL
ARROWHEAD
🠖 🠔 U+1F816, U+1F814 RIGHT/LEFTWARDS ARROW WITH EQUILATERAL ARROWHEAD
🠚 🠘 U+1F81A, U+1F818 HEAVY RIGHT/LEFTWARDS ARROW WITH EQUILATERAL
ARROWHEAD
🠞 🠜 U+1F81E, U+1F81C HEAVY RIGHT/LEFTWARDS ARROW WITH LARGE
EQUILATERAL ARROWHEAD
🠢 🠠 U+1F822, U+1F820 RIGHT/LEFTWARDS TRIANGLE-HEADED ARROW WITH
NARROW SHAFT
🠦 🠤 U+1F826, U+1F824 RIGHT/LEFTWARDS TRIANGLE-HEADED ARROW WITH
MEDIUM SHAFT
🠪 🠨 U+1F82A, U+1F828 RIGHT/LEFTWARDS TRIANGLE-HEADED ARROW WITH BOLD
SHAFT
🠮 🠬 U+1F82E, U+1F82C RIGHT/LEFTWARDS TRIANGLE-HEADED ARROW WITH
HEAVY SHAFT
🠲 🠰 U+1F832, U+1F830 RIGHT/LEFTWARDS TRIANGLE-HEADED ARROW WITH VERY
HEAVY SHAFT
🠶 🠴 U+1F836, U+1F834 RIGHT/LEFTWARDS FINGER-POST ARROW
🠺 🠸 U+1F83A, U+1F838 RIGHT/LEFTWARDS SQUARED ARROW
🠾 🠼 U+1F83E, U+1F83C RIGHT/LEFTWARDS COMPRESSED ARROW
🡂 🡀 U+1F842, U+1F840 RIGHT/LEFTWARDS HEAVY COMPRESSED ARROW
🡆 🡄 U+1F846, U+1F844 RIGHT/LEFTWARDS HEAVY ARROW
🡒 🡐 U+1F852, U+1F850 RIGHT/LEFTWARDS SANS-SERIF ARROW
🡢 🡠 U+1F862, U+1F860 WIDE-HEADED RIGHT/LEFTWARDS LIGHT BARB ARROW
🡪 🡨 U+1F86A, U+1F868 WIDE-HEADED RIGHT/LEFTWARDS BARB ARROW
🡲 🡰 U+1F872, U+1F870 WIDE-HEADED RIGHT/LEFTWARDS MEDIUM BARB ARROW
🡺 🡸 U+1F87A, U+1F878 WIDE-HEADED RIGHT/LEFTWARDS HEAVY BARB ARROW
🢂 🢀 U+1F882, U+1F880 WIDE-HEADED RIGHT/LEFTWARDS VERY HEAVY BARB
ARROW
🢒 🢐 U+1F892, U+1F890 RIGHT/LEFTWARDS TRIANGLE ARROWHEAD
🢖 🢔 U+1F896, U+1F894 RIGHT/LEFTWARDS WHITE ARROW WITHIN TRIANGLE
ARROWHEAD
🢚 🢘 U+1F89A, U+1F898 RIGHT/LEFTWARDS ARROW WITH NOTCHED TAIL
🢡 🢠 U+1F8A1, U+1F8A0 RIGHTWARDS BOTTOM SHADED WHITE ARROW,
LEFTWARDS BOTTOM-SHADED WHITE ARROW
🢣 🢢 U+1F8A3, U+1F8A2 RIGHT/LEFTWARDS TOP SHADED WHITE ARROW
🢥 🢦 U+1F8A5, U+1F8A6 RIGHT/LEFTWARDS RIGHT-SHADED WHITE ARROW
🢧 🢤 U+1F8A7, U+1F8A4 RIGHT/LEFTWARDS LEFT-SHADED WHITE ARROW
🢩 🢨 U+1F8A9, U+1F8A8 RIGHT/LEFTWARDS BACK-TILTED SHADOWED WHITE ARROW
🢫 🢪 U+1F8AB, U+1F8AA RIGHT/LEFTWARDS FRONT-TILTED SHADOWED WHITE
ARROW