5.12.1

NAME

perlrecharclass - Perl Regular Expression Character Classes

perlrecharclass - Perl 正規表現文字クラス

説明

The top level documentation about Perl regular expressions is found in perlre.

Perl 正規表現に関する最上位文書は perlre です。

This manual page discusses the syntax and use of character classes in Perl Regular Expressions.

このマニュアルページは Perl 正規表現の文字クラスの文法と使用法について 議論します。

A character class is a way of denoting a set of characters, in such a way that one character of the set is matched. It's important to remember that matching a character class consumes exactly one character in the source string. (The source string is the string the regular expression is matched against.)

文字クラスは、集合の中の一文字がマッチングするというような方法で、 文字の集合を指定するための方法です。 文字集合はソース文字列の中から正確に一文字だけを消費するということを 覚えておくことは重要です。 (ソース文字列とは正規表現がマッチングしようとしている文字列です。)

There are three types of character classes in Perl regular expressions: the dot, backslashed sequences, and the form enclosed in square brackets. Keep in mind, though, that often the term "character class" is used to mean just the bracketed form. This is true in other Perl documentation.

Perl 正規表現には 3 種類の文字クラスがあります: ドット、 逆スラッシュシーケンス、大かっこで囲まれた形式です。 しかし、「文字クラス」という用語はしばしば大かっこ形式だけを意味するために 使われることに注意してください。 これはその他の Perl 文書では真です。

ドット

The dot (or period), . is probably the most used, and certainly the most well-known character class. By default, a dot matches any character, except for the newline. The default can be changed to add matching the newline with the single line modifier: either for the entire regular expression using the /s modifier, or locally using (?s).

ドット (またはピリオド) . はおそらくもっともよく使われ、そして確実に もっともよく知られている文字クラスです。 デフォルトでは、ドットは改行を除く任意の文字にマッチングします。 デフォルトは 単一行 修飾子を使うことで改行にもマッチングするように 変更されます: 正規表現全体に対して /s 修飾子を使うか、ローカルには (?s) を使います。

Here are some examples:

以下は例です:

 "a"  =~  /./       # Match
 "."  =~  /./       # Match
 ""   =~  /./       # No match (dot has to match a character)
 "\n" =~  /./       # No match (dot does not match a newline)
 "\n" =~  /./s      # Match (global 'single line' modifier)
 "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
 "ab" =~  /^.$/     # No match (dot matches one character)
 "a"  =~  /./       # マッチングする
 "."  =~  /./       # マッチングする
 ""   =~  /./       # マッチングしない (ドットは文字にマッチングする必要がある)
 "\n" =~  /./       # マッチングしない (ドットは改行にはマッチングしない)
 "\n" =~  /./s      # マッチングする (グローバル「単一行」修飾子)
 "\n" =~  /(?s:.)/  # マッチングする (ローカル「単一行」修飾子)
 "ab" =~  /^.$/     # マッチングしない (ドットは一文字にマッチングする)

逆スラッシュシーケンス

Perl regular expressions contain many backslashed sequences that constitute a character class. That is, they will match a single character, if that character belongs to a specific set of characters (defined by the sequence). A backslashed sequence is a sequence of characters starting with a backslash. Not all backslashed sequences are character classes; for a full list, see perlrebackslash.

Perl 正規表現には、文字クラスを構成する多くの逆スラッシュシーケンスを 持ちます。 これは(シーケンスで定義される)ある特定の文字集合に属する一つの文字に マッチングします。 逆スラッシュシーケンスは、逆スラッシュで始まる並びです。 全ての逆スラッシュシーケンスが文字クラスというわけではありません; 完全な リストは、perlrebackslash を参照してください。

Here's a list of the backslashed sequences that are character classes. They are discussed in more detail below.

以下は文字クラスの逆スラッシュシーケンスの一覧です。 以下でさらに詳細に議論します。

 \d             Match a digit character.
 \D             Match a non-digit character.
 \w             Match a "word" character.
 \W             Match a non-"word" character.
 \s             Match a whitespace character.
 \S             Match a non-whitespace character.
 \h             Match a horizontal whitespace character.
 \H             Match a character that isn't horizontal whitespace.
 \N             Match a character that isn't newline.  Experimental.
 \v             Match a vertical whitespace character.
 \V             Match a character that isn't vertical whitespace.
 \pP, \p{Prop}  Match a character matching a Unicode property.
 \PP, \P{Prop}  Match a character that doesn't match a Unicode property.
 \d             数字にマッチング。
 \D             非数字にマッチング。
 \w             「単語」文字にマッチング。
 \W             非「単語」文字にマッチング。
 \s             空白文字にマッチング。
 \S             非空白文字にマッチング。
 \h             水平空白文字にマッチング。
 \H             水平空白でない文字にマッチング。
 \N             改行以外の文字にマッチング。実験的。
 \v             垂直空白文字にマッチング。
 \V             垂直空白でない文字にマッチング。
 \pP, \p{Prop}  Unicode 特性にマッチする文字にマッチング。
 \PP, \P{Prop}  Unicode 特性にマッチしない文字にマッチング。

数字

\d matches a single character that is considered to be a digit. What is considered a digit depends on the internal encoding of the source string and the locale that is in effect. If the source string is in UTF-8 format, \d not only matches the digits '0' - '9', but also Arabic, Devanagari and digits from other languages. Otherwise, if there is a locale in effect, it will match whatever characters the locale considers digits. Without a locale, \d matches the digits '0' to '9'. See "Locale, EBCDIC, Unicode and UTF-8".

\d数字 と考えられる単一の文字にマッチングします。 何が数字と考えられるかはソース文字列の内部エンコーディングとロケールが 有効かどうかに依存します。 ソース文字列が UTF-8 形式なら、\d は数字 '0' - '9' だけでなく、Arabic, Devanagari およびその他の言語の数字もマッチングします。 さもなければ、ロケールが有効なら、ロケールが数字と考える文字に マッチングします。 ロケールがなければ、\d は '0' から '9' の数字にマッチングします。 "Locale, EBCDIC, Unicode and UTF-8" を参照してください。

Any character that isn't matched by \d will be matched by \D.

\d にマッチングしない任意の文字は \D にマッチングします。

単語文字

