localtime EXPR

Converts a time as returned by the time function to a 9-element list with the time analyzed for the local time zone. Typically used as follows:

time 関数が返す時刻を、ローカルなタイムゾーンで測った時刻として、 9 要素の配列に変換します。 普通は、以下のようにして使います:

    #  0    1    2     3     4    5     6     7     8
    ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =

All list elements are numeric and come straight out of the C `struct tm'. $sec, $min, and $hour are the seconds, minutes, and hours of the specified time.

すべてのリスト要素は数値で、C の `struct tm' 構造体から 直接持ってきます。 $sec, $min, $hour は指定された時刻の秒、分、時です。

$mday is the day of the month and $mon the month in the range 0..11, with 0 indicating January and 11 indicating December. This makes it easy to get a month name from a list:

$mday は月の何日目か、$mon は月の値です; 月の値は 0..11 で、0 が 1 月、11 が 12 月です。 これにより、リストから月の名前を得るのが簡単になります:

    my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
    print "$abbr[$mon] $mday";
    # $mon=9, $mday=18 gives "Oct 18"

$year contains the number of years since 1900. To get a 4-digit year write:

$year は 1900 年からの年数を持ちます。 4 桁の年を得るには以下のようにします:

    $year += 1900;

To get the last two digits of the year (e.g., "01" in 2001) do:

西暦の下 2 桁(2001 年では "01")がほしい場合は以下のようにします:

    $year = sprintf("%02d", $year % 100);

$wday is the day of the week, with 0 indicating Sunday and 3 indicating Wednesday. $yday is the day of the year, in the range 0..364 (or 0..365 in leap years.)

$wday は曜日で、0 が日曜日、3 が木曜日です。 $yday はその年の何日目かで、0..364 の値を取ります (うるう年は 0..365 です。)

$isdst is true if the specified time occurs during Daylight Saving Time, false otherwise.

$isdst は指定された時刻が夏時間の場合は真、そうでなければ偽です。

If EXPR is omitted, localtime() uses the current time (as returned by time(3)).

EXPR が省略されると、localtime() は(time(3) によって返される) 現在時刻を使います。

In scalar context, localtime() returns the ctime(3) value:

スカラコンテキストでは、localtime() は ctime(3) の値を返します:

    $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"

The format of this scalar value is not locale-dependent but built into Perl. For GMT instead of local time use the gmtime builtin. See also the Time::Local module (for converting seconds, minutes, hours, and such back to the integer value returned by time()), and the POSIX module's strftime(3) and mktime(3) functions.

このスカラ値の形式はロケール依存 ではなく、Perl の組み込みの値です。 ローカル時刻ではなく GMT がほしい場合は gmtime 組み込み関数を 使ってください。 また、(秒、分、時などの形から、time() が返す値である 1970 年 1 月 1 日の真夜中からの秒数に変換する) Time::Local モジュール 及び POSIX モジュールで提供される strftime(3) と mktime(3) 関数も 参照してください。

To get somewhat similar but locale-dependent date strings, set up your locale environment variables appropriately (please see perllocale) and try for example:

似たような、しかしロケール依存の日付文字列がほしい場合は、 ロケール環境変数を適切に設定して(perllocale を参照してください)、 以下の例を試してください:

    use POSIX qw(strftime);
    $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
    # or for GMT formatted appropriately for your locale:
    $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;

Note that the %a and %b, the short forms of the day of the week and the month of the year, may not necessarily be three characters wide.

曜日と月の短い表現である %a%b は、3 文字とは限らないことに 注意してください。

The Time::gmtime and Time::localtime modules provide a convenient, by-name access mechanism to the gmtime() and localtime() functions, respectively.

Time::gmtime モジュールと Time::localtime モジュールは、それぞれ gmtime() 関数と localtime() 関数に、名前でアクセスする機構を提供する 便利なモジュールです。

For a comprehensive date and time representation look at the DateTime module on CPAN.

包括的な日付と時刻の表現については、CPAN の DateTime モジュールを 参照してください。

Portability issues: "localtime" in perlport.

移植性の問題: "localtime" in perlport