5.18.1
Other versions:
5.16.1
5.14.1
5.12.1
5.10.1

NAME

perlrecharclass - Perl Regular Expression Character Classes

perlrecharclass - Perl 正規表現文字クラス

説明

The top level documentation about Perl regular expressions is found in perlre.

Perl 正規表現に関する最上位文書は perlre です。

This manual page discusses the syntax and use of character classes in Perl regular expressions.

このマニュアルページは Perl 正規表現の文字クラスの文法と使用法について 議論します。

A character class is a way of denoting a set of characters in such a way that one character of the set is matched. It's important to remember that: matching a character class consumes exactly one character in the source string. (The source string is the string the regular expression is matched against.)

文字クラスは、集合の中の一文字がマッチングするというような方法で、 文字の集合を指定するための方法です。 次のことを覚えておくことは重要です: 文字集合はソース文字列の中から正確に 一文字だけを消費します。 (ソース文字列とは正規表現がマッチングしようとしている文字列です。)

There are three types of character classes in Perl regular expressions: the dot, backslash sequences, and the form enclosed in square brackets. Keep in mind, though, that often the term "character class" is used to mean just the bracketed form. Certainly, most Perl documentation does that.

Perl 正規表現には 3 種類の文字クラスがあります: ドット、 逆スラッシュシーケンス、大かっこで囲まれた形式です。 しかし、「文字クラス」という用語はしばしば大かっこ形式だけを意味するために 使われることに注意してください。 確かに、ほとんどの Perl 文書ではそうなっています。

ドット

The dot (or period), . is probably the most used, and certainly the most well-known character class. By default, a dot matches any character, except for the newline. That default can be changed to add matching the newline by using the single line modifier: either for the entire regular expression with the /s modifier, or locally with (?s). (The \N backslash sequence, described below, matches any character except newline without regard to the single line modifier.)

ドット (またはピリオド) . はおそらくもっともよく使われ、そして確実に もっともよく知られている文字クラスです。 デフォルトでは、ドットは改行を除く任意の文字にマッチングします。 このデフォルトは 単一行 修飾子を使うことで改行にもマッチングするように 変更されます: 正規表現全体に対して /s 修飾子を使うか、ローカルには (?s) を使います。 (後述する \N 逆スラッシュシーケンスでは、単一行 修飾子に 関わりなく改行以外の任意の文字にマッチングします。)

Here are some examples:

以下は例です:

 "a"  =~  /./       # Match
 "."  =~  /./       # Match
 ""   =~  /./       # No match (dot has to match a character)
 "\n" =~  /./       # No match (dot does not match a newline)
 "\n" =~  /./s      # Match (global 'single line' modifier)
 "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
 "ab" =~  /^.$/     # No match (dot matches one character)
 "a"  =~  /./       # マッチングする
 "."  =~  /./       # マッチングする
 ""   =~  /./       # マッチングしない (ドットは文字にマッチングする必要がある)
 "\n" =~  /./       # マッチングしない (ドットは改行にはマッチングしない)
 "\n" =~  /./s      # マッチングする (グローバル「単一行」修飾子)
 "\n" =~  /(?s:.)/  # マッチングする (ローカル「単一行」修飾子)
 "ab" =~  /^.$/     # マッチングしない (ドットは一文字にマッチングする)

逆スラッシュシーケンス

A backslash sequence is a sequence of characters, the first one of which is a backslash. Perl ascribes special meaning to many such sequences, and some of these are character classes. That is, they match a single character each, provided that the character belongs to the specific set of characters defined by the sequence.

逆スラッシュシーケンスは、最初がバックスラッシュの文字並びです。 Perl はそのような並びの多くに特別な意味を持たせていて、 その一部は文字クラスです。 つまり、それらはそれぞれ並びによって定義されている特定の文字の集合に 帰属する一文字にマッチングします。

Here's a list of the backslash sequences that are character classes. They are discussed in more detail below. (For the backslash sequences that aren't character classes, see perlrebackslash.)

以下は文字クラスの逆スラッシュシーケンスの一覧です。 以下でさらに詳細に議論します。 (文字クラスではない逆スラッシュシーケンスについては、perlrebackslash を 参照してください。)

 \d             Match a decimal digit character.
 \D             Match a non-decimal-digit character.
 \w             Match a "word" character.
 \W             Match a non-"word" character.
 \s             Match a whitespace character.
 \S             Match a non-whitespace character.
 \h             Match a horizontal whitespace character.
 \H             Match a character that isn't horizontal whitespace.
 \v             Match a vertical whitespace character.
 \V             Match a character that isn't vertical whitespace.
 \N             Match a character that isn't a newline.
 \pP, \p{Prop}  Match a character that has the given Unicode property.
 \PP, \P{Prop}  Match a character that doesn't have the Unicode property
 \d             10 進数字にマッチング。
 \D             非 10 進数字にマッチング。
 \w             「単語」文字にマッチング。
 \W             非「単語」文字にマッチング。
 \s             空白文字にマッチング。
 \S             非空白文字にマッチング。
 \h             水平空白文字にマッチング。
 \H             水平空白でない文字にマッチング。
 \v             垂直空白文字にマッチング。
 \V             垂直空白でない文字にマッチング。
 \N             改行以外の文字にマッチング。
 \pP, \p{Prop}  指定された Unicode 特性を持つ文字にマッチング。
 \PP, \P{Prop}  指定された Unicode 特性を持たない文字にマッチング。

\N

\N, available starting in v5.12, like the dot, matches any character that is not a newline. The difference is that \N is not influenced by the single line regular expression modifier (see "The dot" above). Note that the form \N{...} may mean something completely different. When the {...} is a quantifier, it means to match a non-newline character that many times. For example, \N{3} means to match 3 non-newlines; \N{5,} means to match 5 or more non-newlines. But if {...} is not a legal quantifier, it is presumed to be a named character. See charnames for those. For example, none of \N{COLON}, \N{4F}, and \N{F4} contain legal quantifiers, so Perl will try to find characters whose names are respectively COLON, 4F, and F4.

v5.12 から利用可能な \N は、ドットのように、 改行以外の任意の文字にマッチングします。 違いは、\N単一行 正規表現修飾子の影響を受けないことです (上述の "The dot" 参照)。 \N{...} 型式は何か全く違うものを意味するかも知れないことに 注意してください。 {...}量指定子 なら、これは指定された回数の 非改行文字にマッチングします。 例えば、\N{3} は三つの非改行にマッチングします; \N{5,} は五つ以上の非改行にマッチングします。 しかし、{...} が有効な量指定子でない場合、これは名前付き文字と 推定されます。 これについては charnames を参照してください。 例えば、\N{COLON}, \N{4F}, \N{F4} はどれも有効な 量指定子ではないので、Perl はそれぞれ COLON, 4F, F4 という名前の 文字を探そうとします。

数字