A \w matches a single alphanumeric character (an alphabetic character, or a decimal digit) or an underscore (_), not a whole word. Use \w+ to match a string of Perl-identifier characters (which isn't the same as matching an English word). What is considered a word character depends on the internal encoding of the string and the locale or EBCDIC code page that is in effect. If it's in UTF-8 format, \w matches those characters that are considered word characters in the Unicode database. That is, it not only matches ASCII letters, but also Thai letters, Greek letters, etc. If the source string isn't in UTF-8 format, \w matches those characters that are considered word characters by the current locale or EBCDIC code page. Without a locale or EBCDIC code page, \w matches the ASCII letters, digits and the underscore. See "Locale, EBCDIC, Unicode and UTF-8".

\w は単語全体ではなく、単一の英数字(つまり英字または数字)または 下線(_)にマッチングします。 Perl 識別子文字の文字列にマッチングするために \w+ を使います (これは 英単語にマッチングするものと同じではありません)。 何が単語文字と考えられるかは文字列の内部エンコーディングと有効なロケールや EBCDIC コードページに依存します。 UTF-8 形式の場合、\w は Unicode データベースで単語文字と考えられるものに マッチングします。 これは、ASCII の文字だけではなく、タイの文字、ギリシャの文字、などにも マッチングするということです。 ソース文字列が UTF-8 形式でない場合、\w は現在のロケールや EBCDIC コードページで単語文字と考えられるものにマッチングします。 ロケールや EBCDIC コードページなしの場合、\w は ASCII 文字、数字、下線に マッチングします。 "Locale, EBCDIC, Unicode and UTF-8" を参照してください。

Any character that isn't matched by \w will be matched by \W.

\w にマッチングしない任意の文字は \W にマッチングします。

空白

\s matches any single character that is considered whitespace. In the ASCII range, \s matches the horizontal tab (\t), the new line (\n), the form feed (\f), the carriage return (\r), and the space. (The vertical tab, \cK is not matched by \s.) The exact set of characters matched by \s depends on whether the source string is in UTF-8 format and the locale or EBCDIC code page that is in effect. If it's in UTF-8 format, \s matches what is considered whitespace in the Unicode database; the complete list is in the table below. Otherwise, if there is a locale or EBCDIC code page in effect, \s matches whatever is considered whitespace by the current locale or EBCDIC code page. Without a locale or EBCDIC code page, \s matches the five characters mentioned in the beginning of this paragraph. Perhaps the most notable possible surprise is that \s matches a non-breaking space only if the non-breaking space is in a UTF-8 encoded string or the locale or EBCDIC code page that is in effect has that character. See "Locale, EBCDIC, Unicode and UTF-8".

\s は空白と考えられる単一の文字にマッチングします。 ASCII の範囲では、\s は水平タブ(\t)、改行(\n)、ページ送り(\f)、 復帰(\r)、スペースにマッチングします。 (垂直タブ \cK\s にマッチングしません。) \s がマッチングする文字の正確な集合はソース文字列が UTF-8 形式かどうかや 有効なロケールおよび EBCDIC コードページに依存します。 UTF-8 形式なら、\s は Unicode データベースで空白と考えられるものに マッチングします; 完全な一覧は後述の表にあります。 さもなければ、ロケールや EBICDIC コードページが有効なら、\s は現在の ロケールや EBCDIC コードページで空白と考えられるものにマッチングします。 ロケールや EBCDIC コードページなしでは、\s はこの段落の始めに言及した 五つの文字にマッチングします。 おそらくもっとも顕著な驚きは、non-breaking space は UTF-8 エンコードされた 文字列にあるか、ロケールまたは EBCDIC コードページが有効な場合にのみ、 \s にマッチングするということです。 "Locale, EBCDIC, Unicode and UTF-8" を参照してください。

Any character that isn't matched by \s will be matched by \S.

\s にマッチングしない任意の文字は \S にマッチングします。

\h will match any character that is considered horizontal whitespace; this includes the space and the tab characters and 17 other characters that are listed in the table below. \H will match any character that is not considered horizontal whitespace.

\h は水平空白と考えられる任意の文字にマッチングします; これはスペースと タブ文字および以下の表に上げられている 17 のその他の文字です。 \H は水平空白と考えられない文字にマッチングします。

\N is new in 5.12, and is experimental. It, like the dot, will match any character that is not a newline. The difference is that \N will not be influenced by the single line /s regular expression modifier. Note that there is a second meaning of \N when of the form \N{...}. This form is for named characters. See charnames for those. If \N is followed by an opening brace and something that is not a quantifier, perl will assume that a character name is coming, and not this meaning of \N. For example, \N{3} means to match 3 non-newlines; \N{5,} means to match 5 or more non-newlines, but \N{4F} and \N{F4} are not legal quantifiers, and will cause perl to look for characters named 4F or F4, respectively (and won't find them, thus raising an error, unless they have been defined using custom names).

\N は 5.12 の新機能で、実験的なものです。 これは、ドットのように、改行以外の任意の文字にマッチングします。 違いは、\N は単一行 /s 正規表現修飾子の影響を受けないことです。 \N{...} の形式の時には \N の二番目の意味を持つことに注意してください。 この形式は名前付き文字です。 それについては charnames を参照してください。 \N に引き続いて開き中かっこと量指定子でない何かがある場合、 perl はこの意味での \N ではなく文字名が来ると仮定します。 例えば、\N{3} は三つの非改行にマッチングします; \N{5,} は五つ以上の非改行にマッチングします; しかし \N{4F}\N{F4} は妥当な量指定子ではないので、perl は それぞれ 4FF4 という名前の文字を探します(そして、独自の名前を 定義していない限り見つからないのでエラーが発生します)。

\v will match any character that is considered vertical whitespace; this includes the carriage return and line feed characters (newline) plus 5 other characters listed in the table below. \V will match any character that is not considered vertical whitespace.

\v は垂直空白と考えられる任意の文字にマッチングします; これは復帰と 行送り(改行)文字に加えて以下の表に上げられている五つのその他の文字です。 \V は垂直空白と考えられない任意の文字にマッチングします。

\R matches anything that can be considered a newline under Unicode rules. It's not a character class, as it can match a multi-character sequence. Therefore, it cannot be used inside a bracketed character class; use \v instead (vertical whitespace). Details are discussed in perlrebackslash.

\R は Unicode の規則で改行と考えられるものにマッチングします。 複数文字の並びにマッチングすることもあるので、これは 文字クラスではありません。 従って、大かっこ文字クラスの中では使えません; 代わりに \v (垂直空白) を 使ってください。 詳細は perlrebackslash で議論しています。

Note that unlike \s, \d and \w, \h and \v always match the same characters, regardless whether the source string is in UTF-8 format or not. The set of characters they match is also not influenced by locale nor EBCDIC code page.

\s, \d, \w と違って、\h および \v はソース文字列が UTF-8 形式かどうかに関わらず同じ文字にマッチングします。 マッチングする文字の集合はロケールや EBCDIC コードページの影響も受けません。

One might think that \s is equivalent to [\h\v]. This is not true. The vertical tab ("\x0b") is not matched by \s, it is however considered vertical whitespace. Furthermore, if the source string is not in UTF-8 format, and any locale or EBCDIC code page that is in effect doesn't include them, the next line ("\x85") and the no-break space ("\xA0") characters are not matched by \s, but are by \v and \h respectively. If the source string is in UTF-8 format, both the next line and the no-break space are matched by \s.

\s[\h\v] と等価と考える人がいるかもしれません。 これは正しくありません。 垂直タブ ("\x0b") は \s にマッチングしませんが、垂直空白と 考えられます。 さらに、ソース文字列が UTF-8 形式でないか、これらを含まないロケールや EBCDIC コードページが有効でなければ、next line ("\x85") と no-break space ("\xA0") 文字は \s にマッチングしませんが、 それぞれ \v および \h にはマッチングします。 ソース文字列が UTF-8 形式なら、next line と no-break space は \s に マッチングします。

The following table is a complete listing of characters matched by \s, \h and \v as of Unicode 5.2.

以下の表は Unicode 5.2 現在で \s, \h, \v にマッチングする文字の 完全な一覧です。

The first column gives the code point of the character (in hex format), the second column gives the (Unicode) name. The third column indicates by which class(es) the character is matched (assuming no locale or EBCDIC code page is in effect that changes the \s matching).

最初の列は文字の符号位置(16 進形式)、2 番目の列は (Unicode の)名前です。 3 番目の列はどのクラスにマッチングするかを示しています (\s のマッチングを変更するようなロケールや EBCDIC コードページが 有効でないことを仮定しています)。

 0x00009        CHARACTER TABULATION   h s
 0x0000a              LINE FEED (LF)    vs
 0x0000b             LINE TABULATION    v
 0x0000c              FORM FEED (FF)    vs
 0x0000d        CARRIAGE RETURN (CR)    vs
 0x00020                       SPACE   h s
 0x00085             NEXT LINE (NEL)    vs  [1]
 0x000a0              NO-BREAK SPACE   h s  [1]
 0x01680            OGHAM SPACE MARK   h s
 0x0180e   MONGOLIAN VOWEL SEPARATOR   h s
 0x02000                     EN QUAD   h s
 0x02001                     EM QUAD   h s
 0x02002                    EN SPACE   h s
 0x02003                    EM SPACE   h s
 0x02004          THREE-PER-EM SPACE   h s
 0x02005           FOUR-PER-EM SPACE   h s
 0x02006            SIX-PER-EM SPACE   h s
 0x02007                FIGURE SPACE   h s
 0x02008           PUNCTUATION SPACE   h s
 0x02009                  THIN SPACE   h s
 0x0200a                  HAIR SPACE   h s
 0x02028              LINE SEPARATOR    vs
 0x02029         PARAGRAPH SEPARATOR    vs
 0x0202f       NARROW NO-BREAK SPACE   h s
 0x0205f   MEDIUM MATHEMATICAL SPACE   h s
 0x03000           IDEOGRAPHIC SPACE   h s
[1]

NEXT LINE and NO-BREAK SPACE only match \s if the source string is in UTF-8 format, or the locale or EBCDIC code page that is in effect includes them.

NEXT LINE と NO-BREAK SPACE はソース文字列が UTF-8 形式か、これらを含む ロケールや EBCDIC コードページが有効の場合にのみ \s にマッチングします。

It is worth noting that \d, \w, etc, match single characters, not complete numbers or words. To match a number (that consists of integers), use \d+; to match a word, use \w+.

\d, \w などは単語や数値全体ではなく単一の文字にマッチングすると いうことは注意する価値があります。 (整数で構成される)数値にマッチングするには、\d+ を使ってください; 単語に マッチングするには、\w+ を使ってください。

Unicode 特性

\pP and \p{Prop} are character classes to match characters that fit given Unicode properties. One letter property names can be used in the \pP form, with the property name following the \p, otherwise, braces are required. When using braces, there is a single form, which is just the property name enclosed in the braces, and a compound form which looks like \p{name=value}, which means to match if the property "name" for the character has the particular "value". For instance, a match for a number can be written as /\pN/ or as /\p{Number}/, or as /\p{Number=True}/. Lowercase letters are matched by the property Lowercase_Letter which has as short form Ll. They need the braces, so are written as /\p{Ll}/ or /\p{Lowercase_Letter}/, or /\p{General_Category=Lowercase_Letter}/ (the underscores are optional). /\pLl/ is valid, but means something different. It matches a two character string: a letter (Unicode property \pL), followed by a lowercase l.

\pP\p{Prop} は指定された Unicode 特性に一致する文字に マッチングする文字クラスです。 一文字特性は \pP 形式で、\p に引き続いて特性名です; さもなければ 中かっこが必要です。 中かっこを使うとき、単に特性名を中かっこで囲んだ単一形式と、 \p{name=value} のような形で、文字の特性 "name" が特定の "value" を 持つものにマッチングすることになる複合形式があります。 例えば、数字にマッチングするものは /\pN/ または /\p{Number}/ または /\p{Number=True}/ と書けます。 小文字は LowercaseLetter 特性にマッチングします; これには Ll と言う短縮形式があります。 中かっこが必要なので、/\p{Ll}/ または /\p{Lowercase_Letter}/ または /\p{General_Category=Lowercase_Letter}/ と書きます(下線はオプションです)。 /\pLl/ も妥当ですが、違う意味になります。 これは 2 文字にマッチングします: 英字 (Unicode 特性 \pL)に引き続いて 小文字の l です。

For more details, see "Unicode Character Properties" in perlunicode; for a complete list of possible properties, see "Properties accessible through \p{} and \P{}" in perluniprops. It is also possible to define your own properties. This is discussed in "User-Defined Character Properties" in perlunicode.

さらなる詳細については、 "Unicode Character Properties" in perlunicode を 参照してください; 特性の完全な一覧については "Properties accessible through \p{} and \P{}" in perluniprops を参照して ください。 独自の特性を定義することも可能です。 これは "User-Defined Character Properties" in perlunicode で 議論されています。

 "a"  =~  /\w/      # Match, "a" is a 'word' character.
 "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
 "a"  =~  /\d/      # No match, "a" isn't a digit.
 "7"  =~  /\d/      # Match, "7" is a digit.
 " "  =~  /\s/      # Match, a space is whitespace.
 "a"  =~  /\D/      # Match, "a" is a non-digit.
 "7"  =~  /\D/      # No match, "7" is not a non-digit.
 " "  =~  /\S/      # No match, a space is not non-whitespace.
 "a"  =~  /\w/      # マッチング; "a" は「単語」文字。
 "7"  =~  /\w/      # マッチング; "7" も「単語」文字。
 "a"  =~  /\d/      # マッチングしない; "a" は数字ではない。
 "7"  =~  /\d/      # マッチング; "7" は数字。
 " "  =~  /\s/      # マッチング; スペースは空白。
 "a"  =~  /\D/      # マッチング; "a" は非数字。
 "7"  =~  /\D/      # マッチングしない; "7" は非数字ではない。
 " "  =~  /\S/      # マッチングしない; スペースは非空白ではない。
 " "  =~  /\h/      # Match, space is horizontal whitespace.
 " "  =~  /\v/      # No match, space is not vertical whitespace.
 "\r" =~  /\v/      # Match, a return is vertical whitespace.
 " "  =~  /\h/      # マッチング; スペースは水平空白。
 " "  =~  /\v/      # マッチングしない; スペースは垂直空白ではない。
 "\r" =~  /\v/      # マッチング; 復帰は垂直空白。
 "a"  =~  /\pL/     # Match, "a" is a letter.
 "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
 "a"  =~  /\pL/     # マッチング; "a" は英字。
 "a"  =~  /\p{Lu}/  # マッチングしない; /\p{Lu}/ は大文字にマッチングする。
 "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
                           # 'THAI CHARACTER SO SO', and that's in
                           # Thai Unicode class.
 "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
 "\x{0e0b}" =~ /\p{Thai}/  # マッチング; \x{0e0b} は文字
                           # 'THAI CHARACTER SO SO' で、これは
                           # Thai Unicode クラスにある。
 "a"  =~  /\P{Lao}/ # マッチング; "a" はラオス文字ではない。

かっこ付き文字クラス

The third form of character class you can use in Perl regular expressions is the bracketed form. In its simplest form, it lists the characters that may be matched, surrounded by square brackets, like this: [aeiou]. This matches one of a, e, i, o or u. Like the other character classes, exactly one character will be matched. To match a longer string consisting of characters mentioned in the character class, follow the character class with a quantifier. For instance, [aeiou]+ matches a string of one or more lowercase ASCII vowels.

Perl 正規表現で使える文字クラスの第 3 の形式は大かっこ形式です。 もっとも単純な形式では、以下のように大かっこの中にマッチングする文字を リストします: [aeiou]. これは a, e, i, o, u のどれかにマッチングします。 他の文字クラスと同様、正確に一つの文字にマッチングします。 文字クラスで言及した文字で構成されるより長い文字列にマッチングするには、 文字クラスに量指定子を付けます。 例えば、[aeiou]+ は一つまたはそれ以上の小文字 ASCII 母音に マッチングします。

Repeating a character in a character class has no effect; it's considered to be in the set only once.

文字クラスの中で文字を繰り返しても効果はありません; 一度だけ現れたものと 考えられます。

Examples:

例:

 "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
 "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
 "ae" =~  /^[aeiou]$/      # No match, a character class only matches
                           # a single character.
 "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
 "e"  =~  /[aeiou]/        # マッチング; "e" はクラスにある。
 "p"  =~  /[aeiou]/        # マッチングしない; "p" はクラスにない。
 "ae" =~  /^[aeiou]$/      # マッチングしない; 一つの文字クラスは
                           # 一文字だけにマッチングする。
 "ae" =~  /^[aeiou]+$/     # マッチング; 量指定子により。

かっこ付き文字クラスの中の特殊文字

Most characters that are meta characters in regular expressions (that is, characters that carry a special meaning like ., *, or () lose their special meaning and can be used inside a character class without the need to escape them. For instance, [()] matches either an opening parenthesis, or a closing parenthesis, and the parens inside the character class don't group or capture.

正規表現内でメタ文字(つまり、., *, ( のように特別な意味を持つ 文字)となるほとんどの文字は文字クラス内ではエスケープしなくても特別な意味を 失うので、エスケープする必要はありません。 例えば、[()] は開きかっこまたは閉じかっこにマッチングし、文字クラスの中の かっこはグループや捕捉にはなりません。

Characters that may carry a special meaning inside a character class are: \, ^, -, [ and ], and are discussed below. They can be escaped with a backslash, although this is sometimes not needed, in which case the backslash may be omitted.

文字クラスの中でも特別な意味を持つ文字は: \, ^, -, [, ] で、以下で議論します。 これらは逆スラッシュでエスケープできますが、不要な場合もあり、そのような 場合では逆スラッシュは省略できます。

The sequence \b is special inside a bracketed character class. While outside the character class \b is an assertion indicating a point that does not have either two word characters or two non-word characters on either side, inside a bracketed character class, \b matches a backspace character.

シーケンス \b は大かっこ文字クラスの内側では特別です。 文字クラスの外側では \b 二つの単語文字か二つの非単語文字のどちらかではない 位置を示す表明ですが、大かっこ文字クラスの内側では \b は後退文字に マッチングします。

The sequences \a, \c, \e, \f, \n, \N{NAME}, \N{U+wide hex char}, \r, \t, and \x are also special and have the same meanings as they do outside a bracketed character class.

並び \a, \c, \e, \f, \n, \N{NAME}, \N{U+wide hex char}, \r, \t, \x も特別で、大かっこ文字クラスの外側と同じ意味を持ちます。

Also, a backslash followed by two or three octal digits is considered an octal number.

また、逆スラッシュに引き続いて 2 または 3 桁の 8 進数字があると 8 進数として 扱われます。

A [ is not special inside a character class, unless it's the start of a POSIX character class (see below). It normally does not need escaping.

[ は、POSIX 文字クラス(後述)の開始でない限りは文字クラスの中では 特別ではありません。 これは普通エスケープは不要です。

A ] is normally either the end of a POSIX character class (see below), or it signals the end of the bracketed character class. If you want to include a ] in the set of characters, you must generally escape it. However, if the ] is the first (or the second if the first character is a caret) character of a bracketed character class, it does not denote the end of the class (as you cannot have an empty class) and is considered part of the set of characters that can be matched without escaping.

A ] は普通は POSIX 文字クラス(後述)の終わりか、大かっこ文字クラスの終了を 示すかどちらかです。 文字集合に ] を含める必要がある場合、一般的には エスケープしなければなりません。 しかし、] が大かっこ文字クラスの 最初 (または最初の文字がキャレットなら 2 番目) の文字の場合、(空クラスを作ることはできないので)これはクラスの 終了を意味せず、エスケープなしでマッチングできる文字の集合の一部と 考えられます。

Examples:

例:

 "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
 "\cH" =~ /[\b]/      #  Match, \b inside in a character class
                      #  is equivalent to a backspace.
 "]"   =~ /[][]/      #  Match, as the character class contains.
                      #  both [ and ].
 "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
                      #  containing just ], and the character class is
                      #  followed by a ].
 "+"   =~ /[+?*]/     #  マッチング; 文字クラス内の "+" は特別ではない。
 "\cH" =~ /[\b]/      #  マッチング; 文字クラスの内側の \b は後退と
                      #  等価。
 "]"   =~ /[][]/      #  マッチング; 文字クラスに [ と ] の両方を
                      #  含んでいる。
 "[]"  =~ /[[]]/      #  マッチング; パターンは ] だけを含んでいる
                      #  文字クラスと、それに引き続く
                      #  ] からなる。

文字範囲

It is not uncommon to want to match a range of characters. Luckily, instead of listing all the characters in the range, one may use the hyphen (-). If inside a bracketed character class you have two characters separated by a hyphen, it's treated as if all the characters between the two are in the class. For instance, [0-9] matches any ASCII digit, and [a-m] matches any lowercase letter from the first half of the ASCII alphabet.

文字のある範囲にマッチングしたいというのは珍しくありません。 幸運なことに、その範囲の文字を全て一覧に書く代わりに、ハイフン (-) を 使えます。 大かっこ文字クラスの内側で二つの文字がハイフンで区切られていると、 二つの文字の間の全ての文字がクラスに書かれているかのように扱われます。 例えば、[0-9] は任意の ASCII 数字にマッチングし、[a-m] は ASCII アルファベットの前半分の小文字にマッチングします。