\d matches a single character considered to be a decimal digit. If the /a regular expression modifier is in effect, it matches [0-9]. Otherwise, it matches anything that is matched by \p{Digit}, which includes [0-9]. (An unlikely possible exception is that under locale matching rules, the current locale might not have [0-9] matched by \d, and/or might match other characters whose code point is less than 256. Such a locale definition would be in violation of the C language standard, but Perl doesn't currently assume anything in regard to this.)

\d は 10 進 数字 と考えられる単一の文字にマッチングします。 /a 正規表現修飾子が有効の場合、これは [0-9] にマッチングします。 さもなければ、これは [0-9] を含む、\p{Digit} にマッチングするものに マッチングします。 (ありそうもない例外はロケールマッチングの下で、現在のロケールが \d にマッチングする [0-9] がないか、 符号位置が 256 未満の他の文字にマッチングすることです。 このようなロケール定義は C 言語標準に違反していますが、 Perl は今のところこれに関して何も仮定しません。)

What this means is that unless the /a modifier is in effect \d not only matches the digits '0' - '9', but also Arabic, Devanagari, and digits from other languages. This may cause some confusion, and some security issues.

これが意味することは、/a 修飾子が有効でない限り、\d は数字 '0' - '9' だけでなく、アラビア文字、デバナーガリ文字、およびその他の言語の 数字もマッチングします。 これは混乱やセキュリティ問題を引き起こすことがあります。

Some digits that \d matches look like some of the [0-9] ones, but have different values. For example, BENGALI DIGIT FOUR (U+09EA) looks very much like an ASCII DIGIT EIGHT (U+0038). An application that is expecting only the ASCII digits might be misled, or if the match is \d+, the matched string might contain a mixture of digits from different writing systems that look like they signify a number different than they actually do. "num()" in Unicode::UCD can be used to safely calculate the value, returning undef if the input string contains such a mixture.

\d にマッチングする数字には、[0-9] のように見えるけれども、 異なる値を持つものもあります。 例えば、BENGALI DIGIT FOUR (U+09EA) は ASCII DIGIT EIGHT (U+0038) と とてもよく似ています。 ASCII 数字のみを想定しているアプリケーションはミスリードされるかも知れず、 マッチングが \d+ の場合、 マッチングした文字列は、実際と異なる値を示しているように見える、 異なった書記体系からの数字が混ざったものかもしれません。 "num()" in Unicode::UCD は値を安全に計算するのに使えます; 入力文字列がこのような混合を含んでいる場合は undef を返します。

What \p{Digit} means (and hence \d except under the /a modifier) is \p{General_Category=Decimal_Number}, or synonymously, \p{General_Category=Digit}. Starting with Unicode version 4.1, this is the same set of characters matched by \p{Numeric_Type=Decimal}. But Unicode also has a different property with a similar name, \p{Numeric_Type=Digit}, which matches a completely different set of characters. These characters are things such as CIRCLED DIGIT ONE or subscripts, or are from writing systems that lack all ten digits.

\p{Digit} が意味するもの(つまり、/a 修飾子の下でない \d)は、 \p{General_Category=Decimal_Number}、または同義語として \p{General_Category=Digit} です。 Unicode バージョン 4.1 以降では、これは \p{Numeric_Type=Decimal} に マッチングする文字集合と同じです。 ただし、Unicode には、\p{Numeric_Type=Digit} という類似した名前を持つ 別の特性もあります; これは完全に異なる文字集合とマッチングします。 これらの文字は、CIRCLEED DIGIT ONE や添字のようなものであるか、 10 の数字すべてが揃っていない書記体系からのものです。

The design intent is for \d to exactly match the set of characters that can safely be used with "normal" big-endian positional decimal syntax, where, for example 123 means one 'hundred', plus two 'tens', plus three 'ones'. This positional notation does not necessarily apply to characters that match the other type of "digit", \p{Numeric_Type=Digit}, and so \d doesn't match them.

設計意図は、\d が「通常の」ビッグエンディアンの 位置 10 進構文 (例えば、123 は一つの「100」に二つの「10」と三つの「1」を 加えたものを意味する) で安全に使用できる文字集合と 正確にマッチングするようにすることです; この位置表記は、他のタイプの「digit」である \p{Numeric_Type=Digit} に マッチングする文字には必ずしも適用されないため、 \d はこれらの文字にマッチングしません。

The Tamil digits (U+0BE6 - U+0BEF) can also legally be used in old-style Tamil numbers in which they would appear no more than one in a row, separated by characters that mean "times 10", "times 100", etc. (See http://www.unicode.org/notes/tn21.)

タミル語の数字(U+0BE6-U+0BEF)は、古い様式のタミル語の 数字でも合法的に使用することができます; この数字は、「×10」や「×100」などを意味する文字で区切られて、 1 回に一度にしか現れません。 (http://www.unicode.org/notes/tn21を参照してください)。

Any character not matched by \d is matched by \D.

\d にマッチングしない任意の文字は \D にマッチングします。

単語文字

A \w matches a single alphanumeric character (an alphabetic character, or a decimal digit); or a connecting punctuation character, such as an underscore ("_"); or a "mark" character (like some sort of accent) that attaches to one of those. It does not match a whole word. To match a whole word, use \w+. This isn't the same thing as matching an English word, but in the ASCII range it is the same as a string of Perl-identifier characters.

\w は単語全体ではなく、単一の英数字(つまり英字または数字)または 下線(_) のような接続句読点 またはこれらの一つに付いている(ある種のアクセントのような)「マーク」文字に マッチングします。 これは単語全体にはマッチングしません。 単語全体にマッチングするには、\w+ を使ってください。 これは英語の単語にマッチングするのと同じことではありませんが、 ASCII の範囲では、Perl の識別子文字の文字列と同じです。

If the /a modifier is in effect ...

(/a 修飾子が有効なら ...)

\w matches the 63 characters [a-zA-Z0-9_].

\w は 63 文字 [a-zA-Z0-9_] にマッチングします。

otherwise ...

(さもなければ ...)

For code points above 255 ...

(256 以上の符号位置では ...)

\w matches the same as \p{Word} matches in this range. That is, it matches Thai letters, Greek letters, etc. This includes connector punctuation (like the underscore) which connect two words together, or diacritics, such as a COMBINING TILDE and the modifier letters, which are generally used to add auxiliary markings to letters.

\w はこの範囲で \p{Word} がマッチングするものと同じものに マッチングします。 つまり、タイ文字、ギリシャ文字などです。 これには(下線のような)二つの単語を繋ぐ接続句読点、 COMBINING TILDE や一般的に文字に追加のマークを付けるために 使われる修飾字のようなダイアクリティカルマークが含まれます。

For code points below 256 ...

(255 以下の符号位置では ...)

if locale rules are in effect ...

(ロケール規則が有効なら ...)

\w matches the platform's native underscore character plus whatever the locale considers to be alphanumeric.

\w は、プラットフォームのネイティブな下線に加えてロケールが英数字と 考えるものにマッチングします。

if Unicode rules are in effect ...

(Unicode 規則が有効なら ...)

\w matches exactly what \p{Word} matches.

\w\p{Word} がマッチングするものと同じものにマッチングします。

otherwise ...

(さもなければ ...)

\w matches [a-zA-Z0-9_].

\w は [a-zA-Z0-9_] にマッチングします。

Which rules apply are determined as described in "Which character set modifier is in effect?" in perlre.

どの規則を適用するかは "Which character set modifier is in effect?" in perlre で 記述されている方法で決定されます。

There are a number of security issues with the full Unicode list of word characters. See http://unicode.org/reports/tr36.

完全な Unicode の単語文字の一覧には多くのセキュリティ問題があります。 http://unicode.org/reports/tr36 を参照してください。

Also, for a somewhat finer-grained set of characters that are in programming language identifiers beyond the ASCII range, you may wish to instead use the more customized "Unicode Properties", \p{ID_Start}, \p{ID_Continue}, \p{XID_Start}, and \p{XID_Continue}. See http://unicode.org/reports/tr31.

また、ASCII の範囲を超えたプログラミング言語識別子のための より高精度の文字集合のためには、代わりによりカスタマイズされた Unicode 特性である \p{ID_Start}, \p{ID_Continue}, \p{XID_Start}, and \p{XID_Continue} を 使った方がよいでしょう。 http://unicode.org/reports/tr31 を参照してください。

Any character not matched by \w is matched by \W.

\w にマッチングしない任意の文字は \W にマッチングします。

空白

\s matches any single character considered whitespace.

\s は空白と考えられる単一の文字にマッチングします。

If the /a modifier is in effect ...

(/a 修飾子が有効なら ...)

In all Perl versions, \s matches the 5 characters [\t\n\f\r ]; that is, the horizontal tab, the newline, the form feed, the carriage return, and the space. Starting in Perl v5.18, experimentally, it also matches the vertical tab, \cK. See note [1] below for a discussion of this.

全ての Perl バージョンで、\s は [\t\n\f\r ] の 5 文字にマッチングします; つまり、水平タブ、改行、改頁、復帰、スペースです。 Perl 5.18 から、実験的に、垂直タブ \cK にもマッチングします。 ここでの議論については後述する [1] を参照してください。

otherwise ...

(さもなければ ...)

For code points above 255 ...

(256 以上の符号位置では ...)

\s matches exactly the code points above 255 shown with an "s" column in the table below.

\s は、後述する表の "s" の列で示されている、 255 を超える符号位置に正確にマッチングします。

For code points below 256 ...

(255 以下の符号位置では ...)

if locale rules are in effect ...

(ロケール規則が有効なら ...)

\s matches whatever the locale considers to be whitespace.

\s はロケールが空白だと考えるものにマッチングします。

if Unicode rules are in effect ...

(Unicode 規則が有効なら ...)

\s matches exactly the characters shown with an "s" column in the table below.

\s は正確に以下の表で "s" の列にある文字にマッチングします。

otherwise ...

\s matches [\t\n\f\r\cK ] and, starting, experimentally in Perl v5.18, the vertical tab, \cK. (See note [1] below for a discussion of this.) Note that this list doesn't include the non-breaking space.

\s は [\t\n\f\r\cK ] にマッチングし、Perl v5.18 から実験的に、 垂直タブ \cK にもマッチングします。 (これの議論については後述する [1] を参照してください。) この一覧にはノーブレークスペースが含まれていないことに注意してください。

Which rules apply are determined as described in "Which character set modifier is in effect?" in perlre.

どの規則を適用するかは "Which character set modifier is in effect?" in perlre で 記述されている方法で決定されます。

Any character not matched by \s is matched by \S.

\s にマッチングしない任意の文字は \S にマッチングします。

\h matches any character considered horizontal whitespace; this includes the platform's space and tab characters and several others listed in the table below. \H matches any character not considered horizontal whitespace. They use the platform's native character set, and do not consider any locale that may otherwise be in use.

\h は水平空白と考えられる任意の文字にマッチングします; これは プラットフォームのスペースとタブ文字および以下の表に上げられている いくつかのその他の文字です。 \H は水平空白と考えられない文字にマッチングします。 これらはプラットフォームのネイティブな文字集合を使い、 他の場所では有効なロケールを考慮しません。

\v matches any character considered vertical whitespace; this includes the platform's carriage return and line feed characters (newline) plus several other characters, all listed in the table below. \V matches any character not considered vertical whitespace. They use the platform's native character set, and do not consider any locale that may otherwise be in use.

\v は垂直空白と考えられる任意の文字にマッチングします; これは プラットフォームの復帰と行送り(改行)文字に加えていくつかのその他の文字です; 全ては以下の表に挙げられています。 \V は垂直空白と考えられない任意の文字にマッチングします。 これらはプラットフォームのネイティブな文字集合を使い、 他の場所では有効なロケールを考慮しません。

\R matches anything that can be considered a newline under Unicode rules. It's not a character class, as it can match a multi-character sequence. Therefore, it cannot be used inside a bracketed character class; use \v instead (vertical whitespace). It uses the platform's native character set, and does not consider any locale that may otherwise be in use. Details are discussed in perlrebackslash.

\R は Unicode の規則で改行と考えられるものにマッチングします。 複数文字の並びにマッチングすることもあるので、これは 文字クラスではありません。 従って、大かっこ文字クラスの中では使えません; 代わりに \v (垂直空白) を 使ってください。 これらはプラットフォームのネイティブな文字集合を使い、 他の場所では有効なロケールを考慮しません。 詳細は perlrebackslash で議論しています。

Note that unlike \s (and \d and \w), \h and \v always match the same characters, without regard to other factors, such as the active locale or whether the source string is in UTF-8 format.

\s (および \d\w) と違って、\h および \v は、現在の ロケールやソース文字列が UTF-8 形式かどうかといった他の要素に関わらず 同じ文字にマッチングします。

One might think that \s is equivalent to [\h\v]. This is indeed true starting in Perl v5.18, but prior to that, the sole difference was that the vertical tab ("\cK") was not matched by \s.

\s[\h\v] と等価と考える人がいるかもしれません。 Perl 5.18 からはもちろん正しいです; しかしそれより前では、 唯一の違いは、垂直タブ ("\xcK") は \s にマッチングしないということです。

The following table is a complete listing of characters matched by \s, \h and \v as of Unicode 6.0.

以下の表は Unicode 6.0 現在で \s, \h, \v にマッチングする文字の 完全な一覧です。

The first column gives the Unicode code point of the character (in hex format), the second column gives the (Unicode) name. The third column indicates by which class(es) the character is matched (assuming no locale is in effect that changes the \s matching).

最初の列は文字の Unicode 符号位置(16 進形式)、2 番目の列は (Unicode の) 名前です。 3 番目の列はどのクラスにマッチングするかを示しています (\s のマッチングを変更するようなロケールが 有効でないことを仮定しています)。

 0x0009        CHARACTER TABULATION   h s
 0x000a              LINE FEED (LF)    vs
 0x000b             LINE TABULATION    vs  [1]
 0x000c              FORM FEED (FF)    vs
 0x000d        CARRIAGE RETURN (CR)    vs
 0x0020                       SPACE   h s
 0x0085             NEXT LINE (NEL)    vs  [2]
 0x00a0              NO-BREAK SPACE   h s  [2]
 0x1680            OGHAM SPACE MARK   h s
 0x180e   MONGOLIAN VOWEL SEPARATOR   h s
 0x2000                     EN QUAD   h s
 0x2001                     EM QUAD   h s
 0x2002                    EN SPACE   h s
 0x2003                    EM SPACE   h s
 0x2004          THREE-PER-EM SPACE   h s
 0x2005           FOUR-PER-EM SPACE   h s
 0x2006            SIX-PER-EM SPACE   h s
 0x2007                FIGURE SPACE   h s
 0x2008           PUNCTUATION SPACE   h s
 0x2009                  THIN SPACE   h s
 0x200a                  HAIR SPACE   h s
 0x2028              LINE SEPARATOR    vs
 0x2029         PARAGRAPH SEPARATOR    vs
 0x202f       NARROW NO-BREAK SPACE   h s
 0x205f   MEDIUM MATHEMATICAL SPACE   h s
 0x3000           IDEOGRAPHIC SPACE   h s
[1]

Prior to Perl v5.18, \s did not match the vertical tab. The change in v5.18 is considered an experiment, which means it could be backed out in v5.20 or v5.22 if experience indicates that it breaks too much existing code. If this change adversely affects you, send email to perlbug@perl.org; if it affects you positively, email perlthanks@perl.org. In the meantime, [^\S\cK] (obscurely) matches what \s traditionally did.

Prior to Perl v5.18, \s did not match the vertical tab. The change in v5.18 is considered an experiment, which means it could be backed out in v5.20 or v5.22 if experience indicates that it breaks too much existing code. If this change adversely affects you, send email to perlbug@perl.org; if it affects you positively, email perlthanks@perl.org. In the meantime, [^\S\cK] (obscurely) matches what \s traditionally did. (TBT)

[2]

NEXT LINE and NO-BREAK SPACE may or may not match \s depending on the rules in effect. See the beginning of this section.

NEXT LINE と NO-BREAK SPACE はどの規則が有効かによって \s に マッチングしたりマッチングしなかったりします。 the beginning of this section を参照してください。

Unicode 特性

\pP and \p{Prop} are character classes to match characters that fit given Unicode properties. One letter property names can be used in the \pP form, with the property name following the \p, otherwise, braces are required. When using braces, there is a single form, which is just the property name enclosed in the braces, and a compound form which looks like \p{name=value}, which means to match if the property "name" for the character has that particular "value". For instance, a match for a number can be written as /\pN/ or as /\p{Number}/, or as /\p{Number=True}/. Lowercase letters are matched by the property Lowercase_Letter which has the short form Ll. They need the braces, so are written as /\p{Ll}/ or /\p{Lowercase_Letter}/, or /\p{General_Category=Lowercase_Letter}/ (the underscores are optional). /\pLl/ is valid, but means something different. It matches a two character string: a letter (Unicode property \pL), followed by a lowercase l.

\pP\p{Prop} は指定された Unicode 特性に一致する文字に マッチングする文字クラスです。 一文字特性は \pP 形式で、\p に引き続いて特性名です; さもなければ 中かっこが必要です。 中かっこを使うとき、単に特性名を中かっこで囲んだ単一形式と、 \p{name=value} のような形で、文字の特性 "name" が特定の "value" を 持つものにマッチングすることになる複合形式があります。 例えば、数字にマッチングするものは /\pN/ または /\p{Number}/ または /\p{Number=True}/ と書けます。 小文字は LowercaseLetter 特性にマッチングします; これには Ll と言う短縮形式があります。 中かっこが必要なので、/\p{Ll}/ または /\p{Lowercase_Letter}/ または /\p{General_Category=Lowercase_Letter}/ と書きます(下線はオプションです)。 /\pLl/ も妥当ですが、違う意味になります。 これは 2 文字にマッチングします: 英字 (Unicode 特性 \pL)に引き続いて 小文字の l です。

If locale rules are not in effect, the use of a Unicode property will force the regular expression into using Unicode rules, if it isn't already.

ロケール規則が有効でない場合、Unicode 特性を使うと 正規表現に (まだそうでなければ) Unicode 規則を使うように強制します。

Note that almost all properties are immune to case-insensitive matching. That is, adding a /i regular expression modifier does not change what they match. There are two sets that are affected. The first set is Uppercase_Letter, Lowercase_Letter, and Titlecase_Letter, all of which match Cased_Letter under /i matching. The second set is Uppercase, Lowercase, and Titlecase, all of which match Cased under /i matching. (The difference between these sets is that some things, such as Roman numerals, come in both upper and lower case, so they are Cased, but aren't considered to be letters, so they aren't Cased_Letters. They're actually Letter_Numbers.) This set also includes its subsets PosixUpper and PosixLower, both of which under /i match PosixAlpha.

ほとんど全ての特性は大文字小文字を無視したマッチングから免除されることに 注意してください。 つまり、/i 正規表現修飾子はこれらがマッチングするものに影響を 与えないということです。 影響を与える二つの集合があります。 一つ目の集合は Uppercase_Letter, Lowercase_Letter, Titlecase_Letter で、全て /i マッチングの下で Cased_Letter にマッチングします。 二つ目の集合は Uppercase, Lowercase, Titlecase で、全て/i マッチングの下で Cased にマッチングします。 (これらの集合の違いは、ローマ数字のような一部のものは、 大文字と小文字があるので Cased ですが、 文字とは扱われないので Cased_Letter ではありません。 これらは実際には Letter_Number です。) この集合はその部分集合である PosixUpperPosixLower を含みます; これら両方は /i マッチングの下では PosixAlpha にマッチングします。

For more details on Unicode properties, see "Unicode Character Properties" in perlunicode; for a complete list of possible properties, see "Properties accessible through \p{} and \P{}" in perluniprops, which notes all forms that have /i differences. It is also possible to define your own properties. This is discussed in "User-Defined Character Properties" in perlunicode.

Unicode 特性に関するさらなる詳細については、 "Unicode Character Properties" in perlunicode を参照してください; 特性の完全な 一覧については、/i に違いのある全ての形式について記されている "Properties accessible through \p{} and \P{}" in perluniprops を参照して ください。 独自の特性を定義することも可能です。 これは "User-Defined Character Properties" in perlunicode で 議論されています。

Unicode properties are defined (surprise!) only on Unicode code points. A warning is raised and all matches fail on non-Unicode code points (those above the legal Unicode maximum of 0x10FFFF). This can be somewhat surprising,

Unicode 特性は (驚くべきことに!) Unicode 符号位置に対してのみ 定義されています。 非 Unicode 符号位置 (正当な Unicode の上限の 0x10FFFF を超えるもの) への マッチングの失敗は警告が発生します。 これは驚かされるものかもしれません。

 chr(0x110000) =~ \p{ASCII_Hex_Digit=True}      # Fails.
 chr(0x110000) =~ \p{ASCII_Hex_Digit=False}     # Also fails!

Even though these two matches might be thought of as complements, they are so only on Unicode code points.

これら二つのマッチングは補集合と考えるかもしれませんが、 これらは Unicode 符号位置だけです。

 "a"  =~  /\w/      # Match, "a" is a 'word' character.
 "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
 "a"  =~  /\d/      # No match, "a" isn't a digit.
 "7"  =~  /\d/      # Match, "7" is a digit.
 " "  =~  /\s/      # Match, a space is whitespace.
 "a"  =~  /\D/      # Match, "a" is a non-digit.
 "7"  =~  /\D/      # No match, "7" is not a non-digit.
 " "  =~  /\S/      # No match, a space is not non-whitespace.
 "a"  =~  /\w/      # マッチング; "a" は「単語」文字。
 "7"  =~  /\w/      # マッチング; "7" も「単語」文字。
 "a"  =~  /\d/      # マッチングしない; "a" は数字ではない。
 "7"  =~  /\d/      # マッチング; "7" は数字。
 " "  =~  /\s/      # マッチング; スペースは空白。
 "a"  =~  /\D/      # マッチング; "a" は非数字。
 "7"  =~  /\D/      # マッチングしない; "7" は非数字ではない。
 " "  =~  /\S/      # マッチングしない; スペースは非空白ではない。
 " "  =~  /\h/      # Match, space is horizontal whitespace.
 " "  =~  /\v/      # No match, space is not vertical whitespace.
 "\r" =~  /\v/      # Match, a return is vertical whitespace.
 " "  =~  /\h/      # マッチング; スペースは水平空白。
 " "  =~  /\v/      # マッチングしない; スペースは垂直空白ではない。
 "\r" =~  /\v/      # マッチング; 復帰は垂直空白。
 "a"  =~  /\pL/     # Match, "a" is a letter.
 "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
 "a"  =~  /\pL/     # マッチング; "a" は英字。
 "a"  =~  /\p{Lu}/  # マッチングしない; /\p{Lu}/ は大文字にマッチングする。
 "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
                           # 'THAI CHARACTER SO SO', and that's in
                           # Thai Unicode class.
 "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
 "\x{0e0b}" =~ /\p{Thai}/  # マッチング; \x{0e0b} は文字
                           # 'THAI CHARACTER SO SO' で、これは
                           # Thai Unicode クラスにある。
 "a"  =~  /\P{Lao}/ # マッチング; "a" はラオス文字ではない。

It is worth emphasizing that \d, \w, etc, match single characters, not complete numbers or words. To match a number (that consists of digits), use \d+; to match a word, use \w+. But be aware of the security considerations in doing so, as mentioned above.

\d, \w などは数値や単語全体ではなく、1 文字にマッチングすることは 強調する価値があります。 (数字で構成される) 数値 にマッチングするには \d+ を使います; 単語にマッチングするには \w+ を使います。 しかし前述したように、そうする場合のセキュリティ問題について 注意してください。

かっこ付き文字クラス

The third form of character class you can use in Perl regular expressions is the bracketed character class. In its simplest form, it lists the characters that may be matched, surrounded by square brackets, like this: [aeiou]. This matches one of a, e, i, o or u. Like the other character classes, exactly one character is matched.* To match a longer string consisting of characters mentioned in the character class, follow the character class with a quantifier. For instance, [aeiou]+ matches one or more lowercase English vowels.

Perl 正規表現で使える文字クラスの第 3 の形式は大かっこ文字クラスです。 もっとも単純な形式では、以下のように大かっこの中にマッチングする文字を リストします: [aeiou]. これは a, e, i, o, u のどれかにマッチングします。 他の文字クラスと同様、正確に一つの文字にマッチングします。 文字クラスで言及した文字で構成されるより長い文字列にマッチングするには、 文字クラスに 量指定子 を付けます。 例えば、[aeiou]+ は一つまたはそれ以上の小文字英語母音に マッチングします。

Repeating a character in a character class has no effect; it's considered to be in the set only once.

文字クラスの中で文字を繰り返しても効果はありません; 一度だけ現れたものと 考えられます。

Examples:

例:

 "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
 "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
 "ae" =~  /^[aeiou]$/      # No match, a character class only matches
                           # a single character.
 "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
 "e"  =~  /[aeiou]/        # マッチング; "e" はクラスにある。
 "p"  =~  /[aeiou]/        # マッチングしない; "p" はクラスにない。
 "ae" =~  /^[aeiou]$/      # マッチングしない; 一つの文字クラスは
                           # 一文字だけにマッチングする。
 "ae" =~  /^[aeiou]+$/     # マッチング; 量指定子により。

 -------

* There is an exception to a bracketed character class matching a single character only. When the class is to match caselessly under /i matching rules, and a character that is explicitly mentioned inside the class matches a multiple-character sequence caselessly under Unicode rules, the class (when not inverted) will also match that sequence. For example, Unicode says that the letter LATIN SMALL LETTER SHARP S should match the sequence ss under /i rules. Thus,

* 大かっこ文字クラスは単一の文字にのみマッチングするということには 一つの例外があります。 クラスが /i マッチング規則の下で大文字小文字を無視したマッチングを して、クラスの中で明示的に記述された文字が Unicode の規則の下で複数文字並びに 大文字小文字を無視してマッチングするとき、 そのクラス (否定 でない場合) はその並びにもマッチングします。 例えば、Unicode は文字 LATIN SMALL LETTER SHARP S/i 規則の下では 並び ss にマッチングするとしています。 従って:

 'ss' =~ /\A\N{LATIN SMALL LETTER SHARP S}\z/i             # Matches
 'ss' =~ /\A[aeioust\N{LATIN SMALL LETTER SHARP S}]\z/i    # Matches

For this to happen, the character must be explicitly specified, and not be part of a multi-character range (not even as one of its endpoints). ("Character Ranges" will be explained shortly.) Therefore,

For this to happen, the character must be explicitly specified, and not be part of a multi-character range (not even as one of its endpoints). ("Character Ranges" will be explained shortly.) Therefore, (TBT)

 'ss' =~ /\A[\0-\x{ff}]\z/i        # Doesn't match
 'ss' =~ /\A[\0-\N{LATIN SMALL LETTER SHARP S}]\z/i    # No match
 'ss' =~ /\A[\xDF-\xDF]\z/i    # Matches on ASCII platforms, since \XDF
                               # is LATIN SMALL LETTER SHARP S, and the
                               # range is just a single element

Note that it isn't a good idea to specify these types of ranges anyway.

Note that it isn't a good idea to specify these types of ranges anyway. (TBT)

かっこ付き文字クラスの中の特殊文字

Most characters that are meta characters in regular expressions (that is, characters that carry a special meaning like ., *, or () lose their special meaning and can be used inside a character class without the need to escape them. For instance, [()] matches either an opening parenthesis, or a closing parenthesis, and the parens inside the character class don't group or capture.

正規表現内でメタ文字(つまり、., *, ( のように特別な意味を持つ 文字)となるほとんどの文字は文字クラス内ではエスケープしなくても特別な意味を 失うので、エスケープする必要はありません。 例えば、[()] は開きかっこまたは閉じかっこにマッチングし、文字クラスの中の かっこはグループや捕捉にはなりません。

Characters that may carry a special meaning inside a character class are: \, ^, -, [ and ], and are discussed below. They can be escaped with a backslash, although this is sometimes not needed, in which case the backslash may be omitted.

文字クラスの中でも特別な意味を持つ文字は: \, ^, -, [, ] で、以下で議論します。 これらは逆スラッシュでエスケープできますが、不要な場合もあり、そのような 場合では逆スラッシュは省略できます。

The sequence \b is special inside a bracketed character class. While outside the character class, \b is an assertion indicating a point that does not have either two word characters or two non-word characters on either side, inside a bracketed character class, \b matches a backspace character.

シーケンス \b は大かっこ文字クラスの内側では特別です。 文字クラスの外側では \b 二つの単語文字か二つの非単語文字のどちらかではない 位置を示す表明ですが、大かっこ文字クラスの内側では \b は後退文字に マッチングします。

The sequences \a, \c, \e, \f, \n, \N{NAME}, \N{U+hex char}, \r, \t, and \x are also special and have the same meanings as they do outside a bracketed character class. (However, inside a bracketed character class, if \N{NAME} expands to a sequence of characters, only the first one in the sequence is used, with a warning.)

並び \a, \c, \e, \f, \n, \N{NAME}, \N{U+hex char}, \r, \t, \x も特別で、大かっこ文字クラスの外側と同じ意味を持ちます。 (しかし、大かっこ文字クラスの中では、 \N{NAME} が文字並びに展開されると、 並びの最初の一つだけが使われ、警告が発生します。)

Also, a backslash followed by two or three octal digits is considered an octal number.

また、逆スラッシュに引き続いて 2 または 3 桁の 8 進数字があると 8 進数として 扱われます。

A [ is not special inside a character class, unless it's the start of a POSIX character class (see "POSIX Character Classes" below). It normally does not need escaping.

[ は、POSIX 文字クラス(後述の "POSIX Character Classes" 参照)の 開始でない限りは文字クラスの中では特別ではありません。 これは普通エスケープは不要です。

A ] is normally either the end of a POSIX character class (see "POSIX Character Classes" below), or it signals the end of the bracketed character class. If you want to include a ] in the set of characters, you must generally escape it.

A ] は普通は POSIX 文字クラス(後述の "POSIX Character Classes" 参照)の 終わりか、大かっこ文字クラスの終了を示すかどちらかです。 文字集合に ] を含める必要がある場合、一般的には エスケープしなければなりません。

However, if the ] is the first (or the second if the first character is a caret) character of a bracketed character class, it does not denote the end of the class (as you cannot have an empty class) and is considered part of the set of characters that can be matched without escaping.

しかし、] が大かっこ文字クラスの 最初 (または最初の文字がキャレットなら 2 番目) の文字の場合、(空クラスを作ることはできないので)これはクラスの 終了を意味せず、エスケープなしでマッチングできる文字の集合の一部と 考えられます。

Examples:

例:

 "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
 "\cH" =~ /[\b]/      #  Match, \b inside in a character class.
                      #  is equivalent to a backspace.
 "]"   =~ /[][]/      #  Match, as the character class contains.
                      #  both [ and ].
 "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
                      #  containing just ], and the character class is
                      #  followed by a ].
 "+"   =~ /[+?*]/     #  マッチング; 文字クラス内の "+" は特別ではない。
 "\cH" =~ /[\b]/      #  マッチング; 文字クラスの内側の \b は後退と
                      #  等価。
 "]"   =~ /[][]/      #  マッチング; 文字クラスに [ と ] の両方を
                      #  含んでいる。
 "[]"  =~ /[[]]/      #  マッチング; パターンは ] だけを含んでいる
                      #  文字クラスと、それに引き続く
                      #  ] からなる。

文字範囲

It is not uncommon to want to match a range of characters. Luckily, instead of listing all characters in the range, one may use the hyphen (-). If inside a bracketed character class you have two characters separated by a hyphen, it's treated as if all characters between the two were in the class. For instance, [0-9] matches any ASCII digit, and [a-m] matches any lowercase letter from the first half of the ASCII alphabet.

文字のある範囲にマッチングしたいというのは珍しくありません。 幸運なことに、その範囲の文字を全て一覧に書く代わりに、ハイフン (-) を 使えます。 大かっこ文字クラスの内側で二つの文字がハイフンで区切られていると、 二つの文字の間の全ての文字がクラスに書かれているかのように扱われます。 例えば、[0-9] は任意の ASCII 数字にマッチングし、[a-m] は ASCII アルファベットの前半分の小文字にマッチングします。

Note that the two characters on either side of the hyphen are not necessarily both letters or both digits. Any character is possible, although not advisable. ['-?] contains a range of characters, but most people will not know which characters that means. Furthermore, such ranges may lead to portability problems if the code has to run on a platform that uses a different character set, such as EBCDIC.

ハイフンのそれぞれの側の二つの文字は両方とも英字であったり両方とも 数字であったりする必要はないことに注意してください。 任意の文字が可能ですが、勧められません。 ['-?] は文字の範囲を含みますが、ほとんどの人はどの文字が含まれるか 分かりません。 さらに、このような範囲は、コードが EBCDIC のような異なった文字集合を使う プラットフォームで実行されると移植性の問題を引き起こします。

If a hyphen in a character class cannot syntactically be part of a range, for instance because it is the first or the last character of the character class, or if it immediately follows a range, the hyphen isn't special, and so is considered a character to be matched literally. If you want a hyphen in your set of characters to be matched and its position in the class is such that it could be considered part of a range, you must escape that hyphen with a backslash.

例えば文字クラスの最初または最後であったり、範囲の直後のために、文字クラスの 中のハイフンが文法的に範囲の一部となれない場合、ハイフンは特別ではなく、 リテラルにマッチングするべき文字として扱われます。 マッチングする文字の集合にハイフンを入れたいけれどもその位置が範囲の 一部として考えられる場合はハイフンを逆スラッシュで エスケープしなければなりません。

Examples:

例:

 [a-z]       #  Matches a character that is a lower case ASCII letter.
 [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
             #  the letter 'z'.
 [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
 [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
             #  hyphen ('-'), or the letter 'm'.
 ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
             #  (But not on an EBCDIC platform).
 [a-z]       #  小文字 ASCII 英字にマッチング。
 [a-fz]      #  'a' から 'f' の英字およびと 'z' の英字に
             #  マッチング。
 [-z]        #  ハイフン ('-') または英字 'z' にマッチング。
 [a-f-m]     #  'a' から 'f' の英字、ハイフン ('-')、英字 'm' に
             #  マッチング。
 ['-?]       #  文字 '()*+,-./0123456789:;<=>? のどれかにマッチング
             #  (しかし EBCDIC プラットフォームでは異なります)。

否定

It is also possible to instead list the characters you do not want to match. You can do so by using a caret (^) as the first character in the character class. For instance, [^a-z] matches any character that is not a lowercase ASCII letter, which therefore includes more than a million Unicode code points. The class is said to be "negated" or "inverted".

代わりにマッチングしたくない文字の一覧を指定することも可能です。 文字クラスの先頭の文字としてキャレット (^) を使うことで実現します。 例えば、[^a-z] 小文字の ASCII 英字以外の文字にマッチングします; 従って 100 万種類以上の Unicode 符号位置が含まれます。 このクラスは「否定」("negated") や「反転」("inverted")と呼ばれます。

This syntax make the caret a special character inside a bracketed character class, but only if it is the first character of the class. So if you want the caret as one of the characters to match, either escape the caret or else don't list it first.

この文法はキャレットを大かっこ文字クラスの内側で特別な文字にしますが、 クラスの最初の文字の場合のみです。 それでマッチングしたい文字の一つでキャレットを使いたい場合、キャレットを エスケープするか、最初以外の位置に書いてください。

In inverted bracketed character classes, Perl ignores the Unicode rules that normally say that certain characters should match a sequence of multiple characters under caseless /i matching. Following those rules could lead to highly confusing situations:

否定大かっこ文字クラスでは、通常は大文字小文字を無視した /i マッチングの 下ではある種の文字が複数の文字並びにマッチングするということを Perl は無視します。 これらの規則に従うととても混乱する状況を引き起こすことになるからです:

 "ss" =~ /^[^\xDF]+$/ui;   # Matches!

This should match any sequences of characters that aren't \xDF nor what \xDF matches under /i. "s" isn't \xDF, but Unicode says that "ss" is what \xDF matches under /i. So which one "wins"? Do you fail the match because the string has ss or accept it because it has an s followed by another s? Perl has chosen the latter.

これは /i の下では \xDF または \xDF にマッチングするもの以外の 任意の文字並びにマッチングするべきです。 "s"\xDF ではありませんが、 /i の下では "ss"\xDF がマッチングするものと Unicode は 言っています。 ではどちらが「勝つ」のでしょうか? 文字列は ss だからマッチングに失敗するのでしょうか、 それともこれは s の後にもう一つの s があるから成功するのでしょうか? Perl は後者を選択しました。

Examples:

例:

 "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
 "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
 "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
 "^"  =~  /[x^]/       #  Match, caret is not special here.
 "e"  =~  /[^aeiou]/   #  マッチングしない; 'e' がある。
 "x"  =~  /[^aeiou]/   #  マッチング; 'x' は小文字の母音ではない。
 "^"  =~  /[^^]/       #  マッチングしない; キャレット以外全てにマッチング。
 "^"  =~  /[x^]/       #  マッチング; キャレットはここでは特別ではない。

逆スラッシュシーケンス

You can put any backslash sequence character class (with the exception of \N and \R) inside a bracketed character class, and it will act just as if you had put all characters matched by the backslash sequence inside the character class. For instance, [a-f\d] matches any decimal digit, or any of the lowercase letters between 'a' and 'f' inclusive.

大かっこ文字クラスの中に(\N\R を例外として)逆スラッシュシーケンス 文字クラスを置くことができ、逆スラッシュシーケンスにマッチングする全ての 文字を文字クラスの中に置いたかのように動作します。 例えば、[a-f\d] は任意の 10 進数字、あるいは 'a' から 'f' までの小文字に マッチングします。

\N within a bracketed character class must be of the forms \N{name} or \N{U+hex char}, and NOT be the form that matches non-newlines, for the same reason that a dot . inside a bracketed character class loses its special meaning: it matches nearly anything, which generally isn't what you want to happen.

大かっこ文字クラスの中のドット . が特別な意味を持たないのと同じ理由で、 大かっこ文字クラスの中の \N\N{name} または \N{U+hex char} の形式で、かつ非改行マッチング形式でない形でなければ なりません: これはほとんど何でもマッチングするので、一般的には起こって 欲しいことではありません。

Examples:

例:

 /[\p{Thai}\d]/     # Matches a character that is either a Thai
                    # character, or a digit.
 /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
                    # character, nor a parenthesis.
 /[\p{Thai}\d]/     # タイ文字または数字の文字に
                    # マッチングする。
 /[^\p{Arabic}()]/  # アラビア文字でもかっこでもない文字に
                    # マッチングする。

Backslash sequence character classes cannot form one of the endpoints of a range. Thus, you can't say:

逆スラッシュシーケンス文字クラスは範囲の端点の一つにはできません。 従って、以下のようにはできません:

 /[\p{Thai}-\d]/     # Wrong!

POSIX 文字クラス

POSIX character classes have the form [:class:], where class is name, and the [: and :] delimiters. POSIX character classes only appear inside bracketed character classes, and are a convenient and descriptive way of listing a group of characters.

POSIX 文字クラスは [:class:] の形式で、class は名前、[::] は デリミタです。 POSIX 文字クラスは大かっこ文字クラスの 内側 にのみ現れ、文字のグループを 一覧するのに便利で記述的な方法です。

Be careful about the syntax,

文法について注意してください、

 # Correct:
 $string =~ /[[:alpha:]]/

 # Incorrect (will warn):
 $string =~ /[:alpha:]/

The latter pattern would be a character class consisting of a colon, and the letters a, l, p and h. POSIX character classes can be part of a larger bracketed character class. For example,

後者のパターンは、コロンおよび a, l, p, h の文字からなる 文字クラスです。 これら文字クラスはより大きな大かっこ文字クラスの一部にできます。 例えば、

 [01[:alpha:]%]

is valid and matches '0', '1', any alphabetic character, and the percent sign.

これは妥当で、'0'、'1'、任意の英字、パーセントマークにマッチングします。

Perl recognizes the following POSIX character classes:

Perl は以下の POSIX 文字クラスを認識します:

 alpha  Any alphabetical character ("[A-Za-z]").
 alnum  Any alphanumeric character ("[A-Za-z0-9]").
 ascii  Any character in the ASCII character set.
 blank  A GNU extension, equal to a space or a horizontal tab ("\t").
 cntrl  Any control character.  See Note [2] below.
 digit  Any decimal digit ("[0-9]"), equivalent to "\d".
 graph  Any printable character, excluding a space.  See Note [3] below.
 lower  Any lowercase character ("[a-z]").
 print  Any printable character, including a space.  See Note [4] below.
 punct  Any graphical character excluding "word" characters.  Note [5].
 space  Any whitespace character. "\s" including the vertical tab
        ("\cK").
 upper  Any uppercase character ("[A-Z]").
 word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
 xdigit Any hexadecimal digit ("[0-9a-fA-F]").
 alpha  任意の英字 ("[A-Za-z]")。
 alnum  任意の英数字。("[A-Za-z0-9]")
 ascii  任意の ASCII 文字集合の文字。
 blank  GNU 拡張; スペースまたは水平タブ ("\t") と同じ。
 cntrl  任意の制御文字。後述の [2] 参照。
 digit  任意の 10 進数字 ("[0-9]"); "\d" と等価。
 graph  任意の表示文字; スペースを除く。後述の [3] 参照。
 lower  任意の小文字 ("[a-z]")。
 print  任意の表示文字; スペースを含む。後述の [4] 参照。
 punct  任意の「単語」文字を除く表示文字。[5] 参照。
 space  任意の空白文字。水平タブ ("\cK") を含む "\s"。
 upper  任意の大文字 ("[A-Z]")。
 word   Perl 拡張 ("[A-Za-z0-9_]"); "\w" と等価。
 xdigit 任意の 16 進文字 ("[0-9a-fA-F]")。

Most POSIX character classes have two Unicode-style \p property counterparts. (They are not official Unicode properties, but Perl extensions derived from official Unicode properties.) The table below shows the relation between POSIX character classes and these counterparts.

ほとんどの POSIX 文字クラスには、対応する二つの Unicode 式の \p 特性が あります。 (これは公式 Unicode 特性ではなく、公式 Unicode 特性から派生した Perl エクステンションです。) 以下の表は POSIX 文字クラスと対応するものとの関連を示します。

One counterpart, in the column labelled "ASCII-range Unicode" in the table, matches only characters in the ASCII character set.

対応物の一つである、表で "ASCII-range Unicode" と書かれた列のものは、 ASCII 文字集合の文字にのみマッチングします。

The other counterpart, in the column labelled "Full-range Unicode", matches any appropriate characters in the full Unicode character set. For example, \p{Alpha} matches not just the ASCII alphabetic characters, but any character in the entire Unicode character set considered alphabetic. An entry in the column labelled "backslash sequence" is a (short) equivalent.

もう一つの対応物である、"Full-range Unicode" と書かれた列のものは、 Unicode 文字集合全体の中の適切な任意の文字にマッチングします。 例えば、\p{Alpha} は単に ASCII アルファベット文字だけでなく、 Unicode 文字集合全体の中からアルファベットと考えられる任意の文字に マッチングします。 "backslash sequence" の列は (短い) 同義語です。

 [[:...:]]      ASCII-range          Full-range  backslash  Note
                 Unicode              Unicode     sequence
 -----------------------------------------------------
   alpha      \p{PosixAlpha}       \p{XPosixAlpha}
   alnum      \p{PosixAlnum}       \p{XPosixAlnum}
   ascii      \p{ASCII}
   blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
                                   or \p{HorizSpace}        [1]
   cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
   digit      \p{PosixDigit}       \p{XPosixDigit}  \d
   graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
   lower      \p{PosixLower}       \p{XPosixLower}
   print      \p{PosixPrint}       \p{XPosixPrint}          [4]
   punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
              \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
   space      \p{PosixSpace}       \p{XPosixSpace}          [6]
   upper      \p{PosixUpper}       \p{XPosixUpper}
   word       \p{PosixWord}        \p{XPosixWord}   \w
   xdigit     \p{PosixXDigit}      \p{XPosixXDigit}
[1]

\p{Blank} and \p{HorizSpace} are synonyms.

\p{Blank}\p{HorizSpace} は同義語です。

[2]

Control characters don't produce output as such, but instead usually control the terminal somehow: for example, newline and backspace are control characters. In the ASCII range, characters whose code points are between 0 and 31 inclusive, plus 127 (DEL) are control characters.

制御文字はそれ自体は出力されず、普通は何か端末を制御します: 例えば 改行と後退は制御文字です。 ASCII の範囲では、符号位置が 0 から 31 までの範囲の文字および 127 (DEL) が 制御文字です。

[3]

Any character that is graphical, that is, visible. This class consists of all alphanumeric characters and all punctuation characters.

graphical、つまり見える文字。 このクラスは全ての英数字と全ての句読点文字。

[4]

All printable characters, which is the set of all graphical characters plus those whitespace characters which are not also controls.

全ての表示可能な文字; 全ての graphical 文字に加えて制御文字でない空白文字。

[5]

\p{PosixPunct} and [[:punct:]] in the ASCII range match all non-controls, non-alphanumeric, non-space characters: [-!"#$%&'()*+,./:;<=>?@[\\\]^_`{|}~] (although if a locale is in effect, it could alter the behavior of [[:punct:]]).

ASCII の範囲の \p{PosixPunct}[[:punct:]] は全ての非制御、非英数字、 非空白文字にマッチングします: [-!"#$%&'()*+,./:;<=>?@[\\\]^_`{|}~] (しかしロケールが有効なら、 [[:punct:]] の振る舞いが変わります)。

The similarly named property, \p{Punct}, matches a somewhat different set in the ASCII range, namely [-!"#%&'()*,./:;?@[\\\]_{}]. That is, it is missing the nine characters [$+<=>^`|~]. This is because Unicode splits what POSIX considers to be punctuation into two categories, Punctuation and Symbols.

似たような名前の特性 \p{Punct} は、ASCII 範囲の異なる集合である [-!"#%&'()*,./:;?@[\\\]_{}] にマッチングします。 つまり、[$+<=>^`|~] の 9 文字はありません。 これは、Unicode は POSIX が句読点と考えるものを二つのカテゴリ Punctuation と Symbols に分けているからです。

\p{XPosixPunct} and (under Unicode rules) [[:punct:]], match what \p{PosixPunct} matches in the ASCII range, plus what \p{Punct} matches. This is different than strictly matching according to \p{Punct}. Another way to say it is that if Unicode rules are in effect, [[:punct:]] matches all characters that Unicode considers punctuation, plus all ASCII-range characters that Unicode considers symbols.

\p{XPosixPunct} と (Unicode の規則の下での) [[:punct:]] は、 ASCII の範囲で \p{PosixPunct} がマッチングする物に加えて、 \p{Punct} がマッチングする物にマッチングします。 これは \p{Punct} に従って正確にマッチングする物と異なります。 Unicode 規則が有効な場合のもう一つの言い方は、[[:punct:]] は Unicode が 句読点として扱うものに加えて、Unicode が "symbols" として扱う ASCII 範囲の 全ての文字にマッチングします。

[6]

\p{SpacePerl} and \p{Space} match identically starting with Perl v5.18. In earlier versions, these differ only in that in non-locale matching, \p{SpacePerl} does not match the vertical tab, \cK. Same for the two ASCII-only range forms.

\p{SpacePerl}\p{Space} は、Perl v5.18 からは同じように マッチングします。 以前のバージョンでは、これらの違いは、非ロケールマッチングでは \p{SpacePerl} は垂直タブ \cK にもマッチングしないということだけです。 二つの ASCII のみの範囲の形式では同じです。

There are various other synonyms that can be used besides the names listed in the table. For example, \p{PosixAlpha} can be written as \p{Alpha}. All are listed in "Properties accessible through \p{} and \P{}" in perluniprops, plus all characters matched by each ASCII-range property.

表に挙げられている名前以外にも様々なその他の同義語が使えます。 例えば、\p{PosixAlpha}\p{Alpha} と書けます。 全ての一覧に加えて各 ASCII の範囲の特性にマッチングする全ての文字は、 は "Properties accessible through \p{} and \P{}" in perluniprops に あります。

Both the \p counterparts always assume Unicode rules are in effect. On ASCII platforms, this means they assume that the code points from 128 to 255 are Latin-1, and that means that using them under locale rules is unwise unless the locale is guaranteed to be Latin-1 or UTF-8. In contrast, the POSIX character classes are useful under locale rules. They are affected by the actual rules in effect, as follows:

\p に対応するものの両方は常に Unicode の規則が有効であることを仮定します。 これは、ASCII プラットフォームでは、128 から 255 の符号位置は Latin-1 であることを仮定するということで、ロケールの規則の下で これらを使うということは、ロケールが Latin-1 か UTF-8 であることが 補償されていない限り賢明ではないということです。 一方、POSIX 文字クラスはロケールの規則の下で有用です。 これらは次のように、実際に有効な規則に影響を受けます:

If the /a modifier, is in effect ...

(/a が有効なら...)

Each of the POSIX classes matches exactly the same as their ASCII-range counterparts.

それぞれの POSIX クラスは ASCII の範囲で対応する正確に同じものに マッチングします。

otherwise ...

(さもなければ...)

For code points above 255 ...

(256 以上の符号位置では...)

The POSIX class matches the same as its Full-range counterpart.

POSIX クラスはその Full の範囲で対応する同じものにマッチングします。

For code points below 256 ...

(255 以下の符号位置では...)

if locale rules are in effect ...

(ロケールの規則が有効なら...)

The POSIX class matches according to the locale, except that word uses the platform's native underscore character, no matter what the locale is.

POSIX クラスはロケールに従ってマッチングします; except that word はロケールが何かに関わらず、プラットフォームのネイティブな 下線文字を使います。

if Unicode rules are in effect ...

(Unicode の規則が有効なら...)

The POSIX class matches the same as the Full-range counterpart.

POSIX クラスは Full の範囲の対応する同じものにマッチングします。

otherwise ...

(さもなければ...)

The POSIX class matches the same as the ASCII range counterpart.

POSIX クラスは ASCII の範囲の同じものにマッチングします。

Which rules apply are determined as described in "Which character set modifier is in effect?" in perlre.

どの規則を適用するかは "Which character set modifier is in effect?" in perlre で 記述されている方法で決定されます。

It is proposed to change this behavior in a future release of Perl so that whether or not Unicode rules are in effect would not change the behavior: Outside of locale, the POSIX classes would behave like their ASCII-range counterparts. If you wish to comment on this proposal, send email to perl5-porters@perl.org.

Perl の将来のバージョンではこの振る舞いを変えることが提案されています; Unicode の規則が有効かどうかは振る舞いを変えません: ロケールの外側では、 POSIX クラスはその ASCII の範囲の対応するものと同様に振る舞います。 この提案にコメントしたいなら、perl5-porters@perl.org にメールを 送ってください。

POSIX 文字クラスの否定

A Perl extension to the POSIX character class is the ability to negate it. This is done by prefixing the class name with a caret (^). Some examples:

POSIX 文字クラスに対する Perl の拡張は否定の機能です。 これはクラス名の前にキャレット (^) を置くことで実現します。 いくつかの例です:

     POSIX         ASCII-range     Full-range  backslash
                    Unicode         Unicode    sequence
 -----------------------------------------------------
 [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
 [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
                \P{PerlSpace}   \P{XPerlSpace}    \S
 [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W

The backslash sequence can mean either ASCII- or Full-range Unicode, depending on various factors as described in "Which character set modifier is in effect?" in perlre.

逆スラッシュシーケンスは ASCII- か Full-range Unicode のどちらかを意味します; どちらが使われるかは "Which character set modifier is in effect?" in perlre で 記述されている様々な要素に依存します。

[= =] と [. .]

Perl recognizes the POSIX character classes [=class=] and [.class.], but does not (yet?) support them. Any attempt to use either construct raises an exception.

Perl は POSIX 文字クラス [=class=][.class.] を認識しますが、 これらには(まだ?)対応していません。 このような構文を使おうとすると例外が発生します。

 /[[:digit:]]/            # Matches a character that is a digit.
 /[01[:lower:]]/          # Matches a character that is either a
                          # lowercase letter, or '0' or '1'.
 /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
                          # except the letters 'a' to 'f' and 'A' to
                          # 'F'.  This is because the main character
                          # class is composed of two POSIX character
                          # classes that are ORed together, one that
                          # matches any digit, and the other that
                          # matches anything that isn't a hex digit.
                          # The OR adds the digits, leaving only the
                          # letters 'a' to 'f' and 'A' to 'F' excluded.
 /[[:digit:]]/            # 数字の文字にマッチングする。
 /[01[:lower:]]/          # 小文字、'0'、'1' のいずれかの文字に
                          # マッチングする。
 /[[:digit:][:^xdigit:]]/ # 'a' から 'f' と 'A' から 'F' 以外の任意の文字に
                          # マッチング。これはメインの文字クラスでは二つの
                          # POSIX 文字クラスが OR され、一つは任意の数字に
                          # マッチングし、もう一つは 16 進文字でない全ての
                          # 文字にマッチングします。OR は数字を加え、
                          # 'a' から 'f' および 'A' から 'F' のみが
                          # 除外されて残ります。
                          # 

拡張大かっこ文字クラス

This is a fancy bracketed character class that can be used for more readable and less error-prone classes, and to perform set operations, such as intersection. An example is

This is a fancy bracketed character class that can be used for more readable and less error-prone classes, and to perform set operations, such as intersection. An example is (TBT)

 /(?[ \p{Thai} & \p{Digit} ])/

This will match all the digit characters that are in the Thai script.

This will match all the digit characters that are in the Thai script. (TBT)

This is an experimental feature available starting in 5.18, and is subject to change as we gain field experience with it. Any attempt to use it will raise a warning, unless disabled via

This is an experimental feature available starting in 5.18, and is subject to change as we gain field experience with it. Any attempt to use it will raise a warning, unless disabled via (TBT)

 no warnings "experimental::regex_sets";

Comments on this feature are welcome; send email to perl5-porters@perl.org.

Comments on this feature are welcome; send email to perl5-porters@perl.org. (TBT)

We can extend the example above:

We can extend the example above: (TBT)

 /(?[ ( \p{Thai} + \p{Lao} ) & \p{Digit} ])/

This matches digits that are in either the Thai or Laotian scripts.

This matches digits that are in either the Thai or Laotian scripts. (TBT)

Notice the white space in these examples. This construct always has the /x modifier turned on.

Notice the white space in these examples. This construct always has the /x modifier turned on. (TBT)

The available binary operators are:

The available binary operators are: (TBT)

 &    intersection
 +    union
 |    another name for '+', hence means union
 -    subtraction (the result matches the set consisting of those
      code points matched by the first operand, excluding any that
      are also matched by the second operand)
 ^    symmetric difference (the union minus the intersection).  This
      is like an exclusive or, in that the result is the set of code
      points that are matched by either, but not both, of the
      operands.

There is one unary operator:

There is one unary operator: (TBT)

 !    complement

All the binary operators left associate, and are of equal precedence. The unary operator right associates, and has higher precedence. Use parentheses to override the default associations. Some feedback we've received indicates a desire for intersection to have higher precedence than union. This is something that feedback from the field may cause us to change in future releases; you may want to parenthesize copiously to avoid such changes affecting your code, until this feature is no longer considered experimental.

All the binary operators left associate, and are of equal precedence. The unary operator right associates, and has higher precedence. Use parentheses to override the default associations. Some feedback we've received indicates a desire for intersection to have higher precedence than union. This is something that feedback from the field may cause us to change in future releases; you may want to parenthesize copiously to avoid such changes affecting your code, until this feature is no longer considered experimental. (TBT)

The main restriction is that everything is a metacharacter. Thus, you cannot refer to single characters by doing something like this:

The main restriction is that everything is a metacharacter. Thus, you cannot refer to single characters by doing something like this: (TBT)

 /(?[ a + b ])/ # Syntax error!

The easiest way to specify an individual typable character is to enclose it in brackets:

The easiest way to specify an individual typable character is to enclose it in brackets: (TBT)

 /(?[ [a] + [b] ])/

(This is the same thing as [ab].) You could also have said the equivalent:

(This is the same thing as [ab].) You could also have said the equivalent: (TBT)

 /(?[[ a b ]])/

(You can, of course, specify single characters by using, \x{ }, \N{ }, etc.)

(You can, of course, specify single characters by using, \x{ }, \N{ }, etc.) (TBT)

This last example shows the use of this construct to specify an ordinary bracketed character class without additional set operations. Note the white space within it; /x is turned on even within bracketed character classes, except you can't have comments inside them. Hence,

This last example shows the use of this construct to specify an ordinary bracketed character class without additional set operations. Note the white space within it; /x is turned on even within bracketed character classes, except you can't have comments inside them. Hence, (TBT)

 (?[ [#] ])

matches the literal character "#". To specify a literal white space character, you can escape it with a backslash, like:

matches the literal character "#". To specify a literal white space character, you can escape it with a backslash, like: (TBT)

 /(?[ [ a e i o u \  ] ])/

This matches the English vowels plus the SPACE character. All the other escapes accepted by normal bracketed character classes are accepted here as well; but unrecognized escapes that generate warnings in normal classes are fatal errors here.

This matches the English vowels plus the SPACE character. All the other escapes accepted by normal bracketed character classes are accepted here as well; but unrecognized escapes that generate warnings in normal classes are fatal errors here. (TBT)

All warnings from these class elements are fatal, as well as some practices that don't currently warn. For example you cannot say

All warnings from these class elements are fatal, as well as some practices that don't currently warn. For example you cannot say (TBT)

 /(?[ [ \xF ] ])/     # Syntax error!

You have to have two hex digits after a braceless \x (use a leading zero to make two). These restrictions are to lower the incidence of typos causing the class to not match what you thought it would.

You have to have two hex digits after a braceless \x (use a leading zero to make two). These restrictions are to lower the incidence of typos causing the class to not match what you thought it would. (TBT)

The final difference between regular bracketed character classes and these, is that it is not possible to get these to match a multi-character fold. Thus,

The final difference between regular bracketed character classes and these, is that it is not possible to get these to match a multi-character fold. Thus, (TBT)

 /(?[ [\xDF] ])/iu

does not match the string ss.

does not match the string ss. (TBT)

You don't have to enclose POSIX class names inside double brackets, hence both of the following work:

You don't have to enclose POSIX class names inside double brackets, hence both of the following work: (TBT)

 /(?[ [:word:] - [:lower:] ])/
 /(?[ [[:word:]] - [[:lower:]] ])/

Any contained POSIX character classes, including things like \w and \D respect the /a (and /aa) modifiers.

Any contained POSIX character classes, including things like \w and \D respect the /a (and /aa) modifiers. (TBT)

(?[ ]) is a regex-compile-time construct. Any attempt to use something which isn't knowable at the time the containing regular expression is compiled is a fatal error. In practice, this means just three limitiations:

(?[ ]) is a regex-compile-time construct. Any attempt to use something which isn't knowable at the time the containing regular expression is compiled is a fatal error. In practice, this means just three limitiations: (TBT)

  1. This construct cannot be used within the scope of use locale (or the /l regex modifier).

    This construct cannot be used within the scope of use locale (or the /l regex modifier). (TBT)

  2. Any user-defined property used must be already defined by the time the regular expression is compiled (but note that this construct can be used instead of such properties).

    Any user-defined property used must be already defined by the time the regular expression is compiled (but note that this construct can be used instead of such properties). (TBT)

  3. A regular expression that otherwise would compile using /d rules, and which uses this construct will instead use /u. Thus this construct tells Perl that you don't want /d rules for the entire regular expression containing it.

    A regular expression that otherwise would compile using /d rules, and which uses this construct will instead use /u. Thus this construct tells Perl that you don't want /d rules for the entire regular expression containing it. (TBT)

The /x processing within this class is an extended form. Besides the characters that are considered white space in normal /x processing, there are 5 others, recommended by the Unicode standard:

The /x processing within this class is an extended form. Besides the characters that are considered white space in normal /x processing, there are 5 others, recommended by the Unicode standard: (TBT)

 U+0085 NEXT LINE
 U+200E LEFT-TO-RIGHT MARK
 U+200F RIGHT-TO-LEFT MARK
 U+2028 LINE SEPARATOR
 U+2029 PARAGRAPH SEPARATOR

Note that skipping white space applies only to the interior of this construct. There must not be any space between any of the characters that form the initial (?[. Nor may there be space between the closing ]) characters.

Note that skipping white space applies only to the interior of this construct. There must not be any space between any of the characters that form the initial (?[. Nor may there be space between the closing ]) characters. (TBT)

Just as in all regular expressions, the pattern can can be built up by including variables that are interpolated at regex compilation time. Care must be taken to ensure that you are getting what you expect. For example:

Just as in all regular expressions, the pattern can can be built up by including variables that are interpolated at regex compilation time. Care must be taken to ensure that you are getting what you expect. For example: (TBT)

 my $thai_or_lao = '\p{Thai} + \p{Lao}';
 ...
 qr/(?[ \p{Digit} & $thai_or_lao ])/;

compiles to

compiles to (TBT)

 qr/(?[ \p{Digit} & \p{Thai} + \p{Lao} ])/;

But this does not have the effect that someone reading the code would likely expect, as the intersection applies just to \p{Thai}, excluding the Laotian. Pitfalls like this can be avoided by parenthesizing the component pieces:

But this does not have the effect that someone reading the code would likely expect, as the intersection applies just to \p{Thai}, excluding the Laotian. Pitfalls like this can be avoided by parenthesizing the component pieces: (TBT)

 my $thai_or_lao = '( \p{Thai} + \p{Lao} )';

But any modifiers will still apply to all the components:

But any modifiers will still apply to all the components: (TBT)

 my $lower = '\p{Lower} + \p{Digit}';
 qr/(?[ \p{Greek} & $lower ])/i;

matches upper case things. You can avoid surprises by making the components into instances of this construct by compiling them:

matches upper case things. You can avoid surprises by making the components into instances of this construct by compiling them: (TBT)

 my $thai_or_lao = qr/(?[ \p{Thai} + \p{Lao} ])/;
 my $lower = qr/(?[ \p{Lower} + \p{Digit} ])/;

When these are embedded in another pattern, what they match does not change, regardless of parenthesization or what modifiers are in effect in that outer pattern.

When these are embedded in another pattern, what they match does not change, regardless of parenthesization or what modifiers are in effect in that outer pattern. (TBT)

Due to the way that Perl parses things, your parentheses and brackets may need to be balanced, even including comments. If you run into any examples, please send them to perlbug@perl.org, so that we can have a concrete example for this man page.

Due to the way that Perl parses things, your parentheses and brackets may need to be balanced, even including comments. If you run into any examples, please send them to perlbug@perl.org, so that we can have a concrete example for this man page. (TBT)

We may change it so that things that remain legal uses in normal bracketed character classes might become illegal within this experimental construct. One proposal, for example, is to forbid adjacent uses of the same character, as in (?[ [aa] ]). The motivation for such a change is that this usage is likely a typo, as the second "a" adds nothing.

We may change it so that things that remain legal uses in normal bracketed character classes might become illegal within this experimental construct. One proposal, for example, is to forbid adjacent uses of the same character, as in (?[ [aa] ]). The motivation for such a change is that this usage is likely a typo, as the second "a" adds nothing. (TBT)