Note that the two characters on either side of the hyphen are not necessary both letters or both digits. Any character is possible, although not advisable. ['-?] contains a range of characters, but most people will not know which characters that will be. Furthermore, such ranges may lead to portability problems if the code has to run on a platform that uses a different character set, such as EBCDIC.

ハイフンのそれぞれの側の二つの文字は両方とも英字であったり両方とも 数字であったりする必要はないことに注意してください。 任意の文字が可能ですが、勧められません。 ['-?] は文字の範囲を含みますが、ほとんどの人はどの文字が含まれるか 分かりません。 さらに、このような範囲は、コードが EBCDIC のような異なった文字集合を使う プラットフォームで実行されると移植性の問題を引き起こします。

If a hyphen in a character class cannot syntactically be part of a range, for instance because it is the first or the last character of the character class, or if it immediately follows a range, the hyphen isn't special, and will be considered a character that may be matched literally. You have to escape the hyphen with a backslash if you want to have a hyphen in your set of characters to be matched, and its position in the class is such that it could be considered part of a range.

例えば文字クラスの最初または最後であったり、範囲の直後のために、文字クラスの 中のハイフンが文法的に範囲の一部となれない場合、ハイフンは特別ではなく、 リテラルにマッチングするべき文字として扱われます。 マッチングする文字の集合にハイフンを入れたいけれどもその位置が範囲の 一部として考えられる場合はハイフンを逆スラッシュでエスケープする 必要があります。

Examples:

例:

 [a-z]       #  Matches a character that is a lower case ASCII letter.
 [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
             #  the letter 'z'.
 [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
 [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
             #  hyphen ('-'), or the letter 'm'.
 ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
             #  (But not on an EBCDIC platform).
 [a-z]       #  小文字 ASCII 英字にマッチング。
 [a-fz]      #  'a' から 'f' の英字およびと 'z' の英字に
             #  マッチング。
 [-z]        #  ハイフン ('-') または英字 'z' にマッチング。
 [a-f-m]     #  'a' から 'f' の英字、ハイフン ('-')、英字 'm' に
             #  マッチング。
 ['-?]       #  文字 '()*+,-./0123456789:;<=>? のどれかにマッチング
             #  (しかし EBCDIC プラットフォームでは異なります)。

否定

It is also possible to instead list the characters you do not want to match. You can do so by using a caret (^) as the first character in the character class. For instance, [^a-z] matches a character that is not a lowercase ASCII letter.

代わりにマッチングしたくない文字の一覧を指定することも可能です。 文字クラスの先頭の文字としてキャレット (^) を使うことで実現します。 例えば、[^a-z] 小文字の ASCII 英字以外の文字にマッチングします。

This syntax make the caret a special character inside a bracketed character class, but only if it is the first character of the class. So if you want to have the caret as one of the characters you want to match, you either have to escape the caret, or not list it first.

この文法はキャレットを大かっこ文字クラスの内側で特別な文字にしますが、 クラスの最初の文字の場合のみです。 それでマッチングしたい文字の一つでキャレットを使いたい場合、キャレットを エスケープするか、最初以外の位置に書く必要があります。

Examples:

例:

 "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
 "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
 "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
 "^"  =~  /[x^]/       #  Match, caret is not special here.
 "e"  =~  /[^aeiou]/   #  マッチングしない; 'e' がある。
 "x"  =~  /[^aeiou]/   #  マッチング; 'x' は小文字の母音ではない。
 "^"  =~  /[^^]/       #  マッチングしない; キャレット以外全てにマッチング。
 "^"  =~  /[x^]/       #  マッチング; キャレットはここでは特別ではない。

逆スラッシュシーケンス

You can put any backslash sequence character class (with the exception of \N) inside a bracketed character class, and it will act just as if you put all the characters matched by the backslash sequence inside the character class. For instance, [a-f\d] will match any digit, or any of the lowercase letters between 'a' and 'f' inclusive.

大かっこ文字クラスの中に(\N を例外として)逆スラッシュシーケンス 文字クラスを置くことができ、逆スラッシュシーケンスにマッチングする全ての 文字を文字クラスの中に置いたかのように動作します。 例えば、[a-f\d] は任意の数字、あるいは 'a' から 'f' までの小文字に マッチングします。

\N within a bracketed character class must be of the forms \N{name} or \N{U+wide hex char} for the same reason that a dot . inside a bracketed character class loses its special meaning: it matches nearly anything, which generally isn't what you want to happen.

大かっこ文字クラスの中のドット . が特別な意味を持たないのと同じ理由で、 大かっこ文字クラスの中の \N\N{name} または \N{U+wide hex char} の形式でなければなりません: これはほとんど何でも マッチングするので、一般的には起こって欲しいことではありません。

Examples:

例:

 /[\p{Thai}\d]/     # Matches a character that is either a Thai
                    # character, or a digit.
 /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
                    # character, nor a parenthesis.
 /[\p{Thai}\d]/     # タイ文字または数字の文字に
                    # マッチングする。
 /[^\p{Arabic}()]/  # アラビア文字でもかっこでもない文字に
                    # マッチングする。

Backslash sequence character classes cannot form one of the endpoints of a range.

逆スラッシュシーケンス文字クラスは範囲の端点の一つにはできません。

Posix 文字クラス

Posix character classes have the form [:class:], where class is name, and the [: and :] delimiters. Posix character classes only appear inside bracketed character classes, and are a convenient and descriptive way of listing a group of characters, though they currently suffer from portability issues (see below and "Locale, EBCDIC, Unicode and UTF-8"). Be careful about the syntax,

Posix 文字クラスは [:class:] の形式で、class は名前、[::] は デリミタです。 Posix 文字クラスは大かっこ文字クラスの 内側 にのみ現れ、文字のグループを 一覧するのに便利で記述的な方法ですが、現在の所移植性の問題に影響を与えます (下記と "Locale, EBCDIC, Unicode and UTF-8" を参照してください)。 文法について注意してください、

 # Correct:
 $string =~ /[[:alpha:]]/

 # Incorrect (will warn):
 $string =~ /[:alpha:]/

The latter pattern would be a character class consisting of a colon, and the letters a, l, p and h. These character classes can be part of a larger bracketed character class. For example,

後者のパターンは、コロンおよび a, l, p, h の文字からなる 文字クラスです。 これら文字クラスはより大きな大かっこ文字クラスの一部にできます。 例えば、

 [01[:alpha:]%]

is valid and matches '0', '1', any alphabetic character, and the percent sign.

これは妥当で、'0'、'1'、任意の英字、パーセントマークにマッチングします。

Perl recognizes the following POSIX character classes:

Perl は以下の POSIX 文字クラスを認識します:

 alpha  Any alphabetical character ("[A-Za-z]").
 alnum  Any alphanumerical character. ("[A-Za-z0-9]")
 ascii  Any character in the ASCII character set.
 blank  A GNU extension, equal to a space or a horizontal tab ("\t").
 cntrl  Any control character.  See Note [2] below.
 digit  Any decimal digit ("[0-9]"), equivalent to "\d".
 graph  Any printable character, excluding a space.  See Note [3] below.
 lower  Any lowercase character ("[a-z]").
 print  Any printable character, including a space.  See Note [4] below.
 punct  Any graphical character excluding "word" characters.  Note [5].
 space  Any whitespace character. "\s" plus the vertical tab ("\cK").
 upper  Any uppercase character ("[A-Z]").
 word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
 xdigit Any hexadecimal digit ("[0-9a-fA-F]").
 alpha  任意の英字 ("[A-Za-z]")。
 alnum  任意の英数字。("[A-Za-z0-9]")
 ascii  任意の ASCII 文字集合の文字。
 blank  GNU 拡張; スペースまたは水平タブ ("\t") と同じ。
 cntrl  任意の制御文字。後述の [2] 参照。
 digit  任意の 10 進数字 ("[0-9]"); "\d" と等価。
 graph  任意の表示文字; スペースを除く。後述の [3] 参照。
 lower  任意の小文字 ("[a-z]")。
 print  任意の表示文字; スペースを含む。後述の [4] 参照。
 punct  任意の「単語」文字を除く表示文字。[5] 参照。
 space  任意の空白文字。"\s" に加えて水平タブ ("\cK")。
 upper  任意の大文字 ("[A-Z]")。
 word   Perl 拡張 ("[A-Za-z0-9_]"); "\w" と等価。
 xdigit 任意の 16 進文字 ("[0-9a-fA-F]")。

Most POSIX character classes have two Unicode-style \p property counterparts. (They are not official Unicode properties, but Perl extensions derived from official Unicode properties.) The table below shows the relation between POSIX character classes and these counterparts.

ほとんどの POSIX 文字クラスには、対応する二つの Unicode 式の \p 特性が あります。 (これは公式 Unicode 特性ではなく、公式 Unicode 特性から派生した Perl エクステンションです。) 以下の表は POSIX 文字クラスと対応するものとの関連を示します。

One counterpart, in the column labelled "ASCII-range Unicode" in the table will only match characters in the ASCII range. (On EBCDIC platforms, they match those characters which have ASCII equivalents.)

対応物の一つである、表で "ASCII-range Unicode" と書かれた列のものは、 ASCII の範囲の文字にのみマッチングします。 (EBCDIC プラットフォームでは、ASCII での等価な文字にマッチングします。)

The other counterpart, in the column labelled "Full-range Unicode", matches any appropriate characters in the full Unicode character set. For example, \p{Alpha} will match not just the ASCII alphabetic characters, but any character in the entire Unicode character set that is considered to be alphabetic.

もう一つの対応物である、"Full-range Unicode" と書かれた列のものは、 Unicode 文字集合全体の中の適切な任意の文字にマッチングします。 例えば、\p{Alpha} は単に ASCII アルファベット文字だけでなく、 Unicode 文字集合全体の中からアルファベットと考えられる任意の文字に マッチングします。

(Each of the counterparts has various synonyms as well. "Properties accessible through \p{} and \P{}" in perluniprops lists all the synonyms, plus all the characters matched by each of the ASCII-range properties. For example \p{AHex} is a synonym for \p{ASCII_Hex_Digit}, and any \p property name can be prefixed with "Is" such as \p{IsAlpha}.)

(それぞれの対応物には様々な同義語もあります。 "Properties accessible through \p{} and \P{}" in perluniprops に 全ての同義語と、ASCII 範囲のそれぞれでマッチングする全ての文字の一覧が あります。 例えば、\p{AHex}\p{ASCII_Hex_Digit} の同義語で、 任意の \p 特性名は、\p{IsAlpha} のように、"Is" 接頭辞が使えます。)

Both the \p forms are unaffected by any locale that is in effect, or whether the string is in UTF-8 format or not, or whether the platform is EBCDIC or not. In contrast, the POSIX character classes are affected. If the source string is in UTF-8 format, the POSIX classes (with the exception of [[:punct:]], see Note [5]) behave like their "Full-range" Unicode counterparts. If the source string is not in UTF-8 format, and no locale is in effect, and the platform is not EBCDIC, all the POSIX classes behave like their ASCII-range counterparts. Otherwise, they behave based on the rules of the locale or EBCDIC code page. It is proposed to change this behavior in a future release of Perl so that the the UTF8ness of the source string will be irrelevant to the behavior of the POSIX character classes. This means they will always behave in strict accordance with the official POSIX standard. That is, if either locale or EBCDIC code page is present, they will behave in accordance with those; if absent, the classes will match only their ASCII-range counterparts. If you disagree with this proposal, send email to perl5-porters@perl.org.

両方の \p 形式はどのロケールが有効かや、文字列が UTF-8 形式かどうかや、 プラットフォームが EBCDIC かどうかに影響を受けません。 一方、POSIX 文字クラスは影響を受けます。 ソース文字列が UTF-8 形式なら、POSIX クラス (例外は [[:punct:]] です; [5] 参照) は「全体」Unicode 版と似た振る舞いをします。 ソース文字列が UTF-8 形式でなく、ロケールが有効でなく、プラットフォームが EBCDIC でなければ、全ての POSIX クラスは ASCII 範囲版と似た振る舞いをします。 さもなければ、ロケールや EBCDIC コードページのルールに従った振る舞いを します。 Perl の将来のバージョンではこの振る舞いを変えることが提案されています; ソース文字列が UTF-8 かどうかで POSIX 文字クラスの振る舞いに影響を 与えないようにします。 これにより、常に公式な POSIX 標準に厳密に準拠した振る舞いになります。 つまり、ロケールや EBCDIC コードページがあれば、準拠した振る舞いをします; なければ、クラスは ASCII 範囲版にのみマッチングします。 この提案に意義があるなら、perl5-porters@perl.org にメールを 送ってください。

 [[:...:]]      ASCII-range        Full-range  backslash  Note
                 Unicode            Unicode    sequence
 -----------------------------------------------------
   alpha      \p{PosixAlpha}       \p{Alpha}
   alnum      \p{PosixAlnum}       \p{Alnum}
   ascii      \p{ASCII}          
   blank      \p{PosixBlank}       \p{Blank} =             [1]
                                   \p{HorizSpace}  \h      [1]
   cntrl      \p{PosixCntrl}       \p{Cntrl}               [2]
   digit      \p{PosixDigit}       \p{Digit}       \d
   graph      \p{PosixGraph}       \p{Graph}               [3]
   lower      \p{PosixLower}       \p{Lower}
   print      \p{PosixPrint}       \p{Print}               [4]
   punct      \p{PosixPunct}       \p{Punct}               [5]
              \p{PerlSpace}        \p{SpacePerl}   \s      [6]
   space      \p{PosixSpace}       \p{Space}               [6]
   upper      \p{PosixUpper}       \p{Upper}
   word       \p{PerlWord}         \p{Word}        \w
   xdigit     \p{ASCII_Hex_Digit}  \p{XDigit}
[1]

\p{Blank} and \p{HorizSpace} are synonyms.

\p{Blank}\p{HorizSpace} は同義語です。

[2]

Control characters don't produce output as such, but instead usually control the terminal somehow: for example newline and backspace are control characters. In the ASCII range, characters whose ordinals are between 0 and 31 inclusive, plus 127 (DEL) are control characters.

制御文字はそれ自体は出力されず、普通は何か端末を制御します: 例えば 改行と後退は制御文字です。 ASCII の範囲では、序数が 0 から 31 までの範囲の文字および 127 (DEL) が 制御文字です。

On EBCDIC platforms, it is likely that the code page will define [[:cntrl:]] to be the EBCDIC equivalents of the ASCII controls, plus the controls that in Unicode have ordinals from 128 through 139.

EBCDIC プラットフォームでは、コードページは [[:cntrl:]] を、ASCII 制御文字の EBCDIC 等価物に加えて、Unicode で序数 128 から 139 を持つものと 定義しています。

[3]

Any character that is graphical, that is, visible. This class consists of all the alphanumerical characters and all punctuation characters.

graphical、つまり見える文字。 このクラスは全ての英数字と全ての句読点文字。

[4]

All printable characters, which is the set of all the graphical characters plus whitespace characters that are not also controls.

全ての表示可能な文字; 全ての graphical 文字に加えて制御文字でない空白文字。

[5]

\p{PosixPunct} and [[:punct:]] in the ASCII range match all the non-controls, non-alphanumeric, non-space characters: [-!"#$%&'()*+,./:;<=>?@[\\\]^_`{|}~] (although if a locale is in effect, it could alter the behavior of [[:punct:]]).

ASCII の範囲の \p{PosixPunct}[[:punct:]] は全ての非制御、非英数字、 非空白文字にマッチングします: [-!"#$%&'()*+,./:;<=>?@[\\\]^_`{|}~] (しかしロケールが有効なら、 [[:punct:]] の振る舞いが変わります)。

When the matching string is in UTF-8 format, [[:punct:]] matches the above set, plus what \p{Punct} matches. This is different than strictly matching according to \p{Punct}, because the above set includes characters that aren't considered punctuation by Unicode, but rather "symbols". Another way to say it is that for a UTF-8 string, [[:punct:]] matches all the characters that Unicode considers to be punctuation, plus all the ASCII-range characters that Unicode considers to be symbols.

マッチングする文字列が UTF-8 形式のとき、[[:punct:]] は上述の集合に 加えて、\p{Punct} にマッチングするものにマッチングします。 これは \p{Punct} に従って厳密にマッチングするものと違います; なぜなら 上述の集合には、Unicode で句読点ではなく "symbols" として扱われるものが 含まれているからです。 UTF-8 文字列のためのもう一つの言い方は、[[:punct:]] は Unicode が 句読点として扱うものに加えて、Unicode が "symbols" として扱う ASCII 範囲の 全ての文字にマッチングします。

[6]

\p{SpacePerl} and \p{Space} differ only in that \p{Space} additionally matches the vertical tab, \cK. Same for the two ASCII-only range forms.

\p{SpacePerl}\p{Space} の違いは、\p{Space} は垂直タブ \cK にもマッチングすると言うことだけです。 二つの ASCII のみの範囲の形式では同じです。

否定

A Perl extension to the POSIX character class is the ability to negate it. This is done by prefixing the class name with a caret (^). Some examples:

POSIX 文字クラスに対する Perl の拡張は否定の機能です。 これはクラス名の前にキャレット (^) を置くことで実現します。 いくつかの例です:

     POSIX         ASCII-range     Full-range  backslash
                    Unicode         Unicode    sequence
 -----------------------------------------------------
 [[:^digit:]]   \P{PosixDigit}     \P{Digit}      \D
 [[:^space:]]   \P{PosixSpace}     \P{Space}
                \P{PerlSpace}      \P{SpacePerl}  \S
 [[:^word:]]    \P{PerlWord}       \P{Word}       \W

[= =] と [. .]

Perl will recognize the POSIX character classes [=class=], and [.class.], but does not (yet?) support them. Use of such a construct will lead to an error.

Perl は POSIX 文字クラス [=class=][.class.] を認識しますが、 これらには(まだ?)対応していません。 このような構文の使用はエラーを引き起こします。

 /[[:digit:]]/            # Matches a character that is a digit.
 /[01[:lower:]]/          # Matches a character that is either a
                          # lowercase letter, or '0' or '1'.
 /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
                          # except the letters 'a' to 'f'.  This is
                          # because the main character class is composed
                          # of two POSIX character classes that are ORed
                          # together, one that matches any digit, and
                          # the other that matches anything that isn't a
                          # hex digit.  The result matches all
                          # characters except the letters 'a' to 'f' and
                          # 'A' to 'F'.
 /[[:digit:]]/            # 数字の文字にマッチングする。
 /[01[:lower:]]/          # 小文字、'0'、'1' のいずれかの文字に
                          # マッチングする。
 /[[:digit:][:^xdigit:]]/ # 'a' から 'f' 以外の任意の文字に
                          # マッチング。これはメインの文字クラスでは二つの
                          # POSIX 文字クラスが OR され、一つは任意の数字に
                          # マッチングし、もう一つは 16 進文字でない全ての
                          # 文字にマッチングします。従って
                          # 'a' から 'f' および 'A' から 'F' を
                          # 除く全ての文字に
                          # マッチングすることになります。

ロケール、EBCDIC、Unicode、UTF-8

Some of the character classes have a somewhat different behaviour depending on the internal encoding of the source string, and the locale that is in effect, and if the program is running on an EBCDIC platform.

ソース文字列の内部エンコーディングと有効なロケールに、そしてプログラムが EBCDIC プラットフォームで実行されるかどうかに依存して少し異なった 振る舞いをする文字クラスもあります。

\w, \d, \s and the POSIX character classes (and their negations, including \W, \D, \S) suffer from this behaviour. (Since the backslash sequences \b and \B are defined in terms of \w and \W, they also are affected.)

\w, \d, \s および POSIX 文字クラス (および \W, \D, \S を 含むこれらの否定) はこの振る舞いの影響を受けます。 (逆スラッシュシーケンス \b\B\w\W の点から 定義されているので、これらも影響を受けます。)

The rule is that if the source string is in UTF-8 format, the character classes match according to the Unicode properties. If the source string isn't, then the character classes match according to whatever locale or EBCDIC code page is in effect. If there is no locale nor EBCDIC, they match the ASCII defaults (52 letters, 10 digits and underscore for \w; 0 to 9 for \d; etc.).

ソース文字列が UTF-8 形式なら、文字クラスは Unicode 特性に従って マッチングするという規則です。 ソース文字列が UTF-8 形式ではなければ、文字クラスはロケールや EBCDIC コードページが有効かどうかに従ってマッチングします。 ロケールや EBCDIC が有効でなければ、ASCII のデフォルト (\w では 52 の英字、 10 の数字と下線; \d では 0 から 9; など) にマッチングします。

This usually means that if you are matching against characters whose ord() values are between 128 and 255 inclusive, your character class may match or not depending on the current locale or EBCDIC code page, and whether the source string is in UTF-8 format. The string will be in UTF-8 format if it contains characters whose ord() value exceeds 255. But a string may be in UTF-8 format without it having such characters. See "The "Unicode Bug"" in perluniprops.

これは普通、ord() の値が 128 から 255 の範囲の文字にマッチングするなら、 その文字クラスは現在のロケールや EBCDIC コードページ、およびソース文字列が UTF-8 形式かどうかに依存してマッチングしたりしなかったりします。 ord() 値が 255 を超える文字が含まれているなら文字列は UTF-8 形式です。 しかしそのような文字がなくても UTF-8 形式かもしれません。 "The "Unicode Bug"" in perluniprops を参照してください。

For portability reasons, it may be better to not use \w, \d, \s or the POSIX character classes, and use the Unicode properties instead.

移植性の理由により、\w, \d, \s や POSIX 文字クラスは使わず、 Unicode 特性を使う方が良いです。

 $str =  "\xDF";      # $str is not in UTF-8 format.
 $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
 $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
 $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
 chop $str;
 $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
 $str =  "\xDF";      # $str は UTF-8 形式ではない。
 $str =~ /^\w/;       # マッチングしない; $str は UTF-8 形式ではない。
 $str .= "\x{0e0b}";  # ここで $str は UTF-8 形式。
 $str =~ /^\w/;       # マッチング! $str は UTF-8 形式。
 chop $str;
 $str =~ /^\w/;       # まだマッチング! $str は UTF-8 形式のまま。