5.6.1

名前

perlfunc - Perl builtin functions

perlfunc - Perl 組み込み関数

説明

The functions in this section can serve as terms in an expression. They fall into two major categories: list operators and named unary operators. These differ in their precedence relationship with a following comma. (See the precedence table in perlop.) List operators take more than one argument, while unary operators can never take more than one argument. Thus, a comma terminates the argument of a unary operator, but merely separates the arguments of a list operator. A unary operator generally provides a scalar context to its argument, while a list operator may provide either scalar or list contexts for its arguments. If it does both, the scalar arguments will be first, and the list argument will follow. (Note that there can ever be only one such list argument.) For instance, splice() has three scalar arguments followed by a list, whereas gethostbyname() has four scalar arguments.

この節の関数は、式の中で項として使うことができます。 これらは、大きく 2 つに分けられます: リスト演算子と名前付き単項演算子です。 これらの違いは、その後に出て来るコンマとの優先順位の関係にあります。 (perlop の優先順位の表を参照してください。) リスト演算子は 2 個以上の引数をとるのに対して、 単項演算子が複数の引数をとることはありません。 つまり、コンマは単項演算子の引数の終わりとなりますが、 リスト演算子の場合には、引数の区切りでしかありません。 単項演算子は一般に、 引数に対してスカラコンテキストを与えるのに対して、 スカラ演算子の場合には、引数に対してスカラコンテキストを与える場合も、 リストコンテキストを与える場合もあります。 1 つのリスト演算子が 両方のコンテキストを与える場合には、スカラ引数がいくつか並び、 最後にリスト引数が 1 つ続きます。 (リスト引数は 1 つだけです。) たとえば、splice() は 3 つのスカラ引数に 1 つのリスト引数が続きます。 一方 gethostbyname() は 4 つのスカラ引数を持ちます。

In the syntax descriptions that follow, list operators that expect a list (and provide list context for the elements of the list) are shown with LIST as an argument. Such a list may consist of any combination of scalar arguments or list values; the list values will be included in the list as if each individual element were interpolated at that point in the list, forming a longer single-dimensional list value. Elements of the LIST should be separated by commas.

後に載せる構文記述では、リストをとり (そのリストの要素にリストコンテキストを与える) リスト演算子は、引数として LIST をとるように書いています。 そのようなリストには、任意のスカラ引数の組み合わせやリスト値を 含めることができ、リスト値はリストの中に、 個々の要素が展開されたように埋め込まれます。 1 次元の長いリスト値が形成されることになります。 LIST の要素は、コンマで区切られている必要があります。

Any function in the list below may be used either with or without parentheses around its arguments. (The syntax descriptions omit the parentheses.) If you use the parentheses, the simple (but occasionally surprising) rule is this: It looks like a function, therefore it is a function, and precedence doesn't matter. Otherwise it's a list operator or unary operator, and precedence does matter. And whitespace between the function and left parenthesis doesn't count--so you need to be careful sometimes:

以下のリストの関数はすべて、引数の前後の括弧は省略可能と なっています。 (構文記述では省略しています。) 括弧を使うときには、 単純な (しかし、ときには驚く結果となる) 規則が適用できます: 関数に見えるならば、それは関数で、優先順位は関係ありません。 そう見えなければ、それはリスト演算子か単項演算子で、優先順位が 関係します。 また、関数と開き括弧の間の空白は関係ありませんので、 ときに気を付けなければなりません:

    print 1+2+4;        # Prints 7.
    print(1+2) + 4;     # Prints 3.
    print (1+2)+4;      # Also prints 3!
    print +(1+2)+4;     # Prints 7.
    print ((1+2)+4);    # Prints 7.

If you run Perl with the -w switch it can warn you about this. For example, the third line above produces:

    print (...) interpreted as function at - line 1.
    Useless use of integer addition in void context at - line 1.

Perl に -w スイッチを付けて実行すれば、こういったものには 警告を出してくれます。 たとえば、上記の 3 つめは、以下のような警告が出ます:

         print (...) interpreted as function at - line 1.
         Useless use of integer addition in void context at - line 1.

A few functions take no arguments at all, and therefore work as neither unary nor list operators. These include such functions as time and endpwent. For example, time+86_400 always means time() + 86_400.

いくつかの関数は引数を全くとらないので、単項演算子としても リスト演算子としても動作しません。 このような関数としては timeendpwent があります。 例えば、time+86_400 は常に time() + 86_400 として扱われます。

For functions that can be used in either a scalar or list context, nonabortive failure is generally indicated in a scalar context by returning the undefined value, and in a list context by returning the null list.

スカラコンテキストでも、リストコンテキストでも使える関数は、 致命的でないエラーを示すために、スカラコンテキストでは 未定義値を返し、リストコンテキストでは空リストを返します。

Remember the following important rule: There is no rule that relates the behavior of an expression in list context to its behavior in scalar context, or vice versa. It might do two totally different things. Each operator and function decides which sort of value it would be most appropriate to return in scalar context. Some operators return the length of the list that would have been returned in list context. Some operators return the first value in the list. Some operators return the last value in the list. Some operators return a count of successful operations. In general, they do what you want, unless you want consistency.

以下に述べる重要なルールを忘れないで下さい: リストコンテキストでの 振る舞いとスカラコンテキストでの振る舞いの関係、あるいはその逆に ルールはありません。 2 つの全く異なったことがあります。 それぞれの演算子と関数は、スカラコンテキストでは、もっとも適切と 思われる値を返します。 リストコンテキストで返す時のリストの長さを返す演算子もあります。 リストの最初の値を返す演算子もあります。 リストの最後の値を返す演算子もあります。 成功した操作の数を返す演算子もあります。 一般的には、一貫性を求めない限り、こちらが求めることをします。

An named array in scalar context is quite different from what would at first glance appear to be a list in scalar context. You can't get a list like (1,2,3) into being in scalar context, because the compiler knows the context at compile time. It would generate the scalar comma operator there, not the list construction version of the comma. That means it was never a list to start with.

スカラコンテキストでの名前付き配列は、スカラコンテキストでのリストを 一目見たものとは全く違います。 コンパイラはコンパイル時にコンテキストを知っているので、 (1,2,3) のようなリストをスカラコンテキストで得ることはできません。 これはスカラコンマ演算子を生成し、コンマのリスト作成版ではありません。 これは初めからリストであることはないことを意味します。

In general, functions in Perl that serve as wrappers for system calls of the same name (like chown(2), fork(2), closedir(2), etc.) all return true when they succeed and undef otherwise, as is usually mentioned in the descriptions below. This is different from the C interfaces, which return -1 on failure. Exceptions to this rule are wait, waitpid, and syscall. System calls also set the special $! variable on failure. Other functions do not, except accidentally.

一般的に、同じ名前のシステムコールのラッパーとして動作する Perl の関数 (chown(2), fork(2), closedir(2) など)は、以下に述べるように、 成功時に真を返し、そうでなければ undef を返します。 これは失敗時に -1 を返す C のインターフェースとは違います。 このルールの例外は wait, waitpid, syscall です。 システムコールは失敗時に特殊変数 $! をセットします。 その他の関数は、事故を除いて、セットしません。

カテゴリ別の Perl 関数

Here are Perl's functions (including things that look like functions, like some keywords and named operators) arranged by category. Some functions appear in more than one place.

以下に、カテゴリ別の関数(キーワードや名前付き演算子のような、 関数のように見えるものも含みます)を示します。 複数の場所に現れる関数もあります。

Functions for SCALARs or strings

(スカラや文字列のための関数)

chomp, chop, chr, crypt, hex, index, lc, lcfirst, length, oct, ord, pack, q/STRING/, qq/STRING/, reverse, rindex, sprintf, substr, tr///, uc, ucfirst, y///

Regular expressions and pattern matching

(正規表現とパターンマッチング)

m//, pos, quotemeta, s///, split, study, qr//

Numeric functions

(数値関数)

abs, atan2, cos, exp, hex, int, log, oct, rand, sin, sqrt, srand

Functions for real @ARRAYs

(実配列のための関数)

pop, push, shift, splice, unshift

Functions for list data

(リストデータのための関数)

grep, join, map, qw/STRING/, reverse, sort, unpack

Functions for real %HASHes

(実ハッシュのための関数)

delete, each, exists, keys, values

Input and output functions

(入出力関数)

binmode, close, closedir, dbmclose, dbmopen, die, eof, fileno, flock, format, getc, print, printf, read, readdir, rewinddir, seek, seekdir, select, syscall, sysread, sysseek, syswrite, tell, telldir, truncate, warn, write

Functions for fixed length data or records

(固定長データやレコードのための関数)

pack, read, syscall, sysread, syswrite, unpack, vec

Functions for filehandles, files, or directories

(ファイルハンドル、ファイル、ディレクトリのための関数)

-X, chdir, chmod, chown, chroot, fcntl, glob, ioctl, link, lstat, mkdir, open, opendir, readlink, rename, rmdir, stat, symlink, umask, unlink, utime

Keywords related to the control flow of your perl program

(プログラムの流れを制御することに関連するキーワード)

caller, continue, die, do, dump, eval, exit, goto, last, next, redo, return, sub, wantarray

Keywords related to scoping

(スコープに関するキーワード)

caller, import, local, my, our, package, use

Miscellaneous functions

(さまざまな関数)

defined, dump, eval, formline, local, my, our, reset, scalar, undef, wantarray

Functions for processes and process groups

(プロセスとプロセスグループのための関数)

alarm, exec, fork, getpgrp, getppid, getpriority, kill, pipe, qx/STRING/, setpgrp, setpriority, sleep, system, times, wait, waitpid

Keywords related to perl modules

(perl モジュールに関するキーワード)

do, import, no, package, require, use

Keywords related to classes and object-orientedness

(クラスとオブジェクト指向に関するキーワード)

bless, dbmclose, dbmopen, package, ref, tie, tied, untie, use

Low-level socket functions

(低レベルソケット関数)

accept, bind, connect, getpeername, getsockname, getsockopt, listen, recv, send, setsockopt, shutdown, socket, socketpair

System V interprocess communication functions

(System V プロセス間通信関数)

msgctl, msgget, msgrcv, msgsnd, semctl, semget, semop, shmctl, shmget, shmread, shmwrite

Fetching user and group info

(ユーザーとグループの情報取得)

endgrent, endhostent, endnetent, endpwent, getgrent, getgrgid, getgrnam, getlogin, getpwent, getpwnam, getpwuid, setgrent, setpwent

Fetching network info

(ネットワーク情報取得)

endprotoent, endservent, gethostbyaddr, gethostbyname, gethostent, getnetbyaddr, getnetbyname, getnetent, getprotobyname, getprotobynumber, getprotoent, getservbyname, getservbyport, getservent, sethostent, setnetent, setprotoent, setservent

Time-related functions

(時刻に関する関数)

gmtime, localtime, time, times

Functions new in perl5

(perl5 で新設された関数)

abs, bless, chomp, chr, exists, formline, glob, import, lc, lcfirst, map, my, no, our, prototype, qx, qw, readline, readpipe, ref, sub*, sysopen, tie, tied, uc, ucfirst, untie, use

* - sub was a keyword in perl4, but in perl5 it is an operator, which can be used in expressions.

* - sub は perl4 ではキーワードですが、perl5 では演算子なので、 式で使えます。

Functions obsoleted in perl5

(perl5 では古いものとなった関数)

dbmclose, dbmopen

Portability

Perl was born in Unix and can therefore access all common Unix system calls. In non-Unix environments, the functionality of some Unix system calls may not be available, or details of the available functionality may differ slightly. The Perl functions affected by this are:

Perl は Unix 環境で生まれたので、全ての共通する Unix システムコールに アクセスします。非 Unix 環境では、いくつかの Unix システムコールの 機能が使えなかったり、使える機能の詳細が多少異なったりします。 これによる影響を受ける Perl 関数は以下のものです:

-X, binmode, chmod, chown, chroot, crypt, dbmclose, dbmopen, dump, endgrent, endhostent, endnetent, endprotoent, endpwent, endservent, exec, fcntl, flock, fork, getgrent, getgrgid, gethostent, getlogin, getnetbyaddr, getnetbyname, getnetent, getppid, getprgp, getpriority, getprotobynumber, getprotoent, getpwent, getpwnam, getpwuid, getservbyport, getservent, getsockopt, glob, ioctl, kill, link, lstat, msgctl, msgget, msgrcv, msgsnd, open, pipe, readlink, rename, select, semctl, semget, semop, setgrent, sethostent, setnetent, setpgrp, setpriority, setprotoent, setpwent, setservent, setsockopt, shmctl, shmget, shmread, shmwrite, socket, socketpair, stat, symlink, syscall, sysopen, system, times, truncate, umask, unlink, utime, wait, waitpid

For more information about the portability of these functions, see perlport and other available platform-specific documentation.

これらの関数の移植性に関するさらなる情報については、 perlport とその他のプラットホーム固有のドキュメントを参照して下さい。

Alphabetical Listing of Perl Functions

-X FILEHANDLE
-X EXPR
-X

A file test, where X is one of the letters listed below. This unary operator takes one argument, either a filename or a filehandle, and tests the associated file to see if something is true about it. If the argument is omitted, tests $_, except for -t, which tests STDIN. Unless otherwise documented, it returns 1 for true and '' for false, or the undefined value if the file doesn't exist. Despite the funny names, precedence is the same as any other named unary operator, and the argument may be parenthesized like any other unary operator. The operator may be any of:

X は以下にあげる文字で、ファイルテストを行ないます。 この単項演算子は、ファイル名かファイルハンドルを唯一の 引数として動作し、「あること」について真であるか否かを 判定した結果を返します。 引数が省略されると、-t では STDIN を調べますが、その他は $_ を調べます。 特に記述されていなければ、真として 1 を返し、偽として '' を返し、ファイルが存在しなければ、未定義値を返します。 みかけは変わっていますが、優先順位は名前付き単項演算子と同じで、 他の単項演算子と同じく、引数を括弧で括ることもできます。 演算子には以下のものがあります:

    -r  File is readable by effective uid/gid.
    -w  File is writable by effective uid/gid.
    -x  File is executable by effective uid/gid.
    -o  File is owned by effective uid.
    -r  ファイルが実効 uid/gid で読み出し可
    -w  ファイルが実効 uid/gid で書き込み可
    -x  ファイルが実効 uid/gid で実行可
    -o  ファイルが実効 uid の所有物
    -R  File is readable by real uid/gid.
    -W  File is writable by real uid/gid.
    -X  File is executable by real uid/gid.
    -O  File is owned by real uid.
    -R  ファイルが実 uid/gid で読み出し可
    -W  ファイルが実 uid/gid で書き込み可
    -X  ファイルが実 uid/gid で実行可
    -O  ファイルが実 uid の所有物
    -e  File exists.
    -z  File has zero size (is empty).
    -s  File has nonzero size (returns size in bytes).
    -e  ファイルが存在する
    -z  ファイルの大きさがゼロ(空)
    -s  ファイルの大きさがゼロ以外 (バイト単位での大きさを返す)
    -f  File is a plain file.
    -d  File is a directory.
    -l  File is a symbolic link.
    -p  File is a named pipe (FIFO), or Filehandle is a pipe.
    -S  File is a socket.
    -b  File is a block special file.
    -c  File is a character special file.
    -t  Filehandle is opened to a tty.
    -f  ファイルは通常ファイル
    -d  ファイルはディレクトリ
    -l  ファイルはシンボリックリンク
    -p  ファイルは名前付きパイプ (FIFO) またはファイルハンドルはパイプ
    -S  ファイルはソケット
    -b  ファイルはブロック特殊ファイル
    -c  ファイルはキャラクタ特殊ファイル
    -t  ファイルハンドルは tty にオープンされている
    -u  File has setuid bit set.
    -g  File has setgid bit set.
    -k  File has sticky bit set.
    -u  ファイルの setuid ビットがセットされている
    -g  ファイルの setgid ビットがセットされている
    -k  ファイルの sticky ビットがセットされている
    -T  ファイルは ASCII テキストファイル
    -B  ファイルは「バイナリ」ファイル (-T の反対)
    -M  Age of file in days when script started.
    -A  Same for access time.
    -C  Same for inode change time.
    -M  スクリプト実行開始時のファイル修正からの日数
    -A  同様にアクセスがあってからの日数
    -C  同様に inode が変更されてからの日数

Example:

例:

    while (<>) {
        chomp;
        next unless -f $_;      # ignore specials
        #...
    }

The interpretation of the file permission operators -r, -R, -w, -W, -x, and -X is by default based solely on the mode of the file and the uids and gids of the user. There may be other reasons you can't actually read, write, or execute the file. Such reasons may be for example network filesystem access controls, ACLs (access control lists), read-only filesystems, and unrecognized executable formats.

ファイルのパーミッション演算子 -r, -R, -w, -W, -x, -X の解釈は、ファイルのモードとユーザの実効/実 uid と 実効/実 gid のみから判断されます。 実際にファイルが読めたり、書けたり、実行できたりするためには、 別の条件が必要かもしれません。 条件としてはネットワークファイルシステムアクセスコントロール、 ACL(アクセスコントロールリスト)、読み込み専用ファイルシステム、 認識できない実行ファイルフォーマット、などがあります。

Also note that, for the superuser on the local filesystems, the -r, -R, -w, and -W tests always return 1, and -x and -X return 1 if any execute bit is set in the mode. Scripts run by the superuser may thus need to do a stat() to determine the actual mode of the file, or temporarily set their effective uid to something else.

ローカルファイルシステムのスーパーユーザには、 -r, -R, -w, -W に対して、常に 1 が返り、モード中の いずれかの実行許可ビットが立っていれば、-x, -X にも 1 が 返ることにも注意してください。 スーパーユーザが実行するスクリプトでは、ファイルのモードを調べるためには、 stat() を行なうか、実効 uid を一時的に別のものにする 必要があるでしょう。

If you are using ACLs, there is a pragma called filetest that may produce more accurate results than the bare stat() mode bits. When under the use filetest 'access' the above-mentioned filetests will test whether the permission can (not) be granted using the access() family of system calls. Also note that the -x and -X may under this pragma return true even if there are no execute permission bits set (nor any extra execute permission ACLs). This strangeness is due to the underlying system calls' definitions. Read the documentation for the filetest pragma for more information.

ACL を使っている場合は、生の stat() モードビットより 精度の高い結果を作成する filetest プラグマがあります。 use filetest 'access' とした場合、上述したファイルテストは システムコールの access() ファミリーを使って権限が与えられているか どうかをテストします。 また、このプラグマが指定されている場合、-x-X は たとえ実行許可ビット(または追加の実行許可 ACL)がセットされていない 場合でも真を返すことに注意してください。 この挙動は使用するシステムコールの定義によるものです。 さらなる情報については filetest プラグマのドキュメントを 参照してください。

Note that -s/a/b/ does not do a negated substitution. Saying -exp($foo) still works as expected, however--only single letters following a minus are interpreted as file tests.

-s/a/b は、置換演算 (s///) の符号反転ではありません。 しかし、-exp($foo) は期待どおりに動作します。 マイナス記号の後に英字が 1 字続くときにのみ、ファイルテストと 解釈されます。

The -T and -B switches work as follows. The first block or so of the file is examined for odd characters such as strange control codes or characters with the high bit set. If too many strange characters (>30%) are found, it's a -B file, otherwise it's a -T file. Also, any file containing null in the first block is considered a binary file. If -T or -B is used on a filehandle, the current stdio buffer is examined rather than the first block. Both -T and -B return true on a null file, or a file at EOF when testing a filehandle. Because you have to read a file to do the -T test, on most occasions you want to use a -f against the file first, as in next unless -f $file && -T $file.

ファイルテスト -T-B の動作原理は、次のようになっています。 ファイルの最初の数ブロックを調べて、変わった制御コードや 上位ビットがセットされているような、通常のテキストには現れない文字を探します。 そのような文字が、たくさん (>30%) 見つかるようであれば、 そのファイルは -B ファイルであると判断され、 それほど見つからなければ、-T ファイルとなります。 最初のブロックにヌル文字が含まれるファイルも、 バイナリファイルとみなされます。 -T-B をファイルハンドルに対して用いると、 最初のブロックを調べる代わりに、標準入出力バッファを調べます。 調べたファイルの中身が何もないときや、 ファイルハンドルを調べたときに EOF に達して いたときには、-T-B も「真」を返します。 -T テストをするためにはファイルを読み込まないといけないので、 たいていは next unless -f $file && -T $file というような形で まず調べたいファイルに対して -f を使いたいはずです。

If any of the file tests (or either the stat or lstat operators) are given the special filehandle consisting of a solitary underline, then the stat structure of the previous file test (or stat operator) is used, saving a system call. (This doesn't work with -t, and you need to remember that lstat() and -l will leave values in the stat structure for the symbolic link, not the real file.) Example:

どのファイルテスト (あるいは、statlstat) 演算子にも、 下線だけから成る特別なファイルハンドルを与えると、 前回のファイルテスト (や stat) の stat 構造体が使われ、 システムコールを省きます。 (-t には使えませんし、lstat() や -l は実ファイルではなく、 シンボリックリンクの情報を stat 構造体に残すことを 覚えておく必要があります。)例:

    print "Can do.\n" if -r $a || -w _ || -x _;

    stat($filename);
    print "Readable\n" if -r _;
    print "Writable\n" if -w _;
    print "Executable\n" if -x _;
    print "Setuid\n" if -u _;
    print "Setgid\n" if -g _;
    print "Sticky\n" if -k _;
    print "Text\n" if -T _;
    print "Binary\n" if -B _;
abs VALUE
abs

Returns the absolute value of its argument. If VALUE is omitted, uses $_.

引数の絶対値を返します。 VALUE が省略された場合は、$_ を使います。

accept NEWSOCKET,GENERICSOCKET

Accepts an incoming socket connect, just as the accept(2) system call does. Returns the packed address if it succeeded, false otherwise. See the example in "Sockets: Client/Server Communication" in perlipc.

accept(2) システムコールと同様に、着信するソケットの接続を受け付けます。 成功時にはパックされたアドレスを返し、失敗すれば偽を返します。 "Sockets: Client/Server Communication" in perlipc の 例を参照してください。

On systems that support a close-on-exec flag on files, the flag will be set for the newly opened file descriptor, as determined by the value of $^F. See "$^F" in perlvar.

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 フラグは $^F の値で決定される、新しくオープンされたファイル記述子に対して セットされます。"$^F" in perlvar を参照してください。

alarm SECONDS
alarm

Arranges to have a SIGALRM delivered to this process after the specified number of seconds have elapsed. If SECONDS is not specified, the value stored in $_ is used. (On some machines, unfortunately, the elapsed time may be up to one second less than you specified because of how seconds are counted.) Only one timer may be counting at once. Each call disables the previous timer, and an argument of 0 may be supplied to cancel the previous timer without starting a new one. The returned value is the amount of time remaining on the previous timer.

指定した秒数が経過した後に、自プロセスに SIGALRM が 送られてくるようにします。SECONDS が指定されていない場合は、 $_に格納されている値を使います。 (マシンによっては、秒の 数え方が異なるため、指定した秒数よりも最大で 1 秒少ない経過時間となります。) 一度には 1 つのタイマだけが設定可能です。 呼び出しを行なう度に、以前のタイマを無効にしますし、 新しくタイマを起動しないで以前のタイマをキャンセルするために 引数に 0 を指定して呼び出すことができます。 以前のタイマの残り時間が、返り値となります。

For delays of finer granularity than one second, you may use Perl's four-argument version of select() leaving the first three arguments undefined, or you might be able to use the syscall interface to access setitimer(2) if your system supports it. The Time::HiRes module from CPAN may also prove useful.

1 秒より精度の高いスリープを行なうには、 Perl の 4 引数版 select() を最初の 3 引数を未定義にして使うか、 setitimer(2) をサポートしているシステムでは、Perl の syscall インタフェースを使ってアクセスすることができます。 CPAN の Time::HiRes モジュールも有用でしょう。

It is usually a mistake to intermix alarm and sleep calls. (sleep may be internally implemented in your system with alarm)

alarmsleep を混ぜて使うのは普通は間違いです。 (sleep は内部的に alarm を使って内部的に実装されているかもしれません)

If you want to use alarm to time out a system call you need to use an eval/die pair. You can't rely on the alarm causing the system call to fail with $! set to EINTR because Perl sets up signal handlers to restart system calls on some systems. Using eval/die always works, modulo the caveats given in "Signals" in perlipc.

alarm をシステムコールの時間切れのために使いたいなら、 eval/die のペアで使う必要があります。 システムコールが失敗したときに $!EINTR がセットされることに 頼ってはいけません。なぜならシステムによっては Perl は システムコールを再開するためにシグナルハンドラを設定するからです。 eval/die は常にうまく動きます。 注意点については "Signals" in perlipc を参照して下さい。

    eval {
        local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
        alarm $timeout;
        $nread = sysread SOCKET, $buffer, $size;
        alarm 0;
    };
    if ($@) {
        die unless $@ eq "alarm\n";   # propagate unexpected errors
        # timed out
    }
    else {
        # didn't
    }
atan2 Y,X

Returns the arctangent of Y/X in the range -PI to PI.

-πからπの範囲で Y/X の逆正接を返します。

For the tangent operation, you may use the Math::Trig::tan function, or use the familiar relation:

正接を求めたいときは、Math::Trig::tan を使うか、 以下のよく知られた関係を使ってください。

    sub tan { sin($_[0]) / cos($_[0])  }
bind SOCKET,NAME

Binds a network address to a socket, just as the bind system call does. Returns true if it succeeded, false otherwise. NAME should be a packed address of the appropriate type for the socket. See the examples in "Sockets: Client/Server Communication" in perlipc.

bind(2) システムコールと同様に、ネットワークアドレスをソケットに結び付けます。 成功時には真を返し、失敗時には偽を返します。 NAME は、ソケットに対する、適切な型のパックされたアドレスでなければなりません。 "Sockets: Client/Server Communication" in perlipc の例を参照してください。

binmode FILEHANDLE, DISCIPLINE
binmode FILEHANDLE

Arranges for FILEHANDLE to be read or written in "binary" or "text" mode on systems where the run-time libraries distinguish between binary and text files. If FILEHANDLE is an expression, the value is taken as the name of the filehandle. DISCIPLINE can be either of ":raw" for binary mode or ":crlf" for "text" mode. If the DISCIPLINE is omitted, it defaults to ":raw".

バイナリファイルとテキストファイルを区別する OS において、 FILEHANDLE を「バイナリ」または「テキスト」で読み書きするように 指定します。 FILEHANDLE が式である場合には、その式の値がファイルハンドルの 名前として使われます。 DISCIPLINE はバイナリモードを示す ":raw" か テキストモードを示す ":crlf" のどちらかです。 DISCIPLINE を省略すると、デフォルトとして ":raw" が使われます。

binmode() should be called after open() but before any I/O is done on the filehandle.

binmode() は open() の後、ファイルハンドルに対する入出力が 行われる前に呼び出されるべきです。

On many systems binmode() currently has no effect, but in future, it will be extended to support user-defined input and output disciplines. On some systems binmode() is necessary when you're not working with a text file. For the sake of portability it is a good idea to always use it when appropriate, and to never use it when it isn't appropriate.

多くのシステムでは現在のところ binmode() は何の効果もありませんが、 将来ユーザーが定義した入出力機能に対応するように拡張される予定です。 テキストファイルでないものを扱う場合に binmode() が必要な システムもあります。 移植性のために、適切なときには常にこれを使い、適切でないときには 決して使わないというのは良い考えです。

In other words: Regardless of platform, use binmode() on binary files, and do not use binmode() on text files.

言い換えると: プラットフォームに関わらず、 バイナリファイルに対しては binmode() を使ってください。 テキストファイルには binmode() を使わないでください。

The open pragma can be used to establish default disciplines. See open.

open プラグマを使って、デフォルトの動作を設定できます。 open を参照して下さい。

The operating system, device drivers, C libraries, and Perl run-time system all work together to let the programmer treat a single character (\n) as the line terminator, irrespective of the external representation. On many operating systems, the native text file representation matches the internal representation, but on some platforms the external representation of \n is made up of more than one character.

オペレーションシステム、デバイスドライバ、C ライブラリ、 Perl ランタイムシステムは全て、プログラマが外部表現に関わらず 1 文字 (\n) を行終端として扱えるように協調作業します。 多くのオペレーティングシステムでは、ネイティブテキストファイル表現は 内部表現と同じですが、\n の外部表現が複数文字になる プラットフォームもあります。

Mac OS and all variants of Unix use a single character to end each line in the external representation of text (even though that single character is not necessarily the same across these platforms). Consequently binmode() has no effect on these operating systems. In other systems like VMS, MS-DOS and the various flavors of MS-Windows your program sees a \n as a simple \cJ, but what's stored in text files are the two characters \cM\cJ. That means that, if you don't use binmode() on these systems, \cM\cJ sequences on disk will be converted to \n on input, and any \n in your program will be converted back to \cM\cJ on output. This is what you want for text files, but it can be disastrous for binary files.

Mac OS と全ての Unix 系はテキストの外部表現として各行の末尾に 1 つの文字を 使っています(その文字はプラットフォームによって異なる場合もあります)。 その結果、binmode() はこれらの OS では何の効果もありません。 VMS, MS-DOS, MS-Windows 系といったその他のシステムでは、 プログラムからは \n は単純に \cJ に見えますが、 テキストファイルとして保存される場合は \cM\cJ の 2 文字になります。 つまり、もしこれらのシステムで binmode() を使わないと、 ディスク上の \cM\cJ という並びは入力時に \n に変換され、 プログラムが出力した全ての \n\cM\cJ に逆変換されます。 これはテキストファイルの場合は思い通りの結果でしょうが、 バイナリファイルの場合は悲惨です。

Another consequence of using binmode() (on some systems) is that special end-of-file markers will be seen as part of the data stream. For systems from the Microsoft family this means that if your binary data contains \cZ, the I/O subsystem will regard it as the end of the file, unless you use binmode().

binmode() を(いくつかのシステムで)使うことによるその他の作用としては、 特別なファイル終端マーカーがデータストリームの一部として 見られることです。 Microsoft ファミリーのシステムでは、binmode() を使っていないと もしバイナリデータに \cZ が含まれていたときに、I/O サブシステムが これをファイル終端とみなすことを意味します。

binmode() is not only important for readline() and print() operations, but also when using read(), seek(), sysread(), syswrite() and tell() (see perlport for more details). See the $/ and $\ variables in perlvar for how to manually set your input and output line-termination sequences.

binmode() は readline() と print() 操作にだけではなく、 read(), seek(), sysread(), syswrite(), tell() を使うときにも重要です (詳細は perlport を参照してください)。 入出力の行端末シーケンスを手動でセットする方法については perlvar$/ 変数と $\ 変数を参照してください。

bless REF,CLASSNAME
bless REF

This function tells the thingy referenced by REF that it is now an object in the CLASSNAME package. If CLASSNAME is omitted, the current package is used. Because a bless is often the last thing in a constructor, it returns the reference for convenience. Always use the two-argument version if the function doing the blessing might be inherited by a derived class. See perltoot and perlobj for more about the blessing (and blessings) of objects.

この関数は、REF で渡された オブジェクトに対し、 CLASSNAME 内のオブジェクトとなったことを伝えます。 CLASSNAME が省略された場合には、その時点のパッケージとなります。 bless は通常、コンストラクタの最後に置かれますので、 簡便のためにそのリファレンスを返します。 bless される関数が派生クラスによって継承される場合は、 常に 2 引数版を使ってください。 オブジェクトの bless (や再 bless) について、 詳しくは perltootperlobj を参照してください。

Consider always blessing objects in CLASSNAMEs that are mixed case. Namespaces with all lowercase names are considered reserved for Perl pragmata. Builtin types have all uppercase names, so to prevent confusion, you may wish to avoid such package names as well. Make sure that CLASSNAME is a true value.

大文字小文字が混じっている CLASSNAME のオブジェクトは常に bless することを 考慮してください。 全て小文字の名前を持つ名前空間は Perl プラグマのために予約されています。 組み込みの型は全て大文字の名前を持ちますので、混乱を避けるために、 パッケージ名としてこのような名前は避けるべきです。 CLASSNAME は真の値を持つようにしてください。

"Perl Modules" in perlmod を参照して下さい。

caller EXPR
caller

Returns the context of the current subroutine call. In scalar context, returns the caller's package name if there is a caller, that is, if we're in a subroutine or eval or require, and the undefined value otherwise. In list context, returns

その時点のサブルーチン呼び出しのコンテキストを返します。 スカラコンテキストでは、呼び元がある場合 (サブルーチン、evalrequire の中にいるとき) には 呼び出し元のパッケージ名を返し、その他のときには未定義値を返します。 リストコンテキストでは、以下を返します:

    ($package, $filename, $line) = caller;

With EXPR, it returns some extra information that the debugger uses to print a stack trace. The value of EXPR indicates how many call frames to go back before the current one.

EXPR を付けると、デバッガがスタックトレースを表示するために使う情報を返します。 EXPR の値は、現状から数えて、 いくつ前のコールフレームまで戻るかを示します。

    ($package, $filename, $line, $subroutine, $hasargs,
    $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);

Here $subroutine may be (eval) if the frame is not a subroutine call, but an eval. In such a case additional elements $evaltext and $is_require are set: $is_require is true if the frame is created by a require or use statement, $evaltext contains the text of the eval EXPR statement. In particular, for an eval BLOCK statement, $filename is (eval), but $evaltext is undefined. (Note also that each use statement creates a require frame inside an eval EXPR) frame. $hasargs is true if a new instance of @_ was set up for the frame. $hints and $bitmask contain pragmatic hints that the caller was compiled with. The $hints and $bitmask values are subject to change between versions of Perl, and are not meant for external use.

もしフレームがサブルーチン呼び出しではなく eval だった場合、この $subroutine は (eval) になります。 この場合、追加の要素である $evaltext と $is_require がセットされます: $is_require はフレームが require または use で作られた場合に 真になり、$evaltext は eval EXPR のテキストが入ります。 特に、eval BLOCK の場合、$filename は (eval) になりますが、 $evaltext は未定義値になります。 (それぞれの useeval EXPR の中で require フレームを作ることに 注意してください。) $hasargs はこのフレーム用に @_ の新しい実体が設定された場合に真となります。 $hints$bitmask は caller がコンパイルされたときの 実際的なヒントを含みます。 $hints$bitmask は Perl のバージョンによって変更される 可能性があるので、外部での使用を想定していません。

Furthermore, when called from within the DB package, caller returns more detailed information: it sets the list variable @DB::args to be the arguments with which the subroutine was invoked.

さらに、DB パッケージの中から呼ばれた場合は、caller は より詳細な情報を返します。 サブルーチンが起動されたときの引数を変数 @DB::args に設定します。

Be aware that the optimizer might have optimized call frames away before caller had a chance to get the information. That means that caller(N) might not return information about the call frame you expect it do, for N > 1. In particular, @DB::args might have information from the previous time caller was called.

caller が情報を得る前にオプティマイザが呼び出しフレームを最適化して しまうかもしれないことに注意してください。 これは、caller(N)N > 1 のとき、 あなたが予測した呼び出しフレームの情報を返さないかもしれないことを意味します。 特に、@DB::argscaller が前回呼び出された時の情報を 持っているかもしれません。

chdir EXPR

Changes the working directory to EXPR, if possible. If EXPR is omitted, changes to the directory specified by $ENV{HOME}, if set; if not, changes to the directory specified by $ENV{LOGDIR}. If neither is set, chdir does nothing. It returns true upon success, false otherwise. See the example under die.

(可能であれば、) カレントディレクトリを EXPR に移します。 EXPR を指定しないと、$ENV{HOME} が設定されていれば、 そのディレクトリに移ります。 そうでなく、$ENV{LOGDIR}が設定されていれば、そのディレクトリに移ります。 どちらも設定されていなければ、chdir は何もしません。 成功時には真を返し、そうでなければ偽を返します。 die の項の例を参照してください。

chmod LIST

Changes the permissions of a list of files. The first element of the list must be the numerical mode, which should probably be an octal number, and which definitely should not a string of octal digits: 0644 is okay, '0644' is not. Returns the number of files successfully changed. See also "oct", if all you have is a string.

LIST に含まれるファイルの、パーミッションを変更します。 LIST の最初の要素は、数値表現のモードでなければなりません。 恐らく 8 進表記の数であるべきでしょう。しかし、8 進表記の文字列ではいけません0644 は OK ですが、 '0644' はだめ、ということです。 変更に成功したファイルの数を返します。 文字列を使いたい場合は、"oct" を参照してください。

    $cnt = chmod 0755, 'foo', 'bar';
    chmod 0755, @executables;
    $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
                                             # --w----r-T
    $mode = '0644'; chmod oct($mode), 'foo'; # this is better
    $mode = 0644;   chmod $mode, 'foo';      # this is best

You can also import the symbolic S_I* constants from the Fcntl module:

シンボリックな S_I* 定数を Fcntl モジュールからインポートすることもできます。

    use Fcntl ':mode';

    chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
    # This is identical to the chmod 0755 of the above example.
chomp VARIABLE
chomp LIST
chomp

This safer version of "chop" removes any trailing string that corresponds to the current value of $/ (also known as $INPUT_RECORD_SEPARATOR in the English module). It returns the total number of characters removed from all its arguments. It's often used to remove the newline from the end of an input record when you're worried that the final record may be missing its newline. When in paragraph mode ($/ = ""), it removes all trailing newlines from the string. When in slurp mode ($/ = undef) or fixed-length record mode ($/ is a reference to an integer or the like, see perlvar) chomp() won't remove anything. If VARIABLE is omitted, it chomps $_. Example:

より安全な chop (以下を参照してください) です。 $/ (English モジュールでは、$INPUT_RECORD_SEPARATOR とも言う) のその時点の値に対応する行末文字を削除します。 全ての引数から削除した文字数の合計を返します。 入力レコードから、改行を削除したいのだけれど、最後のレコードには改行が 入っているのかわからないような場合に、使用できます。 段落モード ($/ = "") では、レコードの最後の改行をすべて取り除きます。 吸い込みモード ($/ = undef) や 固定長レコードモード ($/ が整数へのリファレンスや類似のものの場合。perlvarを参照してください) では、chomp() は何も取り除きません。 VARIABLE が省略されると、$_ を対象として chomp します。 例:

    while (<>) {
        chomp;  # avoid \n on last field
        @array = split(/:/);
        # ...
    }
    while (<>) {
        chomp;  # 最後のフィールドの \n を避ける
        @array = split(/:/);
        #...
    }

If VARIABLE is a hash, it chomps the hash's values, but not its keys.

VARIABLE がハッシュなら、ハッシュのキーではなく値について chomp します。

You can actually chomp anything that's an lvalue, including an assignment:

左辺値であれば、代入を含めて、任意のものを chomp できます:

    chomp($cwd = `pwd`);
    chomp($answer = <STDIN>);

If you chomp a list, each element is chomped, and the total number of characters removed is returned.

リストを chomp すると、個々の要素が chomp され、 削除された文字数の合計が返されます。

chop VARIABLE
chop LIST
chop

Chops off the last character of a string and returns the character chopped. It is much more efficient than s/.$//s because it neither scans nor copies the string. If VARIABLE is omitted, chops $_. If VARIABLE is a hash, it chops the hash's values, but not its keys.

文字列の最後の文字を切り捨てて、その切り取った文字を返します。 文字列の検索もコピーも行ないませんので s/.$//s よりも、ずっと効率的です。 VARIABLE が省略されると、$_ を対象として chop します。 VARIABLE がハッシュの場合、ハッシュの value を chop しますが、 key は chop しません。

You can actually chop anything that's an lvalue, including an assignment.

実際のところ、代入を含む左辺値となりうるなんでも chop できます。

If you chop a list, each element is chopped. Only the value of the last chop is returned.

リストを chop すると、個々の要素が chop されます。 最後の chop の値だけが返されます。

Note that chop returns the last character. To return all but the last character, use substr($string, 0, -1).

chop は最後の文字を返すことに注意してください。 最後以外の全ての文字を返すためには、substr($string, 0, -1) を 使ってください。

chown LIST

Changes the owner (and group) of a list of files. The first two elements of the list must be the numeric uid and gid, in that order. A value of -1 in either position is interpreted by most systems to leave that value unchanged. Returns the number of files successfully changed.

LIST に含まれるファイルの所有者 (とグループ) を変更します。 LIST の最初の 2 つの要素には、数値表現 の uid と gid を この順序で与えなければなりません。 どちらかの値を -1 にすると、ほとんどのシステムではその値は 変更しないと解釈します。 変更に成功したファイルの数が返されます。

    $cnt = chown $uid, $gid, 'foo', 'bar';
    chown $uid, $gid, @filenames;

Here's an example that looks up nonnumeric uids in the passwd file:

passwd ファイルから数値表現でない uid を検索する例を 示します:

    print "User: ";
    chomp($user = <STDIN>);
    print "Files: ";
    chomp($pattern = <STDIN>);

    ($login,$pass,$uid,$gid) = getpwnam($user)
        or die "$user not in passwd file";

    @ary = glob($pattern);      # expand filenames
    chown $uid, $gid, @ary;

On most systems, you are not allowed to change the ownership of the file unless you're the superuser, although you should be able to change the group to any of your secondary groups. On insecure systems, these restrictions may be relaxed, but this is not a portable assumption. On POSIX systems, you can detect this condition this way:

ほとんどのシステムでは、スーパーユーザーだけがファイルの所有者を 変更できますが、グループは実行者の副グループに変更できるべきです。 安全でないシステムでは、この制限はゆるめられています。 しかしこれは移植性のある仮定ではありません。 POSIX システムでは、以下のようにしてこの条件を検出できます:

    use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
    $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
chr NUMBER
chr

Returns the character represented by that NUMBER in the character set. For example, chr(65) is "A" in either ASCII or Unicode, and chr(0x263a) is a Unicode smiley face (but only within the scope of a use utf8). For the reverse, use "ord". See utf8 for more about Unicode.

特定の文字セットでの NUMBER で表わされる文字を返します。 たとえば、chr(65) は ASCII と Unicode の両方で "A" となります。 chr(0x263a) は Unicode のスマイリーフェイスです (ただし use utf8 のスコープ内のみです)。 逆を行うためには、"ord" を参照してください。 Unicode についてもっと知りたいなら、utf8 を参照してください。

If NUMBER is omitted, uses $_.

NUMBER が省略された場合、$_ を使います。

chroot FILENAME
chroot

This function works like the system call by the same name: it makes the named directory the new root directory for all further pathnames that begin with a / by your process and all its children. (It doesn't change your current working directory, which is unaffected.) For security reasons, this call is restricted to the superuser. If FILENAME is omitted, does a chroot to $_.

同じ名前のシステムコールと同じことをします。 現在のプロセス及び子プロセスに対して、/で始まるパス名に関して 指定されたディレクトリを新しいルートディレクトリとして扱います。 (これはカレントディレクトリを変更しません。カレントディレクトリはそのままです)。 セキュリティ上の理由により、この呼び出しはスーパーユーザーしか行えません。 FILENAME を省略すると、$_chroot します。

close FILEHANDLE
close

Closes the file or pipe associated with the file handle, returning true only if stdio successfully flushes buffers and closes the system file descriptor. Closes the currently selected filehandle if the argument is omitted.

FILEHANDLE に対応したファイルまたはパイプをクローズします。 標準入出力が正常にバッファのフラッシュを行なって、 ファイル記述子のクローズしたときにのみ「真」を返します。 引数が省略された場合、現在選択されているファイルハンドルをクローズします。

You don't have to close FILEHANDLE if you are immediately going to do another open on it, because open will close it for you. (See open.) However, an explicit close on an input file resets the line counter ($.), while the implicit close done by open does not.

クローズしてすぐにまた、同じファイルハンドルに 対してオープンを行なう場合には、open が自動的に close を行ないますので、close FILEHANDLE する必要はありません (open を参照してください)。 ただし、明示的にクローズを行なったときにのみ入力ファイルの 行番号 ($.) のリセットが行なわれ、open によって行なわれる 暗黙の closeでは行なわれません。

If the file handle came from a piped open close will additionally return false if one of the other system calls involved fails or if the program exits with non-zero status. (If the only problem was that the program exited non-zero $! will be set to 0.) Closing a pipe also waits for the process executing on the pipe to complete, in case you want to look at the output of the pipe afterwards, and implicitly puts the exit status value of that command into $?.

ファイルハンドルがパイプつきオープンなら、 close はその他のシステムコールが失敗したり プログラムが非ゼロのステータスで終了した場合にも偽を返します (プログラムが非ゼロで終了しただけの場合は、$!0にセットされます)。 後でパイプの出力を見たい場合のために、 パイプのクローズでは、パイプ上で実行されている プロセスの完了を待ちます。 また自動的にコマンドのステータス値を $? に設定します。

Prematurely closing the read end of a pipe (i.e. before the process writing to it at the other end has closed it) will result in a SIGPIPE being delivered to the writer. If the other end can't handle that, be sure to read all the data before closing the pipe.

途中で(つまり、書き込み側が閉じる前に) パイプの読み込み側が閉じた場合、 書き込み側に SIGPIPE が配送されます。 書き込み側がこれを扱えない場合、パイプを閉じる前に 確実に全てのデータが読み込まれるようにする必要があります。

Example:

例:

    open(OUTPUT, '|sort >foo')  # pipe to sort
        or die "Can't start sort: $!";
    #...                        # print stuff to output
    close OUTPUT                # wait for sort to finish
        or warn $! ? "Error closing sort pipe: $!"
                   : "Exit status $? from sort";
    open(INPUT, 'foo')          # get sort's results
        or die "Can't open 'foo' for input: $!";

FILEHANDLE may be an expression whose value can be used as an indirect filehandle, usually the real filehandle name.

FILEHANDLE は式でもかまいません。この場合、値は間接ファイルハンドルと して扱われ、普通は実際のファイルハンドル名です。

closedir DIRHANDLE

Closes a directory opened by opendir and returns the success of that system call.

opendir でオープンしたディレクトリをクローズし、 システムコールの返り値を返します。

DIRHANDLE may be an expression whose value can be used as an indirect dirhandle, usually the real dirhandle name.

DIRHANDLE は式でもかまいません。この場合、値は相対ディレクトリハンドルと して扱われ、普通は実際のディレクトリハンドル名です。

connect SOCKET,NAME

Attempts to connect to a remote socket, just as the connect system call does. Returns true if it succeeded, false otherwise. NAME should be a packed address of the appropriate type for the socket. See the examples in "Sockets: Client/Server Communication" in perlipc.

connect(2) システムコールと同様に、リモートソケットへの接続を試みます。 成功時には真を返し、失敗時には偽を返します。 NAME は、ソケットに対する、適切な型のパックされた アドレスでなければなりません。 "Sockets: Client/Server Communication" in perlipc の例を参照してください。

continue BLOCK

Actually a flow control statement rather than a function. If there is a continue BLOCK attached to a BLOCK (typically in a while or foreach), it is always executed just before the conditional is about to be evaluated again, just like the third part of a for loop in C. Thus it can be used to increment a loop variable, even when the loop has been continued via the next statement (which is similar to the C continue statement).

実際には関数ではなく、実行制御文です。 continue BLOCK が BLOCK (典型的には while または foreach の中)にあると、 これは条件文が再評価される直前に常に実行されます。 これは C における for ループの 3 番目の部分と同様です。 従って、これは next 文 (これは C の continue 文と似ています)を使ってループが繰り返されるときでも ループ変数を増やしたいときに使えます。

last, next, or redo may appear within a continue block. last and redo will behave as if they had been executed within the main block. So will next, but since it will execute a continue block, it may be more entertaining.

last, next, redocontinue ブロック内に現れる可能性があります。 lastredo はメインブロックの中で実行されたのと同じように振舞います。 next の場合は、continue ブロックを実行することになるので、 より面白いことになります。

    while (EXPR) {
        ### redo always comes here
        do_something;
    } continue {
        ### next always comes here
        do_something_else;
        # then back the top to re-check EXPR
    }
    ### last always comes here

Omitting the continue section is semantically equivalent to using an empty one, logically enough. In that case, next goes directly back to check the condition at the top of the loop.

continue 節を省略するのは、文法的には空の節を指定したのと同じで、 論理的には十分です。 この場合、next は直接ループ先頭の条件チェックに戻ります。

cos EXPR
cos

Returns the cosine of EXPR (expressed in radians). If EXPR is omitted, takes cosine of $_.

(ラジアンで示した) EXPR の余弦を返します。 EXPR が省略されたときには、$_ の余弦を取ります。

For the inverse cosine operation, you may use the Math::Trig::acos() function, or use this relation:

逆余弦を求めるためには、Math::Trig::acos() 関数を使うか、 以下の関係を使ってください。

    sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
crypt PLAINTEXT,SALT

Encrypts a string exactly like the crypt(3) function in the C library (assuming that you actually have a version there that has not been extirpated as a potential munition). This can prove useful for checking the password file for lousy passwords, amongst other things. Only the guys wearing white hats should do this.

C ライブラリの crypt(3) 関数と全く同じように、文字列を暗号化します (一時的な必需品として、まだ絶滅していないバージョンを持っていると仮定しています)。 パスワードファイルの中で、 あまり良くないものをチェックするために使うことができます。 公正な人だけが、これを行なうべきです。

Note that crypt is intended to be a one-way function, much like breaking eggs to make an omelette. There is no (known) corresponding decrypt function. As a result, this function isn't all that useful for cryptography. (For that, see your nearby CPAN mirror.)

crypt は一方向関数を指向していることに注意してください。 オムレツを作るのに卵を割るようなものです。 (知られている限り)対応する復号化関数はありません。 結果として、この関数はあらゆる暗号に対して有効というわけではありません (このためには、お近くの CPAN を参照してください)。

When verifying an existing encrypted string you should use the encrypted text as the salt (like crypt($plain, $crypted) eq $crypted). This allows your code to work with the standard crypt and with more exotic implementations. When choosing a new salt create a random two character string whose characters come from the set [./0-9A-Za-z] (like join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]).

すでにある暗号化された文字列の検証するには、暗号化されたテキストを (crypt($plain, $crypted) eq $crypted のようにして)salt として使います。 これによって標準的な crypt や、より風変わりな実装で動作します。 新しい salt を選択する場合は、集合 [./0-9A-Za-z] から (join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64] のようにして) ランダムに2 つの文字を選びます。

Here's an example that makes sure that whoever runs this program knows their own password:

プログラムを実行する人が、 自分のパスワードを知っていることを確認する例です:

    $pwd = (getpwuid($<))[1];

    system "stty -echo";
    print "Password: ";
    chomp($word = <STDIN>);
    print "\n";
    system "stty echo";

    if (crypt($word, $pwd) ne $pwd) {
        die "Sorry...\n";
    } else {
        print "ok\n";
    }

Of course, typing in your own password to whoever asks you for it is unwise.

もちろん、自分自身のパスワードを誰にでも入力するのは賢明ではありません。

The crypt function is unsuitable for encrypting large quantities of data, not least of all because you can't get the information back. Look at the by-module/Crypt and by-module/PGP directories on your favorite CPAN mirror for a slew of potentially useful modules.

crypt 関数は大量のデータの暗号化には向いていません。 これは情報を戻せないという理由だけではありません。 あなたのお好みの CPAN ミラー の by-module/Cryptby-module/PGP ディレクトリを見れば、あなたの役に立ちそうなモジュールが大量にあります。

dbmclose HASH

[This function has been largely superseded by the untie function.]

Breaks the binding between a DBM file and a hash.

[この関数は、untie 関数に大きくとって代わられました。]

DBM ファイルとハッシュの連結をはずします。

dbmopen HASH,DBNAME,MASK

[This function has been largely superseded by the tie function.]

This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a hash. HASH is the name of the hash. (Unlike normal open, the first argument is not a filehandle, even though it looks like one). DBNAME is the name of the database (without the .dir or .pag extension if any). If the database does not exist, it is created with protection specified by MASK (as modified by the umask). If your system supports only the older DBM functions, you may perform only one dbmopen in your program. In older versions of Perl, if your system had neither DBM nor ndbm, calling dbmopen produced a fatal error; it now falls back to sdbm(3).

[この関数は、tie 関数に大きくとって代わられました。]

dbm(3), ndbm(3), sdbm(3), gdbm(3) ファイルまたは Berkeley DB ファイルを連想配列に結び付けます。 HASH は、その連想配列の名前です。 (普通の open とは違って、最初の引数はファイルハンドル ではありません。まあ、似たようなものですが。) DBNAME は、データベースの名前です (拡張子の .dir や .pag はもしあってもつけません)。 データベースが存在しなければ、MODE MASK (を umask で修正したもの) で 指定されたモードで作られます。 古い DBM 関数のみをサポートしているシステムでは、プログラム中で 1 度だけ dbmopen() を実行することができます。 昔のバージョンの Perl では、DBM も ndbm も持っていないシステムでは、 dbmopen() を呼び出すと致命的エラーになります。 現在では sdbm(3) にフォールバックします。

If you don't have write access to the DBM file, you can only read hash variables, not set them. If you want to test whether you can write, either use file tests or try setting a dummy hash entry inside an eval, which will trap the error.

DBM ファイルに対して、書き込み権が無いときには、ハッシュ 配列を読みだすことだけができ、設定することはできません。 書けるか否かを調べたい場合には、ファイルテスト 演算子を使うか、エラーをトラップしてくれる、eval の中で、ダミーのハッシュエントリを設定してみることになります。

Note that functions such as keys and values may return huge lists when used on large DBM files. You may prefer to use the each function to iterate over large DBM files. Example:

大きな DBM ファイルを扱うときには、keysvalues のような関数は、 巨大なリストを返します。 大きな DBM ファイルでは、each 関数を使って繰り返しを行なった方が 良いかもしれません。 例:

    # print out history file offsets
    dbmopen(%HIST,'/usr/lib/news/history',0666);
    while (($key,$val) = each %HIST) {
        print $key, ' = ', unpack('L',$val), "\n";
    }
    dbmclose(%HIST);

See also AnyDBM_File for a more general description of the pros and cons of the various dbm approaches, as well as DB_File for a particularly rich implementation.

様々な dbm 手法に対する利点欠点に関するより一般的な記述および 特にリッチな実装である DB_File に関しては AnyDBM_File も参照してください。

You can control which DBM library you use by loading that library before you call dbmopen():

dbmopen() を呼び出す前にライブラリを読み込むことで、 どの DBM ライブラリを使うかを制御できます:

    use DB_File;
    dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
        or die "Can't open netscape history file: $!";
defined EXPR
defined

Returns a Boolean value telling whether EXPR has a value other than the undefined value undef. If EXPR is not present, $_ will be checked.

左辺値 EXPR が未定義値 undef 以外の値を持つか否かを示す、ブール値を 返します。 EXPR がない場合は、$_ がチェックされます。

Many operations return undef to indicate failure, end of file, system error, uninitialized variable, and other exceptional conditions. This function allows you to distinguish undef from other values. (A simple Boolean test will not distinguish among undef, zero, the empty string, and "0", which are all equally false.) Note that since undef is a valid scalar, its presence doesn't necessarily indicate an exceptional condition: pop returns undef when its argument is an empty array, or when the element to return happens to be undef.

多くの演算子が、EOF や未初期化変数、システムエラーといった、 例外的な条件で undef を返すようになっています。 この関数は、他の値と undef とを区別するために使えます。 (単純な真偽値テストでは、undef、0、空文字、"0" のいずれも偽を返すので、 区別することができません。) undef は有効なスカラ値なので、その存在が 必ずしも 例外的な状況を表すとは限らないということに注意してください: pop は引数が空の配列だったときに undef を返しますが、 あるいは 返すべき要素がたまたま undef だったのかもしれません。

You may also use defined(&func) to check whether subroutine &func has ever been defined. The return value is unaffected by any forward declarations of &foo. Note that a subroutine which is not defined may still be callable: its package may have an AUTOLOAD method that makes it spring into existence the first time that it is called -- see perlsub.

defined(&func) とすることでサブルーチン &func の存在を、 確かめることもできます。 返り値は &foo の前方定義には影響されません。 定義されていないサブルーチンも呼び出し可能であることに注意してください。 最初に呼び出されたときに存在するようにするための AUTOLOAD メソッドを持ったパッケージかもしれません-- perlsub を参照して下さい。

Use of defined on aggregates (hashes and arrays) is deprecated. It used to report whether memory for that aggregate has ever been allocated. This behavior may disappear in future versions of Perl. You should instead use a simple test for size:

集合(ハッシュや配列)への defined の使用は非推奨です。 これはその集合にメモリが割り当てられたかを報告するのに 用いられていました。 この振る舞いは将来のバージョンの Perl では消滅するかもしれません。 代わりにサイズに対する簡単なテストを使うべきです。

    if (@an_array) { print "has array elements\n" }
    if (%a_hash)   { print "has hash members\n"   }

When used on a hash element, it tells you whether the value is defined, not whether the key exists in the hash. Use "exists" for the latter purpose.

Examples:

ハッシュの要素に対して用いると、value が定義されているか否かを 返すものであって、ハッシュに key が存在するか否かを返すのではありません。 この用途には、"exists" を使ってください。

例:

    print if defined $switch{'D'};
    print "$val\n" while defined($val = pop(@ary));
    die "Can't readlink $sym: $!"
        unless defined($value = readlink $sym);
    sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
    $debugging = 0 unless defined $debugging;

Note: Many folks tend to overuse defined, and then are surprised to discover that the number 0 and "" (the zero-length string) are, in fact, defined values. For example, if you say

注意: 多くの人々が defined を使いすぎて、0""(空文字列) が 実際のところ定義された値であることに驚くようです。 例えば、以下のように書くと:

    "ab" =~ /a(.*)b/;

The pattern match succeeds, and $1 is defined, despite the fact that it matched "nothing". But it didn't really match nothing--rather, it matched something that happened to be zero characters long. This is all very above-board and honest. When a function returns an undefined value, it's an admission that it couldn't give you an honest answer. So you should use defined only when you're questioning the integrity of what you're trying to do. At other times, a simple comparison to 0 or "" is what you want.

パターンマッチングが成功し、$1 が定義されても、実際には 「なし」にマッチしています。 しかしこれは何にもマッチしていないわけではありません-- 何かにはマッチしているのですが、たまたまそれが長さ 0 だっただけです。 これは非常に率直で正直なことです。 関数が未定義値を返すとき、正直な答えを返すことができないことを 告白しています。 ですので、あなたが自分がしようとしていることの完全性を確認するときにだけ defined を使うべきです。 その他の場合では、単に 0 または "" と比較するというのがあなたの 求めているものです。

See also "undef", "exists", "ref".

"undef", "exists", "ref" も参照してください。

delete EXPR

Given an expression that specifies a hash element, array element, hash slice, or array slice, deletes the specified element(s) from the hash or array. In the case of an array, if the array elements happen to be at the end, the size of the array will shrink to the highest element that tests true for exists() (or 0 if no such element exists).

ハッシュ要素、配列要素、ハッシュスライス、配列スライスを指定する式を取り、 指定された要素をハッシュや配列からを削除します。 配列の場合、配列要素が最後にあった場合は、 配列の大きさは exists() が真を返す最後尾の要素に縮みます (そのような要素がない場合は 0 になります)。

Returns each element so deleted or the undefined value if there was no such element. Deleting from $ENV{} modifies the environment. Deleting from a hash tied to a DBM file deletes the entry from the DBM file. Deleting from a tied hash or array may not necessarily return anything.

削除された値か、(何も削除されなかった場合には) 未定義値が返されます。 $ENV{} から削除を行なうと、実際に環境変数を変更します。 DBM ファイルに tie された配列からの削除は、その DBM ファイルからエントリを 削除します。 しかし、tie されたハッシュや配列からの削除は、 値を返すとは限りません。

Deleting an array element effectively returns that position of the array to its initial, uninitialized state. Subsequently testing for the same element with exists() will return false. Note that deleting array elements in the middle of an array will not shift the index of the ones after them down--use splice() for that. See "exists".

配列要素を削除した場合、配列の位置は初期の、初期化されていない状態になります。 引き続いて同じ要素に対して exists() でテストすると偽を返します。 配列の途中の配列要素を削除してもインデックスはシフトしないことに 注意してください -- このためには splice() を使ってください。 "exists" を参照してください。

The following (inefficiently) deletes all the values of %HASH and @ARRAY:

以下は、%HASH と @ARRAY のすべての値を(非効率的に)削除します:

    foreach $key (keys %HASH) {
        delete $HASH{$key};
    }

    foreach $index (0 .. $#ARRAY) {
        delete $ARRAY[$index];
    }

And so do these:

そして以下のようにもできます:

    delete @HASH{keys %HASH};

    delete @ARRAY[0 .. $#ARRAY];

But both of these are slower than just assigning the empty list or undefining %HASH or @ARRAY:

しかし、これら二つは単に空リストを代入するか、%HASH や @ARRAY を undef するより遅いです:

    %HASH = ();         # completely empty %HASH
    undef %HASH;        # forget %HASH ever existed

    @ARRAY = ();        # completely empty @ARRAY
    undef @ARRAY;       # forget @ARRAY ever existed

Note that the EXPR can be arbitrarily complicated as long as the final operation is a hash element, array element, hash slice, or array slice lookup:

最終的な操作がハッシュ要素、配列要素、ハッシュスライス、配列スライスの いずれかである限りは、EXPR には任意の複雑な式を置くことができることに 注意してください:

    delete $ref->[$x][$y]{$key};
    delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};

    delete $ref->[$x][$y][$index];
    delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
die LIST

Outside an eval, prints the value of LIST to STDERR and exits with the current value of $! (errno). If $! is 0, exits with the value of ($? >> 8) (backtick `command` status). If ($? >> 8) is 0, exits with 255. Inside an eval(), the error message is stuffed into $@ and the eval is terminated with the undefined value. This makes die the way to raise an exception.

eval の外では、LIST の値を STDERR に出力し、その時点の $! (errno) の値で exit します。 $! の値が 0 ならば、 ($? >> 8) (backtick `command` のステータス) の値で exitします。 ($? >> 8)0 であれば、255 で exit することになります。 eval の中で使用すると、エラーメッセージが、 $@ に入れられます。 eval は中断され、未定義値を返します。 これが die が例外を発生させる方法です。

Equivalent examples:

等価な例:

    die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
    chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"

If the value of EXPR does not end in a newline, the current script line number and input line number (if any) are also printed, and a newline is supplied. Note that the "input line number" (also known as "chunk") is subject to whatever notion of "line" happens to be currently in effect, and is also available as the special variable $.. See "$/" in perlvar and "$." in perlvar.

EXPR の評価結果が改行で終わっていなければ、その時点の スクリプト名とスクリプトの行番号、(もしあれば) 入力ファイルの行番号と改行文字が、続けて表示されます。 「入力行番号」("chunk" とも呼ばれます)は 「行」という概念が現在有効であると仮定しています。 また特殊変数 $. でも利用可能です。 "$/" in perlvar"$." in perlvar も参照してください。

Hint: sometimes appending ", stopped" to your message will cause it to make better sense when the string "at foo line 123" is appended. Suppose you are running script "canasta".

ヒント: メッセージの最後を ", stopped" のようなもので 終わるようにしておけば、"at foo line 123" のように 追加されて、わかりやすくなります。 "canasta" というスクリプトを実行しているとします。

    die "/etc/games is no good";
    die "/etc/games is no good, stopped";

produce, respectively

これは、それぞれ以下のように表示します。

    /etc/games is no good at canasta line 123.
    /etc/games is no good, stopped at canasta line 123.

See also exit(), warn(), and the Carp module.

exit() と warn() と Carp モジュールも参照してください。

If LIST is empty and $@ already contains a value (typically from a previous eval) that value is reused after appending "\t...propagated". This is useful for propagating exceptions:

LIST が空で $@ が(典型的には前回の eval で)既に値を持っている場合、 値は "\t...propagated" を追加した後再利用されます。 これは例外を伝播させる場合に有効です:

    eval { ... };
    die unless $@ =~ /Expected exception/;

If $@ is empty then the string "Died" is used.

$@ が空の場合、"Died" が使われます。

die() can also be called with a reference argument. If this happens to be trapped within an eval(), $@ contains the reference. This behavior permits a more elaborate exception handling implementation using objects that maintain arbitrary state about the nature of the exception. Such a scheme is sometimes preferable to matching particular string values of $@ using regular expressions. Here's an example:

die() はリファレンス引数と共に呼び出すこともできます。 eval() 内部でこのように呼び出された場合、$@ はリファレンスを持ちます。 この振る舞いは、例外の性質にすいて任意の状態を管理するオブジェクトを使った より複雑な例外ハンドリングの実装を可能にします。 このようなスキーマは $@ の特定の文字列値を正規表現を使って マッチングするときに時々好まれます。以下に例を示します:

    eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
    if ($@) {
        if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
            # handle Some::Module::Exception
        }
        else {
            # handle all other possible exceptions
        }
    }

Because perl will stringify uncaught exception messages before displaying them, you may want to overload stringification operations on such custom exception objects. See overload for details about that.

perl は捕らえられなかった例外のメッセージを表示する前に文字列化するので、 このようなカスタム例外オブジェクトの文字列化をオーバーロードしたいと 思うかもしれません。 これに関する詳細は overload を参照してください。

You can arrange for a callback to be run just before the die does its deed, by setting the $SIG{__DIE__} hook. The associated handler will be called with the error text and can change the error message, if it sees fit, by calling die again. See "$SIG{expr}" in perlvar for details on setting %SIG entries, and "eval BLOCK" for some examples. Although this feature was meant to be run only right before your program was to exit, this is not currently the case--the $SIG{__DIE__} hook is currently called even inside eval()ed blocks/strings! If one wants the hook to do nothing in such situations, put

$SIG{__DIE__} フックをセットすることで、die がその行動を行う 直前に実行されるコールバックを設定できます。 結び付けられたハンドラはエラーテキストと共に呼び出され、 必要なら再び die を呼び出すことでエラーテキストを変更できアス。 %SIG のエントリをセットする詳細については、"$SIG{expr}" in perlvar を、 例については "eval BLOCK" を参照してください。 この機能はプログラムが終了しようとする前に 1 回だけ実行されることを 意味していましたが、現在ではそうではありません -- $SIG{__DIE__} フックは eval() されたブロック/文字列の中でも 呼ばれるのです! もしそのような状況で何もしなくない時は:

        die @_ if $^S;

as the first line of the handler (see "$^S" in perlvar). Because this promotes strange action at a distance, this counterintuitive behavior may be fixed in a future release.

をハンドラの最初の行に置いてください("$^S" in perlvar を参照してください)。 これは離れたところで不思議な行動を引き起こすので、 この直感的でない振る舞いは将来のリリースで修正されるかもしれません。

do BLOCK

Not really a function. Returns the value of the last command in the sequence of commands indicated by BLOCK. When modified by a loop modifier, executes the BLOCK once before testing the loop condition. (On other statements the loop modifiers test the conditional first.)

実際は関数ではありません。 BLOCK で示されるコマンド列の最後の値を返します。 ループ修飾子で修飾すると、 ループ条件を調べる前に 1 度、BLOCK を実行します。 (これ以外の実行文は、ループ修飾子により、条件が最初に 調べられます。)

do BLOCK does not count as a loop, so the loop control statements next, last, or redo cannot be used to leave or restart the block. See perlsyn for alternative strategies.

do BLOCK はループとしては 扱われません。 従って、next, last, redo といったループ制御文は ブロックから抜けたり再開することはできません。 その他の戦略については perlsyn を参照して下さい。

do SUBROUTINE(LIST)

A deprecated form of subroutine call. See perlsub.

推奨されない形のサブルーチン呼び出しです。 perlsub を参照してください。

do EXPR

Uses the value of EXPR as a filename and executes the contents of the file as a Perl script. Its primary use is to include subroutines from a Perl subroutine library.

EXPR の値をファイル名として用い、そのファイルの中身を Perl のスクリプトとして実行します。 主に、Perl のサブルーチンライブラリからサブルーチンを インクルードするために用います。

    do 'stat.pl';

is just like

は以下のものと同じようなものですが、

    scalar eval `cat stat.pl`;

except that it's more efficient and concise, keeps track of the current filename for error messages, searches the @INC libraries, and updates %INC if the file is found. See "Predefined Names" in perlvar for these variables. It also differs in that code evaluated with do FILENAME cannot see lexicals in the enclosing scope; eval STRING does. It's the same, however, in that it does reparse the file every time you call it, so you probably don't want to do this inside a loop.

より効率的で、簡潔であり、エラーメッセージでファイル名がわかる、 カレントディレクトリでファイルが見つからなかったときに @INC ライブラリを検索する、ファイルがあったときに %INC を更新する、 といったことがあります。 "Predefined Names" in perlvar も参照してください。 do FILENAME で評価されたコードは、入れ子のスコープにある レキシカル変数を見ることができないのに対し、eval STRINGではできる、 という違いがあります。 しかし、呼び出すたびにファイルを解析し直すという点では同じですから、 ループ内でこれを使おうなどとは、間違っても思ったりしないように。

If do cannot read the file, it returns undef and sets $! to the error. If do can read the file but cannot compile it, it returns undef and sets an error message in $@. If the file is successfully compiled, do returns the value of the last expression evaluated.

doがファイルを読み込めなかった場合、undef を返して $! に エラーを設定します。 do がファイルを読み込めたがコンパイルできなかった場合、 undef を返して $@ にエラーメッセージを設定します。 ファイルのコンパイルに成功した場合、do は最後に評価した表現の値を返します。

Note that inclusion of library modules is better done with the use and require operators, which also do automatic error checking and raise an exception if there's a problem.

ライブラリモジュールのインクルードには、use 演算子や require 演算子を使った方がよいことに注意してください。 これらは自動的にエラーをチェックして、問題があれば例外を発生させます。

You might like to use do to read in a program configuration file. Manual error checking can be done this way:

do をプログラム設定ファイルを読み込むのに使いたいかもしれません。 手動のエラーチェックは以下のようにして行えます:

    # read in config files: system first, then user 
    for $file ("/share/prog/defaults.rc",
               "$ENV{HOME}/.someprogrc") 
   {
        unless ($return = do $file) {
            warn "couldn't parse $file: $@" if $@;
            warn "couldn't do $file: $!"    unless defined $return;
            warn "couldn't run $file"       unless $return;
        }
    }
dump LABEL
dump

This function causes an immediate core dump. See also the -u command-line switch in perlrun, which does the same thing. Primarily this is so that you can use the undump program (not supplied) to turn your core dump into an executable binary after having initialized all your variables at the beginning of the program. When the new binary is executed it will begin by executing a goto LABEL (with all the restrictions that goto suffers). Think of it as a goto with an intervening core dump and reincarnation. If LABEL is omitted, restarts the program from the top.

この関数は即座にコアダンプを行ないます。 同様のことを行う perlrun-u オプションも参照してください。 プログラムの先頭で、 すべての変数を初期化したあとのコアダンプを undump プログラム(提供していません)を使って実行ファイルに返ることができます。 この新しいバイナリが実行されると、goto LABEL から始めます (goto に関する制限はすべて適用されます)。 コアダンプをはさんで再生する goto と考えてください。 LABEL が省略されると、プログラムを先頭から再開します。

WARNING: Any files opened at the time of the dump will not be open any more when the program is reincarnated, with possible resulting confusion on the part of Perl.

警告: dump 時点でオープンされていたファイルは、 プログラムが再生されたときには、もはやオープンされていません。 Perl を部分的に混乱させる可能性があります。

This function is now largely obsolete, partly because it's very hard to convert a core file into an executable, and because the real compiler backends for generating portable bytecode and compilable C code have superseded it.

この関数は大幅に時代遅れのものです; 理由としては、コアファイルを 実行形式に変換するのが非常に困難であること、また移植性のある バイトコードとコンパイル可能な C コードが生成される 実際のコンパイラバックエンドがこれを置き換えたことがあります。

If you're looking to use dump to speed up your program, consider generating bytecode or native C code as described in perlcc. If you're just trying to accelerate a CGI script, consider using the mod_perl extension to Apache, or the CPAN module, Fast::CGI. You might also consider autoloading or selfloading, which at least make your program appear to run faster.

プログラムの速度を上げるために dump を使うことを考えているなら、 perlcc で記述されているような、バイトコードかネイティブな C コードを 生成することを検討してみてください。 もし単に CGI スクリプトを高速化したいなら、Apache の拡張である mod_perl や、CPAN モジュールである Fast::CGI を検討してみてください。 少なくともプログラムが速く動作する ようにみえる、オートロードや 自力ロードも検討してみてください。

each HASH

When called in list context, returns a 2-element list consisting of the key and value for the next element of a hash, so that you can iterate over it. When called in scalar context, returns only the key for the next element in the hash.

リストコンテキストで呼び出した場合は、 ハッシュの次の 要素 に対する、key と 要素 からなる 2 要素のリストを返しますので、ハッシュ上での繰り返しを 行なうことができます。 スカラコンテキストで呼び出した場合は、 ハッシュの次の要素のための key を返します。

Entries are returned in an apparently random order. The actual random order is subject to change in future versions of perl, but it is guaranteed to be in the same order as either the keys or values function would produce on the same (unmodified) hash.

エントリは見かけ上、ランダムな順序で返されます。 実際のランダムな順番は perl の将来のバージョンでは変わるかもしれませんが、 keysvalues 関数が同じ(変更されていない)ハッシュに対して 生成するのと同じ順番であることは保証されます。

When the hash is entirely read, a null array is returned in list context (which when assigned produces a false (0) value), and undef in scalar context. The next call to each after that will start iterating again. There is a single iterator for each hash, shared by all each, keys, and values function calls in the program; it can be reset by reading all the elements from the hash, or by evaluating keys HASH or values HASH. If you add or delete elements of a hash while you're iterating over it, you may get entries skipped or duplicated, so don't. Exception: It is always safe to delete the item most recently returned by each(), which means that the following code will work:

ハッシュをすべて読み込んでしまうと、リストコンテキストでは空配列が 返されます(これは代入されると、偽 (0) となります)。 スカラコンテキストでは undef が返されます。 そのあと、もう一度 each を呼び出すと、 再び繰り返しを始めます。 ハッシュごとに反復子が 1 つあり、プログラム中のすべての each 関数、keys 関数、values 関数で共用されます。 反復子は、配列の要素をすべて読むことによって、またはkeys HASH, values HASHを評価することでリセットすることができます。 繰り返しを行なっている間に、ハッシュに要素を追加したり削除したりすると、 要素が飛ばされたり重複したりするので、してはいけません。 例外: 一番最近に each() から返されたものを削除するのは常に安全です。 これは以下のようなコードが正しく動くことを意味します:

        while (($key, $value) = each %hash) {
          print $key, "\n";
          delete $hash{$key};   # This is safe
        }

The following prints out your environment like the printenv(1) program, only in a different order:

以下のプログラムは、順番が異なるものの、 printenv(1) プログラムのように環境変数を表示します:

    while (($key,$value) = each %ENV) {
        print "$key=$value\n";
    }

See also keys, values and sort.

keysvaluessort も参照してください。

eof FILEHANDLE
eof ()
eof

Returns 1 if the next read on FILEHANDLE will return end of file, or if FILEHANDLE is not open. FILEHANDLE may be an expression whose value gives the real filehandle. (Note that this function actually reads a character and then ungetcs it, so isn't very useful in an interactive context.) Do not read from a terminal file (or call eof(FILEHANDLE) on it) after end-of-file is reached. File types such as terminals may lose the end-of-file condition if you do.

次に FILEHANDLE 上で読み込みを行なったときに、 EOF が返されるときか、 FILEHANDLE がオープンされていないと、1 を返します。 FILEHANDLE は、値が実際のファイルハンドルを示す式であってもかまいません。 (この関数は、実際に文字を読み、ungetc を行ないますので、 対話型の場合には、それ程有用ではありません。) 端末ファイルは EOF に達した後にさらに読み込んだり eof(FILEHANDLE) を 呼び出したりしてはいけません。 そのようなことをすると、端末のようなファイルタイプは EOF 状態を失ってしまうかもしれません。

An eof without an argument uses the last file read. Using eof() with empty parentheses is very different. It refers to the pseudo file formed from the files listed on the command line and accessed via the <> operator. Since <> isn't explicitly opened, as a normal filehandle is, an eof() before <> has been used will cause @ARGV to be examined to determine if input is available.

引数を省略した eof は、最後に読み込みを行なったファイルを使います。 空の括弧をつけた eof() は大きく異なります。 これはコマンドラインのファイルリストで構成され、<> 演算子経由で アクセスされる擬似ファイルを示すために用いられます。 通常のファイルハンドルと違って <> は明示的にオープンされないので、 <> を使う前に eof() を使うと、 入力が正常か確認するために @ARGV がテストされます。

In a while (<>) loop, eof or eof(ARGV) can be used to detect the end of each file, eof() will only detect the end of the last file. Examples:

while (<>) ループの中では、個々のファイルの終わりを調べるには、 eofeof(ARGV) を用います。 eof() は最後のファイルの終わりのみを調べます。 例:

    # reset line numbering on each input file
    while (<>) {
        next if /^\s*#/;        # skip comments 
        print "$.\t$_";
    } continue {
        close ARGV  if eof;     # Not eof()!
    }

    # insert dashes just before last line of last file
    while (<>) {
        if (eof()) {            # check for end of current file
            print "--------------\n";
            close(ARGV);        # close or last; is needed if we
                                # are reading from the terminal
        }
        print;
    }

Practical hint: you almost never need to use eof in Perl, because the input operators typically return undef when they run out of data, or if there was an error.

現実的なヒント: Perl で eof が必要となることは、ほとんどありません。 基本的には、 データがなくなったときやエラーがあったときに、入力演算子が undef を返してくれるからです。

eval EXPR
eval BLOCK

In the first form, the return value of EXPR is parsed and executed as if it were a little Perl program. The value of the expression (which is itself determined within scalar context) is first parsed, and if there weren't any errors, executed in the lexical context of the current Perl program, so that any variable settings or subroutine and format definitions remain afterwards. Note that the value is parsed every time the eval executes. If EXPR is omitted, evaluates $_. This form is typically used to delay parsing and subsequent execution of the text of EXPR until run time.

第一の形式では、EXPR の返り値が Perl のプログラムであるかのように 解析され、実行されます。 式の値(それ自身スカラコンテキストの中で決定される)はまずパースされ、 エラーがなければ Perl プログラムのレキシカルコンテキストの中で実行されますので、変数の設定、 サブルーチンやフォーマットの定義は、その後も残っています。 返される値は eval が実行されるごとにパースされます。 サブルーチン同様に、最後に評価した式の値か、return 文の値です。 EXPR を省略すると、$_ を評価します。 この形は主に EXPR のテキストのパースと実行を実行時にまで 遅延させるのに用います。

In the second form, the code within the BLOCK is parsed only once--at the same time the code surrounding the eval itself was parsed--and executed within the context of the current Perl program. This form is typically used to trap exceptions more efficiently than the first (see below), while also providing the benefit of checking the code within BLOCK at compile time.

第二の形式では、BLOCK 内部のコードは一度だけパースされ--コードを 囲む eval 自身がパースされるのと同じ時点です--現在の Perl プログラムの コンテキストで実行されます。 この形式は典型的には第一の形式より効率的に例外をトラップします(後述)。 また BLOCK 内部のコードはコンパイル時にチェックされるという利点を提供します。

The final semicolon, if any, may be omitted from the value of EXPR or within the BLOCK.

最後のセミコロンは、もしあれば、EXPR の値や BLOCK の中身から省くことができます。

In both forms, the value returned is the value of the last expression evaluated inside the mini-program; a return statement may be also used, just as with subroutines. The expression providing the return value is evaluated in void, scalar, or list context, depending on the context of the eval itself. See "wantarray" for more on how the evaluation context can be determined.

どちらの形式でも、返される値はミニプログラムの内部で最後に評価された 表現の値です; サブルーチンと同様、return ステートメントも使えます。 返り値として提供される表現は、eval 自身のコンテキストに依存して 無効・スカラ・リストのいずれかのコンテキストで評価されます。 評価コンテキストの決定方法についての詳細は "wantarray" を参照してください。

If there is a syntax error or runtime error, or a die statement is executed, an undefined value is returned by eval, and $@ is set to the error message. If there was no error, $@ is guaranteed to be a null string. Beware that using eval neither silences perl from printing warnings to STDERR, nor does it stuff the text of warning messages into $@. To do either of those, you have to use the $SIG{__WARN__} facility. See "warn" and perlvar.

構文エラーや実行エラーが発生するか、die 文が実行されると、 eval の値として未定義値が返され、$@ にエラーメッセージが設定されます。 エラーがなければ、$@ は、空文字列であることが保証されます。 eval を、STDERR に警告メッセージを表示させない目的や、 警告メッセージを $@ に格納する目的では使わないでください。 そのような用途では、$SIG{__WARN__} 機能を使わなければなりません。 "warn"perlvar を参照してください。

Note that, because eval traps otherwise-fatal errors, it is useful for determining whether a particular feature (such as socket or symlink) is implemented. It is also Perl's exception trapping mechanism, where the die operator is used to raise exceptions.

eval は、致命的エラーとなるようなものをトラップすることができますから、 (socketsymlink といった) 特定の機能が実装されているかを、 調べるために使うことができることに注意してください。 die 演算子が例外を発生させるものとすれば、 これはまた、Perl の例外捕捉機能と捉えることもできます。

If the code to be executed doesn't vary, you may use the eval-BLOCK form to trap run-time errors without incurring the penalty of recompiling each time. The error, if any, is still returned in $@. Examples:

実行するコードが変わらないのであれば、毎回多量の再コンパイルすることなしに、 実行時エラーのトラップを行なうために、 eval-BLOCK 形式を使うことができます。 エラーがあれば、やはり $@ に返されます。 例:

    # make divide-by-zero nonfatal
    eval { $answer = $a / $b; }; warn $@ if $@;

    # same thing, but less efficient
    eval '$answer = $a / $b'; warn $@ if $@;

    # a compile-time error
    eval { $answer = };                 # WRONG

    # a run-time error
    eval '$answer =';   # sets $@

Due to the current arguably broken state of __DIE__ hooks, when using the eval{} form as an exception trap in libraries, you may wish not to trigger any __DIE__ hooks that user code may have installed. You can use the local $SIG{__DIE__} construct for this purpose, as shown in this example:

eval{} 形式をライブラリの例外を補足するために使うとき、 現在の __DIE__ フックの状態はほぼ確実に壊れているという理由で、 ユーザーのコードが設定した __DIE__ フックを実行したくないかもしれません。 この目的には以下の例のように、local $SIG{__DIE__} 構造が使えます。

    # a very private exception trap for divide-by-zero
    eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
    warn $@ if $@;

This is especially significant, given that __DIE__ hooks can call die again, which has the effect of changing their error messages:

これは特に顕著です。与えられた __DIE__ フックは die をもう一度 呼び出すことができ、これによってエラーメッセージを変える効果があります:

    # __DIE__ hooks may modify error messages
    {
       local $SIG{'__DIE__'} =
              sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
       eval { die "foo lives here" };
       print $@ if $@;                # prints "bar lives here"
    }

Because this promotes action at a distance, this counterintuitive behavior may be fixed in a future release.

これは距離の離れた行動であるため、この直感的でない振る舞いは 将来のリリースでは修正されるかもしれません。

With an eval, you should be especially careful to remember what's being looked at when:

eval では、以下のような場合に、 何が調べられるかに特に注意しておくことが必要です:

    eval $x;            # CASE 1
    eval "$x";          # CASE 2

    eval '$x';          # CASE 3
    eval { $x };        # CASE 4

    eval "\$$x++";      # CASE 5
    $$x++;              # CASE 6

Cases 1 and 2 above behave identically: they run the code contained in the variable $x. (Although case 2 has misleading double quotes making the reader wonder what else might be happening (nothing is).) Cases 3 and 4 likewise behave in the same way: they run the code '$x', which does nothing but return the value of $x. (Case 4 is preferred for purely visual reasons, but it also has the advantage of compiling at compile-time instead of at run-time.) Case 5 is a place where normally you would like to use double quotes, except that in this particular situation, you can just use symbolic references instead, as in case 6.

上記の CASE 1 と CASE 2 の動作は同一で、変数 $x 内の コードを実行します。 (ただし、CASE 2 では、必要のないダブルクォートによって、 読む人が何が起こるか混乱することでしょう (何も起こりませんが)。) 同様に CASE 3 と CASE 4 の動作も等しく、$x の値を返す以外に 何もしない $x というコードを実行します (純粋に見た目の問題で、CASE 4 が好まれますが、 実行時でなくコンパイル時にコンパイルされるという利点もあります)。 CASE 5 の場合は、通常ダブルクォートを使用します。 この状況を除けば、CASE 6 のように、単に シンボリックリファレンスを使えば良いでしょう。

eval BLOCK does not count as a loop, so the loop control statements next, last, or redo cannot be used to leave or restart the block.

eval BLOCK はループとして 扱われません。 従って、next, last, redo といったループ制御文でブロックから離れたり 再実行したりはできません。

exec LIST
exec PROGRAM LIST

The exec function executes a system command and never returns-- use system instead of exec if you want it to return. It fails and returns false only if the command does not exist and it is executed directly instead of via your system's command shell (see below).

exec 関数は、システムのコマンドを実行し、戻ってはきません。 戻って欲しい場合には、execではなく system 関数を使ってください。 コマンドが存在せず、しかも システムのコマンドシェル経由でなく 直接コマンドを実行しようとした場合にのみこの関数は失敗して偽を返します。

Since it's a common mistake to use exec instead of system, Perl warns you if there is a following statement which isn't die, warn, or exit (if -w is set - but you always do that). If you really want to follow an exec with some other statement, you can use one of these styles to avoid the warning:

system の代わりに exec を使うというよくある間違いを防ぐために、 引き続く文が die, warn, exit(-w がセットされている場合 - でもいつもセットしてますよね) 以外の場合、Perl は警告を出します。 もし 本当に exec の後に他の文を書きたい場合、 以下のどちらかのスタイルを使うことで警告を回避できます:

    exec ('foo')   or print STDERR "couldn't exec foo: $!";
    { exec ('foo') }; print STDERR "couldn't exec foo: $!";

If there is more than one argument in LIST, or if LIST is an array with more than one value, calls execvp(3) with the arguments in LIST. If there is only one scalar argument or an array with one element in it, the argument is checked for shell metacharacters, and if there are any, the entire argument is passed to the system's command shell for parsing (this is /bin/sh -c on Unix platforms, but varies on other platforms). If there are no shell metacharacters in the argument, it is split into words and passed directly to execvp, which is more efficient. Examples:

LIST に複数の引数がある場合か、LIST が複数の値を持つ 配列の場合には、LIST の引数を使って、execvp(3) を呼び出します。 1 つのスカラ引数のみまたは要素が 1 つの配列の場合には、その引数から シェルのメタ文字をチェックし、もし、メタ文字があれば、 引数全体をシステムのコマンドシェル(これはUnix では /bin/sh -c ですが、システムによって異なります)に渡して解析させます。 もし、メタキャラクタがなければ、その引数を単語に分け、 より効率的な execvp に直接渡します。 例:

    exec '/bin/echo', 'Your arguments are: ', @ARGV;
    exec "sort $outfile | uniq";

If you don't really want to execute the first argument, but want to lie to the program you are executing about its own name, you can specify the program you actually want to run as an "indirect object" (without a comma) in front of the LIST. (This always forces interpretation of the LIST as a multivalued list, even if there is only a single scalar in the list.) Example:

第一引数に指定するものを本当に実行したいが、実行する プログラムに対して別の名前を教えたい場合には、LISTの前に、 「間接オブジェクト」(コンマなし) として、実際に 実行したいプログラムを指定することができます。 (これによって、LIST に単一のスカラしかなくても、複数 値のリストであるように、LIST の解釈を行ないます。) 例:

    $shell = '/bin/csh';
    exec $shell '-sh';          # pretend it's a login shell

or, more directly,

あるいは、より直接的に、

    exec {'/bin/csh'} '-sh';    # pretend it's a login shell

When the arguments get executed via the system shell, results will be subject to its quirks and capabilities. See "`STRING`" in perlop for details.

引数がシステムシェルで実行されるとき、結果はシェルの奇癖と能力によって 変わります。 詳細については "`STRING`" in perlop を参照してください。

Using an indirect object with exec or system is also more secure. This usage (which also works fine with system()) forces interpretation of the arguments as a multivalued list, even if the list had just one argument. That way you're safe from the shell expanding wildcards or splitting up words with whitespace in them.

execsystem で間接オブジェクトを使うのもより安全です。 この使い方(system() でも同様にうまく動きます)は、たとえ引数が一つだけの 場合も、複数の値を持つリストとして引数を解釈することを強制します。 この方法で、シェルによるワイルドカード展開や、空白による単語の分割から 守られます。

    @args = ( "echo surprise" );

    exec @args;               # subject to shell escapes
                                # if @args == 1
    exec { $args[0] } @args;  # safe even with one-arg list

The first version, the one without the indirect object, ran the echo program, passing it "surprise" an argument. The second version didn't--it tried to run a program literally called "echo surprise", didn't find it, and set $? to a non-zero value indicating failure.

間接オブジェクトなしの一つ目のバージョンでは、echo プログラムが実行され、 "surprise" が引数として渡されます。 二つ目のバージョンでは違います -- 文字通り "echo surprise" という名前の プログラムを実行しようとして、見つからないので、失敗したことを示すために $? に非 0 がセットされます。

Beginning with v5.6.0, Perl will attempt to flush all files opened for output before the exec, but this may not be supported on some platforms (see perlport). To be safe, you may need to set $| ($AUTOFLUSH in English) or call the autoflush() method of IO::Handle on any open handles in order to avoid lost output.

v5.6.0 から、Perl は exec の前に出力用に開かれている全てのファイルを フラッシュしようとしますが、これに対応していないプラットフォームもあります (perlport を参照してください)。 安全のためには、出力が重複するのを避けるために、全てのオープンしている ハンドルに対して $| (English モジュールでは $AUTOFLUSH) を設定するか、 IO::Handle モジュールの autoflush() メソッドをを呼ぶ必要が あるかもしれません。

Note that exec will not call your END blocks, nor will it call any DESTROY methods in your objects.

execEND ブロックや、オブジェクトの DESTROY メソッドを 呼び出さないことに注意してください。

exists EXPR

Given an expression that specifies a hash element or array element, returns true if the specified element in the hash or array has ever been initialized, even if the corresponding value is undefined. The element is not autovivified if it doesn't exist.

ハッシュ要素か配列要素を示す表現が与えられ、 指定された要素が、ハッシュか配列に存在すれば、 たとえ対応する value が未定義でも真を返します。 要素が存在しなかった場合は自動活性化されません。

    print "Exists\n"    if exists $hash{$key};
    print "Defined\n"   if defined $hash{$key};
    print "True\n"      if $hash{$key};

    print "Exists\n"    if exists $array[$index];
    print "Defined\n"   if defined $array[$index];
    print "True\n"      if $array[$index];

A hash or array element can be true only if it's defined, and defined if it exists, but the reverse doesn't necessarily hold true.

ハッシュまたは配列要素は、定義されているときにのみ真となり、 存在しているときにのみ定義されますが、逆は必ずしも真ではありません。

Given an expression that specifies the name of a subroutine, returns true if the specified subroutine has ever been declared, even if it is undefined. Mentioning a subroutine name for exists or defined does not count as declaring it. Note that a subroutine which does not exist may still be callable: its package may have an AUTOLOAD method that makes it spring into existence the first time that it is called -- see perlsub.

引数としてサブルーチンの名前が指定された場合、 指定されたサブルーチンが宣言されていれば(たとえ未定義でも) 真を返します。 exists や defined のために言及されているサブルーチン名は 宣言としてのカウントに入りません。 存在しないサブルーチンでも呼び出し可能かもしれないことに注意してください: パッケージが AUTOLOAD メソッドを持っていて、最初に呼び出された時に 存在を作り出すかもしれません -- perlsub を参照してください。

    print "Exists\n"    if exists &subroutine;
    print "Defined\n"   if defined &subroutine;

Note that the EXPR can be arbitrarily complicated as long as the final operation is a hash or array key lookup or subroutine name:

最終的な操作がハッシュや配列の key による検索またはサブルーチン名である限りは、 EXPR には任意の複雑な式を置くことができます:

    if (exists $ref->{A}->{B}->{$key})  { }
    if (exists $hash{A}{B}{$key})       { }

    if (exists $ref->{A}->{B}->[$ix])   { }
    if (exists $hash{A}{B}[$ix])        { }

    if (exists &{$ref->{A}{B}{$key}})   { }

Although the deepest nested array or hash will not spring into existence just because its existence was tested, any intervening ones will. Thus $ref->{"A"} and $ref->{"A"}->{"B"} will spring into existence due to the existence test for the $key element above. This happens anywhere the arrow operator is used, including even:

ネストした配列やハッシュの一番深い部分は、その存在をテストしただけでは 存在するようにはなりませんが、途中のものは存在するようになります。 従って $ref->{"A"}$ref->{"A"}->{"B"} は上記の $key の 存在をテストしたことによって存在するようになります。 これは、矢印演算子が使われるところでは、以下のようなものを含むどこででも 起こります。

    undef $ref;
    if (exists $ref->{"Some key"})      { }
    print $ref;             # prints HASH(0x80d3d5c)

This surprising autovivification in what does not at first--or even second--glance appear to be an lvalue context may be fixed in a future release.

一目見ただけでは -- あるいは二目見ても -- 驚かされる、左辺値コンテキストでの 自動有効化は将来のリリースでは修正されるでしょう。

See "Pseudo-hashes: Using an array as a hash" in perlref for specifics on how exists() acts when used on a pseudo-hash.

擬似ハッシュに用いた場合に exists() がどのように振舞うかの仕様については "Pseudo-hashes: Using an array as a hash" in perlref を参照してください。

Use of a subroutine call, rather than a subroutine name, as an argument to exists() is an error.

exists() の引数としてサブルーチン名でなくサブルーチン呼び出しを使うと、 エラーになります。

    exists &sub;        # OK
    exists &sub();      # Error
exit EXPR

Evaluates EXPR and exits immediately with that value. Example:

EXPR を評価し、即座にその値を持って終了します。 例:

    $ans = <STDIN>;
    exit 0 if $ans =~ /^[Xx]/;

See also die. If EXPR is omitted, exits with 0 status. The only universally recognized values for EXPR are 0 for success and 1 for error; other values are subject to interpretation depending on the environment in which the Perl program is running. For example, exiting 69 (EX_UNAVAILABLE) from a sendmail incoming-mail filter will cause the mailer to return the item undelivered, but that's not true everywhere.

die も参照してください。 EXPR が省略された場合には、ステータスを 0 として終了します。 EXPR の値として広く利用可能なのは 0 が成功で 1 がエラーということだけです。 その他の値は、 Perl が実行される環境によって異なる解釈がされる 可能性があります。 例えば、sendmail 到着メールフィルタから 69 (EX_UNAVAILABLE) で終了すると メーラーはアイテムを配達せずに差し戻しますが、 これはいつでも真ではありません。

Don't use exit to abort a subroutine if there's any chance that someone might want to trap whatever error happened. Use die instead, which can be trapped by an eval.

誰かが発生したエラーをトラップしようと考えている可能性がある場合は、 サブルーチンの中断に exit を使わないでください。 代わりに eval でトラップできる die を使ってください。

The exit() function does not always exit immediately. It calls any defined END routines first, but these END routines may not themselves abort the exit. Likewise any object destructors that need to be called are called before the real exit. If this is a problem, you can call POSIX:_exit($status) to avoid END and destructor processing. See perlmod for details.

exit() 関数は常に直ちに終了するわけではありません。 まず、定義されている END ルーチンを呼び出しますが、 END ルーチン自身は exit を止められません。 同様に、呼び出す必要のあるオブジェクトデストラクタは すべて、実際の終了前に呼び出されます。 これが問題になる場合は、END やデストラクタが実行されることを 防ぐために POSIX:_exit($status) を呼び出してください。 詳しくは perlmod を参照してください。

exp EXPR
exp

Returns e (the natural logarithm base) to the power of EXPR. If EXPR is omitted, gives exp($_).

e (自然対数の底) の EXPR 乗を返します。 EXPR を省略した場合には、exp($_) を返します。

fcntl FILEHANDLE,FUNCTION,SCALAR

Implements the fcntl(2) function. You'll probably have to say

    use Fcntl;

first to get the correct constant definitions. Argument processing and value return works just like ioctl below. For example:

fcntl(2) 関数を実装します。 正しい定数定義を得るために、まず、

    use Fcntl;

と書くことが必要でしょう。 引数の処理と返り値については、下記の ioctl と同様に動作します。 例:

    use Fcntl;
    fcntl($filehandle, F_GETFL, $packed_return_buffer)
        or die "can't fcntl F_GETFL: $!";

You don't have to check for defined on the return from fnctl. Like ioctl, it maps a 0 return from the system call into "0 but true" in Perl. This string is true in boolean context and 0 in numeric context. It is also exempt from the normal -w warnings on improper numeric conversions.

fcntl からの返り値のチェックに defined を使う必要はありません。 ioctl と違って、fnctl はシステムコールの結果が 0 だった場合は "0 だが真" を返します。 この文字列は真偽値コンテキストでは真となり、 数値コンテキストでは 0 になります。 これはまた、不適切な数値変換に関する通常の -w 警告を回避します。

Note that fcntl will produce a fatal error if used on a machine that doesn't implement fcntl(2). See the Fcntl module or your fcntl(2) manpage to learn what functions are available on your system.

fcntl(2) が実装されていないマシンでは、fcntlは致命的エラーを 引き起こすことに注意してください。 システムでどの関数が利用可能かについては Fcntl モジュールや fcntl(2) man ページを参照してください。

fileno FILEHANDLE

Returns the file descriptor for a filehandle, or undefined if the filehandle is not open. This is mainly useful for constructing bitmaps for select and low-level POSIX tty-handling operations. If FILEHANDLE is an expression, the value is taken as an indirect filehandle, generally its name.

ファイルハンドルに対するファイル記述子を返します。 ファイルハンドルがオープンしていない場合は未定義値を返します。 これは主に select や低レベル POSIX tty 操作に対する、ビットマップを 構成するときに便利です。 FILEHANDLE が式であれば、 その値が間接ファイルハンドル(普通は名前)として使われます。

You can use this to find out whether two handles refer to the same underlying descriptor:

これを、二つのハンドルが同じ記述子を参照しているかどうかを 調べるのに使えます:

    if (fileno(THIS) == fileno(THAT)) {
        print "THIS and THAT are dups\n";
    } 
flock FILEHANDLE,OPERATION

Calls flock(2), or an emulation of it, on FILEHANDLE. Returns true for success, false on failure. Produces a fatal error if used on a machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3). flock is Perl's portable file locking interface, although it locks only entire files, not records.

FILEHANDLE に対して flock(2)、またはそのエミュレーションを呼び出します。 成功時には真を、失敗時には偽を返します。 flock(2), fcntl(2) ロック, lockf(3) のいずれかを実装していない マシンで使うと、致命的エラーが発生します。 flock は Perl の移植性のあるファイルロックインターフェースです。 しかしレコードではなく、ファイル全体のみをロックします。

Two potentially non-obvious but traditional flock semantics are that it waits indefinitely until the lock is granted, and that its locks merely advisory. Such discretionary locks are more flexible, but offer fewer guarantees. This means that files locked with flock may be modified by programs that do not also use flock. See perlport, your port's specific documentation, or your system-specific local manpages for details. It's best to assume traditional behavior if you're writing portable programs. (But if you're not, you should as always feel perfectly free to write for your own system's idiosyncrasies (sometimes called "features"). Slavish adherence to portability concerns shouldn't get in the way of your getting your job done.)

明白ではないものの、伝統的な flock の動作としては、ロックが得られるまで 無限に待ち続けるものと、単に勧告的に ロックするものの二つがあります。 このような自由裁量のロックはより柔軟ですが、保障されるものはより少ないです。 これは、flock でロックされたファイルは flock を使わない プログラムによって書き換えられるかもしれないことを意味します。 詳細については、perlport、システム固有のドキュメント、システム固有の ローカルの man ページを参照してください。 移植性のあるプログラムを書く場合は、伝統的な振る舞いを仮定するのが ベストです。 (しかし移植性のないプログラムを書く場合は、自身のシステムの性癖(しばしば 「仕様」と呼ばれます)に合わせて書くことも完全に自由です。 盲目的に移植性に固執することで、あなたの作業を仕上げるのを邪魔するべきでは ありません。)

OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with LOCK_NB. These constants are traditionally valued 1, 2, 8 and 4, but you can use the symbolic names if you import them from the Fcntl module, either individually, or as a group using the ':flock' tag. LOCK_SH requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN releases a previously requested lock. If LOCK_NB is bitwise-or'ed with LOCK_SH or LOCK_EX then flock will return immediately rather than blocking waiting for the lock (check the return status to see if you got it).

OPERATION は LOCK_SH, LOCK_EX, LOCK_UN のいずれかで、LOCK_NB と 組み合わされることもあります。 これらの定数は伝統的には 1, 2, 8, 4 の値を持ちますが、Fcntl モジュールから シンボル名を独立してインポートするか、 ':flock' タグを使うグループとして、 シンボル名をを使うことができます。 LOCK_SH は共有ロックを要求し、LOCK_EX は排他ロックを要求し、LOCK_UN は 前回要求したロックを開放します。 LOCK_NB と LOCK_SH か LOCK_EX がビット単位の論理和されると、flock は ロックを取得するまで待つのではなく、すぐに返ります(ロックが取得できたか どうかは返り値を調べます)。

To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE before locking or unlocking it.

不一致の可能性を避けるために、Perl はファイルをロック、アンロックする前に FILEHANDLE をフラッシュします。

Note that the emulation built with lockf(3) doesn't provide shared locks, and it requires that FILEHANDLE be open with write intent. These are the semantics that lockf(3) implements. Most if not all systems implement lockf(3) in terms of fcntl(2) locking, though, so the differing semantics shouldn't bite too many people.

lockf(3) で作成されたエミュレーションは共有ロックを提供せず、 FILEHANDLE が書き込みモードで開いていることを必要とすることに 注意してください。 これは lockf(3) が実装している動作です。 しかし、全てではないにしてもほとんどのシステムでは fcntl(2) を使って lockf(3) を実装しているので、異なった動作で多くの人々を混乱させることは ないはずです。

Note also that some versions of flock cannot lock things over the network; you would need to use the more system-specific fcntl for that. If you like you can force Perl to ignore your system's flock(2) function, and so provide its own fcntl(2)-based emulation, by passing the switch -Ud_flock to the Configure program when you configure perl.

ネットワーク越しにはロックできない flock もあることに注意してください; このためには、よりシステム依存な fcntl を使う必要があります。 Perl にシステムの flock(2) 関数を無視させ、自身の fcntl(2) ベースの エミュレーションを使う場合は、perl を設定するときに Configure プログラムに -Ud_flock オプションを渡してください。

Here's a mailbox appender for BSD systems.

BSD システムでのメールボックスへの追加処理の例を示します。

    use Fcntl ':flock'; # import LOCK_* constants

    sub lock {
        flock(MBOX,LOCK_EX);
        # and, in case someone appended
        # while we were waiting...
        seek(MBOX, 0, 2);
    }

    sub unlock {
        flock(MBOX,LOCK_UN);
    }

    open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
            or die "Can't open mailbox: $!";

    lock();
    print MBOX $msg,"\n\n";
    unlock();

On systems that support a real flock(), locks are inherited across fork() calls, whereas those that must resort to the more capricious fcntl() function lose the locks, making it harder to write servers.

真の flock() に対応しているシステムではロックは fork() を通して 継承されるのに対して、より不安定な fcntl() に頼らなければならない場合、 サーバを書くのはより難しくなります。

See also DB_File for other flock() examples.

その他の flock() の例としては DB_File も参照してください。

fork

Does a fork(2) system call to create a new process running the same program at the same point. It returns the child pid to the parent process, 0 to the child process, or undef if the fork is unsuccessful. File descriptors (and sometimes locks on those descriptors) are shared, while everything else is copied. On most systems supporting fork(), great care has gone into making it extremely efficient (for example, using copy-on-write technology on data pages), making it the dominant paradigm for multitasking over the last few decades.

同じプログラムの同じ地点から開始する新しいプロセスを作成するために システムコール fork(2) を行ないます。 親プロセスには、チャイルドプロセスの pid を、 チャイルドプロセスに 0 を返しますが、 fork に失敗したときには、undefを返します。 ファイル記述子(および記述子に関連するロック)は共有され、 その他の全てはコピーされます。 fork() に対応するほとんどのシステムでは、 これを極めて効率的にするために多大な努力が払われてきました (例えば、データページへの copy-on-write テクノロジーなどです)。 これはここ 20 年にわたるマルチタスクに関する主要なパラダイムとなっています。

Beginning with v5.6.0, Perl will attempt to flush all files opened for output before forking the child process, but this may not be supported on some platforms (see perlport). To be safe, you may need to set $| ($AUTOFLUSH in English) or call the autoflush() method of IO::Handle on any open handles in order to avoid duplicate output.

v5.6.0 から、Perl は子プロセスを fork する前に出力用にオープンしている全ての ファイルをフラッシュしようとしますが、これに対応していないプラットフォームも あります(perlport を参照してください)。 安全のためには、出力が重複するのを避けるために、 全てのオープンしているハンドルに対して $| (English モジュールでは $AUTOFLUSH) を設定するか、 IO::Handle モジュールの autoflush()メソッドをを呼ぶ必要が あるかもしれません。

If you fork without ever waiting on your children, you will accumulate zombies. On some systems, you can avoid this by setting $SIG{CHLD} to "IGNORE". See also perlipc for more examples of forking and reaping moribund children.

チャイルドプロセスの終了を待たずに、fork を繰り返せば、 ゾンビをためこむことになります。 $SIG{CHLD}"IGNORE" を指定することでこれを回避できるシステムもあります。 fork と消滅しかけている子プロセスを回収するための更なる例については perlipc も参照してください。

Note that if your forked child inherits system file descriptors like STDIN and STDOUT that are actually connected by a pipe or socket, even if you exit, then the remote server (such as, say, a CGI script or a backgrounded job launched from a remote shell) won't think you're done. You should reopen those to /dev/null if it's any issue.

fork した子プロセスが STDIN や STDOUT といったシステムファイル記述子を 継承する場合、(CGI スクリプトやリモートシェルといった バックグラウンドジョブのような)リモートサーバは考え通りに 動かないであろうことに注意してください。 このような場合ではこれらを /dev/null として再オープンするべきです。

format

Declare a picture format for use by the write function. For example:

write 関数で使うピクチャーフォーマットを宣言します。 例:

    format Something =
        Test: @<<<<<<<< @||||| @>>>>>
              $str,     $%,    '$' . int($num)
    .

    $str = "widget";
    $num = $cost/$quantity;
    $~ = 'Something';
    write;

See perlform for many details and examples.

詳細と例については perlform を参照して下さい。

formline PICTURE,LIST

This is an internal function used by formats, though you may call it, too. It formats (see perlform) a list of values according to the contents of PICTURE, placing the output into the format output accumulator, $^A (or $ACCUMULATOR in English). Eventually, when a write is done, the contents of $^A are written to some filehandle, but you could also read $^A yourself and then set $^A back to "". Note that a format typically does one formline per line of form, but the formline function itself doesn't care how many newlines are embedded in the PICTURE. This means that the ~ and ~~ tokens will treat the entire PICTURE as a single line. You may therefore need to use multiple formlines to implement a single record format, just like the format compiler.

これは、format が使用する内部関数ですが、直接呼び出すこともできます。 これは、PICTURE の内容にしたがって、 LIST の値を整形し (perlform manpage を参照してください)、 結果をフォーマット出力アキュムレータ $^A(English モジュールでは $ACCUMULATOR) に納めます。 最終的に、write が実行されると、$^A の中身が、 何らかのファイルハンドルに書き出されますが、自分で $^A を読んで、 $^A の内容を "" に戻してもかまいません。 format は通常、1 行ごとに formline を行ないますが、 formline 関数自身は、PICTURE の中にいくつの改行が入っているかは、 関係がありません。 これは、~~~トークンは PICTURE 全体を一行として扱うことを意味します。 従って、1 レコードフォーマットを実装するためには フォーマットコンパイラのような複数 formline を使う必要があります。

Be careful if you put double quotes around the picture, because an @ character may be taken to mean the beginning of an array name. formline always returns true. See perlform for other examples.

ダブルクォートで PICTURE を囲む場合には、@ という文字が 配列名の始まりと解釈されますので、注意してください。 formline は常に真を返します。 その他の例については perlform を参照してください。

getc FILEHANDLE
getc

Returns the next character from the input file attached to FILEHANDLE, or the undefined value at end of file, or if there was an error. If FILEHANDLE is omitted, reads from STDIN. This is not particularly efficient. However, it cannot be used by itself to fetch single characters without waiting for the user to hit enter. For that, try something more like:

FILEHANDLE につながれている入力ファイルから、次の一文字を返します。 ファイルの最後、またはエラーが発生した場合は、未定義値を返します。 FILEHANDLE が省略された場合には、STDIN から読み込みを行ないます。 これは特に効率的ではありません。 しかし、これはユーザーがリターンキーを押すのを待つことなく 一文字を読み込む用途には使えません。 そのような場合には、以下のようなものを試して見てください:

    if ($BSD_STYLE) {
        system "stty cbreak </dev/tty >/dev/tty 2>&1";
    }
    else {
        system "stty", '-icanon', 'eol', "\001";
    }

    $key = getc(STDIN);

    if ($BSD_STYLE) {
        system "stty -cbreak </dev/tty >/dev/tty 2>&1";
    }
    else {
        system "stty", 'icanon', 'eol', '^@'; # ASCII null
    }
    print "\n";

Determination of whether $BSD_STYLE should be set is left as an exercise to the reader.

$BSD_STYLE をセットするべきかどうかを決定する方法については 読者への宿題として残しておきます。

The POSIX::getattr function can do this more portably on systems purporting POSIX compliance. See also the Term::ReadKey module from your nearest CPAN site; details on CPAN can be found on "CPAN" in perlmodlib.

POSIX::getattr 関数は POSIX 準拠を主張するシステムで これをより移植性のある形で行います。お近くの CPAN サイトから Term::ReadKey モジュールも参照して下さい; CPAN に関する詳細は "CPAN" in perlmodlib にあります。

getlogin

Implements the C library function of the same name, which on most systems returns the current login from /etc/utmp, if any. If null, use getpwuid.

同じ名前の C ライブラリ関数の実装です。 多くのシステムでは、もしあれば、/etc/utmp から現在のログイン名を返します。 ヌルであれば、getpwuid() を使ってください。

    $login = getlogin || getpwuid($<) || "Kilroy";

Do not consider getlogin for authentication: it is not as secure as getpwuid.

getlogin を認証に使ってはいけません。 これは getpwuid のように安全ではありません。

getpeername SOCKET

Returns the packed sockaddr address of other end of the SOCKET connection.

SOCKET コネクションの向こう側のパックされた aockaddr アドレスを返します。

    use Socket;
    $hersockaddr    = getpeername(SOCK);
    ($port, $iaddr) = sockaddr_in($hersockaddr);
    $herhostname    = gethostbyaddr($iaddr, AF_INET);
    $herstraddr     = inet_ntoa($iaddr);
getpgrp PID

Returns the current process group for the specified PID. Use a PID of 0 to get the current process group for the current process. Will raise an exception if used on a machine that doesn't implement getpgrp(2). If PID is omitted, returns process group of current process. Note that the POSIX version of getpgrp does not accept a PID argument, so only PID==0 is truly portable.

指定された PID の現在のプロセスグループを返します。 PID に 0 を与えるとカレントプロセスの指定となります。 getpgrp(2) を実装していないマシンで実行した場合には、例外が発生します。 PID を省略するとカレントプロセスのプロセスグループを返します。 POSIX 版の getpgrp は PID 引数を受け付けないので、 PID==0 のみが完全に移植性があります。

getppid

Returns the process id of the parent process.

親プロセスのプロセス id を返します。

getpriority WHICH,WHO

Returns the current priority for a process, a process group, or a user. (See getpriority(2).) Will raise a fatal exception if used on a machine that doesn't implement getpriority(2).

プロセス、プロセスグループ、ユーザに対する現在の優先度を返します。 (getpriority(2) を参照してください。) getpriority(2) を実装していない マシンで実行した場合には、例外が発生します。

getpwnam NAME
getgrnam NAME
gethostbyname NAME
getnetbyname NAME
getprotobyname NAME
getpwuid UID
getgrgid GID
getservbyname NAME,PROTO
gethostbyaddr ADDR,ADDRTYPE
getnetbyaddr ADDR,ADDRTYPE
getprotobynumber NUMBER
getservbyport PORT,PROTO
getpwent
getgrent
gethostent
getnetent
getprotoent
getservent
setpwent
setgrent
sethostent STAYOPEN
setnetent STAYOPEN
setprotoent STAYOPEN
setservent STAYOPEN
endpwent
endgrent
endhostent
endnetent
endprotoent
endservent

These routines perform the same functions as their counterparts in the system library. In list context, the return values from the various get routines are as follows:

これらのルーチンは、システムライブラリの同名の関数を実行します。 リストコンテキストでは、さまざまな get ルーチンからの返り値は、次のようになります:

    ($name,$passwd,$uid,$gid,
       $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
    ($name,$passwd,$gid,$members) = getgr*
    ($name,$aliases,$addrtype,$length,@addrs) = gethost*
    ($name,$aliases,$addrtype,$net) = getnet*
    ($name,$aliases,$proto) = getproto*
    ($name,$aliases,$port,$proto) = getserv*

(If the entry doesn't exist you get a null list.)

(エントリが存在しなければ、空リストが返されます。)

The exact meaning of the $gcos field varies but it usually contains the real name of the user (as opposed to the login name) and other information pertaining to the user. Beware, however, that in many system users are able to change this information and therefore it cannot be trusted and therefore the $gcos is tainted (see perlsec). The $passwd and $shell, user's encrypted password and login shell, are also tainted, because of the same reason.

$gcos フィールドの正確な意味はさまざまですが、通常は(ログイン名ではなく) ユーザーの実際の名前とユーザーに付随する情報を含みます。 但し、多くのシステムではユーザーがこの情報を変更できるので、この情報は 信頼できず、従って $gcos は汚染されます(perlsec を参照してください)。 ユーザーの暗号化されたパスワードとログインシェルである $passwd と $shell も、同様の理由で汚染されます。

In scalar context, you get the name, unless the function was a lookup by name, in which case you get the other thing, whatever it is. (If the entry doesn't exist you get the undefined value.) For example:

スカラコンテキストでは、*nam、*byname といった NAME で検索するもの以外は、 name を返し、NAME で検索するものは、何か別のものを返します。 (エントリが存在しなければ、未定義値が返ります。) 例:

    $uid   = getpwnam($name);
    $name  = getpwuid($num);
    $name  = getpwent();
    $gid   = getgrnam($name);
    $name  = getgrgid($num;
    $name  = getgrent();
    #etc.

In getpw*() the fields $quota, $comment, and $expire are special cases in the sense that in many systems they are unsupported. If the $quota is unsupported, it is an empty scalar. If it is supported, it usually encodes the disk quota. If the $comment field is unsupported, it is an empty scalar. If it is supported it usually encodes some administrative comment about the user. In some systems the $quota field may be $change or $age, fields that have to do with password aging. In some systems the $comment field may be $class. The $expire field, if present, encodes the expiration period of the account or the password. For the availability and the exact meaning of these fields in your system, please consult your getpwnam(3) documentation and your pwd.h file. You can also find out from within Perl what your $quota and $comment fields mean and whether you have the $expire field by using the Config module and the values d_pwquota, d_pwage, d_pwchange, d_pwcomment, and d_pwexpire. Shadow password files are only supported if your vendor has implemented them in the intuitive fashion that calling the regular C library routines gets the shadow versions if you're running under privilege or if there exists the shadow(3) functions as found in System V ( this includes Solaris and Linux.) Those systems which implement a proprietary shadow password facility are unlikely to be supported.

getpw*() では、$quota, $comment, $expire フィールドは、 多くのシステムでは対応していないので特別な処理がされます。 $quota が非対応の場合、空のスカラになります。 対応している場合、通常はディスククォータの値が入ります。 $comment フィールドが非対応の場合、空のスカラになります。 対応している場合、通常はユーザーに関する管理上のコメントが入ります。 $quota フィールドはパスワードの寿命を示す $change や $age である システムもあります。 $comment フィールドは $class であるシステムもあります。 $expire フィールドがある場合は、アカウントやパスワードが時間切れになる 期間が入ります。 動作させるシステムでのこれらのフィールドの有効性と正確な意味については、 getpwnam(3) のドキュメントと pwd.h ファイルを参照してください。 $quota と $comment フィールドが何を意味しているかと、$expire フィールドが あるかどうかは、Config モジュールを使って、d_pwquota, d_pwage, d_pwchange, d_pwcomment, d_pwexpire の値を調べることによって Perl 自身で調べることも出来ます。 シャドウパスワードは、通常の C ライブラリルーチンを権限がある状態で 呼び出すことでシャドウ版が取得できるか、System V にあるような (Solaris と Linux を含みます) shadow(3) 関数があるといった、 直感的な方法で実装されている場合にのみ対応されます。 独占的なシャドウパスワード機能を実装しているシステムでは、 それに対応されることはないでしょう。

The $members value returned by getgr*() is a space separated list of the login names of the members of the group.

getgr*() によって返る値 $members は、グループのメンバの ログイン名をスペースで区切ったものです。

For the gethost*() functions, if the h_errno variable is supported in C, it will be returned to you via $? if the function call fails. The @addrs value returned by a successful call is a list of the raw addresses returned by the corresponding system library call. In the Internet domain, each address is four bytes long and you can unpack it by saying something like:

    ($a,$b,$c,$d) = unpack('C4',$addr[0]);

gethost*() 関数では、C で h_errno 変数がサポートされていれば、 関数呼出が失敗したときに、$? を通して、その値が返されます。 成功時に返される @addrs 値は、対応するシステムコールが返す、 生のアドレスのリストです。 インターネットドメインでは、個々のアドレスは、4 バイト長で、 以下のようにして unpack することができます。

    ($a,$b,$c,$d) = unpack('C4',$addr[0]);

The Socket library makes this slightly easier:

Socket ライブラリを使うともう少し簡単になります。

    use Socket;
    $iaddr = inet_aton("127.1"); # or whatever address
    $name  = gethostbyaddr($iaddr, AF_INET);

    # or going the other way
    $straddr = inet_ntoa($iaddr);

If you get tired of remembering which element of the return list contains which return value, by-name interfaces are provided in standard modules: File::stat, Net::hostent, Net::netent, Net::protoent, Net::servent, Time::gmtime, Time::localtime, and User::grent. These override the normal built-ins, supplying versions that return objects with the appropriate names for each field. For example:

返り値のリストの何番目がどの要素かを覚えるのに疲れたなら、 名前ベースのインターフェースが標準モジュールで提供されています: File::stat, Net::hostent, Net::netent, Net::protoent, Net::servent, Time::gmtime, Time::localtime, User::grent です。 これらは通常の組み込みを上書きし、 それぞれのフィールドに適切な名前をつけたオブジェクトを返します。 例:

   use File::stat;
   use User::pwent;
   $is_his = (stat($filename)->uid == pwent($whoever)->uid);

Even though it looks like they're the same method calls (uid), they aren't, because a File::stat object is different from a User::pwent object.

同じメソッド(uid)を呼び出しているように見えますが、違います。 なぜなら File::stat オブジェクトは User::pwent オブジェクトとは 異なるからです。

getsockname SOCKET

Returns the packed sockaddr address of this end of the SOCKET connection, in case you don't know the address because you have several different IPs that the connection might have come in on.

SOCKET 接続のこちら側の pack された sockaddr アドレスを返します。 複数の異なる IP から接続されるためにアドレスがわからない場合に使います。

    use Socket;
    $mysockaddr = getsockname(SOCK);
    ($port, $myaddr) = sockaddr_in($mysockaddr);
    printf "Connect to %s [%s]\n", 
       scalar gethostbyaddr($myaddr, AF_INET),
       inet_ntoa($myaddr);
getsockopt SOCKET,LEVEL,OPTNAME

Returns the socket option requested, or undef if there is an error.

要求されたソケットオプションを返し、 エラーの場合には undef を返します。

glob EXPR
glob

Returns the value of EXPR with filename expansions such as the standard Unix shell /bin/csh would do. This is the internal function implementing the <*.c> operator, but you can use it directly. If EXPR is omitted, $_ is used. The <*.c> operator is discussed in more detail in "I/O Operators" in perlop.

EXPR の値を、標準 Unix シェル /bin/csh が行なうように、 ファイル名の展開を行なって返します。 これは、<*.c> 演算子を実装する内部関数ですが、 直接使用することもできます。 EXPR を省略すると、$_が使われます。 <*.c>演算子については "I/O Operators" in perlop でより詳細に議論しています。

Beginning with v5.6.0, this operator is implemented using the standard File::Glob extension. See File::Glob for details.

v5.6.0 から、この演算子は標準の File::Glob 拡張を使って 実装されています。 詳細は File::Glob を参照して下さい。

gmtime EXPR

Converts a time as returned by the time function to a 8-element list with the time localized for the standard Greenwich time zone. Typically used as follows:

time 関数が返す時刻を、グリニッジタイムゾーンで測った時刻として、 8 要素のリストに変換します。 通常は、以下のようにして使用します:

    #  0    1    2     3     4    5     6     7  
    ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
                                            gmtime(time);

All list elements are numeric, and come straight out of the C `struct tm'. $sec, $min, and $hour are the seconds, minutes, and hours of the specified time. $mday is the day of the month, and $mon is the month itself, in the range 0..11 with 0 indicating January and 11 indicating December. $year is the number of years since 1900. That is, $year is 123 in year 2023. $wday is the day of the week, with 0 indicating Sunday and 3 indicating Wednesday. $yday is the day of the year, in the range 0..364 (or 0..365 in leap years.)

すべてのリスト要素は数値で、C の `struct tm' 構造体から 直接持ってきます。 $sec, $min, $hour は指定された時刻の秒、分、時です。 $mday は月の何日目か、$mon は月の値です。 月の値は 0..11 で、0 が 1 月、11 が 12 月です。 $year は 1900 年からの年数です。 つまり、$year が 123 なら 2023 年です。 $wday は曜日で、0 が日曜日、3 が木曜日です。 $yday はその年の何日目かで、0..364 の値を取ります (うるう年は 0..365 です)。

Note that the $year element is not simply the last two digits of the year. If you assume it is, then you create non-Y2K-compliant programs--and you wouldn't want to do that, would you?

$year 要素は単純に年の下 2 桁を返す のではない ことに注意してください。 もしそう仮定してしまうと、Y2K 準拠でないプログラムを作ってしまいます-- そうはしたくないでしょう?

The proper way to get a complete 4-digit year is simply:

完全な 4 桁の年を得る正しい方法は単純です:

        $year += 1900;

And to get the last two digits of the year (e.g., '01' in 2001) do:

そして年の下 2 桁(2001 年なら '01')を得るには次のようにします:

        $year = sprintf("%02d", $year % 100);

If EXPR is omitted, gmtime() uses the current time (gmtime(time)).

EXPR が省略されると、gmtime() は現在の時刻を使います (gmtime(time))。

In scalar context, gmtime() returns the ctime(3) value:

スカラコンテキストでは、gmtime() は ctime(3) の値を返します:

    $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"

Also see the timegm function provided by the Time::Local module, and the strftime(3) function available via the POSIX module.

Time::Local で提供されている timegm 関数も参照して下さい。 また、POSIX モジュールで strftime(3) 関数が利用可能です。

This scalar value is not locale dependent (see perllocale), but is instead a Perl builtin. Also see the Time::Local module, and the strftime(3) and mktime(3) functions available via the POSIX module. To get somewhat similar but locale dependent date strings, set up your locale environment variables appropriately (please see perllocale) and try for example:

このスカラ値はロケール依存 ではなく (perllocale を参照してください)、 Perl 組み込み機能です。 ロケール依存で似たような日付文字列を得るには、ロケール環境変数を 適切に設定(perllocale を参照してください)した上で、 以下の例を試してください:

    use POSIX qw(strftime);
    $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;

Note that the %a and %b escapes, which represent the short forms of the day of the week and the month of the year, may not necessarily be three characters wide in all locales.

%a%b、つまり曜日と月の短い表現は全てのロケールで 3 文字であるとは 限らないことに注意してください。

goto LABEL
goto EXPR
goto &NAME

The goto-LABEL form finds the statement labeled with LABEL and resumes execution there. It may not be used to go into any construct that requires initialization, such as a subroutine or a foreach loop. It also can't be used to go into a construct that is optimized away, or to get out of a block or subroutine given to sort. It can be used to go almost anywhere else within the dynamic scope, including out of subroutines, but it's usually better to use some other construct such as last or die. The author of Perl has never felt the need to use this form of goto (in Perl, that is--C is another matter).

goto-LABEL の形式は、LABEL というラベルの付いた文を 探して、そこへ実行を移すものです。 サブルーチンや foreach ループなど、何らかの初期化が必要な構造の中に 入り込むことは許されません。 最適化によってなくなってしまう構造の中にも goto することはできません。 また、sortで与えられたブロックやサブルーチンから外へ出ることもできません。 これ以外は、サブルーチンの外を含む、動的スコープ内の ほとんどすべての場所へ行くために使用できますが、普通は、 lastdie といった別の構造を使った方が良いでしょう。 Perl の作者はこの形式の goto を使う必要を感じたことは、 1 度もありません (Perl では。C は別のお話です)。

The goto-EXPR form expects a label name, whose scope will be resolved dynamically. This allows for computed gotos per FORTRAN, but isn't necessarily recommended if you're optimizing for maintainability:

goto-EXPR の形式はラベル名を予測し、このスコープは動的に解決されます。 これにより FORTRAN のような算術 goto が可能になりますが、 保守性を重視するならお勧めしません。

    goto ("FOO", "BAR", "GLARCH")[$i];

The goto-&NAME form is quite different from the other forms of goto. In fact, it isn't a goto in the normal sense at all, and doesn't have the stigma associated with other gotos. Instead, it substitutes a call to the named subroutine for the currently running subroutine. This is used by AUTOLOAD subroutines that wish to load another subroutine and then pretend that the other subroutine had been called in the first place (except that any modifications to @_ in the current subroutine are propagated to the other subroutine.) After the goto, not even caller will be able to tell that this routine was called first.

goto-&NAME の形式は、その他の goto の形式とはかなり 異なったものです。 実際、これは普通の感覚でいうところのどこかへ行くものでは全くなく、 他の goto が持つ不名誉を持っていません。 これは、実行中のサブルーチンを、NAME で指定されたサブルーチンの 呼び出しで置き換えます。 これは、AUTOLOAD サブルーチンが別のサブルーチンをロードして、 その別のサブルーチンが最初に呼ばれたようにするために使われます (ただし、現在のサブルーチンで @_ を修正した場合には、 その別のサブルーチンに伝えられます)。 goto のあとは、caller でさえも、現在のサブルーチンが 最初に呼び出されたと言うことができません。

NAME needn't be the name of a subroutine; it can be a scalar variable containing a code reference, or a block which evaluates to a code reference.

NAME はサブルーチンの名前である必要はありません; コードリファレンスを 含むスカラ値や、コードリファレンスと評価されるブロックでも構いません。

grep BLOCK LIST
grep EXPR,LIST

This is similar in spirit to, but not the same as, grep(1) and its relatives. In particular, it is not limited to using regular expressions.

これは grep(1) とその親類と同じようなものですが、同じではありません。 特に、正規表現の使用に制限されません。

Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each element) and returns the list value consisting of those elements for which the expression evaluated to true. In scalar context, returns the number of times the expression was true.

LIST の個々の要素に対して、BLOCK か EXPR を評価し ($_ は、ローカルに個々の要素が設定されます) 、 その要素のうち、評価した式が真となったものからなるリスト値が返されます。 スカラコンテキストでは、式が真となった回数を返します。 例:

    @foo = grep(!/^#/, @bar);    # weed out comments

or equivalently,

あるいは等価な例として:

    @foo = grep {!/^#/} @bar;    # weed out comments

Note that $_ is an alias to the list value, so it can be used to modify the elements of the LIST. While this is useful and supported, it can cause bizarre results if the elements of LIST are not variables. Similarly, grep returns aliases into the original list, much as a for loop's index variable aliases the list elements. That is, modifying an element of a list returned by grep (for example, in a foreach, map or another grep) actually modifies the element in the original list. This is usually something to be avoided when writing clear code.

$_ は、LIST の値へのエイリアスですので、LIST の要素を 変更するために使うことができます。 これは、便利でサポートされていますが、 LIST の要素が変数でないと、おかしな結果になります。 同様に、grep は元のリストへのエイリアスを返します。 for ループのインデックス変数がリスト要素のエイリアスであるのと 同様です。 つまり、grep で返されたリストの要素を (foreach, map, または他の grep で)修正すると 元のリストの要素が変更されます。 これはきれいなコードを書こうとする邪魔になることが多いです。

See also "map" for a list composed of the results of the BLOCK or EXPR.

BLOCK や EXPR の結果をリストの形にしたい場合は "map" を参照してください。

hex EXPR
hex

Interprets EXPR as a hex string and returns the corresponding value. (To convert strings that might start with either 0, 0x, or 0b, see "oct".) If EXPR is omitted, uses $_.

EXPR を 16 進数の文字列と解釈して、対応する値を返します。 (0, 0x, 0b で始まる文字列の変換には、"oct" を 参照してください。) EXPR が省略されると、$_ を使用します。

    print hex '0xAf'; # prints '175'
    print hex 'aF';   # same

Hex strings may only represent integers. Strings that would cause integer overflow trigger a warning.

16 進文字列は整数のみを表現します。 整数オーバーフローを起こすような文字列は警告を引き起こします。

import

There is no builtin import function. It is just an ordinary method (subroutine) defined (or inherited) by modules that wish to export names to another module. The use function calls the import method for the package used. See also "use", perlmod, and Exporter.

組み込みの import 関数というものはありません。 これは単に、別のモジュールに名前をエクスポートしたいモジュールが 定義した(または継承した)、通常のメソッド(サブルーチン)です。 use 関数はパッケージを使う時に import メソッドを呼び出します。 "use", perlmod, Exporter も参照してください。

index STR,SUBSTR,POSITION
index STR,SUBSTR

The index function searches for one string within another, but without the wildcard-like behavior of a full regular-expression pattern match. It returns the position of the first occurrence of SUBSTR in STR at or after POSITION. If POSITION is omitted, starts searching from the beginning of the string. The return value is based at 0 (or whatever you've set the $[ variable to--but don't do that). If the substring is not found, returns one less than the base, ordinarily -1.

index 関数は ある文字列をもうひとつの文字列から検索しますが、 完全正規表現パターンマッチのワイルドカード的な振る舞いはしません。 STR の中の POSITION の位置以降で、最初に SUBSTR が見つかった位置を返します。 POSITION が省略された場合には、STR の最初から探し始めます。 返り値のベースは、0 (もしくは、変数 $[ に設定した値です -- しかし、 これは使ってはいけません)。 SURSTR が見つからなかった場合には、ベースよりも 1 小さい値、 通常は -1 が返されます。

int EXPR
int

Returns the integer portion of EXPR. If EXPR is omitted, uses $_. You should not use this function for rounding: one because it truncates towards 0, and two because machine representations of floating point numbers can sometimes produce counterintuitive results. For example, int(-6.725/0.025) produces -268 rather than the correct -269; that's because it's really more like -268.99999999999994315658 instead. Usually, the sprintf, printf, or the POSIX::floor and POSIX::ceil functions will serve you better than will int().

EXPR の整数部を返します。 EXPR を省略すると、$_ を使います。 この関数を丸めのために使うべきではありません。 第一の理由として 0 の方向への切捨てを行うから、第二の理由として 浮動小数点数の機械表現は時々直感に反した結果を生み出すからです。 たとえば、int(-6.725/0.025) は正しい結果である -269 ではなく -268 を返します。 これは実際には -268.99999999999994315658 というような値になっているからです。 通常、sprintf, printf, POSIX::floor, POSIX::ceil の方が int() より便利です。

ioctl FILEHANDLE,FUNCTION,SCALAR

Implements the ioctl(2) function. You'll probably first have to say

ioctl(2) 関数を実装します。 正しい関数の定義を得るために、おそらく最初に

    require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph

to get the correct function definitions. If ioctl.ph doesn't exist or doesn't have the correct definitions you'll have to roll your own, based on your C header files such as <sys/ioctl.h>. (There is a Perl script called h2ph that comes with the Perl kit that may help you in this, but it's nontrivial.) SCALAR will be read and/or written depending on the FUNCTION--a pointer to the string value of SCALAR will be passed as the third argument of the actual ioctl call. (If SCALAR has no string value but does have a numeric value, that value will be passed rather than a pointer to the string value. To guarantee this to be true, add a 0 to the scalar before using it.) The pack and unpack functions may be needed to manipulate the values of structures used by ioctl.

としなくてはならないでしょう。 ioctl.h がないか、間違った定義をしている場合には、 <sys/ioctl.ph>のような C のヘッダファイルをもとに、 自分で作らなければなりません。 (Perl の配布キットに入っている h2ph という Perl スクリプトがこれを手助けしてくれるでしょうが、これは重要です。) FOUNCTION に応じて SCALAR が読み書きされます。 SCALAR の文字列値へのポインタが、実際の ioctl コールの 3 番目の引数として渡されます。 (SCALAR が文字列値を持っておらず、数値を持っている場合には、 文字列値へのポインタの代わりに、その値が渡されます。 このことを保証するためには、使用する前に SCALAR に0 を足してください。) ioctl で使われる構造体の値を操作するには、 pack 関数と unpack 関数が必要となるでしょう。

The return value of ioctl (and fcntl) is as follows:

ioctl (と fcntl) の返り値は、以下のようになります:

        if OS returns:          then Perl returns:
            -1                    undefined value
             0                  string "0 but true"
        anything else               that number
        OS が返した値:                 Perl が返す値:
            -1                       未定義値
             0                  「0 だが真」の文字列
          その他             その値そのもの

Thus Perl returns true on success and false on failure, yet you can still easily determine the actual value returned by the operating system:

つまり Perl は、成功時に「真」、失敗時に「偽」を返す ことになり、OS が実際に返した値も、以下のように簡単に知ることができます。

    $retval = ioctl(...) || -1;
    printf "System returned %d\n", $retval;

The special string "0 but true" is exempt from -w complaints about improper numeric conversions.

特別な文字列 "0 だが真" は、不適切な数値変換に関する -w 警告を回避します。

Here's an example of setting a filehandle named REMOTE to be non-blocking at the system level. You'll have to negotiate $| on your own, though.

これは REMOTE というファイルハンドルをシステムレベルで 非ブロックモードにセットする例です。 ただし、 $| を自分で管理しなければなりません。

    use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);

    $flags = fcntl(REMOTE, F_GETFL, 0)
                or die "Can't get flags for the socket: $!\n";

    $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
                or die "Can't set flags for the socket: $!\n";
join EXPR,LIST

Joins the separate strings of LIST into a single string with fields separated by the value of EXPR, and returns that new string. Example:

LIST の個別の文字列を、EXPR の値で区切って 1 つの文字列につなげ、その文字列を返します。 例:

    $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);

Beware that unlike split, join doesn't take a pattern as its first argument. Compare "split".

split と違って、join は最初の引数にパターンは取れないことに 注意してください。 "split" と比較してください。

keys HASH

Returns a list consisting of all the keys of the named hash. (In scalar context, returns the number of keys.) The keys are returned in an apparently random order. The actual random order is subject to change in future versions of perl, but it is guaranteed to be the same order as either the values or each function produces (given that the hash has not been modified). As a side effect, it resets HASH's iterator.

指定したハッシュのすべての key からなる、リストを返します。 (スカラコンテキストでは、key の数を返します。) キーは見たところではランダムな順番に返されます。 実際のランダムな順番は perl の将来のバージョンでは変わるかもしれませんが、 valueseach 関数が同じ(変更されていない)ハッシュに対して 生成するのと同じ順番であることは保証されます。 副作用として、HASH の反復子を初期化します。

Here is yet another way to print your environment:

環境変数を表示する別の例です:

    @keys = keys %ENV;
    @values = values %ENV;
    while (@keys) { 
        print pop(@keys), '=', pop(@values), "\n";
    }

or how about sorted by key:

key でソートしてもいいでしょう:

    foreach $key (sort(keys %ENV)) {
        print $key, '=', $ENV{$key}, "\n";
    }

The returned values are copies of the original keys in the hash, so modifying them will not affect the original hash. Compare "values".

返される値はハッシュにある元のキーのコピーなので、 これを変更しても元のハッシュには影響を与えません。 "values" と比較してください。

To sort a hash by value, you'll need to use a sort function. Here's a descending numeric sort of a hash by its values:

ハッシュを値でソートするためには、sort 関数を使う必要があります。 以下ではハッシュの値を数値の降順でソートしています:

    foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
        printf "%4d %s\n", $hash{$key}, $key;
    }

As an lvalue keys allows you to increase the number of hash buckets allocated for the given hash. This can gain you a measure of efficiency if you know the hash is going to get big. (This is similar to pre-extending an array by assigning a larger number to $#array.) If you say

左辺値としては、keys を使うことで与えられたハッシュに割り当てられた ハッシュ表の大きさを増やすことができます。 これによって、ハッシュが大きくなっていくなっていくときの 効率の測定ができます。以下のようにすると:

    keys %hash = 200;

then %hash will have at least 200 buckets allocated for it--256 of them, in fact, since it rounds up to the next power of two. These buckets will be retained even if you do %hash = (), use undef %hash if you want to free the storage while %hash is still in scope. You can't shrink the number of buckets allocated for the hash using keys in this way (but you needn't worry about doing this by accident, as trying has no effect).

%hash は少なくとも 200 の大きさの表が割り当てられます -- 実際には 2 のべき乗に切り上げられるので、256 が割り当てられます。 この表はたとえ %hash = () としても残るので、 もし %hash がスコープにいるうちにこの領域を開放したい場合は undef %hash を使います。 この方法で keys を使うことで、表の大きさを小さくすることはできません (間違えてそのようなことをしても何も起きないので気にすることはありません)。

See also each, values and sort.

each, values, sort も参照してください。

kill SIGNAL, LIST

Sends a signal to a list of processes. Returns the number of processes successfully signaled (which is not necessarily the same as the number actually killed).

プロセスのリストにシグナルを送ります。シグナル送信に成功したプロセスの 数を返します (実際に kill に成功したプロセスと同じとは限りません)。

    $cnt = kill 1, $child1, $child2;
    kill 9, @goners;

If SIGNAL is zero, no signal is sent to the process. This is a useful way to check that the process is alive and hasn't changed its UID. See perlport for notes on the portability of this construct.

SIGNAL がゼロの場合、プロセスにシグナルは送られません。 これはプロセスが生きていて、 UID が変わっていないことを調べる時に 有用です。 この構成の移植性に関する注意については perlport を参照して下さい。

Unlike in the shell, if SIGNAL is negative, it kills process groups instead of processes. (On System V, a negative PROCESS number will also kill process groups, but that's not portable.) That means you usually want to use positive not negative signals. You may also use a signal name in quotes. See "Signals" in perlipc for details.

シェルとは異なり、シグナルに負の数を与えると、 プロセスではなくプロセスグループに対して kill を行ないます。 (Syetem V では、プロセス番号として負の値を与えても、 プロセスグループの kill を行ないますが、 移植性がありません。) すなわち、通常は、負のシグナルは用いず、正のシグナルを使うことになります。 シグナル名をクォートして使うこともできます。 詳細は"Signals" in perlipcを参照してください。

last LABEL
last

The last command is like the break statement in C (as used in loops); it immediately exits the loop in question. If the LABEL is omitted, the command refers to the innermost enclosing loop. The continue block, if any, is not executed:

last コマンドは、(ループ内で使った) C の break 文と 同じようなもので、LABEL で指定されるループを即座に抜けます。 LABEL が省略されると、一番内側のループが対象となります。 continue ブロックがあっても実行されません:

    LINE: while (<STDIN>) {
        last LINE if /^$/;      # exit when done with header
        #...
    }

last cannot be used to exit a block which returns a value such as eval {}, sub {} or do {}, and should not be used to exit a grep() or map() operation.

lasteval {}, sub {}, do {} といった 値を返すブロックを終了するのには使えませんし、 grep() や map() 操作を終了するのに使うべきではありません。

Note that a block by itself is semantically identical to a loop that executes once. Thus last can be used to effect an early exit out of such a block.

ブロックはそれ自体文法的には一度だけ実行されるループと同等であることに 注意してください。従って、last でそのようなブロックを 途中で抜け出すことができます。

See also "continue" for an illustration of how last, next, and redo work.

last, next, redo がどのように働くかについては "continue" を参照して下さい。

lc EXPR
lc

Returns an lowercased version of EXPR. This is the internal function implementing the \L escape in double-quoted strings. Respects current LC_CTYPE locale if use locale in force. See perllocale and utf8.

EXPR を小文字に変換したものを返します。 これは、ダブルクォート文字列における、 \L エスケープを実装する内部関数です。 use locale が有効な場合は、現在の LC_CTYPE ロケールを参照します。 perllocaleutf8 を参照してください。

If EXPR is omitted, uses $_.

EXPR が省略されると、$_を使います。

lcfirst EXPR
lcfirst

Returns the value of EXPR with the first character lowercased. This is the internal function implementing the \l escape in double-quoted strings. Respects current LC_CTYPE locale if use locale in force. See perllocale.

最初の文字だけを小文字にした、EXPR を返します。 これは、ダブルクォート文字列における、\l エスケープを 実装する内部関数です。 use locale が有効な場合は、現在の LC_CTYPE ロケールを参照します。 perllocale を参照してください。

If EXPR is omitted, uses $_.

EXPR が省略されると、$_を使います。

length EXPR
length

Returns the length in characters of the value of EXPR. If EXPR is omitted, returns length of $_. Note that this cannot be used on an entire array or hash to find out how many elements these have. For that, use scalar @array and scalar keys %hash respectively.

EXPR の値の文字の長さを返します。 EXPR が省略されたときには、$_ の長さを返します。 これは配列やハッシュ全体に対してどれだけの要素を含んでいるかを 調べるためには使えません。 そのような用途には、それぞれ scalar @arrayscalar keys %hash を 利用してください。

link OLDFILE,NEWFILE

Creates a new filename linked to the old filename. Returns true for success, false otherwise.

OLDFILE にリンクされた、新しいファイル NEWFILE を作 ります。 成功時には true を、失敗時には false を返します。

listen SOCKET,QUEUESIZE

Does the same thing that the listen system call does. Returns true if it succeeded, false otherwise. See the example in "Sockets: Client/Server Communication" in perlipc.

listen システムコールと同じことをします。成功時には真を返し、 失敗時には偽を返します。 "Sockets: Client/Server Communication" in perlipcの例を参照してください。

local EXPR

You really probably want to be using my instead, because local isn't what most people think of as "local". See "Private Variables via my()" in perlsub for details.

あなたはが本当に望んでいるのは my の方でしょう。 local はほとんどの人々が「ローカル」と考えるものと違うからです。 詳細は"Private Variables via my()" in perlsubを参照してください。

A local modifies the listed variables to be local to the enclosing block, file, or eval. If more than one value is listed, the list must be placed in parentheses. See "Temporary Values via local()" in perlsub for details, including issues with tied arrays and hashes.

"local" はリストアップされた変数を、囲っているブロック、 ファイル、eval の中で、ローカルなものにします。 複数の値を指定する場合は、リストは括弧でくくらなければなりません。 tie した配列とハッシュに関する事項を含む詳細については "Temporary Values via local()" in perlsub を参照してください。

localtime EXPR

Converts a time as returned by the time function to a 9-element list with the time analyzed for the local time zone. Typically used as follows:

time 関数が返す時刻を、ローカルなタイムゾーンで測った時刻として、 9 要素の配列に変換します。 通常は、以下のようにして使用します。

    #  0    1    2     3     4    5     6     7     8
    ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
                                                localtime(time);

All list elements are numeric, and come straight out of the C `struct tm'. $sec, $min, and $hour are the seconds, minutes, and hours of the specified time. $mday is the day of the month, and $mon is the month itself, in the range 0..11 with 0 indicating January and 11 indicating December. $year is the number of years since 1900. That is, $year is 123 in year 2023. $wday is the day of the week, with 0 indicating Sunday and 3 indicating Wednesday. $yday is the day of the year, in the range 0..364 (or 0..365 in leap years.) $isdst is true if the specified time occurs during daylight savings time, false otherwise.

すべてのリスト要素は数値で、C の `struct tm' 構造体から 直接持ってきます。 $sec, $min, $hour は指定された時刻の秒、分、時です。 $mday は月の何日目か、$mon は月の値です。 月の値は 0..11 で、0 が 1 月、11 が 12 月です。 $year は 1900 年からの年数です。 つまり、$year が 123 なら 2023 年です。 $wday は曜日で、0 が日曜日、3 が木曜日です。 $yday はその年の何日目かで、0..364 の値を取ります (うるう年は 0..365 です)。 $isdst は指定された時刻が夏時間の場合は真、そうでなければ偽です。

Note that the $year element is not simply the last two digits of the year. If you assume it is, then you create non-Y2K-compliant programs--and you wouldn't want to do that, would you?

$year 要素が単に西暦の下 2 桁を表している のではない ことに 注意してください。これを仮定すると、Y2K 問題を含んだプログラムを 作ることになります。それはお望みじゃないでしょう?

The proper way to get a complete 4-digit year is simply:

完全な 4 桁の西暦を得るには単に以下のようにしてください:

        $year += 1900;

And to get the last two digits of the year (e.g., '01' in 2001) do:

そして西暦の下 2 桁(2001 年では '01')がほしい場合は以下のようにします:

        $year = sprintf("%02d", $year % 100);

If EXPR is omitted, localtime() uses the current time (localtime(time)).

EXPR が省略されると、localtime(time()) を行ないます。

In scalar context, localtime() returns the ctime(3) value:

スカラコンテキストでは、ctime(3) の値を返します:

    $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"

This scalar value is not locale dependent, see perllocale, but instead a Perl builtin. Also see the Time::Local module (to convert the second, minutes, hours, ... back to seconds since the stroke of midnight the 1st of January 1970, the value returned by time()), and the strftime(3) and mktime(3) functions available via the POSIX module. To get somewhat similar but locale dependent date strings, set up your locale environment variables appropriately (please see perllocale) and try for example:

スカラ値はロケール依存 ではなく、Perl の組み込みの値です (perllocale を参照してください)。 また、(秒、分、時…の形から、time() が返す値である 1970 年 1 月 1 日の真夜中からの秒数に変換する) Time::Local モジュール 及び POSIX モジュールで提供される strftime(3) と mktime(3) 関数も 参照してください。 似たような、しかしロケール依存の日付文字列がほしい場合は、 ロケール環境変数を適切に設定して(perllocale を参照してください)、 以下の例を試してください:

    use POSIX qw(strftime);
    $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;

Note that the %a and %b, the short forms of the day of the week and the month of the year, may not necessarily be three characters wide.

曜日と月の短い表現である %a%b は、3 文字とは限らないことに 注意してください。

lock
    lock THING

This function places an advisory lock on a variable, subroutine, or referenced object contained in THING until the lock goes out of scope. This is a built-in function only if your version of Perl was built with threading enabled, and if you've said use Threads. Otherwise a user-defined function by this name will be called. See Thread.

この関数は THING が含む変数、サブルーチン、リファレンスされた オブジェクトに、スコープから出るまでアドバイサリロックを掛けます. これはスレッドを有効にしてビルドされた Perl で、かつ use Threads した 場合にのみ組み込み関数となります。 それ以外の場合はこの名前をもつユーザーが定義した関数が呼び出されます。 Thread を参照してください。

log EXPR
log

Returns the natural logarithm (base e) of EXPR. If EXPR is omitted, returns log of $_. To get the log of another base, use basic algebra: The base-N log of a number is equal to the natural log of that number divided by the natural log of N. For example:

EXPR の (e を底とする) 自然対数を返します。 EXPR が省略されると、$_ の対数を返します。 底の異なる対数を求めるためには、基礎代数を利用してください: ある数の N を底とする対数は、その数の自然対数を N の自然対数で割ったものです。 例:

    sub log10 {
        my $n = shift;
        return log($n)/log(10);
    } 

See also "exp" for the inverse operation.

逆操作については "exp" を参照して下さい。

lstat FILEHANDLE
lstat EXPR
lstat

Does the same thing as the stat function (including setting the special _ filehandle) but stats a symbolic link instead of the file the symbolic link points to. If symbolic links are unimplemented on your system, a normal stat is done.

(特別なファイルハンドルである _ の設定を含めて) stat 関数と同じことをしますが、シンボリックリンクが 指しているファイルではなく、シンボリックリンク自体の stat をとります。 シンボリックリンクがシステムに実装されていないと、通常の stat が行なわれます。

If EXPR is omitted, stats $_.

EXPR が省略されると、$_ の stat をとります。

m//

The match operator. See perlop.

マッチ演算子です。 perlop を参照してください。

map BLOCK LIST
map EXPR,LIST

Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each element) and returns the list value composed of the results of each such evaluation. In scalar context, returns the total number of elements so generated. Evaluates BLOCK or EXPR in list context, so each element of LIST may produce zero, one, or more elements in the returned value.

LIST の個々の要素に対して、BLOCK か EXPR を評価し ($_ は、ローカルに個々の要素が設定されます) 、 それぞれの評価結果からなるリスト値が返されます。 スカラコンテキストでは、生成された要素の数を返します。 BLOCK や EXPR をリストコンテキストで評価しますので、LIST の 個々の要素によって作られる、返り値であるリストの要素数は、 0 個の場合もあれば、複数の場合もあります。

    @chars = map(chr, @nums);

translates a list of numbers to the corresponding characters. And

は、数のリストを対応する文字に変換します。また、

    %hash = map { getkey($_) => $_ } @array;

is just a funny way to write

は以下のものをちょっと変わった書き方で書いたものです。

    %hash = ();
    foreach $_ (@array) {
        $hash{getkey($_)} = $_;
    }

Note that $_ is an alias to the list value, so it can be used to modify the elements of the LIST. While this is useful and supported, it can cause bizarre results if the elements of LIST are not variables. Using a regular foreach loop for this purpose would be clearer in most cases. See also "grep" for an array composed of those items of the original list for which the BLOCK or EXPR evaluates to true.

$_ は、LIST の値へのエイリアスですので、LIST の要素を 変更するために使うことができます。 これは、便利でサポートされていますが、 LIST の要素が変数でないと、おかしな結果になります。 この目的には通常の foreach ループを使うことで、ほとんどの場合は より明確になります。 BLOCK や EXPR が真になる元のリストの要素からなる配列については、 "grep" も参照してください。

{ starts both hash references and blocks, so map { ... could be either the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look ahead for the closing } it has to take a guess at which its dealing with based what it finds just after the {. Usually it gets it right, but if it doesn't it won't realize something is wrong until it gets to the } and encounters the missing (or unexpected) comma. The syntax error will be reported close to the } but you'll need to change something near the { such as using a unary + to give perl some help:

{ はハッシュリファレンスとブロックの両方の開始文字なので、 map { ... は map BLOCK LIST の場合と map EXPR, LIST の場合があります。 perl は終了文字の } を先読みしないので、{ の直後の文字を見て どちらとして扱うかを推測します。 通常この推測は正しいですが、もし間違った場合は、} まで読み込んで カンマが足りない(または多い)ことがわかるまで、何かがおかしいことに 気付きません。 } の近くで文法エラーが出ますが、perl を助けるために単項の + を 使うというように、{ の近くの何かを変更する必要があります。

    %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
    %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
    %hash = map { ("\L$_", 1) } @array  # this also works
    %hash = map {  lc($_), 1  } @array  # as does this.
    %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!

    %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)

or to force an anon hash constructor use +{

または +{ を使って無名ハッシュコンストラクタを強制します:

   @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end

and you get list of anonymous hashes each with only 1 entry.

こうするとそれぞれ 1 要素だけの無名ハッシュのリストを得られます。

mkdir FILENAME,MASK
mkdir FILENAME

Creates the directory specified by FILENAME, with permissions specified by MASK (as modified by umask). If it succeeds it returns true, otherwise it returns false and sets $! (errno). If omitted, MASK defaults to 0777.

FILENAME で指定したディレクトリを、MASK で指定した許可モード(を umask で修正したもの) で作成します。 成功時には真を返し、失敗時には偽を返して $! (errno) を設定します。 MASK を省略すると、0777 とみなします。

In general, it is better to create directories with permissive MASK, and let the user modify that with their umask, than it is to supply a restrictive MASK and give the user no way to be more permissive. The exceptions to this rule are when the file or directory should be kept private (mail files, for instance). The perlfunc(1) entry on umask discusses the choice of MASK in more detail.

一般的に、制限された MASK を使ってユーザーがより寛容にする方法を 与えないより、寛容な MASK でディレクトリを作り、ユーザーが自身の umask で 修正するようにした方がよいです。 例外は、(例えばメールファイルのような)プライベートに保つべきファイルや ディレクトリを書く場合です。 perlfunc(1) の umask で、MASK の選択に関して詳細に議論しています。

msgctl ID,CMD,ARG

Calls the System V IPC function msgctl(2). You'll probably have to say

    use IPC::SysV;

first to get the correct constant definitions. If CMD is IPC_STAT, then ARG must be a variable which will hold the returned msqid_ds structure. Returns like ioctl: the undefined value for error, "0 but true" for zero, or the actual return value otherwise. See also "SysV IPC" in perlipc, IPC::SysV, and IPC::Semaphore documentation.

System V IPC 関数 msgctl を呼び出します。正しい定数定義を得るために、まず

    use IPC::SysV;

と宣言する必要があるでしょう。 CMD が IPC_STAT であれば、ARG は返される msqid_ds 構造体を 納める変数でなければなりません。 ioctl と同じように、エラー時には未定義値、 ゼロのときは "0 but true"、それ以外なら、その値そのものを返します。 "SysV IPC" in perlipc, IPC::SysV, IPC::Semaphore も参照してください。

msgget KEY,FLAGS

Calls the System V IPC function msgget(2). Returns the message queue id, or the undefined value if there is an error. See also "SysV IPC" in perlipc and IPC::SysV and IPC::Msg documentation.

System V IPC 関数 msgget を呼び出します。 メッセージキューの ID か、エラー時には未定義値を返します。 "SysV IPC" in perlipc, IPC::SysV, IPC::Msg も参照してください。

msgrcv ID,VAR,SIZE,TYPE,FLAGS

Calls the System V IPC function msgrcv to receive a message from message queue ID into variable VAR with a maximum message size of SIZE. Note that when a message is received, the message type as a native long integer will be the first thing in VAR, followed by the actual message. This packing may be opened with unpack("l! a*"). Taints the variable. Returns true if successful, or false if there is an error. See also "SysV IPC" in perlipc, IPC::SysV, and IPC::SysV::Msg documentation.

System V IPC 関数 msgrcv を呼び出し、メッセージキュー ID から、 変数 VAR に最大メッセージ長 SIZE のメッセージを受信します。 メッセージが受信された時、ネイティブな long 整数のメッセージタイプが VAR の先頭となり、実際のメッセージが続きます。 このパッキングは unpack("l! a*") で展開できます。 変数は汚染されます。 成功時には真を返し、エラー時には偽を返します。 "SysV IPC" in perlipc, IPC::SysV, IPC::SysV::Msg も参照してください。

msgsnd ID,MSG,FLAGS

Calls the System V IPC function msgsnd to send the message MSG to the message queue ID. MSG must begin with the native long integer message type, and be followed by the length of the actual message, and finally the message itself. This kind of packing can be achieved with pack("l! a*", $type, $message). Returns true if successful, or false if there is an error. See also IPC::SysV and IPC::SysV::Msg documentation.

System V IPC 関数 msgsnd を呼び出し、メッセージキュー ID に メッセージ MSG を送信します。 MSG の先頭は、ネイティブなlong 整数のメッセージタイプでなければならず、 メッセージの長さ、メッセージ本体と続きます。 これは、pack("l! a*", $type, $message) として生成できます。 成功時には真を、エラー時には偽を返します。 IPC::SysVIPC::SysV::Msg も参照してください。

my EXPR
my EXPR : ATTRIBUTES

A my declares the listed variables to be local (lexically) to the enclosing block, file, or eval. If more than one value is listed, the list must be placed in parentheses. See "Private Variables via my()" in perlsub for details.

my はリストアップされた変数を、囲っているブロック、ファイル、 eval の中でローカルな (レキシカルな) ものにします。 複数の値を並べる場合には、括弧で括る必要があります。 詳しくは"Private Variables via my()" in perlsubを参照してください。

next LABEL
next

The next command is like the continue statement in C; it starts the next iteration of the loop:

next コマンドは、C での continue 文のようなもので、 ループの次の繰り返しを開始します:

    LINE: while (<STDIN>) {
        next LINE if /^#/;      # discard comments
        #...
    }

Note that if there were a continue block on the above, it would get executed even on discarded lines. If the LABEL is omitted, the command refers to the innermost enclosing loop.

continue ブロックが存在すれば、たとえ捨てられる行に あっても、それが実行されます。 LABEL が省略されると、このコマンドはもっとも内側のループを参照します。

next cannot be used to exit a block which returns a value such as eval {}, sub {} or do {}, and should not be used to exit a grep() or map() operation.

nexteval {}, sub {}, do {} のように値を返す ブロックから抜けるのには使えません。 また、grep() や map() 操作から抜けるのに使うべきではありません。

Note that a block by itself is semantically identical to a loop that executes once. Thus next will exit such a block early.

ブロック自身は一回だけ実行されるループと文法的に同一であることに 注意してください。 従って、next はそのようなブロックから早く抜けるのに使えます。

See also "continue" for an illustration of how last, next, and redo work.

last, next, redo がどのように働くかについては "continue" も参照して下さい。

no Module LIST

See the "use" function, which no is the opposite of.

"use" 関数を参照してください。no は、その逆を行なうものです。

oct EXPR
oct

Interprets EXPR as an octal string and returns the corresponding value. (If EXPR happens to start off with 0x, interprets it as a hex string. If EXPR starts off with 0b, it is interpreted as a binary string.) The following will handle decimal, binary, octal, and hex in the standard Perl or C notation:

EXPR を 8 進数文字列と解釈して、対応する値を返します。 (EXPR が 0x で始まるときには、16 進数文字列と解釈します。 EXPR が 0bで始まるときは、2 進数文字列と解釈します。) 以下の例は、標準的な Perl や C の記法での 10 進数、2 進数、8 進数、16 進数を扱います:

    $val = oct($val) if $val =~ /^0/;

If EXPR is omitted, uses $_. To go the other way (produce a number in octal), use sprintf() or printf():

EXPR を省略すると、$_ を使用します。 (8 進数を扱う)その他の方法としては sprintf() または printf()があります。

    $perms = (stat("filename"))[2] & 07777;
    $oct_perms = sprintf "%lo", $perms;

The oct() function is commonly used when a string such as 644 needs to be converted into a file mode, for example. (Although perl will automatically convert strings into numbers as needed, this automatic conversion assumes base 10.)

oct() 関数は例えば、 644 といった文字列をファイルモードに変換する時に よく使います。 (Perl は必要に応じて自動的に文字列を数値に変換しますが、 この自動変換は十進数を仮定します。)

open FILEHANDLE,MODE,LIST
open FILEHANDLE,EXPR
open FILEHANDLE

Opens the file whose filename is given by EXPR, and associates it with FILEHANDLE. If FILEHANDLE is an expression, its value is used as the name of the real filehandle wanted. (This is considered a symbolic reference, so use strict 'refs' should not be in effect.)

EXPR でファイル名を指定するファイルをオープンして、 FILEHANDLE に対応させます。 FILEHANDLE が式のときには、その値が実際に使用するファイルハンドルの 名前として使われます。 (これはシンボリックリファレンスと考えられますので、 use strict 'refs'効果がありません。)

If EXPR is omitted, the scalar variable of the same name as the FILEHANDLE contains the filename. (Note that lexical variables--those declared with my--will not work for this purpose; so if you're using my, specify EXPR in your call to open.) See perlopentut for a kinder, gentler explanation of opening files.

EXPR を省略すると、FILEHANDLE と同じ名前のスカラ変数に、 ファイル名が入れられているものとして処理されます。 (my で宣言されたレキシカル変数はこの目的には使えません。 従って、myを使った場合は、open を呼び出すときに EXPR を指定してください。) ファイルのオープンに関するより親切な説明については perlopentut を参照して下さい。

If MODE is '<' or nothing, the file is opened for input. If MODE is '>', the file is truncated and opened for output, being created if necessary. If MODE is '>>', the file is opened for appending, again being created if necessary. You can put a '+' in front of the '>' or '<' to indicate that you want both read and write access to the file; thus '+<' is almost always preferred for read/write updates--the '+>' mode would clobber the file first. You can't usually use either read-write mode for updating textfiles, since they have variable length records. See the -i switch in perlrun for a better approach. The file is created with permissions of 0666 modified by the process' umask value.

MODE が '<' か、何も付けなかった場合には、 入力用としてオープンされることになります。 MODE が '>' の場合には、ファイルは空にされたあと出力用に オープンされ、必要ならファイルが作成されます。 MODE が '>>' の場合には、追記用にオープンされ、 必要ならファイルが作成されます。 '>''<' の前に '+' を置くことで、 ファイルを読み書き両用にすることもできます。 従って、'+<' はほとんどの場合読み書き更新をするために適したものです。 '+>' は最初にファイルを上書きします。 テキストファイルを更新する場合には普通はどちらの読み書きモードも使えません。 可変長のレコードを持つからです。 よりよい手法については perlrun-i オプションを参照して下さい。 作成されるファイルのパーミッションは 0666 を プロセスの umask の値で修正したものになります。

These various prefixes correspond to the fopen(3) modes of 'r', 'r+', 'w', 'w+', 'a', and 'a+'.

これらの様々な前置詞は fopen(3) の 'r', 'r+', 'w', 'w+', 'a', 'a+' のモードに対応します。

In the 2-arguments (and 1-argument) form of the call the mode and filename should be concatenated (in this order), possibly separated by spaces. It is possible to omit the mode if the mode is '<'.

2 引数(と 1 引数) の形式ではモードとファイル名は(この順番で) 結合されます(空白によって分割されているかもしれません)。 モードが '<' の場合はモードを省略できます。

If the filename begins with '|', the filename is interpreted as a command to which output is to be piped, and if the filename ends with a '|', the filename is interpreted as a command which pipes output to us. See "Using open() for IPC" in perlipc for more examples of this. (You are not allowed to open to a command that pipes both in and out, but see IPC::Open2, IPC::Open3, and "Bidirectional Communication with Another Process" in perlipc for alternatives.)

ファイル名の先頭に '|' を付けると、 そのファイル名をコマンドとして解釈し、ファイルハンドルへの 出力がパイプを通じて、そのコマンドへ入力されます。 逆にファイル名の最後に '|' を付けた場合には、 同様にファイル名をコマンドと解釈し、そのコマンドの出力がパイプを通じて、 ファイルハンドルから入力として読み込むことができるようになります。 これに関するさらなる例については "Using open() for IPC" in perlipc を 参照してください。 (open を入出力 両用 にパイプすることは出来ませんが 代替案としては IPC::Open2, IPC::Open3, "Bidirectional Communication with Another Process" in perlipc を参照してください。)

If MODE is '|-', the filename is interpreted as a command to which output is to be piped, and if MODE is '-|', the filename is interpreted as a command which pipes output to us. In the 2-arguments (and 1-argument) form one should replace dash ('-') with the command. See "Using open() for IPC" in perlipc for more examples of this. (You are not allowed to open to a command that pipes both in and out, but see IPC::Open2, IPC::Open3, and "Bidirectional Communication" in perlipc for alternatives.)

MODE が '|-' の場合、ファイル名は出力がパイプされるコマンドとして 解釈され、MODE が '-|' の場合、ファイル名は出力がこちらに パイプされるコマンドとして解釈されます。 2 引数(と 1 引数) の形式ではハイフン('-')をコマンドの代わりに 使えます。 これに関するさらなる例については "Using open() for IPC" in perlipc を 参照してください。 (open を入出力 両用 にパイプすることは出来ませんが 代替案としては IPC::Open2, IPC::Open3, "Bidirectional Communication" in perlipc を参照してください。)

In the 2-arguments (and 1-argument) form opening '-' opens STDIN and opening '>-' opens STDOUT.

2 引数(と 1 引数)で '-' を open すると STDIN がオープンされ、 '>-' を open すると STDOUT がオープンされます。

Open returns nonzero upon success, the undefined value otherwise. If the open involved a pipe, the return value happens to be the pid of the subprocess.

open は、成功時にはゼロ以外を返し、失敗時には未定義値を返します。 パイプに関る open のときには、返り値はサブプロセスの pid となります。

If you're unfortunate enough to be running Perl on a system that distinguishes between text files and binary files (modern operating systems don't care), then you should check out "binmode" for tips for dealing with this. The key distinction between systems that need binmode and those that don't is their text file formats. Systems like Unix, MacOS, and Plan9, which delimit lines with a single character, and which encode that character in C as "\n", do not need binmode. The rest need it.

不幸にしてテキストファイルとバイナリファイルを区別するシステムで Perl を動かす場合(最近の OS は区別しません)、これを扱うための TIPS について "binmode" をチェックするべきです。 binmode が必要なシステムと不要なシステムを区別する鍵は テキストファイルの形式です。 Unix, MacOS, Plan9 のような、行が 1 文字で分割され、その文字が C では "\n" でエンコードされる場合、binmode は不要です。 そうでない場合は必要です。

When opening a file, it's usually a bad idea to continue normal execution if the request failed, so open is frequently used in connection with die. Even if die won't do what you want (say, in a CGI script, where you want to make a nicely formatted error message (but there are modules that can help with that problem)) you should always check the return value from opening a file. The infrequent exception is when working with an unopened filehandle is actually what you want to do.

ファイルを開く時、開くのに失敗した時に通常の処理を続けるのは 普通は悪い考えですので、open はしばしば die と結び付けられて 使われます。 望むものが die がない場合(例えば、CGI スクリプト のように きれいにフォーマットされたエラーメッセージを作りたい場合 (但しこの問題を助けるモジュールがあります))でも、 ファイルを開いた時の帰り値を常にチェックするべきです。 めったにない例外は、開いていないファイルハンドルを使うのが 本当にやりたいことの場合です。

Examples:

例:

    $ARTICLE = 100;
    open ARTICLE or die "Can't find article $ARTICLE: $!\n";
    while (<ARTICLE>) {...

    open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
    # if the open fails, output is discarded

    open(DBASE, '+<', 'dbase.mine')             # open for update
        or die "Can't open 'dbase.mine' for update: $!";

    open(DBASE, '+<dbase.mine')                 # ditto
        or die "Can't open 'dbase.mine' for update: $!";

    open(ARTICLE, '-|', "caesar <$article")     # decrypt article
        or die "Can't start caesar: $!";

    open(ARTICLE, "caesar <$article |")         # ditto
        or die "Can't start caesar: $!";

    open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
        or die "Can't start sort: $!";

    # process argument list of files along with any includes

    foreach $file (@ARGV) {
        process($file, 'fh00');
    }

    sub process {
        my($filename, $input) = @_;
        $input++;               # this is a string increment
        unless (open($input, $filename)) {
            print STDERR "Can't open $filename: $!\n";
            return;
        }

        local $_;
        while (<$input>) {              # note use of indirection
            if (/^#include "(.*)"/) {
                process($1, $input);
                next;
            }
            #...                # whatever
        }
    }

You may also, in the Bourne shell tradition, specify an EXPR beginning with '>&', in which case the rest of the string is interpreted as the name of a filehandle (or file descriptor, if numeric) to be duped and opened. You may use & after >, >>, <, +>, +>>, and +<. The mode you specify should match the mode of the original filehandle. (Duping a filehandle does not take into account any existing contents of stdio buffers.) Duping file handles is not yet supported for 3-argument open().

Bourne シェルの慣例にしたがって、EXPR の先頭に '>&' を付けると、EXPR の残りの文字列をファイルハンドル名 (数字であれば、ファイル記述子) と解釈して、それを複製してオープンします。 & は、>, >>, <, +>, +>>, +<というモード指定に付けることができます。 指定するモード指定は、もとのファイルハンドルのモードと 合っていないといけません。 (ファイルハンドルの複製は既に存在する stdio バッファの内容に含めません。) ファイルハンドルの複製は 3 引数 open() ではまだ対応していません。

Here is a script that saves, redirects, and restores STDOUT and STDERR:

STDOUT と STDERR を保存し、リダイレクトし、元に戻すスクリプトを示します。

    #!/usr/bin/perl
    open(OLDOUT, ">&STDOUT");
    open(OLDERR, ">&STDERR");

    open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
    open(STDERR, ">&STDOUT")     || die "Can't dup stdout";

    select(STDERR); $| = 1;     # make unbuffered
    select(STDOUT); $| = 1;     # make unbuffered

    print STDOUT "stdout 1\n";  # this works for
    print STDERR "stderr 1\n";  # subprocesses too

    close(STDOUT);
    close(STDERR);

    open(STDOUT, ">&OLDOUT");
    open(STDERR, ">&OLDERR");

    print STDOUT "stdout 2\n";
    print STDERR "stderr 2\n";

If you specify '<&=N', where N is a number, then Perl will do an equivalent of C's fdopen of that file descriptor; this is more parsimonious of file descriptors. For example:

N を数値として、'<&=N' と指定すると、Perl は、 そのファイル記述子に対する C の fdopen と同じことを行ないます。 これはファイル記述子をより節約します。たとえば:

    open(FILEHANDLE, "<&=$fd")

Note that this feature depends on the fdopen() C library function. On many UNIX systems, fdopen() is known to fail when file descriptors exceed a certain value, typically 255. If you need more file descriptors than that, consider rebuilding Perl to use the sfio library.

この機能は fdopen() C ライブラリ関数に依存します。 多くの UNIX システムでは、fdopen() はファイル記述子がある値 (典型的には 255)を超えた場合に失敗することが知られています。 これより多くのファイル記述子が必要な場合は、 sfio ライブラリを使って Perl を再ビルドすることを検討して下さい。

If you open a pipe on the command '-', i.e., either '|-' or '-|' with 2-arguments (or 1-argument) form of open(), then there is an implicit fork done, and the return value of open is the pid of the child within the parent process, and 0 within the child process. (Use defined($pid) to determine whether the open was successful.) The filehandle behaves normally for the parent, but i/o to that filehandle is piped from/to the STDOUT/STDIN of the child process. In the child process the filehandle isn't opened--i/o happens from/to the new STDOUT or STDIN. Typically this is used like the normal piped open when you want to exercise more control over just how the pipe command gets executed, such as when you are running setuid, and don't want to have to scan shell commands for metacharacters. The following triples are more or less equivalent:

2 引数(または 1 引数)の形の open() で '-|''|-' というふうに、'-' というコマンドに パイプをオープンすると、fork が行なわれ、open の返り値として、 親プロセスにはチャイルドプロセスの pid が、チャイルドプロセスには 0 が返されます。 (open が成功したかどうかは、 defined($pid) のようにして調べることができます。) 親プロセスでは、このファイルハンドルは 通常通りに動作しますが、行なわれる入出力は、 チャイルドプロセスの STDIN/STDOUT にパイプされます。 チャイルドプロセス側では、そのファイルハンドルは オープンされず、入出力は新しい STDOUT か STDIN に対して行なわれます。 これは、setuid で実行して、シェルコマンドのメタ文字を 検索させたくないような場合に、パイプコマンドの起動の仕方を 制御したいとき、普通のパイプのopen と同じように使います。 以下の組み合わせは、だいたい同じものです:

    open(FOO, "|tr '[a-z]' '[A-Z]'");
    open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
    open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';

    open(FOO, "cat -n '$file'|");
    open(FOO, '-|', "cat -n '$file'");
    open(FOO, '-|') || exec 'cat', '-n', $file;

See "Safe Pipe Opens" in perlipc for more examples of this.

これに関する更なる例については "Safe Pipe Opens" in perlipc を参照して下さい。

Beginning with v5.6.0, Perl will attempt to flush all files opened for output before any operation that may do a fork, but this may not be supported on some platforms (see perlport). To be safe, you may need to set $| ($AUTOFLUSH in English) or call the autoflush() method of IO::Handle on any open handles.

v5.6.0 から、Perl は書き込み用に開いている全てのファイルに対して fork を行う前にフラッシュしようとしますが、これに対応していない プラットフォームもあります(perlport を参照してください)。 安全のために、$| (English モジュールでは $AUTOFLUSH) をセットするか、 全ての開いているハンドルに対して IO::Handleautoflush() メソッドを 呼び出すようにしてください。

On systems that support a close-on-exec flag on files, the flag will be set for the newly opened file descriptor as determined by the value of $^F. See "$^F" in perlvar.

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 フラグは$^F の値で決定される、新しくオープンされたファイル記述子に対して セットされます。 "$^F" in perlvarを参照してください。

Closing any piped filehandle causes the parent process to wait for the child to finish, and returns the status value in $?.

パイプのファイルハンドルを close することで、 親プロセスは、チャイルドプロセスの終了を待ち、$? に ステータス値を返します。

The filename passed to 2-argument (or 1-argument) form of open() will have leading and trailing whitespace deleted, and the normal redirection characters honored. This property, known as "magic open", can often be used to good effect. A user could specify a filename of "rsh cat file |", or you could change certain filenames as needed:

2 引数(と 1 引数)の形の open() に渡されたファイル名は、 はじめと終わりの空白が取り除かれ、 通常のリダイレクト文字列を受け付けます。 この機能は "magic open" として知られていますが、 普通いい効果をもたらします。 ユーザーは "rsh cat file |" といったファイル名を指定できますし、 特定のファイル名を必要に応じて変更できます。

    $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
    open(FH, $filename) or die "Can't open $filename: $!";

Use 3-argument form to open a file with arbitrary weird characters in it,

妙な文字が含まれているようなファイル名をオープンするには、 3 引数の形を使います。

    open(FOO, '<', $file);

otherwise it's necessary to protect any leading and trailing whitespace:

あるいは、次のようにして、最初と最後の空白を保護します:

    $file =~ s#^(\s)#./$1#;
    open(FOO, "< $file\0");

(this may not work on some bizarre filesystems). One should conscientiously choose between the magic and 3-arguments form of open():

(これは奇妙なファイルシステムでは動作しないかもしれません)。 open() の magic と 3 引数形式を誠実に選択するべきです。

    open IN, $ARGV[0];

will allow the user to specify an argument of the form "rsh cat file |", but will not work on a filename which happens to have a trailing space, while

とするとユーザーは "rsh cat file |" という形の引数を指定できますが、 末尾にスペースがついてしまったファイル名では動作しません。一方:

    open IN, '<', $ARGV[0];

will have exactly the opposite restrictions.

はまったく逆の制限があります。

If you want a "real" C open (see open(2) on your system), then you should use the sysopen function, which involves no such magic (but may use subtly different filemodes than Perl open(), which is mapped to C fopen()). This is another way to protect your filenames from interpretation. For example:

もし「本当の」C 言語の open (システムの open(2) を参照してください)が 必要なら、このような副作用のない sysopen 関数を使うべきです (ただし、C の fopen() に割り付けられる Perl の open() とは かすかに違うファイルモードを持ちます)。 これはファイル名を解釈から守るもう一つの方法です。 例えば:

    use IO::Handle;
    sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
        or die "sysopen $path: $!";
    $oldfh = select(HANDLE); $| = 1; select($oldfh);
    print HANDLE "stuff $$\n";
    seek(HANDLE, 0, 0);
    print "File contains: ", <HANDLE>;

Using the constructor from the IO::Handle package (or one of its subclasses, such as IO::File or IO::Socket), you can generate anonymous filehandles that have the scope of whatever variables hold references to them, and automatically close whenever and however you leave that scope:

IO::Handle パッケージ(または IO::FileIO::Socket といった サブパッケージ)のコンストラクタを使うことで、 これらへのリファレンスを保持している変数のスコープを持ち、 スコープから離れると自動的に閉じる無名ファイルハンドルを作成できます:

    use IO::File;
    #...
    sub read_myfile_munged {
        my $ALL = shift;
        my $handle = new IO::File;
        open($handle, "myfile") or die "myfile: $!";
        $first = <$handle>
            or return ();     # Automatically closed here.
        mung $first or die "mung failed";       # Or here.
        return $first, <$handle> if $ALL;       # Or here.
        $first;                                 # Or here.
    }

See "seek" for some details about mixing reading and writing.

読み書きを混ぜる場合の詳細については "seek" を参照して下さい。

opendir DIRHANDLE,EXPR

Opens a directory named EXPR for processing by readdir, telldir, seekdir, rewinddir, and closedir. Returns true if successful. DIRHANDLEs have their own namespace separate from FILEHANDLEs.

readdirtelldirseekdirrewinddirclosedir で処理するために、EXPR で指定された名前の ディレクトリをオープンします。成功時には真を返します。 DIRHANDLE は、FILEHANDLE とは別に名前空間を持っています。

ord EXPR
ord

Returns the numeric (ASCII or Unicode) value of the first character of EXPR. If EXPR is omitted, uses $_. For the reverse, see "chr". See utf8 for more about Unicode.

EXPR の最初の文字の数値としての(ASCII または Unicode) 値を返します。 EXPR を省略した場合には、$_ を使用します。 逆のことをするには "chr" を参照してください。 Unicode については utf8 を参照してください。

our EXPR

An our declares the listed variables to be valid globals within the enclosing block, file, or eval. That is, it has the same scoping rules as a "my" declaration, but does not create a local variable. If more than one value is listed, the list must be placed in parentheses. The our declaration has no semantic effect unless "use strict vars" is in effect, in which case it lets you use the declared global variable without qualifying it with a package name. (But only within the lexical scope of the our declaration. In this it differs from "use vars", which is package scoped.)

our は挙げられた変数をブロック、ファイル、eval 内で グローバルとして宣言します。 これは "my" 宣言と同じスコープルールをもちますが、 ローカル変数を作りません。 複数の変数を指定する場合は、変数は括弧で囲わなければなりません。 our 宣言は "use strict vars" が有効でなければ 意味論的な効果はもちません。 この場合、宣言したグローバル変数をパッケージ名で修飾せずに使えます。 (しかし our 宣言のレキシカルスコープの内側だけです。 これは "use vars" と異なります。こちらはパッケージスコープです。)

An our declaration declares a global variable that will be visible across its entire lexical scope, even across package boundaries. The package in which the variable is entered is determined at the point of the declaration, not at the point of use. This means the following behavior holds:

our 宣言はレキシカルスコープ全体に対して(たとえパッケージ境界を 越えていても)見えるグローバル変数を宣言します。 この変数が入るパッケージは宣言した時点で定義され、 使用した時点ではありません。 これにより、以下のような振る舞いになります:

    package Foo;
    our $bar;           # declares $Foo::bar for rest of lexical scope
    $bar = 20;

    package Bar;
    print $bar;         # prints 20

Multiple our declarations in the same lexical scope are allowed if they are in different packages. If they happened to be in the same package, Perl will emit warnings if you have asked for them.

同じレキシカルスコープでも、パッケージが異なっていれば、複数の our 宣言ができます。 同じパッケージになっていると、警告が出力されるようになっていれば 警告が出力されます。

    use warnings;
    package Foo;
    our $bar;           # declares $Foo::bar for rest of lexical scope
    $bar = 20;

    package Bar;
    our $bar = 30;      # declares $Bar::bar for rest of lexical scope
    print $bar;         # prints 30

    our $bar;           # emits warning
pack TEMPLATE,LIST

Takes a LIST of values and converts it into a string using the rules given by the TEMPLATE. The resulting string is the concatenation of the converted values. Typically, each converted value looks like its machine-level representation. For example, on 32-bit machines a converted integer may be represented by a sequence of 4 bytes.

LIST の値を TEMPLATE で与えられたルールを用いて 文字列に変換します。 結果の文字列は変換した値を連結したものです。 典型的には、それぞれの変換された値はマシンレベルの表現のように見えます。 例えば、32-bit マシンでは、整数を変換すると 4 バイトのデータとして 表現されます。

The TEMPLATE is a sequence of characters that give the order and type of values, as follows:

TEMPLATE は、以下の ような値の型と順番を指定する文字を並べたものです:

    a   A string with arbitrary binary data, will be null padded.
    A   An ASCII string, will be space padded.
    Z   A null terminated (asciz) string, will be null padded.

    b   A bit string (ascending bit order inside each byte, like vec()).
    B   A bit string (descending bit order inside each byte).
    h   A hex string (low nybble first).
    H   A hex string (high nybble first).

    c   A signed char value.
    C   An unsigned char value.  Only does bytes.  See U for Unicode.

    s   A signed short value.
    S   An unsigned short value.
          (This 'short' is _exactly_ 16 bits, which may differ from
           what a local C compiler calls 'short'.  If you want
           native-length shorts, use the '!' suffix.)

    i   A signed integer value.
    I   An unsigned integer value.
          (This 'integer' is _at_least_ 32 bits wide.  Its exact
           size depends on what a local C compiler calls 'int',
           and may even be larger than the 'long' described in
           the next item.)

    l   A signed long value.
    L   An unsigned long value.
          (This 'long' is _exactly_ 32 bits, which may differ from
           what a local C compiler calls 'long'.  If you want
           native-length longs, use the '!' suffix.)

    n   An unsigned short in "network" (big-endian) order.
    N   An unsigned long in "network" (big-endian) order.
    v   An unsigned short in "VAX" (little-endian) order.
    V   An unsigned long in "VAX" (little-endian) order.
          (These 'shorts' and 'longs' are _exactly_ 16 bits and
           _exactly_ 32 bits, respectively.)

    q   A signed quad (64-bit) value.
    Q   An unsigned quad value.
          (Quads are available only if your system supports 64-bit
           integer values _and_ if Perl has been compiled to support those.
           Causes a fatal error otherwise.)

    f   A single-precision float in the native format.
    d   A double-precision float in the native format.

    p   A pointer to a null-terminated string.
    P   A pointer to a structure (fixed-length string).

    u   A uuencoded string.
    U   A Unicode character number.  Encodes to UTF-8 internally.
        Works even if use utf8 is not in effect.

    w   A BER compressed integer.  Its bytes represent an unsigned
        integer in base 128, most significant digit first, with as
        few digits as possible.  Bit eight (the high bit) is set
        on each byte except the last.

    x   A null byte.
    X   Back up a byte.
    @   Null fill to absolute position.
    a   任意のバイナリデータを含む文字列、ヌル文字で埋める
    A   ASCII 文字列、スペース文字で埋める
    Z   ヌル文字終端(asciz)文字列、ヌル文字で埋める

    b   ビット列 (バイトごとに昇ビット順、vec() と同じ)
    B   ビット列 (バイトごとに降ビット順)
    h   16 進数文字列 (低位ニブルが先)
    H   16 進数文字列 (高位ニブルが先)

    c   signed char 値
    C   unsigned char 値。バイトのみ。Unicode 用は U。

    s   signed short 値
    S   unsigned short 値
          (ここでの 'short' は「正確に」 16 bit です。
           ローカルの C コンパイラの 'short' のサイズとは違うかもしれません。
           ネイティブな長さの short を使いたい場合は、
           '!' 前置詞を使ってください。)

    i   signed int 値
    I   unsigned int 値
          (ここでの 'integer' は 「最低」 32 bits 幅です。
           正確なサイズはローカルの C コンパイラの
           'int'のサイズに依存します。
           また、下記の 'long' より大きい可能性もあります)

    l   signed long 値
    L   unsigned long 値
          (ここでの 'long' は「正確に」32 ビットです。これは
           ローカルの C コンパイラの 'long' のサイズとは違うかもしれません。
           ネイティブな長さの 'long' が必要な場合は、'!' 前置詞を使ってください)

    n   "network" 順序 (ビッグエンディアン) の unsigned  short
    N   "network" 順序 (ビッグエンディアン) の unsigned long
    v   "VAX" 順序 (リトルエンディアン) の unsigned short
    V   "VAX" 順序 (リトルエンディアン) の unsigned long
          (これらの 'short' と 'long' は「正確に」それぞれ 16 ビットと
           32 ビットす)

    q   符号付き 64 ビット整数
    Q   符号なし 64 ビット整数
          (64 ビット整数は、システムが 64 ビット整数に対応していて、かつ Perl が
           64 ビット整数対応としてコンパイルされている場合にのみ使用可能です。
           それ以外の場合は致命的エラーが発生します。)

    f   機種依存の単精度浮動小数点数
    d   機種依存の倍精度浮動小数点数

    p   ヌル文字で終端する文字列へのポインタ
    P   構造体 (固定長文字列) へのポインタ

    u   uuencode 文字列
    U   Unicode 文字番号。内部的に UTF-8 にエンコードされます。
        use utf8 が有効でなくても動作します。

    w   A BER 圧縮変数。このバイト列はできるだけ少ない桁数で表現された
        128 を基とした符号なし整数で、最上位ビットから順に並びます。
        最後のバイト以外の各バイトのビット 8 (上位ビット) がセットされます。

    x   ヌル文字
    X   1 文字後退
    @   絶対位置までヌル文字で埋める

The following rules apply:

以下の条件が適用されます:

  • Each letter may optionally be followed by a number giving a repeat count. With all types except a, A, Z, b, B, h, H, and P the pack function will gobble up that many values from the LIST. A * for the repeat count means to use however many items are left, except for @, x, X, where it is equivalent to 0, and u, where it is equivalent to 1 (or 45, what is the same).

    これらの文字の後には、繰り返し数を示す数字を付けることができます。 a, A, Z, b, B, h, H, P 以外の全ての型では、 LIST からその数の値を取り出して使います。 くり返し数に * を指定すると、その時点で残っているすべての要素を意味します。 ただし、@, x, Xでは 0u と等価で、 1 (あるいは 45 でも同じ) と等価です。

    When used with Z, * results in the addition of a trailing null byte (so the packed result will be one longer than the byte length of the item).

    *Z と共に使われた場合、末尾にヌルバイトをつけます (従ってパックされた結果は要素の length の値より 1 大きくなります)。

    The repeat count for u is interpreted as the maximal number of bytes to encode per line of output, with 0 and 1 replaced by 45.

    u での繰り返し回数は、出力行毎に最大何バイトまでをエンコードするかを 示します。0 と 1 は 45 として扱われます。

  • The a, A, and Z types gobble just one value, but pack it as a string of length count, padding with nulls or spaces as necessary. When unpacking, A strips trailing spaces and nulls, Z strips everything after the first null, and a returns data verbatim. When packing, a, and Z are equivalent.

    a, A, Z という型を使うと、値を一つだけ取り出して使いますが、 繰り返し数で示す長さの文字列となるように、必要に応じてヌル文字か スペース文字を付け足します。 unpack するとき、A は後続のスペース文字やヌル文字を取り除きます。 Zは最初のヌル文字以降の全てを取り除きます。 aはデータをそのまま返します。 pack するときは、 aZ は等価です。

    If the value-to-pack is too long, it is truncated. If too long and an explicit count is provided, Z packs only $count-1 bytes, followed by a null byte. Thus Z always packs a trailing null byte under all circumstances.

    pack する値が長すぎる場合、切り詰められます。 長すぎてかつ明示的に個数が指定されている場合、 Z$count-1 バイトまで pack し、その後にヌルバイトがつきます。 従って、Z はどのような状態でも常に末尾にヌルバイトがつきます。

  • Likewise, the b and B fields pack a string that many bits long. Each byte of the input field of pack() generates 1 bit of the result. Each result bit is based on the least-significant bit of the corresponding input byte, i.e., on ord($byte)%2. In particular, bytes "0" and "1" generate bits 0 and 1, as do bytes "\0" and "\1".

    同様に、bB は、繰り返し数で示すビット長のビット列に pack します。 pack() の入力フィールドの各バイトは結果の 1 ビットを生成します。 結果ビットのそれぞれは対応する入力バイトの最下位ビットを基にします (つまり ord($byte)%2)。 特に、バイト "0""1" は バイト "\0""\1" と同様に、ビット 0 と 1 を生成します。

    Starting from the beginning of the input string of pack(), each 8-tuple of bytes is converted to 1 byte of output. With format b the first byte of the 8-tuple determines the least-significant bit of a byte, and with format B it determines the most-significant bit of a byte.

    pack() の入力文字列の先頭から始めて、8 タプル毎に 1 バイトの出力に 変換されます。 b フォーマットでは 8 タプルの最初のバイトが出力の最下位ビットとなり、 B フォーマットでは出力の最上位ビットとなります。

    If the length of the input string is not exactly divisible by 8, the remainder is packed as if the input string were padded by null bytes at the end. Similarly, during unpack()ing the "extra" bits are ignored.

    もし入力文字列の長さが 8 で割り切れない場合、余りの部分は入力文字列の 最後にヌルバイトがパッディングされているものとしてパックされます。 同様に、unpack() 中は「余分な」ビットは無視されます。

    If the input string of pack() is longer than needed, extra bytes are ignored. A * for the repeat count of pack() means to use all the bytes of the input field. On unpack()ing the bits are converted to a string of "0"s and "1"s.

    pack() の入力文字列が必要な分よりも長い場合、余分な部分は無視されます。 pack() の繰り返し数として * が指定されると、入力フィールドの全ての バイト列がが使われます。 unpack() 時にはビット列は "0""1" の文字列に変換されます。

  • The h and H fields pack a string that many nybbles (4-bit groups, representable as hexadecimal digits, 0-9a-f) long.

    hH は、多ニブル長(16 進文字である 0-9a-f で表現可能な 4 ビットグループ)のニブル列に pack します。

    Each byte of the input field of pack() generates 4 bits of the result. For non-alphabetical bytes the result is based on the 4 least-significant bits of the input byte, i.e., on ord($byte)%16. In particular, bytes "0" and "1" generate nybbles 0 and 1, as do bytes "\0" and "\1". For bytes "a".."f" and "A".."F" the result is compatible with the usual hexadecimal digits, so that "a" and "A" both generate the nybble 0xa==10. The result for bytes "g".."z" and "G".."Z" is not well-defined.

    pack() の入力フィールドの各バイトは結果の 4 ビットを生成します。 英字でないバイトの場合、結果は入力バイトの下位 4 ビットを 基にします(つまり ord($byte)%16)。 特に、バイト "0""1" はバイト "\0""\1" と同様に ニブル 0 と 1 を生成します。 バイト "a".."f""A".."F" の場合は結果は通常の 16 進数と同じ結果になりますので、"a""A" はどちらも ニブル 0xa==10 を生成します。 バイト "g".."z""G".."Z" に対する結果は未定義です。

    Starting from the beginning of the input string of pack(), each pair of bytes is converted to 1 byte of output. With format h the first byte of the pair determines the least-significant nybble of the output byte, and with format H it determines the most-significant nybble.

    pack() の入力文字列の先頭から始めて、2 バイト毎に 1 バイトの出力に 変換されます。 h フォーマットでは 1 バイト目が出力の最下位ニブルとなり、 H フォーマットでは出力の最上位ニブルとなります。

    If the length of the input string is not even, it behaves as if padded by a null byte at the end. Similarly, during unpack()ing the "extra" nybbles are ignored.

    入力文字列の長さが偶数でない場合、最後にヌルバイトでパッディングされて いるかのように振る舞います。 同様に、unpack() 中は「余分な」ニブルは無視されます。

    If the input string of pack() is longer than needed, extra bytes are ignored. A * for the repeat count of pack() means to use all the bytes of the input field. On unpack()ing the bits are converted to a string of hexadecimal digits.

    pack() の入力文字列が必要な分より長い場合、余分な部分は無視されます。 pack() の繰り返し数として * が指定されると、入力フィールドの全ての バイト列がが使われます。 unpack() 時にはビット列は 16 進数の文字列に変換されます。

  • The p type packs a pointer to a null-terminated string. You are responsible for ensuring the string is not a temporary value (which can potentially get deallocated before you get around to using the packed result). The P type packs a pointer to a structure of the size indicated by the length. A NULL pointer is created if the corresponding value for p or P is undef, similarly for unpack().

    pは、ヌル文字終端文字列へのポインタを pack します。 文字列が一時的な値でない(つまり pack された結果を使う前に文字列が 解放されない) ことに責任を持つ必要があります P は、指定した長さの構造体へのポインタを pack します。 pまたはPに対応する値が undef だった場合、 unpack() と同様にヌルポインタが作成されます。

  • The / template character allows packing and unpacking of strings where the packed structure contains a byte count followed by the string itself. You write length-item/string-item.

    / テンプレート文字は、文字列の長さを示すバイト列の後に 文字列そのものが入っている形の文字列を pack 及び unpack します。 length-item/string-item の形になります。

    The length-item can be any pack template letter, and describes how the length value is packed. The ones likely to be of most use are integer-packing ones like n (for Java strings), w (for ASN.1 or SNMP) and N (for Sun XDR).

    length-item には任意の pack テンプレート文字が利用でき、 長さの値がどのようにパックされているかを指定します。 もっともよく使われるのは n(Java 文字列), w(SNMP), N(Sun XDR) と いった整数型です。

    The string-item must, at present, be "A*", "a*" or "Z*". For unpack the length of the string is obtained from the length-item, but if you put in the '*' it will be ignored.

    string-item は現在のところ "A*", "a*", "Z*" のいずれかで なければなりません。 unpack の場合は文字列の長さは length-item から得られますが、 '*' を置くと無視されます。

        unpack 'C/a', "\04Gurusamy";        gives 'Guru'
        unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
        pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"

    The length-item is not returned explicitly from unpack.

    length-itemunpack から明示的には返されません。

    Adding a count to the length-item letter is unlikely to do anything useful, unless that letter is A, a or Z. Packing with a length-item of a or Z may introduce "\000" characters, which Perl does not regard as legal in numeric strings.

    length-item 文字に繰り返し数をつけるのは 文字が A, a, Z でない限りは有用ではありません。 aZlength-item としてパックすると "\000" 文字が 出力されることがあり、Perl はこれを有効な数値文字列として認識しません。

  • The integer types s, S, l, and L may be immediately followed by a ! suffix to signify native shorts or longs--as you can see from above for example a bare l does mean exactly 32 bits, the native long (as seen by the local C compiler) may be larger. This is an issue mainly in 64-bit platforms. You can see whether using ! makes any difference by

    s, S, l, L の整数タイプの直後に接尾辞として ! を つけることで、ネイティブの short や long を指定できます -- 上述のように、例えば l は正確に 32 ビットであり、ネイティブな (ローカルな C コンパイラによる)long はもっと大きいかもしれません。 これは主に 64 ビットプラットフォームで意味があります。 ! を使うことによって違いがあるかどうかは以下のようにして調べられます:

            print length(pack("s")), " ", length(pack("s!")), "\n";
            print length(pack("l")), " ", length(pack("l!")), "\n";

    i! and I! also work but only because of completeness; they are identical to i and I.

    i!I! も動作しますが、単に完全性のためだけです; これは i 及び I と同じです。

    The actual sizes (in bytes) of native shorts, ints, longs, and long longs on the platform where Perl was built are also available via Config:

    Perl がビルドされたプラットフォームでの short, int, long, long long の 実際の(バイト数での)サイズは Config でも得られます。

           use Config;
           print $Config{shortsize},    "\n";
           print $Config{intsize},      "\n";
           print $Config{longsize},     "\n";
           print $Config{longlongsize}, "\n";

    (The $Config{longlongsize} will be undefine if your system does not support long longs.)

    (システムが long long に対応していない場合は $Config{longlongsize} は 未定義値になります。)

  • The integer formats s, S, i, I, l, and L are inherently non-portable between processors and operating systems because they obey the native byteorder and endianness. For example a 4-byte integer 0x12345678 (305419896 decimal) be ordered natively (arranged in and handled by the CPU registers) into bytes as

    整数フォーマット s, S, i, I, l, L は ネイティブなバイト順序とエンディアンに従っているため、 本質的にプロセッサ間や OS 間で移植性がありません。 例えば 4 バイトの整数 0x12345678 (10 進数では 305419896) は 内部では(CPU レジスタによって変換され扱われる形では) 以下のようなバイト列に並べられます:

            0x12 0x34 0x56 0x78     # big-endian
            0x78 0x56 0x34 0x12     # little-endian

    Basically, the Intel and VAX CPUs are little-endian, while everybody else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray are big-endian. Alpha and MIPS can be either: Digital/Compaq used/uses them in little-endian mode; SGI/Cray uses them in big-endian mode.

    基本的に、Intel と VAX の CPU はリトルエンディアンです。 一方それ以外、例えば Motorola m68k/88k, PPC, Sparc, HP PA, Power, Cray などはビッグエンディアンです。 Alpha と MIPS は両方ともあります: Digital/Compaq はリトルエンディアンモードで使っています(いました); SGI/Cray はビッグエンディアンモードで使っています。

    The names `big-endian' and `little-endian' are comic references to the classic "Gulliver's Travels" (via the paper "On Holy Wars and a Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and the egg-eating habits of the Lilliputians.

    「ビッグエンディアン」と「リトルエンディアン」の名前は 古典である「ガリバー旅行記」とリリパット族の卵を食べる習慣から 取られています。

    Some systems may have even weirder byte orders such as

    以下のような、さらに変わったバイト順序を持つシステムもあるかもしれません:

            0x56 0x78 0x12 0x34
            0x34 0x12 0x78 0x56

    You can see your system's preference with

    システムの設定は以下のようにして見ることができます:

            print join(" ", map { sprintf "%#02x", $_ }
                                unpack("C*",pack("L",0x12345678))), "\n";

    The byteorder on the platform where Perl was built is also available via Config:

    Perl がビルドされたプラットフォームでのバイト順序は Config でも知ることができます:

            use Config;
            print $Config{byteorder}, "\n";

    Byteorders '1234' and '12345678' are little-endian, '4321' and '87654321' are big-endian.

    '1234''12345678' はリトルエンディアン、 '4321''87654321' はビッグエンディアンです。

    If you want portable packed integers use the formats n, N, v, and V, their byte endianness and size is known. See also perlport.

    移植性のあるパック化された整数がほしい場合は、 n, N, v, V を使ってください。 これらはバイトエンディアンとサイズが固定されています。 perlport も参照して下さい。

  • Real numbers (floats and doubles) are in the native machine format only; due to the multiplicity of floating formats around, and the lack of a standard "network" representation, no facility for interchange has been made. This means that packed floating point data written on one machine may not be readable on another - even if both use IEEE floating point arithmetic (as the endian-ness of the memory representation is not part of the IEEE spec). See also perlport.

    実数 (float と double) は、機種依存のフォーマットしかありません。 いろんな浮動小数点数のフォーマットが在り、標準的な "network" 表現といったものがないため、データ交換のための機能は 用意してありません。 つまり、あるマシンで pack した浮動小数点数は、別のマシンでは 読めないかもしれないということです。 たとえ双方で IEEE フォーマットの浮動小数点数演算を行なっていてもです (IEEE の仕様では、メモリ表現上のバイト順序までは、 規定されていないからです)。 perlport も参照してください。

    Note that Perl uses doubles internally for all numeric calculation, and converting from double into float and thence back to double again will lose precision (i.e., unpack("f", pack("f", $foo)) will not in general equal $foo).

    Perl では、すべての数値演算のために、内部的に double を使用しています。 double から float へ変換し、それから再び double に戻すと 精度が落ちることになります (つまり、unpack("f", pack("f", $foo)) は、 一般には $foo と同じではないということです)。

  • If the pattern begins with a U, the resulting string will be treated as Unicode-encoded. You can force UTF8 encoding on in a string with an initial U0, and the bytes that follow will be interpreted as Unicode characters. If you don't want this to happen, you can begin your pattern with C0 (or anything else) to force Perl not to UTF8 encode your string, and then follow this with a U* somewhere in your pattern.

    パターンが U で始まっている場合、結果の文字列は Unicode で エンコードされているものとして扱われます。 先頭に U0 を持つ文字列で UTF8 エンコーディングを強制でき、 引き続くバイト列は Unicode 文字列として解釈されます。 このようなことが起きてほしくない場合は、 パターンを C0 (か他のもの)で始めることによって、 Perl に文字列を UTF8 エンコードさせないように強制でき、 その後にパターンのどこかに U* を置きます。

  • You must yourself do any alignment or padding by inserting for example enough 'x'es while packing. There is no way to pack() and unpack() could know where the bytes are going to or coming from. Therefore pack (and unpack) handle their output and input as flat sequences of bytes.

    パックするときに、例えば十分な数の 'x' を挿入することによって アライメントやパッディングを行うのは全て自分でしなければなりません。 バイト列がどこへ行くか・どこから来たかを pack() や unpack() が 知る方法はありません。 従って pack (と unpack) は出力と入力をフラットなバイト列として 扱います。

  • A comment in a TEMPLATE starts with # and goes to the end of line.

    TEMPLATE の中の # から行末まではコメントです。

  • If TEMPLATE requires more arguments to pack() than actually given, pack() assumes additional "" arguments. If TEMPLATE requires less arguments to pack() than actually given, extra arguments are ignored.

    TEMPLATE が要求する引数の数が pack() が実際に与えている数より多い場合、 追加の "" 引数があるものと仮定します。 TEMPLATE が要求する引数の数の方が少ない場合、余分の引数は無視されます。

Examples:

例:

    $foo = pack("CCCC",65,66,67,68);
    # foo eq "ABCD"
    $foo = pack("C4",65,66,67,68);
    # same thing
    $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
    # same thing with Unicode circled letters

    $foo = pack("ccxxcc",65,66,67,68);
    # foo eq "AB\0\0CD"

    # note: the above examples featuring "C" and "c" are true
    # only on ASCII and ASCII-derived systems such as ISO Latin 1
    # and UTF-8.  In EBCDIC the first example would be
    # $foo = pack("CCCC",193,194,195,196);

    $foo = pack("s2",1,2);
    # "\1\0\2\0" on little-endian
    # "\0\1\0\2" on big-endian

    $foo = pack("a4","abcd","x","y","z");
    # "abcd"

    $foo = pack("aaaa","abcd","x","y","z");
    # "axyz"

    $foo = pack("a14","abcdefg");
    # "abcdefg\0\0\0\0\0\0\0"

    $foo = pack("i9pl", gmtime);
    # a real struct tm (on my system anyway)

    $utmp_template = "Z8 Z8 Z16 L";
    $utmp = pack($utmp_template, @utmp1);
    # a struct utmp (BSDish)

    @utmp2 = unpack($utmp_template, $utmp);
    # "@utmp1" eq "@utmp2"

    sub bintodec {
        unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
    }

    $foo = pack('sx2l', 12, 34);
    # short 12, two zero bytes padding, long 34
    $bar = pack('s@4l', 12, 34);
    # short 12, zero fill to position 4, long 34
    # $foo eq $bar

The same template may generally also be used in unpack().

一般には、pack で使用したものと同じテンプレートが、 unpack 関数でも使用できます。

package NAMESPACE
package

Declares the compilation unit as being in the given namespace. The scope of the package declaration is from the declaration itself through the end of the enclosing block, file, or eval (the same as the my operator). All further unqualified dynamic identifiers will be in this namespace. A package statement affects only dynamic variables--including those you've used local on--but not lexical variables, which are created with my. Typically it would be the first declaration in a file to be included by the require or use operator. You can switch into a package in more than one place; it merely influences which symbol table is used by the compiler for the rest of that block. You can refer to variables and filehandles in other packages by prefixing the identifier with the package name and a double colon: $Package::Variable. If the package name is null, the main package as assumed. That is, $::sail is equivalent to $main::sail (as well as to $main'sail, still seen in older code).

与えられた名前空間でのコンパイル単位を宣言します。 パッケージ宣言のスコープは、宣言自体から、閉じたブロック、ファイル、 eval の終わりまでです(my 演算子と同じです)。 全てのさらなる修飾されてない動的識別子はこの名前空間になります。 package 文は動的変数にのみ影響します -- local で使ったものも 含みます -- が、my で作成されたレキシカル変数には 影響しません。 典型的にはこれは requireuse 演算子でインクルードされるファイルの 最初に宣言されます。 パッケージを複数の場所で切り替えることができます; これは単にコンパイラがこのブロックの残りに対してどのシンボルテーブルを 使うかにのみ影響します。 他のパッケージの変数やファイルハンドルは、識別子にパッケージ名と コロン 2 つをつけることで参照できます($Package::Variable)。 パッケージ名が空文字列の場合、main パッケージが仮定されます。 つまり、$::sail$main::sail と等価です($main'sail も 古いコードではまだ見られます)。

If NAMESPACE is omitted, then there is no current package, and all identifiers must be fully qualified or lexicals. This is stricter than use strict, since it also extends to function names.

NAMESPACE が省略されると、カレントパッケージはなくなるので、 全ての識別子は完全修飾されるかレキシカルでなければなりません。 これは関数名にも適用されるので、use strict より厳しいです。

See "Packages" in perlmod for more information about packages, modules, and classes. See perlsub for other scoping issues.

パッケージ、モジュール、クラスに関するさらなる情報については "Packages" in perlmod を参照してください。 その他のスコープに関する話題については perlsub を参照してください。

pipe READHANDLE,WRITEHANDLE

Opens a pair of connected pipes like the corresponding system call. Note that if you set up a loop of piped processes, deadlock can occur unless you are very careful. In addition, note that Perl's pipes use stdio buffering, so you may need to set $| to flush your WRITEHANDLE after each command, depending on the application.

対応するシステムコールと同じように、 接続されたパイプのペアをオープンします。 パイプでプロセスをループにするときには、よほど気を付けないと、 デッドロックが起こり得ます。 さらに、Perl のパイプでは、stdio のバッファリングを使いますから、 アプリケーションによっては、コマンドごとに WRITEHANDLE を フラッシュするように、$| を設定することが必要になるかもしれません。

See IPC::Open2, IPC::Open3, and "Bidirectional Communication" in perlipc for examples of such things.

これらに関する例については、IPC::Open2, IPC::Open3, "Bidirectional Communication" in perlipc を参照して下さい。

On systems that support a close-on-exec flag on files, the flag will be set for the newly opened file descriptors as determined by the value of $^F. See "$^F" in perlvar.

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 フラグは $^F の値で決定される、新しくオープンされたファイル記述子に対して セットされます。 "$^F" in perlvar を参照してください。

pop ARRAY
pop

Pops and returns the last value of the array, shortening the array by one element. Has an effect similar to

配列の最後の値をポップして返し、配列の大きさを 1 だけ小さくします。 これは、以下と同じ効果があります。

    $ARRAY[$#ARRAY--]

If there are no elements in the array, returns the undefined value (although this may happen at other times as well). If ARRAY is omitted, pops the @ARGV array in the main program, and the @_ array in subroutines, just like shift.

指定された配列に要素がなければ、未定義値が返されます (しかしこれは他の場合にも起こり得ます)。 ARRAY が省略されると、shift と同様に、メインプログラムでは @ARGVが、 サブルーチンでは @_ が使われます。

pos SCALAR
pos

Returns the offset of where the last m//g search left off for the variable in question ($_ is used when the variable is not specified). May be modified to change that offset. Such modification will also influence the \G zero-width assertion in regular expressions. See perlre and perlop.

対象の変数に対して、前回の m//g が終了した場所の オフセットを返します(変数が指定されなかった場合は $_ が使われます)。 そのオフセットを変えるために、変更することができます。 そのような変更は正規表現における \G ゼロ幅アサートにも 影響を与えます。 perlreperlop を参照してください。

print FILEHANDLE LIST
print LIST
print

Prints a string or a list of strings. Returns true if successful. FILEHANDLE may be a scalar variable name, in which case the variable contains the name of or a reference to the filehandle, thus introducing one level of indirection. (NOTE: If FILEHANDLE is a variable and the next token is a term, it may be misinterpreted as an operator unless you interpose a + or put parentheses around the arguments.) If FILEHANDLE is omitted, prints by default to standard output (or to the last selected output channel--see "select"). If LIST is also omitted, prints $_ to the currently selected output channel. To set the default output channel to something other than STDOUT use the select operation. The current value of $, (if any) is printed between each LIST item. The current value of $\ (if any) is printed after the entire LIST has been printed. Because print takes a LIST, anything in the LIST is evaluated in list context, and any subroutine that you call will have one or more of its expressions evaluated in list context. Also be careful not to follow the print keyword with a left parenthesis unless you want the corresponding right parenthesis to terminate the arguments to the print--interpose a + or put parentheses around all the arguments.

文字列か文字列のリストを出力します。 成功時には、真を返します。FILEHANDLE は、 スカラ変数名でもよく、その場合には、その変数にファイル ハンドル名またはそのリファレンスが 入っているものとして扱われますから、一段階の間接指定が行なえます。 (注: FILEHANDLE に変数を使い、次のトークンが「項」のときには、 間に + を置くか、引数の前後を括弧で括らなければ、 誤って解釈されることがあります。) FILEHANDLE を省略した場合には、標準出力 (か、 最後に選択された出力チャネル --- "select"を参照) に出力します。 LIST も省略すると、$_ を現在選択されている出力チャネルに 出力することになります。 デフォルトの出力チャネルを STDOUT 以外にしたければ、select 演算子を 使ってください。 $, の値が(もしあれば)各 LIST 要素の間に出力されます。 print の引数は LIST なので、LISTの中のものは、 すべてリストコンテキストで評価されます。 サブルーチンの呼び出しがあれば、リストコンテキストでは、 複数の値を返すかもしれません。また、すべての 引数を括弧で括るのでなければ、print というキーワードの 次に開き括弧を書いてはいけません。 "print" と引数の間に + を書くか、 すべての引数を括弧で括ってください。

Note that if you're storing FILEHANDLES in an array or other expression, you will have to use a block returning its value instead:

もし FILESHANDLES を配列やその他の表現に保存している場合は、 代わりにその値を返すブロックを使う必要があります:

    print { $files[$i] } "stuff\n";
    print { $OK ? STDOUT : STDERR } "stuff\n";
printf FILEHANDLE FORMAT, LIST
printf FORMAT, LIST

Equivalent to print FILEHANDLE sprintf(FORMAT, LIST), except that $\ (the output record separator) is not appended. The first argument of the list will be interpreted as the printf format. If use locale is in effect, the character used for the decimal point in formatted real numbers is affected by the LC_NUMERIC locale. See perllocale.

$\(出力レコードセパレータ)を追加しないことを除けば、 print FILEHANDLE sprintf(FORMAT, LIST) と等価です。 リストの最初の要素は、printf フォーマットと解釈されます。 use localeが効力をもっていれば、小数点に使われる文字は LC_NUMERIC ロケールの影響を受けます。 perllocale を参照してください。

Don't fall into the trap of using a printf when a simple print would do. The print is more efficient and less error prone.

単純な print を使うべきところで printf を使ってしまう 罠にかからないようにしてください。 print はより効率的で、間違いが起こりにくいです。

prototype FUNCTION

Returns the prototype of a function as a string (or undef if the function has no prototype). FUNCTION is a reference to, or the name of, the function whose prototype you want to retrieve.

関数のプロトタイプを文字列として返します(関数にプロトタイプがない場合は undef を返します)。 FUNCTION はプロトタイプを得たい関数の名前、またはリファレンスです。

If FUNCTION is a string starting with CORE::, the rest is taken as a name for Perl builtin. If the builtin is not overridable (such as qw//) or its arguments cannot be expressed by a prototype (such as system) returns undef because the builtin does not really behave like a Perl function. Otherwise, the string describing the equivalent prototype is returned.

FUNCTION が CORE:: で始まっている場合、残りは Perl ビルドインの名前として 扱われます。 このビルドインが(qw// のように) オーバーライド可能 でない、 またはこの引数が(system のように)プロトタイプとして記述できない場合、 undef を返します。 なぜならビルドインは実際に Perl 関数のように振舞わないからです。 それ以外では、等価なプロトタイプを表現した文字列が返されます。

push ARRAY,LIST

Treats ARRAY as a stack, and pushes the values of LIST onto the end of ARRAY. The length of ARRAY increases by the length of LIST. Has the same effect as

    for $value (LIST) {
        $ARRAY[++$#ARRAY] = $value;
    }

but is more efficient. Returns the new number of elements in the array.

ARRAY をスタックとして扱い、LIST 内の値を ARRAY の終わりにプッシュします。 ARRAY の大きさは、LIST の長さ分だけ大きくなります。これは、

    for $value (LIST) {
        $ARRAY[++$#ARRAY] = $value;
    }

とするのと同じ効果がありますが、より効率的です。 変更後の配列の要素数を返します。

q/STRING/
qq/STRING/
qr/STRING/
qx/STRING/
qw/STRING/

Generalized quotes. See "Regexp Quote-Like Operators" in perlop.

汎用のクォートです。 "Regexp Quote-Like Operators" in perlopを参照してください。

quotemeta EXPR
quotemeta

Returns the value of EXPR with all non-"word" characters backslashed. (That is, all characters not matching /[A-Za-z_0-9]/ will be preceded by a backslash in the returned string, regardless of any locale settings.) This is the internal function implementing the \Q escape in double-quoted strings.

EXPR の中のすべての非英数字キャラクタをバックスラッシュで エスケープしたものを返します (つまり、/[A-Za-z_0-9]/ にマッチしない全ての文字の前には ロケールに関わらずバックスラッシュが前置されます)。 これは、ダブルクォート文字列での \Q エスケープを 実装するための内部関数です。

If EXPR is omitted, uses $_.

EXPR が省略されると、$_ を使います。

rand EXPR
rand

Returns a random fractional number greater than or equal to 0 and less than the value of EXPR. (EXPR should be positive.) If EXPR is omitted, the value 1 is used. Automatically calls srand unless srand has already been called. See also srand.

0 以上 EXPR の値未満の小数の乱数値を返します。 (EXPRは正の数である必要があります。) EXPR を省略すると、1 とみなします。 srand が既に呼ばれている場合以外は、自動的に srand 関数を 呼び出します。 srand も参照してください。

(Note: If your rand function consistently returns numbers that are too large or too small, then your version of Perl was probably compiled with the wrong number of RANDBITS.)

(注: もし、rand 関数が、常に大きい値ばかりや、小さい数ばかりを 返すようなら、お使いになっている Perl が、 良くない RANDBITS を使ってコンパイルされている可能性があります。)

read FILEHANDLE,SCALAR,LENGTH,OFFSET
read FILEHANDLE,SCALAR,LENGTH

Attempts to read LENGTH bytes of data into variable SCALAR from the specified FILEHANDLE. Returns the number of bytes actually read, 0 at end of file, or undef if there was an error. SCALAR will be grown or shrunk to the length actually read. If SCALAR needs growing, the new bytes will be zero bytes. An OFFSET may be specified to place the read data into some other place in SCALAR than the beginning. The call is actually implemented in terms of stdio's fread(3) call. To get a true read(2) system call, see sysread.

指定した FILEHANDLE から、変数 SCALAR に LENGTH バイトの データを読み込みます。 実際に読み込まれたバイト数、 ファイル終端の場合は 0、エラーの場合は undef のいずれかを返します。 SCALAR は、実際に読み込んだ長さに応じて、伸び縮みします。 SCALAR が伸びた場合、伸びた部分はバイト 0 になります。 OFFSET を指定すると、SCALAR の先頭以外の場所から、 読み込みを行なうことができます。 この関数は、stdio ライブラリの fread(3) 関数を使って実装しています。 本当の read(2) システムコールを利用するには、sysread を参照してください。

readdir DIRHANDLE

Returns the next directory entry for a directory opened by opendir. If used in list context, returns all the rest of the entries in the directory. If there are no more entries, returns an undefined value in scalar context or a null list in list context.

opendir でオープンしたディレクトリで、 次のディレクトリエントリを返します。 リストコンテキストで用いると、 そのディレクトリの残りのエントリを、すべて返します。 エントリが残っていない場合には、スカラコンテキストでは未定義値を、 リストコンテキストでは空リストを返します。

If you're planning to filetest the return values out of a readdir, you'd better prepend the directory in question. Otherwise, because we didn't chdir there, it would have been testing the wrong file.

readdir の返り値をファイルテストに使おうと計画しているなら、 頭にディレクトリをつける必要があります。 さもなければ、ここでは chdir はしないので、 間違ったファイルをテストしてしまうことになるでしょう。

    opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
    @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
    closedir DIR;
readline EXPR

Reads from the filehandle whose typeglob is contained in EXPR. In scalar context, each call reads and returns the next line, until end-of-file is reached, whereupon the subsequent call returns undef. In list context, reads until end-of-file is reached and returns a list of lines. Note that the notion of "line" used here is however you may have defined it with $/ or $INPUT_RECORD_SEPARATOR). See "$/" in perlvar.

typeglob が EXPR に含まれているファイルハンドルから読み込みます。 スカラコンテキストでは、呼び出し毎に一行読み込んで返します。 ファイルの最後まで読み込んだら、以後の呼び出しでは undef を返します。 リストコンテキストでは、ファイルの最後まで読み込んで、 行のリストを返します。 ここでの「行」とは、$/ または $INPUT_RECORD_SEPARATOR で 定義されることに注意してください。"$/" in perlvar も参照して下さい。

When $/ is set to undef, when readline() is in scalar context (i.e. file slurp mode), and when an empty file is read, it returns '' the first time, followed by undef subsequently.

$/undef を設定した場合は、readline() はスカラコンテキスト (つまりファイル吸い込みモード)となり、 空のファイルを読み込んだ場合は、最初は '' を返し、 それ以降は undef を返します。

This is the internal function implementing the <EXPR> operator, but you can use it directly. The <EXPR> operator is discussed in more detail in "I/O Operators" in perlop.

これは <EXPR> 演算子を実装している内部関数ですが、 直接使うこともできます。 <EXPR> 演算子についてのさらなる詳細については "I/O Operators" in perlop で議論されています。

    $line = <STDIN>;
    $line = readline(*STDIN);           # same thing
readlink EXPR
readlink

Returns the value of a symbolic link, if symbolic links are implemented. If not, gives a fatal error. If there is some system error, returns the undefined value and sets $! (errno). If EXPR is omitted, uses $_.

シンボリックリンクが実装されていれば、 シンボリックリンクの値を返します。 実装されていないときには、致命的エラーとなります。 何らかのシステムエラーが検出されると、 未定義値を返し、$! (errno)を設定します。 EXPR を省略すると、$_ を使用します。

readpipe EXPR

EXPR is executed as a system command. The collected standard output of the command is returned. In scalar context, it comes back as a single (potentially multi-line) string. In list context, returns a list of lines (however you've defined lines with $/ or $INPUT_RECORD_SEPARATOR). This is the internal function implementing the qx/EXPR/ operator, but you can use it directly. The qx/EXPR/ operator is discussed in more detail in "I/O Operators" in perlop.

EXPR がシステムコマンドとして実行されます。 コマンドの標準出力の内容が返されます。 スカラコンテキストでは、単一の(内部的に複数行の)文字列を返します。 リストコンテキストでは、行のリストを返します (但し、行は $/ または $INPUT_RECORD_SEPARATOR で定義されます)。 これは qx/EXPR/ 演算子を実装する内部関数ですが、 直接使うことも出来ます。 qx/EXPR/ 演算子は "I/O Operators" in perlop でより詳細に 述べられています。

recv SOCKET,SCALAR,LENGTH,FLAGS

Receives a message on a socket. Attempts to receive LENGTH bytes of data into variable SCALAR from the specified SOCKET filehandle. SCALAR will be grown or shrunk to the length actually read. Takes the same flags as the system call of the same name. Returns the address of the sender if SOCKET's protocol supports this; returns an empty string otherwise. If there's an error, returns the undefined value. This call is actually implemented in terms of recvfrom(2) system call. See "UDP: Message Passing" in perlipc for examples.

ソケット上のメッセージを受信します。 指定されたファイルハンドル SOCKET から、変数 SCALAR に LENGTH バイトのデータを読み込もうとします。 SCALAR は、実際に読まれた長さによって、大きくなったり、 小さくなったりします。 同名のシステムコールと同じ FLAGS を使います。 SOCKET のプロトコルが対応していれば、送信側のアドレスを返します。 エラー発生時には、未定義値を返します。 実際には、C のrecvfrom(2) を呼びます。 例については"UDP: Message Passing" in perlipcを参照してください。

redo LABEL
redo

The redo command restarts the loop block without evaluating the conditional again. The continue block, if any, is not executed. If the LABEL is omitted, the command refers to the innermost enclosing loop. This command is normally used by programs that want to lie to themselves about what was just input:

redo コマンドは、条件を再評価しないで、ループブロックの始めからもう一度 実行を開始します。 continue ブロックがあっても、実行されません。 LABEL が省略されると、このコマンドは、もっとも内側のループを参照します。 このコマンドは通常、自分への入力を欺くために使用します:

    # a simpleminded Pascal comment stripper
    # (warning: assumes no { or } in strings)
    LINE: while (<STDIN>) {
        while (s|({.*}.*){.*}|$1 |) {}
        s|{.*}| |;
        if (s|{.*| |) {
            $front = $_;
            while (<STDIN>) {
                if (/}/) {      # end of comment?
                    s|^|$front\{|;
                    redo LINE;
                }
            }
        }
        print;
    }

redo cannot be used to retry a block which returns a value such as eval {}, sub {} or do {}, and should not be used to exit a grep() or map() operation.

redoeval {}, sub {}, do {} のように値を返す ブロックを繰り返すのには使えません。 また、grep() や map() 操作から抜けるのに使うべきではありません。

Note that a block by itself is semantically identical to a loop that executes once. Thus redo inside such a block will effectively turn it into a looping construct.

ブロック自身は一回だけ実行されるループと文法的に同一であることに 注意してください。 従って、ブロックの中で redo を使うことで効果的に ループ構造に変換します。

See also "continue" for an illustration of how last, next, and redo work.

last, next, redo がどのように働くかについては "continue" を参照して下さい。

ref EXPR
ref

Returns a true value if EXPR is a reference, false otherwise. If EXPR is not specified, $_ will be used. The value returned depends on the type of thing the reference is a reference to. Builtin types include:

EXPR がリファレンスであれば、真を返し、さもなくば、偽を返します。 EXPR が指定されなければ、$_ が使われます。 返される値は、リファレンスが参照するものの型に依存します。 組み込みの型には、以下のものがあります。

    SCALAR
    ARRAY
    HASH
    CODE
    REF
    GLOB
    LVALUE

If the referenced object has been blessed into a package, then that package name is returned instead. You can think of ref as a typeof operator.

参照されるオブジェクトが、何らかのパッケージに bless されたものであれば、これらの代わりに、 そのパッケージ名が返されます。 ref は、typeof 演算子のように考えることができます。

    if (ref($r) eq "HASH") {
        print "r is a reference to a hash.\n";
    }
    unless (ref($r)) {
        print "r is not a reference at all.\n";
    }
    if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
        print "r is a reference to something that isa hash.\n";
    } 

See also perlref.

perlref も参照してください。

rename OLDNAME,NEWNAME

Changes the name of a file; an existing file NEWNAME will be clobbered. Returns true for success, false otherwise.

ファイルの名前を変更します。 NEWNAME というファイルが既に存在した場合、上書きされるかもしれません。 成功時には真、失敗時には偽を返します。

Behavior of this function varies wildly depending on your system implementation. For example, it will usually not work across file system boundaries, even though the system mv command sometimes compensates for this. Other restrictions include whether it works on directories, open files, or pre-existing files. Check perlport and either the rename(2) manpage or equivalent system documentation for details.

この関数の振る舞いはシステムの実装に大きく依存して異なります。 普通はファイルシステムにまたがってパス名を付け替えることはできません。 システムの mv がこれを補完している場合でもそうです。 その他の制限には、ディレクトリ、オープンしているファイル、既に存在している ファイルに対して使えるか、といったことを含みます。 詳しくは、perlport および rename(2) man ページあるいは同様の システムドキュメントを参照してください。

require VERSION
require EXPR
require

Demands some semantics specified by EXPR, or by $_ if EXPR is not supplied.

EXPR (省略時には $_) によって指定されるいくつかの動作を要求します。

If a VERSION is specified as a literal of the form v5.6.1, demands that the current version of Perl ($^V or $PERL_VERSION) be at least as recent as that version, at run time. (For compatibility with older versions of Perl, a numeric argument will also be interpreted as VERSION.) Compare with "use", which can do a similar check at compile time.

VERSION が v5.6.1 の形で指定されると、実行時の Perl の現在のバージョン($^V または $PERL_VERSION)が そのバージョン以降であることを要求します。 (古いバージョンの Perl との互換性のために、数値の引数も VERSION として解釈されます) "use" と似ていますが、これはコンパイル時にチェックされます。

    require v5.6.1;     # run time version check
    require 5.6.1;      # ditto
    require 5.005_03;   # float version allowed for compatibility

Otherwise, demands that a library file be included if it hasn't already been included. The file is included via the do-FILE mechanism, which is essentially just a variety of eval. Has semantics similar to the following subroutine:

それ以外の場合には、既に読み込まれていないときに、 読み込むライブラリファイルを要求するものとなります。 そのファイルは、基本的には eval の一種である、 do-FILE によって読み込まれます。 意味的には、次のようなサブルーチンと同じようなものです:

    sub require {
        my($filename) = @_;
        return 1 if $INC{$filename};
        my($realfilename,$result);
        ITER: {
            foreach $prefix (@INC) {
                $realfilename = "$prefix/$filename";
                if (-f $realfilename) {
                    $INC{$filename} = $realfilename;
                    $result = do $realfilename;
                    last ITER;
                }
            }
            die "Can't find $filename in \@INC";
        }
        delete $INC{$filename} if $@ || !$result;
        die $@ if $@;
        die "$filename did not return true value" unless $result;
        return $result;
    }

Note that the file will not be included twice under the same specified name. The file must return true as the last statement to indicate successful execution of any initialization code, so it's customary to end such a file with 1; unless you're sure it'll return true otherwise. But it's better just to put the 1;, in case you add more statements.

ファイルは、同じ名前で 2 回読み込まれることはありません。 初期化コードの実行がうまくいったことを示すために、 ファイルは真を返さなければなりませんから、 真を返すようになっている自信がある場合を除いては、 ファイルの最後に 1; と書くのが習慣です。 実行文を追加するような場合に備えて、1; と書いておいた方が 良いでしょう。

If EXPR is a bareword, the require assumes a ".pm" extension and replaces "::" with "/" in the filename for you, to make it easy to load standard modules. This form of loading of modules does not risk altering your namespace.

EXPR が裸の単語であるときには、標準モジュールのロードを 簡単にするように、require は拡張子が ".pm" であり、 "::" を "/" に変えたものがファイル名であると仮定します。 この形式のモジュールロードは、 名前空間を変更してしまう危険はありません。

In other words, if you try this:

言い換えると、以下のようにすると:

        require Foo::Bar;    # a splendid bareword 

The require function will actually look for the "Foo/Bar.pm" file in the directories specified in the @INC array.

But if you try this:

require 関数は @INC 配列で指定されたディレクトリにある "Foo/Bar.pm" ファイルを探します。

しかし、以下のようにすると:

        $class = 'Foo::Bar';
        require $class;      # $class is not a bareword
    #or
        require "Foo::Bar";  # not a bareword because of the ""

The require function will look for the "Foo::Bar" file in the @INC array and will complain about not finding "Foo::Bar" there. In this case you can do:

require 関数は @INC 配列の "Foo::Bar" ファイルを探し、 おそらくそこに "Foo::Bar" がないと文句をいうことになるでしょう。 このような場合には、以下のようにします:

        eval "require $class";

For a yet-more-powerful import facility, see "use" and perlmod.

より強力な import 機能については、このドキュメントの "use" の項と、perlmod を参照してください。

reset EXPR
reset

Generally used in a continue block at the end of a loop to clear variables and reset ?? searches so that they work again. The expression is interpreted as a list of single characters (hyphens allowed for ranges). All variables and arrays beginning with one of those letters are reset to their pristine state. If the expression is omitted, one-match searches (?pattern?) are reset to match again. Resets only variables or searches in the current package. Always returns 1. Examples:

通常、ループの最後に、変数をクリアし、?? 検索を再び 動作するようにリセットするため、continue ブロックで使われます。 EXPR は、文字を並べたもの (範囲を指定するのに、ハイフンが使えます) と 解釈されます。 名前がその文字のいずれかで始まる変数や配列は、 最初の状態にリセットされます。 EXPR を省略すると、1 回検索 (?PATTERN?) を再びマッチするように リセットできます。 カレントパッケージの変数もしくは検索だけがリセットされます。 常に 1 を返します。 例:

    reset 'X';          # reset all X variables
    reset 'a-z';        # reset lower case variables
    reset;              # just reset ?one-time? searches

Resetting "A-Z" is not recommended because you'll wipe out your @ARGV and @INC arrays and your %ENV hash. Resets only package variables--lexical variables are unaffected, but they clean themselves up on scope exit anyway, so you'll probably want to use them instead. See "my".

reset "A-Z" とすると、@ARGV, @INC 配列や %ENV ハッシュも なくなってしまいますから、止めた方が良いでしょう。 パッケージ変数だけがリセットされます。 レキシカル変数は、影響を受けませんが、スコープから外れれば、 自動的に綺麗になりますので、これからは、こちらを使うようにした方が よいでしょう。 "my" を参照してください。

return EXPR
return

Returns from a subroutine, eval, or do FILE with the value given in EXPR. Evaluation of EXPR may be in list, scalar, or void context, depending on how the return value will be used, and the context may vary from one execution to the next (see wantarray). If no EXPR is given, returns an empty list in list context, the undefined value in scalar context, and (of course) nothing at all in a void context.

サブルーチン, eval, do FILE から EXPR で与えられた値をもって、 リターンします。 EXPR の評価は、返り値がどのように使われるかによって リスト、スカラ、無効コンテキストになります。 またコンテキストは実行毎に変わります(wantarray を参照してください)。 EXPR が指定されなかった場合は、リストコンテキストでは空リストを、 スカラコンテキストでは未定義値を返します。 そして(もちろん)無効コンテキストでは何も返しません。

(Note that in the absence of a explicit return, a subroutine, eval, or do FILE will automatically return the value of the last expression evaluated.)

(サブルーチン, eval, do FILE に明示的に return が なければ、最後に評価された値で、自動的にリターンします。)

reverse LIST

In list context, returns a list value consisting of the elements of LIST in the opposite order. In scalar context, concatenates the elements of LIST and returns a string value with all characters in the opposite order.

リストコンテキストでは、LIST を構成するよ要素を逆順に並べた リスト値を返します。 スカラコンテキストでは、LIST の要素を連結して、 全ての文字を逆順にした文字列を返します。

    print reverse <>;           # line tac, last line first

    undef $/;                   # for efficiency of <>
    print scalar reverse <>;    # character tac, last line tsrif

This operator is also handy for inverting a hash, although there are some caveats. If a value is duplicated in the original hash, only one of those can be represented as a key in the inverted hash. Also, this has to unwind one hash and build a whole new one, which may take some time on a large hash, such as from a DBM file.

この演算子はハッシュの逆順にするのにも便利ですが、いくつかの弱点があります。 元のハッシュで値が重複していると、それらのうち一つだけが 逆順になったハッシュのキーとして表現されます。 また、これは一つのハッシュをほどいて完全に新しいハッシュを作るので、 DBM ファイルからのような大きなハッシュでは少し時間がかかります。

    %by_name = reverse %by_address;     # Invert the hash
rewinddir DIRHANDLE

Sets the current position to the beginning of the directory for the readdir routine on DIRHANDLE.

DIRHANDLE に対する readdir ルーチンの現在位置を ディレクトリの最初に設定します。

rindex STR,SUBSTR,POSITION
rindex STR,SUBSTR

Works just like index() except that it returns the position of the LAST occurrence of SUBSTR in STR. If POSITION is specified, returns the last occurrence at or before that position.

STR 中で最後に見つかった SUBSTR の位置を返すことを除いて、 index() と同じように動作します。 POSITION を指定すると、その位置より前の、最後の位置を返します。

rmdir FILENAME
rmdir

Deletes the directory specified by FILENAME if that directory is empty. If it succeeds it returns true, otherwise it returns false and sets $! (errno). If FILENAME is omitted, uses $_.

FILENAME で指定したディレクトリが空であれば、 そのディレクトリを削除します。 成功時には真を返し、失敗時には偽を返し、$! (errno) を設定します。 FILENAMEを省略した場合には、$_ を使用します。

s///

The substitution operator. See perlop.

置換演算子。 perlop を参照してください。

scalar EXPR

Forces EXPR to be interpreted in scalar context and returns the value of EXPR.

EXPR を強制的にスカラコンテキストで解釈されるようにして、 EXPR の値を返します。

    @counts = ( scalar @a, scalar @b, scalar @c );

There is no equivalent operator to force an expression to be interpolated in list context because in practice, this is never needed. If you really wanted to do so, however, you could use the construction @{[ (some expression) ]}, but usually a simple (some expression) suffices.

式を強制的にリストコンテキストで解釈させるようにする演算子はありません。 理論的には不要だからです。 それでも、もしそうしたいのなら、@{[ (some expression) ]} という構造を 使えます。 しかし、普通は単に (some expression) とすれば十分です。

Because scalar is unary operator, if you accidentally use for EXPR a parenthesized list, this behaves as a scalar comma expression, evaluating all but the last element in void context and returning the final element evaluated in scalar context. This is seldom what you want.

scalar は単項演算子なので、EXPR として括弧でくくったリストを使った場合、 これはスカラカンマ表現として振舞い、最後以外の全ては無効コンテキストとして 扱われ、最後の要素をスカラコンテキストとして扱った結果が返されます。 これがあなたの望むものであることはめったにないでしょう。

The following single statement:

以下の 1 つの文は:

        print uc(scalar(&foo,$bar)),$baz;

is the moral equivalent of these two:

以下の 2 つの文と等価です。

        &foo;
        print(uc($bar),$baz);

See perlop for more details on unary operators and the comma operator.

単項演算子とカンマ演算子に関する詳細については perlop を参照して下さい。

seek FILEHANDLE,POSITION,WHENCE

Sets FILEHANDLE's position, just like the fseek call of stdio. FILEHANDLE may be an expression whose value gives the name of the filehandle. The values for WHENCE are 0 to set the new position to POSITION, 1 to set it to the current position plus POSITION, and 2 to set it to EOF plus POSITION (typically negative). For WHENCE you may use the constants SEEK_SET, SEEK_CUR, and SEEK_END (start of the file, current position, end of the file) from the Fcntl module. Returns 1 upon success, 0 otherwise.

stdio ライブラリの fseek 関数のように、FILEHANDLE の ファイルポインタを任意の位置に設定します。 FILEHANDLE は、実際のファイルハンドル名を与える式でもかまいません。 WHENCE の値が、0 ならば、 新しい位置を POSITION の位置へ、1 ならば、現在位置から POSITION 加えた位置へ、2 ならば、EOF から POSITION だけ加えた位置へ、新しい位置を設定します。 この値には、Fcntl モジュールで使われている SEEK_SETSEEK_CURSEEK_END (ファイルの先頭、現在位置、ファイルの最後)という定数を使うこともできます。 成功時には、1 を、失敗時には 0 を返します。

If you want to position file for sysread or syswrite, don't use seek--buffering makes its effect on the file's system position unpredictable and non-portable. Use sysseek instead.

sysreadsyswrite のためにファイルの位置を指定したい場合は、 seek は使えません -- バッファリングのために動作は予測不能で 移植性のないものになってしまいます。 代わりに sysseek を使ってください。

Due to the rules and rigors of ANSI C, on some systems you have to do a seek whenever you switch between reading and writing. Amongst other things, this may have the effect of calling stdio's clearerr(3). A WHENCE of 1 (SEEK_CUR) is useful for not moving the file position:

ANSI C の規則と困難により、システムによっては読み込みと書き込みを 切り替える度にシークしなければならない場合があります。 その他のことの中で、これは stdio の clearerr(3) を呼び出す効果があります。 WHENCE の 1 (SEEK_CUR) が、ファイル位置を変えないので有用です:

    seek(TEST,0,1);

This is also useful for applications emulating tail -f. Once you hit EOF on your read, and then sleep for a while, you might have to stick in a seek() to reset things. The seek doesn't change the current position, but it does clear the end-of-file condition on the handle, so that the next <FILE> makes Perl try again to read something. We hope.

これはアプリケーションで tail -f をエミュレートするのにも有用です。 一度読み込み時に EOF に到達すると、しばらくスリープし、 seek() することでリセットする必要があります。 seek は現在の位置を変更しませんが、ハンドルの EOF 状態を クリアします ので、次の <FILE> で Perl は再び何かを 読み込もうとします。 そのはずです。

If that doesn't work (some stdios are particularly cantankerous), then you may need something more like this:

これが動かない場合(特に意地の悪い stdio もあります)、 以下のようなことをする必要があります:

    for (;;) {
        for ($curpos = tell(FILE); $_ = <FILE>;
             $curpos = tell(FILE)) {
            # search for some stuff and put it into files
        }
        sleep($for_a_while);
        seek(FILE, $curpos, 0);
    }
seekdir DIRHANDLE,POS

Sets the current position for the readdir routine on DIRHANDLE. POS must be a value returned by telldir. Has the same caveats about possible directory compaction as the corresponding system library routine.

DIRHANDLE での readdir ルーチンの現在位置を設定します。 POS は、telldir が返す値でなければなりません。 同名のシステムライブラリルーチンと同じく、 ディレクトリ縮小時の問題が考えられます。

select FILEHANDLE
select

Returns the currently selected filehandle. Sets the current default filehandle for output, if FILEHANDLE is supplied. This has two effects: first, a write or a print without a filehandle will default to this FILEHANDLE. Second, references to variables related to output will refer to this output channel. For example, if you have to set the top of form format for more than one output channel, you might do the following:

その時点で、選択されていたファイルハンドルを返します。 FILEHANDLE を指定した場合には、その値を出力のデフォルト ファイルハンドルに設定します。 これには、2 つの効果があります。 まず、ファイルハンドルを指定しないで writeprint を行なった場合のデフォルトが、 この FILEHANDLE になります。 もう一つは、出力関連の変数への参照は、 この出力チャネルを参照するようになります。 たとえば、複数の出力チャネルに対して、ページ先頭フォーマットを 設定しなければならないのであれば、 以下のようにしなければならないでしょう。

    select(REPORT1);
    $^ = 'report1_top';
    select(REPORT2);
    $^ = 'report2_top';

FILEHANDLE may be an expression whose value gives the name of the actual filehandle. Thus:

FILEHANDLE は、実際のファイルハンドルの名前を示す式でもかまいません。 つまり、以下のようなものです:

    $oldfh = select(STDERR); $| = 1; select($oldfh);

Some programmers may prefer to think of filehandles as objects with methods, preferring to write the last example as:

ファイルハンドルはメソッドを持ったオブジェクトであると 考えることを好むプログラマもいるかもしれません。 そのような場合のための最後の例は以下のようなものです。

    use IO::Handle;
    STDERR->autoflush(1);
select RBITS,WBITS,EBITS,TIMEOUT

This calls the select(2) system call with the bit masks specified, which can be constructed using fileno and vec, along these lines:

これは、select(2) システムコールを、指定したビットマスクで呼び出します。 ビットマスクは、filenovec を使って、以下のようにして作成できます。

    $rin = $win = $ein = '';
    vec($rin,fileno(STDIN),1) = 1;
    vec($win,fileno(STDOUT),1) = 1;
    $ein = $rin | $win;

If you want to select on many filehandles you might wish to write a subroutine:

複数のファイルハンドルに select を行ないたいのであれば、 以下のようにします。

    sub fhbits {
        my(@fhlist) = split(' ',$_[0]);
        my($bits);
        for (@fhlist) {
            vec($bits,fileno($_),1) = 1;
        }
        $bits;
    }
    $rin = fhbits('STDIN TTY SOCK');

The usual idiom is:

通常は、

    ($nfound,$timeleft) =
      select($rout=$rin, $wout=$win, $eout=$ein, $timeout);

or to block until something becomes ready just do this

のように使い、いずれかの準備が整うまでブロックするには、 以下のようにします。

    $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);

Most systems do not bother to return anything useful in $timeleft, so calling select() in scalar context just returns $nfound.

ほとんどのシステムではわざわざ意味のある値を $timeleft に返さないので、 select() をスカラコンテキストで呼び出すと、単に $nfound を返します。

Any of the bit masks can also be undef. The timeout, if specified, is in seconds, which may be fractional. Note: not all implementations are capable of returning the$timeleft. If not, they always return $timeleft equal to the supplied $timeout.

どのビットマスクにも undef を設定することができます。 TIMEOUT を指定するときは、秒数で指定し、小数でかまいません。 注: すべての実装で、$timeleft が返せるものではありません。 その場合、$timeleft には、常に指定した TIMEOUT と同じ値が返されます。

You can effect a sleep of 250 milliseconds this way:

250 ミリ秒の sleep と同じ効果が、以下のようにして得られます。

    select(undef, undef, undef, 0.25);

WARNING: One should not attempt to mix buffered I/O (like read or <FH>) with select, except as permitted by POSIX, and even then only on POSIX systems. You have to use sysread instead.

警告: バッファ付き I/O (read や <FH>) と select を 混ぜて使ってはいけません(例外: POSIX で認められている形で使い、 POSIX システムでだけ動かす場合を除きます)。 代わりに sysread を使わなければなりません。

semctl ID,SEMNUM,CMD,ARG

Calls the System V IPC function semctl. You'll probably have to say

    use IPC::SysV;

first to get the correct constant definitions. If CMD is IPC_STAT or GETALL, then ARG must be a variable which will hold the returned semid_ds structure or semaphore value array. Returns like ioctl: the undefined value for error, "0 but true" for zero, or the actual return value otherwise. The ARG must consist of a vector of native short integers, which may be created with pack("s!",(0)x$nsem). See also "SysV IPC" in perlipc, IPC::SysV, IPC::Semaphore documentation.

System V IPC 関数 semctl を呼び出します。正しい定数定義を得るために、まず

    use IPC::SysV;

と宣言する必要があるでしょう。 CMD が、IPC_STAT か GETALL のときには、ARG は、返される semid_ds 構造体か、セマフォ値の配列を納める変数でなければなりません。 ioctl と同じように、エラー時には未定義値、 ゼロのときは "0 だが真"、それ以外なら、その値そのものを返します。 ARG はネイティブな short int のベクターから成っていなければなりません。 これは pack("s!",(0)x$nsem) で作成できます。 "SysV IPC" in perlipc, IPC::SysV, IPC::Semaphore も参照してください。

semget KEY,NSEMS,FLAGS

Calls the System V IPC function semget. Returns the semaphore id, or the undefined value if there is an error. See also "SysV IPC" in perlipc, IPC::SysV, IPC::SysV::Semaphore documentation.

System V IPC 関数 semget を呼び出します。 セマフォ ID か、エラー時には未定義値を返します。 "SysV IPC" in perlipc, IPC::SysV, IPC::SysV::Semaphore も 参照してください。

semop KEY,OPSTRING

Calls the System V IPC function semop to perform semaphore operations such as signaling and waiting. OPSTRING must be a packed array of semop structures. Each semop structure can be generated with pack("sss", $semnum, $semop, $semflag). The number of semaphore operations is implied by the length of OPSTRING. Returns true if successful, or false if there is an error. As an example, the following code waits on semaphore $semnum of semaphore id $semid:

シグナルを送信や、待ち合わせなどのセマフォ操作を行なうために、 System V IPC 関数 semop を呼び出します。 OPSTRING は、semop 構造体の pack された配列でなければなりません。 semop 構造体は、それぞれ、 pack("sss", $semnum, $semop, $semflag) のように作ることができます。 セマフォ操作の数は、OPSTRING の長さからわかります。 成功時には真を、エラー時には偽を返します。 以下の例は、セマフォ ID $semid のセマフォ $semnum で 待ち合わせを行ないます。

    $semop = pack("sss", $semnum, -1, 0);
    die "Semaphore trouble: $!\n" unless semop($semid, $semop);

To signal the semaphore, replace -1 with 1. See also "SysV IPC" in perlipc, IPC::SysV, and IPC::SysV::Semaphore documentation.

セマフォにシグナルを送るには、-11 に変更してください。 "SysV IPC" in perlipc, IPC::SysV, IPC::SysV::Semaphore も 参照してください。

send SOCKET,MSG,FLAGS,TO
send SOCKET,MSG,FLAGS

Sends a message on a socket. Takes the same flags as the system call of the same name. On unconnected sockets you must specify a destination to send TO, in which case it does a C sendto. Returns the number of characters sent, or the undefined value if there is an error. The C system call sendmsg(2) is currently unimplemented. See "UDP: Message Passing" in perlipc for examples.

SOCKET に MSG を送ります。 FLAGS には、同名のシステムコールと同じフラグを指定します。 接続していないソケットには、送信先 TO を指定しなければならず、 この場合、C の sendto を実行します。 送信した文字数か、エラー時には、未定義値を返します。 C の システムコール sendmsg(2) は現在実装されていません。 例については "UDP: Message Passing" in perlipc を参照してください。

setpgrp PID,PGRP

Sets the current process group for the specified PID, 0 for the current process. Will produce a fatal error if used on a machine that doesn't implement POSIX setpgid(2) or BSD setpgrp(2). If the arguments are omitted, it defaults to 0,0. Note that the BSD 4.2 version of setpgrp does not accept any arguments, so only setpgrp(0,0) is portable. See also POSIX::setsid().

指定した PID (0 を指定するとカレントプロセス) に 対するプロセスグループを設定します。 POSIX setpgrp(2) または BSD setpgrp(2) が実装されていないマシンでは、 致命的エラーが発生します。 引数が省略された場合は、0,0が使われます。 BSD 4.2 版の setpgrp は引数を取ることができないので、 setpgrp(0,0) のみが移植性があることに注意してください。 POSIX::setsid() も参照してください。

setpriority WHICH,WHO,PRIORITY

Sets the current priority for a process, a process group, or a user. (See setpriority(2).) Will produce a fatal error if used on a machine that doesn't implement setpriority(2).

プロセス、プロセスグループ、ユーザに対する優先順位を設定します。 (setpriority(2) を参照してください。) setpriority(2) が実装されていないマシンでは、 致命的エラーが発生します。

setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL

Sets the socket option requested. Returns undefined if there is an error. OPTVAL may be specified as undef if you don't want to pass an argument.

要求したソケットオプションを設定します。 エラー時には、未定義値が返されます。 引数を渡したくない場合には、OPTVAL に undef を指定します。

shift ARRAY
shift

Shifts the first value of the array off and returns it, shortening the array by 1 and moving everything down. If there are no elements in the array, returns the undefined value. If ARRAY is omitted, shifts the @_ array within the lexical scope of subroutines and formats, and the @ARGV array at file scopes or within the lexical scopes established by the eval '', BEGIN {}, INIT {}, CHECK {}, and END {} constructs.

配列の最初の値を取り出して、その値を返し、配列を一つ 短くして、すべての要素を前へずらします。 配列に要素がなければ、未定義値を返します。 ARRAY を省略すると、 サブルーチンやフォーマットのレキシカルスコープでは @_ を、 ファイルスコープまたは eval '', BEGIN {}, INIT {}, CHECK {}, END {} で作成されたレキシカルスコープでは @ARGV が用いられます。

See also unshift, push, and pop. shift and unshift do the same thing to the left end of an array that pop and push do to the right end.

unshiftpushpop も参照してください。 shiftunshift は、poppush が配列の右端で行なうことを、左端で行ないます。

shmctl ID,CMD,ARG

Calls the System V IPC function shmctl. You'll probably have to say

    use IPC::SysV;

first to get the correct constant definitions. If CMD is IPC_STAT, then ARG must be a variable which will hold the returned shmid_ds structure. Returns like ioctl: the undefined value for error, "0 but true" for zero, or the actual return value otherwise. See also "SysV IPC" in perlipc and IPC::SysV documentation.

System V IPC 関数 shmctl を呼び出します。正しい定数定義を得るために、まず

    use IPC::SysV;

と宣言する必要があるでしょう。 CMD が、IPC_STAT ならば、ARG は、返される shmid_ds 構造体を 納める変数でなければなりません。 ioctl と同じように、エラー時には未定義値、ゼロのときは "0 だが真"、 それ以外なら、その値そのものを返します。 "SysV IPC" in perlipcIPC::SysV も参照してください。

shmget KEY,SIZE,FLAGS

Calls the System V IPC function shmget. Returns the shared memory segment id, or the undefined value if there is an error. See also "SysV IPC" in perlipc and IPC::SysV documentation.

System V IPC 関数 shmget を呼び出します。 共有メモリのセグメント ID か、エラー時には未定義値を返します。 "SysV IPC" in perlipcIPC::SysV も参照してください。

shmread ID,VAR,POS,SIZE
shmwrite ID,STRING,POS,SIZE

Reads or writes the System V shared memory segment ID starting at position POS for size SIZE by attaching to it, copying in/out, and detaching from it. When reading, VAR must be a variable that will hold the data read. When writing, if STRING is too long, only SIZE bytes are used; if STRING is too short, nulls are written to fill out SIZE bytes. Return true if successful, or false if there is an error. shmread() taints the variable. See also "SysV IPC" in perlipc, IPC::SysV documentation, and the IPC::Shareable module from CPAN.

System V 共有メモリセグメント ID に対し、アタッチして、 コピーを行ない、デタッチするという形で、位置 POS から、 サイズ SIZE だけ、読み込みか書き込みを行ないます。 読み込み時には、VAR は読み込んだデータを納める 変数でなければなりません。 書き込み時には、STRING が長すぎても、SIZE バイトだけが使われます。 STRING が短すぎる場合には、SIZE バイトを埋めるために、 ヌル文字が書き込まれます。 成功時には真を、エラー時には偽を返します。 shmread() は変数を汚染します。 "SysV IPC" in perlipcIPC::SysV の文章と、 CPAN の IPC::Shareable も参照してください。

shutdown SOCKET,HOW

Shuts down a socket connection in the manner indicated by HOW, which has the same interpretation as in the system call of the same name.

同名のシステムコールと同じように解釈される HOW によって、 指定された方法でソケット接続のシャットダウンを行ないます。

    shutdown(SOCKET, 0);    # I/we have stopped reading data
    shutdown(SOCKET, 1);    # I/we have stopped writing data
    shutdown(SOCKET, 2);    # I/we have stopped using this socket

This is useful with sockets when you want to tell the other side you're done writing but not done reading, or vice versa. It's also a more insistent form of close because it also disables the file descriptor in any forked copies in other processes.

これは、こちらがソケットを書き終わったが読み終わっていない、 またはその逆を相手側に伝えたいときに便利です。 これはその他のプロセスでフォークしたファイル記述子のコピーも 無効にするので、よりしつこい閉じ方です。

sin EXPR
sin

Returns the sine of EXPR (expressed in radians). If EXPR is omitted, returns sine of $_.

(ラジアンで示した) EXPR の正弦を返します。 EXPR が省略されたときには、$_ の正弦を返します。

For the inverse sine operation, you may use the Math::Trig::asin function, or use this relation:

逆正弦を求めるためには、Math::Trig::asin 関数を使うか、 以下の関係を使ってください:

    sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
sleep EXPR
sleep

Causes the script to sleep for EXPR seconds, or forever if no EXPR. May be interrupted if the process receives a signal such as SIGALRM. Returns the number of seconds actually slept. You probably cannot mix alarm and sleep calls, because sleep is often implemented using alarm.

スクリプトを EXPR で指定した秒数 (省略時には、永久に) スリープさせます。 そのプロセスには、SIGALRMのようなシグナルを 受信すると、割り込みがかかります。 実際にスリープした秒数を返します。sleep は、alarm を 使って実装されることが多いので、alarmsleep は、おそらく混ぜて使用することはできません。

On some older systems, it may sleep up to a full second less than what you requested, depending on how it counts seconds. Most modern systems always sleep the full amount. They may appear to sleep longer than that, however, because your process might not be scheduled right away in a busy multitasking system.

古いシステムでは、どのように秒を数えるかによって、要求した秒数に完全に 満たないうちに、スリープから抜ける場合があります。 最近のシステムでは、常に完全にスリープします。 しかし、負荷の高いマルチタスクシステムでは 正しくスケジューリングされないがために より長い時間スリープすることがあります。

For delays of finer granularity than one second, you may use Perl's syscall interface to access setitimer(2) if your system supports it, or else see "select" above. The Time::HiRes module from CPAN may also help.

1 秒より精度の高いスリープを行なうには、 setitimer(2) をサポートしているシステムでは、Perl の syscall インタフェースを使ってアクセスするか、 さもなければ上述の "select" を参照してください。 CPAN の Time::HiRes モジュールも有用でしょう。

See also the POSIX module's pause function.

POSIX モジュールの pause 関数も参照して下さい。

socket SOCKET,DOMAIN,TYPE,PROTOCOL

Opens a socket of the specified kind and attaches it to filehandle SOCKET. DOMAIN, TYPE, and PROTOCOL are specified the same as for the system call of the same name. You should use Socket first to get the proper definitions imported. See the examples in "Sockets: Client/Server Communication" in perlipc.

指定した種類のソケットをオープンし、ファイルハンドル SOCKET にアタッチします。 DOMAIN、TYPE、PROTOCOL は、 同名のシステムコールと同じように指定します。 適切な定義を import するために、まず、use Socket と するとよいでしょう。 例については "Sockets: Client/Server Communication" in perlipc を 参照してください。

On systems that support a close-on-exec flag on files, the flag will be set for the newly opened file descriptor, as determined by the value of $^F. See "$^F" in perlvar.

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 フラグは$^F の値で決定される、新しくオープンされたファイル記述子に対して セットされます。 "$^F" in perlvarを参照してください。

socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL

Creates an unnamed pair of sockets in the specified domain, of the specified type. DOMAIN, TYPE, and PROTOCOL are specified the same as for the system call of the same name. If unimplemented, yields a fatal error. Returns true if successful.

指定した DOMAIN に、指定した TYPE で名前の無いソケットのペアを生成します。 DOMAIN、TYPE、PROTOCOL は、同名のシステムコールと同じように指定します。 実装されていない場合には、致命的エラーとなります。 成功時には真を返します。

On systems that support a close-on-exec flag on files, the flag will be set for the newly opened file descriptors, as determined by the value of $^F. See "$^F" in perlvar.

ファイルに対する close-on-exec フラグをサポートしているシステムでは、 フラグは$^F の値で決定される、新しくオープンされたファイル記述子に対して セットされます。 "$^F" in perlvar を参照してください。

Some systems defined pipe in terms of socketpair, in which a call to pipe(Rdr, Wtr) is essentially:

pipesocketpair を使って定義しているシステムもあります; pipe(Rdr, Wtr) は本質的には以下のようになります:

    use Socket;
    socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
    shutdown(Rdr, 1);        # no more writing for reader
    shutdown(Wtr, 0);        # no more reading for writer

See perlipc for an example of socketpair use.

socketpair の使用例については perlipc を参照してください。

sort SUBNAME LIST
sort BLOCK LIST
sort LIST

Sorts the LIST and returns the sorted list value. If SUBNAME or BLOCK is omitted, sorts in standard string comparison order. If SUBNAME is specified, it gives the name of a subroutine that returns an integer less than, equal to, or greater than 0, depending on how the elements of the list are to be ordered. (The <=> and cmp operators are extremely useful in such routines.) SUBNAME may be a scalar variable name (unsubscripted), in which case the value provides the name of (or a reference to) the actual subroutine to use. In place of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort subroutine.

LIST をソートし、ソートされたリスト値を返します。 SUBNAME や BLOCK を省略すると、標準の文字列比較の順番でソートが 行なわれます。 SUBNAME を指定すると、それは、リストの 要素をどのような順番に並べるかに応じて、負、ゼロ、正の整数を返す サブルーチンの名前であると解釈されます。 (このようなルーチンには、<=> 演算子や cmp 演算子が、 たいへん便利です。) SUBNAME は、スカラ変数名(添え字なし)でもよく、 その場合には、その値が使用する実際のサブルーチンの 名前(またはそのリファレンス)と解釈されます。 SUBNAME の代わりに、無名のインライン ソートルーチンとして、BLOCK を書くことができます。

If the subroutine's prototype is ($$), the elements to be compared are passed by reference in @_, as for a normal subroutine. This is slower than unprototyped subroutines, where the elements to be compared are passed into the subroutine as the package global variables $a and $b (see example below). Note that in the latter case, it is usually counter-productive to declare $a and $b as lexicals.

サブルーチンのプロトタイプが ($$)の場合、 比較する要素は通常のサブルーチンと同じように @_ の中に リファレンスとして渡されます。 これはプロトタイプなしのサブルーチンより遅いです。 この場合は比較のためサブルーチンに渡される 2 つの 要素は、パッケージのグローバル変数 $a と $b で渡されます (次の例を参照してください)。 後者の場合、レキシカルに $a と $b を宣言するのは普通逆効果になります。

In either case, the subroutine may not be recursive. The values to be compared are always passed by reference, so don't modify them.

どちらの場合でも、サブルーチンは再帰的であってはなりません。 $a や $b はリファレンスによって渡されるので、変更しないでください。

You also cannot exit out of the sort block or subroutine using any of the loop control operators described in perlsyn or with goto.

また、ソートブロックやサブルーチンから perlsyn で説明されている ループ制御子や goto を使って抜けてはいけません。

When use locale is in effect, sort LIST sorts LIST according to the current collation locale. See perllocale.

use locale が有効の場合、sort LIST は LIST を現在の比較ロケールに 従ってソートします。perllocale を参照して下さい。

Examples:

例:

    # sort lexically
    @articles = sort @files;

    # same thing, but with explicit sort routine
    @articles = sort {$a cmp $b} @files;

    # now case-insensitively
    @articles = sort {uc($a) cmp uc($b)} @files;

    # same thing in reversed order
    @articles = sort {$b cmp $a} @files;

    # sort numerically ascending
    @articles = sort {$a <=> $b} @files;

    # sort numerically descending
    @articles = sort {$b <=> $a} @files;

    # this sorts the %age hash by value instead of key
    # using an in-line function
    @eldest = sort { $age{$b} <=> $age{$a} } keys %age;

    # sort using explicit subroutine name
    sub byage {
        $age{$a} <=> $age{$b};  # presuming numeric
    }
    @sortedclass = sort byage @class;

    sub backwards { $b cmp $a }
    @harry  = qw(dog cat x Cain Abel);
    @george = qw(gone chased yz Punished Axed);
    print sort @harry;
            # prints AbelCaincatdogx
    print sort backwards @harry;
            # prints xdogcatCainAbel
    print sort @george, 'to', @harry;
            # prints AbelAxedCainPunishedcatchaseddoggonetoxyz

    # inefficiently sort by descending numeric compare using
    # the first integer after the first = sign, or the
    # whole record case-insensitively otherwise

    @new = sort {
        ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
                            ||
                    uc($a)  cmp  uc($b)
    } @old;

    # same thing, but much more efficiently;
    # we'll build auxiliary indices instead
    # for speed
    @nums = @caps = ();
    for (@old) {
        push @nums, /=(\d+)/;
        push @caps, uc($_);
    }

    @new = @old[ sort {
                        $nums[$b] <=> $nums[$a]
                                 ||
                        $caps[$a] cmp $caps[$b]
                       } 0..$#old
               ];

    # same thing, but without any temps
    @new = map { $_->[0] }
           sort { $b->[1] <=> $a->[1]
                           ||
                  $a->[2] cmp $b->[2]
           } map { [$_, /=(\d+)/, uc($_)] } @old;

    # using a prototype allows you to use any comparison subroutine
    # as a sort subroutine (including other package's subroutines)
    package other;
    sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here

    package main;
    @new = sort other::backwards @old;

If you're using strict, you must not declare $a and $b as lexicals. They are package globals. That means if you're in the main package and type

use strict している場合、$a と $b をレキシカルとして 宣言しては いけません。 これはパッケージグローバルです。 つまり、main パッケージで以下のように書いた場合:

    @articles = sort {$b <=> $a} @files;

then $a and $b are $main::a and $main::b (or $::a and $::b), but if you're in the FooPack package, it's the same as typing

$a$b$main::a$main::b (または $::a$::b) を 意味しますが、FooPack パッケージ内の場合、これは以下と同じになります:

    @articles = sort {$FooPack::b <=> $FooPack::a} @files;

The comparison function is required to behave. If it returns inconsistent results (sometimes saying $x[1] is less than $x[2] and sometimes saying the opposite, for example) the results are not well-defined.

比較関数は一貫した振る舞いをすることが求められます。 一貫しない結果を返す(例えば、あるときは $x[1]$x[2] より 小さいと返し、またあるときは逆を返す)場合、結果は未定義です。

splice ARRAY,OFFSET,LENGTH,LIST
splice ARRAY,OFFSET,LENGTH
splice ARRAY,OFFSET
splice ARRAY

Removes the elements designated by OFFSET and LENGTH from an array, and replaces them with the elements of LIST, if any. In list context, returns the elements removed from the array. In scalar context, returns the last element removed, or undef if no elements are removed. The array grows or shrinks as necessary. If OFFSET is negative then it starts that far from the end of the array. If LENGTH is omitted, removes everything from OFFSET onward. If LENGTH is negative, leaves that many elements off the end of the array. If both OFFSET and LENGTH are omitted, removes everything.

The following equivalences hold (assuming $[ == 0):

ARRAY から OFFSET、LENGTH で指定される要素を取り除き、 LIST があれば、それを代わりに挿入します。 リストコンテキストでは、配列から取り除かれた要素を返します。 スカラコンテキストでは、取り除かれた最後の要素を返します。 要素が取り除かれなかった場合は undef を返します。 配列は、必要に応じて、大きくなったり、小さくなったりします。 OFFSET が負の数の場合は、配列の最後からの距離を示します。 LENGTH が省略されると、OFFSET 以降のすべての要素を取り除きます。 LENGTH が負の数の場合は、指定された数だけ配列の最後から要素を取り除きます。 OFFSET と LENGTH の両方が省略されると、全ての要素を取り除きます。

以下は、($[ == 0 と仮定すると) それぞれ、等価です。

    push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
    pop(@a)             splice(@a,-1)
    shift(@a)           splice(@a,0,1)
    unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
    $a[$x] = $y         splice(@a,$x,1,$y)

Example, assuming array lengths are passed before arrays:

次の例では、配列の前に、それぞれの配列の大きさが渡されるものとしています:

    sub aeq {   # compare two list values
        my(@a) = splice(@_,0,shift);
        my(@b) = splice(@_,0,shift);
        return 0 unless @a == @b;       # same len?
        while (@a) {
            return 0 if pop(@a) ne pop(@b);
        }
        return 1;
    }
    if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
split /PATTERN/,EXPR,LIMIT
split /PATTERN/,EXPR
split /PATTERN/
split

Splits a string into a list of strings and returns that list. By default, empty leading fields are preserved, and empty trailing ones are deleted.

文字列を文字列のリストに分割して、リストを返します。 デフォルトでは、行頭の空白は保存され、末尾の空白は削除されます。

In scalar context, returns the number of fields found and splits into the @_ array. Use of split in scalar context is deprecated, however, because it clobbers your subroutine arguments.

スカラコンテキストの場合には、見つかったフィールドの数を返し、 配列 @_ に分割結果を設定します。 しかし、スカラコンテキストでの split の使用は推奨されません。 サブルーチンの引数を上書きしてしまうからです。

If EXPR is omitted, splits the $_ string. If PATTERN is also omitted, splits on whitespace (after skipping any leading whitespace). Anything matching PATTERN is taken to be a delimiter separating the fields. (Note that the delimiter may be longer than one character.)

EXPR を省略すると、文字列 $_ を split します。 もし、PATTERN も省略すると、 (先頭の空白文字をスキップした後) 空白で split します。 PATTERN にマッチするものは、フィールドを分割するデリミタとして扱われます。 (デリミタは、1 文字とは限りません。)

If LIMIT is specified and positive, splits into no more than that many fields (though it may split into fewer). If LIMIT is unspecified or zero, trailing null fields are stripped (which potential users of pop would do well to remember). If LIMIT is negative, it is treated as if an arbitrarily large LIMIT had been specified.

正の数の LIMIT を指定した場合には、最大その数までのフィールドに split します (しかし、それより少ないことはあります)。 LIMIT を指定しないかゼロなら、末尾の空フィールドを捨ててしまいます (pop を行なうときには気を付けないといけません)。 LIMIT が負ならば、LIMIT に任意の大きな数を指定したのと同じことになります。

A pattern matching the null string (not to be confused with a null pattern //, which is just one member of the set of patterns matching a null string) will split the value of EXPR into separate characters at each point it matches that way. For example:

    print join(':', split(/ */, 'hi there'));

produces the output 'h:i:t:h:e:r:e'.

空文字列にマッチするパターン (ヌルパターン // と混同しないでください。 これは、空文字列にマッチするパターンの一つでしかありません) は、 どの場所にもマッチし、EXPR の値を1 文字ずつに分割します。 たとえば、

    print join(':', split(/ */, 'hi there'));

は、'h:i:t:h:e:r:e' という出力になります。

Empty leading (or trailing) fields are produced when there are positive width matches at the beginning (or end) of the string; a zero-width match at the beginning (or end) of the string does not produce an empty field. For example:

先頭と末尾の空フィールドは、文字列の先頭または末尾で 0 でない幅で マッチした場合は生成されます。 幅 0 でマッチした場合は生成されません。 例えば:

   print join(':', split(/(?=\w)/, 'hi there!'));

produces the output 'h:i :t:h:e:r:e!'.

これの出力は 'h:i :t:h:e:r:e!' となります。

The LIMIT parameter can be used to split a line partially

LIMIT を使うと、行を部分的に split することができます。

    ($login, $passwd, $remainder) = split(/:/, $_, 3);

When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT one larger than the number of variables in the list, to avoid unnecessary work. For the list above LIMIT would have been 4 by default. In time critical applications it behooves you not to split into more fields than you really need.

リストへ代入するとき、LIMIT を省略すると、Perl は、 無駄な仕事を避けるため、そのリストの変数の数より、1 つだけ大きい LIMIT が与えられたものとして処理を行ないます。 上のリストの場合には、LIMIT はデフォルトで 4 になります。 時間が問題となるアプリケーションでは、 必要以上のフィールドに分けないようにする必要があります。

If the PATTERN contains parentheses, additional list elements are created from each matching substring in the delimiter.

PATTERN に括弧が含まれていると、デリミタ内の部分文字列にマッチするものも、 リスト要素に含まれるようになります。

    split(/([,-])/, "1-10,20", 3);

produces the list value

は、以下のリスト値を生成します。

    (1, '-', 10, ',', 20)

If you had the entire header of a normal Unix email message in $header, you could split it up into fields and their values this way:

$header に Unix E メールメッセージヘッダ全体が入っているとすると、 以下のようにしてフィールドとその値に分割できます:

    $header =~ s/\n\s+/ /g;  # fix continuation lines
    %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);

The pattern /PATTERN/ may be replaced with an expression to specify patterns that vary at runtime. (To do runtime compilation only once, use /$variable/o.)

/PATTERN/ は、実行時に変わるパターンを指定する式で置き換えることができます。 (実行時のコンパイルを 1 度にするために、/$variable/o を使ってください。)

As a special case, specifying a PATTERN of space (' ') will split on white space just as split with no arguments does. Thus, split(' ') can be used to emulate awk's default behavior, whereas split(/ /) will give you as many null initial fields as there are leading spaces. A split on /\s+/ is like a split(' ') except that any leading whitespace produces a null first field. A split with no arguments really does a split(' ', $_) internally.

特別な場合として、PATTERN にスペース (' ') を指定すると、 引数なしの split のように空白で split を行ないます。 つまり、split(' ')awk のデフォルトの動作をエミュレートするために 使うことができ、split(/ /) は行頭のスペースの数に応じた空フィールドが できます。 split /\s+/split(' ') と同様ですが、 先頭の空白は先頭の空フィールドとなります。 引数なしの split は内部的には split(' ', $_) を実行します。

A PATTERN of /^/ is treated as if it were /^/m, since it isn't much use otherwise.

Example:

PATTERN に /^/ を指定すると /^/m として扱われます。 他の意味に使われることはまずないからです。

例:

    open(PASSWD, '/etc/passwd');
    while (<PASSWD>) {
        chomp;
        ($login, $passwd, $uid, $gid,
         $gcos, $home, $shell) = split(/:/);
        #...
    }
sprintf FORMAT, LIST

Returns a string formatted by the usual printf conventions of the C library function sprintf. See below for more details and see sprintf(3) or printf(3) on your system for an explanation of the general principles.

For example:

普通の C 言語の printf 記法のフォーマットで、整形された文字列を返します。 一般的な原則の説明については以下の説明と、システムの sprintf(3) または printf(3) の説明を参照してください。

例:

        # Format number with up to 8 leading zeroes
        $result = sprintf("%08d", $number);

        # Round number to 3 digits after decimal point
        $rounded = sprintf("%.3f", $number);

Perl does its own sprintf formatting--it emulates the C function sprintf, but it doesn't use it (except for floating-point numbers, and even then only the standard modifiers are allowed). As a result, any non-standard extensions in your local sprintf are not available from Perl.

Perl は sprintf フォーマット処理を自力で行います。 これは C の sprintf 関数をエミュレートしますが、 C の関数は使いません(浮動小数点を除きますが、それでも標準の 記述子のみが利用できます)。 従って、ローカルな非標準の sprintf 拡張機能は Perl では使えません。

Unlike printf, sprintf does not do what you probably mean when you pass it an array as your first argument. The array is given scalar context, and instead of using the 0th element of the array as the format, Perl will use the count of elements in the array as the format, which is almost never useful.

printf と違って、 sprintf の最初の引数に配列を渡しても あなたが多分望むとおりには動作しません。 配列はスカラコンテキストで渡されるので、配列の 0 番目の要素ではなく、 配列の要素数をフォーマットとして扱います。 これはほとんど役に立ちません。

Perl's sprintf permits the following universally-known conversions:

Perl の sprintf は以下の一般に知られている変換に対応しています:

   %%   a percent sign
   %c   a character with the given number
   %s   a string
   %d   a signed integer, in decimal
   %u   an unsigned integer, in decimal
   %o   an unsigned integer, in octal
   %x   an unsigned integer, in hexadecimal
   %e   a floating-point number, in scientific notation
   %f   a floating-point number, in fixed decimal notation
   %g   a floating-point number, in %e or %f notation

In addition, Perl permits the following widely-supported conversions:

さらに、Perl では以下のよく使われている変換に対応しています:

   %X   like %x, but using upper-case letters
   %E   like %e, but using an upper-case "E"
   %G   like %g, but with an upper-case "E" (if applicable)
   %b   an unsigned integer, in binary
   %p   a pointer (outputs the Perl value's address in hexadecimal)
   %n   special: *stores* the number of characters output so far
        into the next variable in the parameter list 

Finally, for backward (and we do mean "backward") compatibility, Perl permits these unnecessary but widely-supported conversions:

最後に、過去との互換性(これは「過去」だと考えています)のために、 Perl は以下の不要ではあるけれども広く使われている変換に対応しています。

   %i   a synonym for %d
   %D   a synonym for %ld
   %U   a synonym for %lu
   %O   a synonym for %lo
   %F   a synonym for %f

Note that the number of exponent digits in the scientific notation by %e, %E, %g and %G for numbers with the modulus of the exponent less than 100 is system-dependent: it may be three or less (zero-padded as necessary). In other words, 1.23 times ten to the 99th may be either "1.23e99" or "1.23e099".

%e, %E, %g, %G において、指数部が 100 未満の場合の 指数部の科学的な表記法はシステム依存であることに注意してください: 3 桁かもしれませんし、それ以下かもしれません(必要に応じて 0 で パッディングされます)。 言い換えると、 1.23 掛ける 10 の 99 乗は "1.23e99" かもしれませんし "1.23e099" かもしれません。

Perl permits the following universally-known flags between the % and the conversion letter:

Perl は % と変換文字の間のフラグとして以下の一般に知られている ものに対応しています:

   space   prefix positive number with a space
   +       prefix positive number with a plus sign
   -       left-justify within the field
   0       use zeros, not spaces, to right-justify
   #       prefix non-zero octal with "0", non-zero hex with "0x"
   number  minimum field width
   .number "precision": digits after decimal point for
           floating-point, max length for string, minimum length
           for integer
   l       interpret integer as C type "long" or "unsigned long"
   h       interpret integer as C type "short" or "unsigned short"
           If no flags, interpret integer as C type "int" or "unsigned"

There are also two Perl-specific flags:

さらに Perl 独自の 2 つのフラグがあります:

   V       interpret integer as Perl's standard integer type
   v       interpret string as a vector of integers, output as
           numbers separated either by dots, or by an arbitrary
           string received from the argument list when the flag
           is preceded by *

Where a number would appear in the flags, an asterisk (*) may be used instead, in which case Perl uses the next item in the parameter list as the given number (that is, as the field width or precision). If a field width obtained through * is negative, it has the same effect as the - flag: left-justification.

フラグとして数値を使えるところでは、代わりにアスタリスク (*) を 使うことができます: その場合、Perl はパラメータリストの次の要素を 与えられた数値(フィールド幅か精度)として使います。 * を通して得られたフィールドの値が負数の場合、- フラグと 同様の効果 (左詰め) があります。

The v flag is useful for displaying ordinal values of characters in arbitrary strings:

v フラグは任意の文字列の文字を順序付きの値として表示するのに 便利です:

    printf "version is v%vd\n", $^V;            # Perl's version
    printf "address is %*vX\n", ":", $addr;     # IPv6 address
    printf "bits are %*vb\n", " ", $bits;       # random bitstring

If use locale is in effect, the character used for the decimal point in formatted real numbers is affected by the LC_NUMERIC locale. See perllocale.

use locale が有効の場合、フォーマットされた実数の小数点として 使われる文字は LC_NUMERIC ロケールの影響を受けます。 perllocale を参照してください。

If Perl understands "quads" (64-bit integers) (this requires either that the platform natively support quads or that Perl be specifically compiled to support quads), the characters

Perl が 64 ビット整数を理解する場合(これにはプラットフォームが内部で 64 ビット整数に対応しているか、Perl が特別に 64ビット整数に対応するように コンパイルされている必要があります)、以下の文字には:

        d u o x X b i D U O

print quads, and they may optionally be preceded by

64 ビット整数を表示し、また以下のフラグを前につけることができます:

        ll L q

For example

例えば以下のようにします:

        %lld %16LX %qo

You can find out whether your Perl supports quads via Config:

Perl が 64 ビット整数に対応しているかどうかは Config を使って 調べられます:

        use Config;
        ($Config{use64bitint} eq 'define' || $Config{longsize} == 8) &&
                print "quads\n";

If Perl understands "long doubles" (this requires that the platform support long doubles), the flags

Perl が "long double" を理解する場合(これにはプラットフォームが long double に対応している必要があります)、以下の文字には:

        e f g E F G

may optionally be preceded by

以下のフラグを前につけることができます:

        ll L

For example

例えば以下のようにします:

        %llf %Lg

You can find out whether your Perl supports long doubles via Config:

Perl が long double に対応しているかどうかは Config を使って 調べられます:

        use Config;
        $Config{d_longdbl} eq 'define' && print "long doubles\n";
sqrt EXPR
sqrt

Return the square root of EXPR. If EXPR is omitted, returns square root of $_. Only works on non-negative operands, unless you've loaded the standard Math::Complex module.

EXPR の平方根を返します。 EXPR を省略すると、$_ の平方根を返します。 標準の Math::Complex モジュールを使わない場合は、 負の数の引数は扱えません。

    use Math::Complex;
    print sqrt(-2);    # prints 1.4142135623731i
srand EXPR
srand

Sets the random number seed for the rand operator. If EXPR is omitted, uses a semi-random value supplied by the kernel (if it supports the /dev/urandom device) or based on the current time and process ID, among other things. In versions of Perl prior to 5.004 the default seed was just the current time. This isn't a particularly good seed, so many old programs supply their own seed value (often time ^ $$ or time ^ ($$ + ($$ << 15))), but that isn't necessary any more.

rand 演算子のためのシード値を設定します。 EXPR を省略すると、カーネルで提供されるもの (/dev/urandom デバイスに対応している場合)または 現在時刻やプロセス ID やその他のものを基礎にした 擬似乱数を使います。 5.004 以前の Perl では、デフォルトのシード値は現在の time でした。 これは特によいシード値ではありませんでしたので、 多くの古いプログラムは自力でシード値を指定しています (time ^ $$ または time ^ ($$ + ($$ << 15)) がよく使われました)が、 もはやこれは必要ありません。

In fact, it's usually not necessary to call srand at all, because if it is not called explicitly, it is called implicitly at the first use of the rand operator. However, this was not the case in version of Perl before 5.004, so if your script will run under older Perl versions, it should call srand.

実際、普通は srand を呼び出す必要は全くありません。 明示的に呼び出されない場合、rand 演算子を最初に使ったときに 自動的に呼び出されるからです。 しかし、5.004 以前のバージョンの Perl ではこれは行われないので、 古い Perl で動作させる可能性がある場合は、srand を呼び出すべきです。

Note that you need something much more random than the default seed for cryptographic purposes. Checksumming the compressed output of one or more rapidly changing operating system status programs is the usual method. For example:

暗号処理には、 もっとランダムな値を使う必要があります。急激に変化する OS のステータス値プログラムの出力をひとつ または複数用い、圧縮してチェックサムをとる、 というようなことが普通、行なわれます。 例えば:

    srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);

If you're particularly concerned with this, see the Math::TrulyRandom module in CPAN.

特にこのようなことに関心がある場合は、 CPAN の Math::TrulyRandom モジュールを参照して下さい。

Do not call srand multiple times in your program unless you know exactly what you're doing and why you're doing it. The point of the function is to "seed" the rand function so that rand can produce a different sequence each time you run your program. Just do it once at the top of your program, or you won't get random numbers out of rand!

何をしようとしているか、そしてなぜそうするのかを正確に把握していない限り、 srand をプログラム中で複数回呼び出してはいけません。 この関数のポイントは、プログラムを実行するごとに rand 関数が 異なる乱数列を生成できるように rand 関数の「種」を設定することです。 単にプログラムの先頭で一回だけ呼び出してください。 さもなければ rand で乱数を 得られません!

Frequently called programs (like CGI scripts) that simply use

(CGI スクリプトのような)頻繁に呼び出されるプログラムで単純に

    time ^ $$

for a seed can fall prey to the mathematical property that

を種として使うと、3 回に 1 回は以下の数学特性

    a^b == (a+1)^(b+1)

one-third of the time. So don't do that.

の餌食になります。 従ってこのようなことはしてはいけません。

stat FILEHANDLE
stat EXPR
stat

Returns a 13-element list giving the status info for a file, either the file opened via FILEHANDLE, or named by EXPR. If EXPR is omitted, it stats $_. Returns a null list if the stat fails. Typically used as follows:

FILEHANDLE を通じてオープンされているファイルか、 EXPR で指定されるファイルの情報を与える、13 要素のリストを返します。 EXPR が省略されると、 $_ が用いられます。 stat に失敗した場合には、空リストを返します。 普通は、以下のようにして使います:

    ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
       $atime,$mtime,$ctime,$blksize,$blocks)
           = stat($filename);

Not all fields are supported on all filesystem types. Here are the meaning of the fields:

全てのファイルシステムで全てのフィールドに対応しているわけではありません。 フィールドの意味は以下の通りです。

  0 dev      device number of filesystem
  1 ino      inode number
  2 mode     file mode  (type and permissions)
  3 nlink    number of (hard) links to the file
  4 uid      numeric user ID of file's owner
  5 gid      numeric group ID of file's owner
  6 rdev     the device identifier (special files only)
  7 size     total size of file, in bytes
  8 atime    last access time in seconds since the epoch
  9 mtime    last modify time in seconds since the epoch
 10 ctime    inode change time (NOT creation time!) in seconds since the epoch
 11 blksize  preferred block size for file system I/O
 12 blocks   actual number of blocks allocated

(The epoch was at 00:00 January 1, 1970 GMT.)

  0 dev      ファイルシステムのデバイス番号
  1 ino      inode 番号
  2 mode     ファイルモード (タイプとパーミッション)
  3 nlink    ファイルへの(ハード)リンクの数
  4 uid      ファイル所有者のユーザー ID の数値
  5 gid      ファイル所有者のグループ ID の数値
  6 rdev     デバイス識別子(特殊ファイルのみ)
  7 size     ファイルサイズ(バイト単位)
  8 atime    紀元から、最後にアクセスされた時刻までの秒数
  9 mtime    紀元から、最後に修正(modify)された時刻までの秒数
 10 ctime    紀元から、inode 変更(change)された時刻(作成された時刻ではない!)までの秒数
 11 blksize  ファイルシステム I/O に適したブロックサイズ
 12 blocks   実際に割り当てられているブロックの数

(紀元は GMT で 1970/01/01 00:00:00)

If stat is passed the special filehandle consisting of an underline, no stat is done, but the current contents of the stat structure from the last stat or filetest are returned. Example:

下線だけの _ という特別なファイルハンドルを stat に渡すと、 実際には stat を行なわず、stat 構造体に残っている 前回の stat やファイルテストの情報が返されます。 例:

    if (-x $file && (($d) = stat(_)) && $d < 0) {
        print "$file is executable NFS file\n";
    }

(This works on machines only for which the device number is negative under NFS.)

(これは、NFS のもとでデバイス番号が負になるマシンで のみ動作します。)

Because the mode contains both the file type and its permissions, you should mask off the file type portion and (s)printf using a "%o" if you want to see the real permissions.

モードにはファイルタイプとその権限の両方が含まれているので、 本当の権限を見たい場合は、(s)printf で "%" を使うことで ファイルタイプをマスクするべきです。

    $mode = (stat($filename))[2];
    printf "Permissions are %04o\n", $mode & 07777;

In scalar context, stat returns a boolean value indicating success or failure, and, if successful, sets the information associated with the special filehandle _.

スカラコンテキストでは、stat は成功か失敗を表す真偽値を返し、 成功した場合は、特別なファイルハンドル _ に結び付けられた 情報をセットします。

The File::stat module provides a convenient, by-name access mechanism:

File::stat モジュールは、便利な名前によるアクセス機構を提供します。

    use File::stat;
    $sb = stat($filename);
    printf "File is %s, size is %s, perm %04o, mtime %s\n", 
        $filename, $sb->size, $sb->mode & 07777,
        scalar localtime $sb->mtime;

You can import symbolic mode constants (S_IF*) and functions (S_IS*) from the Fcntl module:

モード定数 (S_IF*) と関数 (S_IS*) を Fcntl モジュールから インポートできます。

    use Fcntl ':mode';

    $mode = (stat($filename))[2];

    $user_rwx      = ($mode & S_IRWXU) >> 6;
    $group_read    = ($mode & S_IRGRP) >> 3;
    $other_execute =  $mode & S_IXOTH;

    printf "Permissions are %04o\n", S_ISMODE($mode), "\n";

    $is_setuid     =  $mode & S_ISUID;
    $is_setgid     =  S_ISDIR($mode);

You could write the last two using the -u and -d operators. The commonly available S_IF* constants are

最後の二つは -u-d 演算子を使っても書けます。 一般に利用可能な S_IF* 定数は以下のものです。

    # Permissions: read, write, execute, for user, group, others.

    S_IRWXU S_IRUSR S_IWUSR S_IXUSR
    S_IRWXG S_IRGRP S_IWGRP S_IXGRP
    S_IRWXO S_IROTH S_IWOTH S_IXOTH

    # Setuid/Setgid/Stickiness.

    S_ISUID S_ISGID S_ISVTX S_ISTXT

    # File types.  Not necessarily all are available on your system.

    S_IFREG S_IFDIR S_IFLNK S_IFBLK S_ISCHR S_IFIFO S_IFSOCK S_IFWHT S_ENFMT

    # The following are compatibility aliases for S_IRUSR, S_IWUSR, S_IXUSR.

    S_IREAD S_IWRITE S_IEXEC

and the S_IF* functions are

一般に利用可能な S_IF* 関数は以下のものです。

    S_IFMODE($mode)     the part of $mode containing the permission bits
                        and the setuid/setgid/sticky bits

    S_IFMT($mode)       the part of $mode containing the file type
                        which can be bit-anded with e.g. S_IFREG 
                        or with the following functions

    # The operators -f, -d, -l, -b, -c, -p, and -s.

    S_ISREG($mode) S_ISDIR($mode) S_ISLNK($mode)
    S_ISBLK($mode) S_ISCHR($mode) S_ISFIFO($mode) S_ISSOCK($mode)

    # No direct -X operator counterpart, but for the first one
    # the -g operator is often equivalent.  The ENFMT stands for
    # record flocking enforcement, a platform-dependent feature.

    S_ISENFMT($mode) S_ISWHT($mode)

See your native chmod(2) and stat(2) documentation for more details about the S_* constants.

S_* 定数に関する詳細についてはネイティブの chmod(2) と stat(2) の ドキュメントを参照して下さい。

study SCALAR
study

Takes extra time to study SCALAR ($_ if unspecified) in anticipation of doing many pattern matches on the string before it is next modified. This may or may not save time, depending on the nature and number of patterns you are searching on, and on the distribution of character frequencies in the string to be searched--you probably want to compare run times with and without it to see which runs faster. Those loops which scan for many short constant strings (including the constant parts of more complex patterns) will benefit most. You may have only one study active at a time--if you study a different scalar the first is "unstudied". (The way study works is this: a linked list of every character in the string to be searched is made, so we know, for example, where all the 'k' characters are. From each search string, the rarest character is selected, based on some static frequency tables constructed from some C programs and English text. Only those places that contain this "rarest" character are examined.)

次に変更される前に、何回も文字列に対するパターンマッチを 行なうアプリケーションで、 そのような文字列 SCALAR(省略時には $_) を予め学習しておきます。 これは、検索のために、どのようなパターンを何回使うかによって、 また、検索される文字列内の文字頻度の分布によって、 時間を節約することになるかもしれませんし、逆に浪費する ことになるかもしれません。 予習をした場合と、しない場合の実行時間を比較して、 どちらが速いか調べることが、必要でしょう。 短い固定文字列 (複雑なパターンの固定部分を含みます) をたくさん 検索するループで、もっとも効果があるでしょう。 同時には、一つの studyだけが有効です。 別のスカラを study した場合には、以前に学習した内容は 「忘却」されてしまいます。 (この study の仕組みは、まず、検索される文字列内の すべての文字のリンクされたリストが作られ、たとえば、 すべての 'k' がどこにあるかがわかるようになります。 各々の検索文字列から、C プログラムや英語のテキストから作られた 頻度の統計情報に基づいて、もっとも珍しい文字が選ばれます。 この「珍しい」文字を含む場所だけが調べられるのです。)

For example, here is a loop that inserts index producing entries before any line containing a certain pattern:

たとえば、特定のパターンを含む行の前にインデックスを 付けるエントリを入れる例を示します。

    while (<>) {
        study;
        print ".IX foo\n"       if /\bfoo\b/;
        print ".IX bar\n"       if /\bbar\b/;
        print ".IX blurfl\n"    if /\bblurfl\b/;
        # ...
        print;
    }

In searching for /\bfoo\b/, only those locations in $_ that contain f will be looked at, because f is rarer than o. In general, this is a big win except in pathological cases. The only question is whether it saves you more time than it took to build the linked list in the first place.

fo よりも珍しいので、/\bfoo\b/ を探すとき、$_f を 含む場所だけが探されます。 一般に、病的な場合を除いて、かなりの結果が得られます。 唯一の問題は、節約できる時間が、最初にリンクリストを作る 時間よりも多いかどうかです、

Note that if you have to look for strings that you don't know till runtime, you can build an entire loop as a string and eval that to avoid recompiling all your patterns all the time. Together with undefining $/ to input entire files as one record, this can be very fast, often faster than specialized programs like fgrep(1). The following scans a list of files (@files) for a list of words (@words), and prints out the names of those files that contain a match:

実行時まで、探そうとする文字列がわからないときには、 ループ全体を文字列として組み立てて、eval すれば、 いつも、すべてのパターンを再コンパイルするという事態は 避けられます。 ファイル全体を一つのレコードとして入力するために、 $/ を未定義にすれば、かなり速くなり、 多くの場合 fgrep(1) のような専用のプログラムより速くなります。 以下の例は、ファイルのリスト (@files) から単語のリスト (@words) を 探して、マッチするものがあったファイル名を出力します。

    $search = 'while (<>) { study;';
    foreach $word (@words) {
        $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
    }
    $search .= "}";
    @ARGV = @files;
    undef $/;
    eval $search;               # this screams
    $/ = "\n";          # put back to normal input delimiter
    foreach $file (sort keys(%seen)) {
        print $file, "\n";
    }
sub BLOCK
sub NAME
sub NAME BLOCK

This is subroutine definition, not a real function per se. With just a NAME (and possibly prototypes or attributes), it's just a forward declaration. Without a NAME, it's an anonymous function declaration, and does actually return a value: the CODE ref of the closure you just created. See perlsub and perlref for details.

これはサブルーチン定義であり、本質的には 実際の関数ではありません。 NAME (とプロトタイプや属性) のみの場合は、単なる前方定義です。 NAME なしの場合は、無名関数定義であり、実際には値(作成したブロックの コードリファレンス)を返します。 詳しくは perlsubperlref を参照して下さい。

substr EXPR,OFFSET,LENGTH,REPLACEMENT
substr EXPR,OFFSET,LENGTH
substr EXPR,OFFSET

Extracts a substring out of EXPR and returns it. First character is at offset 0, or whatever you've set $[ to (but don't do that). If OFFSET is negative (or more precisely, less than $[), starts that far from the end of the string. If LENGTH is omitted, returns everything to the end of the string. If LENGTH is negative, leaves that many characters off the end of the string.

EXPR から、部分文字列を取り出して返します。 最初の文字がオフセット 0 もしくは、$[ に設定した値 (しかしこれを使ってはいけません)となります。 OFFSET に負の値(より厳密には、$[より小さい値)を設定すると、 EXPR の終わりからのオフセットとなります。 LENGTH を省略すると、EXPR の最後まですべてが返されます。 LENGTH が負の値だと、文字列の最後から指定された数だけ文字を取り除きます。

You can use the substr() function as an lvalue, in which case EXPR must itself be an lvalue. If you assign something shorter than LENGTH, the string will shrink, and if you assign something longer than LENGTH, the string will grow to accommodate it. To keep the string the same length you may need to pad or chop your value using sprintf.

substr() を左辺値として使用することも可能で、その場合には、 EXPR が自身左辺値でなければなりません。 LENGTH より短いものを代入したときには、 EXPR は短くなり、LENGTH より長いものを代入したときには、 EXPR はそれに合わせて伸びることになります。 EXPR の長さを一定に保つためには、sprintf を使って、 代入する値の長さを調整することが、必要になるかもしれません。

If OFFSET and LENGTH specify a substring that is partly outside the string, only the part within the string is returned. If the substring is beyond either end of the string, substr() returns the undefined value and produces a warning. When used as an lvalue, specifying a substring that is entirely outside the string is a fatal error. Here's an example showing the behavior for boundary cases:

OFFSET と LENGTH として文字列の外側を含むような部分文字列が指定されると、 文字列の内側の部分だけが返されます。 部分文字列が文字列の両端の外側の場合、substr() は未定義値を返し、 警告が出力されます。 左辺値として使った場合、文字列の完全に外側を部分文字列として指定すると 致命的エラーになります。 以下は境界条件の振る舞いを示す例です:

    my $name = 'fred';
    substr($name, 4) = 'dy';            # $name is now 'freddy'
    my $null = substr $name, 6, 2;      # returns '' (no warning)
    my $oops = substr $name, 7;         # returns undef, with warning
    substr($name, 7) = 'gap';           # fatal error

An alternative to using substr() as an lvalue is to specify the replacement string as the 4th argument. This allows you to replace parts of the EXPR and return what was there before in one operation, just as you can with splice().

substr() を左辺値として使う代わりの方法は、置き換える文字列を 4 番目の 引数として指定することです。 これにより、EXPR の一部を置き換え、置き換える前が何であったかを返す、 ということを(splice() と同様) 1 動作で行えます。

symlink OLDFILE,NEWFILE

Creates a new filename symbolically linked to the old filename. Returns 1 for success, 0 otherwise. On systems that don't support symbolic links, produces a fatal error at run time. To check for that, use eval:

NEWFILE として、OLDFILE へのシンボリックリンクを生成します。 成功時には 1 を返し、失敗時には 0 を返します。 シンボリックリンクをサポートしていないシステムでは、 実行時に致命的エラーが発生します。 これをチェックするには、eval を使用します:

    $symlink_exists = eval { symlink("",""); 1 };
syscall LIST

Calls the system call specified as the first element of the list, passing the remaining elements as arguments to the system call. If unimplemented, produces a fatal error. The arguments are interpreted as follows: if a given argument is numeric, the argument is passed as an int. If not, the pointer to the string value is passed. You are responsible to make sure a string is pre-extended long enough to receive any result that might be written into a string. You can't use a string literal (or other read-only string) as an argument to syscall because Perl has to assume that any string pointer might be written through. If your integer arguments are not literals and have never been interpreted in a numeric context, you may need to add 0 to them to force them to look like numbers. This emulates the syswrite function (or vice versa):

LIST の最初の要素で指定するシステムコールを、残りの要素をその システムコールの引数として呼び出します。 実装されていないときには、致命的エラーとなります。 引数は、以下のように解釈されます: 引数が数字であれば、int として 引数を渡します。 そうでなければ、文字列値へのポインタが渡されます。 文字列に結果を受け取るときには、その結果を受け取るのに十分なくらいに、 文字列を予め伸ばしておく必要があります。 文字列リテラル(あるいはその他の読み込み専用の文字列)を syscall の 引数として使うことはできません。 Perl は全ての文字列ポインタは書き込まれると仮定しなければならないからです。 整数引数が、リテラルでなく、数値コンテキストで評価されたことの ないものであれば、数値として解釈されるように、 0 を足しておく必要があるかもしれません。 以下は syswrite 関数(あるいはその逆)をエミュレートします。

    require 'syscall.ph';               # may need to run h2ph
    $s = "hi there\n";
    syscall(&SYS_write, fileno(STDOUT), $s, length $s);

Note that Perl supports passing of up to only 14 arguments to your system call, which in practice should usually suffice.

Perl は、システムコールに最大 14 個の引数しか渡せませんが、 実用上問題はないでしょう。

Syscall returns whatever value returned by the system call it calls. If the system call fails, syscall returns -1 and sets $! (errno). Note that some system calls can legitimately return -1. The proper way to handle such calls is to assign $!=0; before the call and check the value of $! if syscall returns -1.

syscall は、呼び出したシステムコールが返した値を返します。 システムコールが失敗すると、syscall-1 を返し、 $!(errno) を設定します。 システムコールが正常に -1 を返す場合があることに注意してください。 このようなシステムコールを正しく扱うには、 $!=0; をシステムコールの前に実行し、 syscall が -1 を返した時には $! の値を調べてください。

There's a problem with syscall(&SYS_pipe): it returns the file number of the read end of the pipe it creates. There is no way to retrieve the file number of the other end. You can avoid this problem by using pipe instead.

syscall(&SYS_pipe) には問題があり、 作ったパイプの、読み出し側のファイル番号を返しますが、 もう一方のファイル番号を得る方法がありません。 この問題を避けるためには、代わりに pipe を使ってください。

sysopen FILEHANDLE,FILENAME,MODE
sysopen FILEHANDLE,FILENAME,MODE,PERMS

Opens the file whose filename is given by FILENAME, and associates it with FILEHANDLE. If FILEHANDLE is an expression, its value is used as the name of the real filehandle wanted. This function calls the underlying operating system's open function with the parameters FILENAME, MODE, PERMS.

FILENAME で与えられたファイル名のファイルをオープンし、 FILEHANDLE と結び付けます。 FILEHANDLE が式の場合、その値は実際に求めているファイルハンドルの名前として 扱われます。 この関数呼び出しはシステムの open 関数を FILENAME, MODE, PERMS の 引数で呼び出すことを基礎としています。

The possible values and flag bits of the MODE parameter are system-dependent; they are available via the standard module Fcntl. See the documentation of your operating system's open to see which values and flag bits are available. You may combine several flags using the |-operator.

MODE パラメータに指定できるフラグビットと値はシステム依存です; これは標準モジュール Fcntl 経由で利用可能です。 どのようなフラグビットと値が利用可能であるかについては、 OS の open に関する文書を参照してください。 | 演算子を使って複数のフラグを結合することができます。

Some of the most common values are O_RDONLY for opening the file in read-only mode, O_WRONLY for opening the file in write-only mode, and O_RDWR for opening the file in read-write mode, and.

もっともよく使われる値は、ファイルを読み込み専用で開く O_RDONLY、 ファイルを書き込み専用で開く O_WRONLY、 ファイルを読み書き両用で開く O_RDWR です。

For historical reasons, some values work on almost every system supported by perl: zero means read-only, one means write-only, and two means read/write. We know that these values do not work under OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to use them in new code.

歴史的な理由により、perl が対応しているほとんどのシステムで 使える値があります。 0 は読み込み専用、1 は書き込み専用、2 は読み書き両用を意味します。 OS/390 & VM/ESA Unix と Macintosh では動作 しない ことが分かっています; 新しく書くコードではこれらは使わないほうがよいでしょう。

If the file named by FILENAME does not exist and the open call creates it (typically because MODE includes the O_CREAT flag), then the value of PERMS specifies the permissions of the newly created file. If you omit the PERMS argument to sysopen, Perl uses the octal value 0666. These permission values need to be in octal, and are modified by your process's current umask.

FILENAME という名前のファイルが存在せず、(典型的には MODE が O_CREAT フラグを含んでいたために) open 呼び出しがそれを作った場合、 PERMS の値は新しく作られたファイルの権限を指定します。 sysopen の PERMS 引数を省略した場合、Perl は 8 進数 0666 を使います。 これらの権限は 8 進数である必要があり、プロセスの現在の umask で 修正されます。

In many systems the O_EXCL flag is available for opening files in exclusive mode. This is not locking: exclusiveness means here that if the file already exists, sysopen() fails. The O_EXCL wins O_TRUNC.

多くのシステムではファイルを排他モードで開くために O_EXCL が 利用可能です。 これはロック ではありません: 排他性というのは既にファイルが 存在していた場合、sysopen() が失敗することを意味します。 O_EXCLO_TRUNC より優先します。

Sometimes you may want to truncate an already-existing file: O_TRUNC.

既に存在しているファイルを切り詰めたい場合もあるかもしれません: O_TRUNC

You should seldom if ever use 0644 as argument to sysopen, because that takes away the user's option to have a more permissive umask. Better to omit it. See the perlfunc(1) entry on umask for more on this.

めったなことでは sysopen の引数に 0644 を指定するべきではないでしょう: ユーザーがより寛大な umask を指定する選択肢を奪うからです。 省略した方がいいです。 これに関するさらなる情報については perlfunc(1) の umask を 参照してください。

Note that sysopen depends on the fdopen() C library function. On many UNIX systems, fdopen() is known to fail when file descriptors exceed a certain value, typically 255. If you need more file descriptors than that, consider rebuilding Perl to use the sfio library, or perhaps using the POSIX::open() function.

sysopen は C の fdopen() ライブラリ関数に依存していることに注意してください。 多くの UNIX システムでは、fdopen() はファイル記述子がある値(例えば 255)を超えると 失敗することが知られています。 これより多くのファイル記述子が必要な場合は、 Perl を sfio ライブラリを使って再ビルドするか、 POSIX::open() 関数を使うことを健闘してください。

See perlopentut for a kinder, gentler explanation of opening files.

ファイル操作に関するより親切な説明については perlopentut を参照して下さい。

sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
sysread FILEHANDLE,SCALAR,LENGTH

Attempts to read LENGTH bytes of data into variable SCALAR from the specified FILEHANDLE, using the system call read(2). It bypasses stdio, so mixing this with other kinds of reads, print, write, seek, tell, or eof can cause confusion because stdio usually buffers data. Returns the number of bytes actually read, 0 at end of file, or undef if there was an error. SCALAR will be grown or shrunk so that the last byte actually read is the last byte of the scalar after the read.

システムコール read(2) を用いて、指定した FILEHANDLE から、変数 SCALAR へ、LENGTH バイトのデータの読み込みを試みます。 これは、stdio ルーチンを通りませんから、 他の入力関数, print, write, seek, tell, eof と混ぜて使うと、入力がおかしくなる かもしれません。stdio は普通データをバッファリングするからです。 ファイルの最後では 0が、 エラー時には undef が、 それ以外では実際に読み込まれたデータの長さが返されます。 実際に読み込んだ最後のバイトが read した後の最後のバイトになるので、 SCALAR は伸び縮みします。

An OFFSET may be specified to place the read data at some place in the string other than the beginning. A negative OFFSET specifies placement at that many bytes counting backwards from the end of the string. A positive OFFSET greater than the length of SCALAR results in the string being padded to the required size with "\0" bytes before the result of the read is appended.

OFFSET を指定すると、 SCALAR の先頭以外の場所から、読み込みを行なうことができます。 OFFSET に負の値を指定すると、文字列の最後から逆向きに何バイト目かで 位置を指定します。 OFFSET が正の値で、SCALAR の長さよりも大きかった場合、 必要なサイズになるまで "\0" でパッディングされ、その後に 読み込み結果が追加されます。

There is no syseof() function, which is ok, since eof() doesn't work very well on device files (like ttys) anyway. Use sysread() and check for a return value for 0 to decide whether you're done.

syseof() 関数はありませんが、問題ありません。 どちらにしろ eof() は(tty のような)デバイスファイルに対しては うまく動作しないからです。 sysread() を使って、 返り値が 0 かどうかで最後まで読んだかを 判断してください。

sysseek FILEHANDLE,POSITION,WHENCE

Sets FILEHANDLE's system position using the system call lseek(2). It bypasses stdio, so mixing this with reads (other than sysread), print, write, seek, tell, or eof may cause confusion. FILEHANDLE may be an expression whose value gives the name of the filehandle. The values for WHENCE are 0 to set the new position to POSITION, 1 to set the it to the current position plus POSITION, and 2 to set it to EOF plus POSITION (typically negative). For WHENCE, you may also use the constants SEEK_SET, SEEK_CUR, and SEEK_END (start of the file, current position, end of the file) from the Fcntl module.

FILEHANDLE のシステム位置を lseek(2) システムコールを使って設定します。 これは stdio をバイパスしますので、 (sysread以外の)読み込み、 print, write, seek, tell, eof と混ぜて使うと 混乱を引き起こします。 FILEHANDLE は式でも構いません。その場合はその値がファイルハンドルの 名前となります。 WHENCE の値が、0 ならば、 新しい位置を POSITION の位置へ、1 ならば、現在位置から POSITION 加えた位置へ、2 ならば、EOF から POSITION だけ加えた位置へ、新しい位置を設定します。 この値には、Fcntl モジュールで使われている SEEK_SETSEEK_CURSEEK_END (ファイルの先頭、現在位置、ファイルの最後)という定数を使うこともできます。

Returns the new position, or the undefined value on failure. A position of zero is returned as the string "0 but true"; thus sysseek returns true on success and false on failure, yet you can still easily determine the new position.

新しい位置を返します。失敗したときは未定義値を返します。 位置がゼロの場合は、"0 but true" の文字列として返されます。 従って sysseek は成功時に真を返し、失敗時に偽を返しますが、 簡単に新しい位置を判定できます。

system LIST
system PROGRAM LIST

Does exactly the same thing as exec LIST, except that a fork is done first, and the parent process waits for the child process to complete. Note that argument processing varies depending on the number of arguments. If there is more than one argument in LIST, or if LIST is an array with more than one value, starts the program given by the first element of the list with arguments given by the rest of the list. If there is only one scalar argument, the argument is checked for shell metacharacters, and if there are any, the entire argument is passed to the system's command shell for parsing (this is /bin/sh -c on Unix platforms, but varies on other platforms). If there are no shell metacharacters in the argument, it is split into words and passed directly to execvp, which is more efficient.

exec LIST とほとんど同じですが、まず fork を行ない、 親プロセスではチャイルドプロセスが終了するのを wait します。 exec の項で述べたように、引数の処理は、引数の数によって異なることに 注意してください。 LIST に複数の引数がある場合、または LIST が複数の要素からなる配列の場合、 リストの最初の要素で与えられるプログラムを、リストの残りの要素を 引数として起動します。 スカラの引数が一つだけの場合、 引数はシェルのメタキャラクタをチェックされ、もしあれば パーズのために引数全体がシステムコマンドシェル (これは Unix プラットフォームでは /bin/sh -c ですが、 他のプラットフォームでは異なります)に渡されます。 シェルメタキャラクタがなかった場合、 引数は単語に分解されて直接 execvp に渡されます。 この方がより効率的です。

Beginning with v5.6.0, Perl will attempt to flush all files opened for output before any operation that may do a fork, but this may not be supported on some platforms (see perlport). To be safe, you may need to set $| ($AUTOFLUSH in English) or call the autoflush() method of IO::Handle on any open handles.

v5.6.0から、Perl は fork を行うようなあらゆる動作の前に 出力用にオープンしていた全てのファイルをフラッシュしようとします。 しかしこれをサポートしていないプラットフォームもあります(perlport 参照)。 安全のためには、$l(English モジュールを使っているなら $AUTOFLUSH)を 設定するか、あらゆるオープン済みハンドルにおいて IO::Handleautoflush() メソッドが必要となるかもしれません。

The return value is the exit status of the program as returned by the wait call. To get the actual exit value divide by 256. See also "exec". This is not what you want to use to capture the output from a command, for that you should use merely backticks or qx//, as described in "`STRING`" in perlop. Return value of -1 indicates a failure to start the program (inspect $! for the reason).

返り値は、wait が返すプログラムの exit 状態です。 実際の exit 値を得るには 256 で割ってください。 "exec" も参照してください。 これはコマンドからの出力を捕らえるために使うものではありません。 そのような用途には、"`STRING`" in perlop に記述されている 逆クォートや qx// を使用してください。 -1 の返り値はプログラムを開始させることに失敗したことを示します (理由は $! を調べてください)。

Like exec, system allows you to lie to a program about its name if you use the system PROGRAM LIST syntax. Again, see "exec".

exec と同様に、system でも system PROGRAM LIST の文法を 使うことで、プログラムに対してその名前を嘘をつくことができます。 再び、"exec" を参照して下さい。

Because system and backticks block SIGINT and SIGQUIT, killing the program they're running doesn't actually interrupt your program.

system とバッククォートは SIGINTSIGQUIT をブロックするので、 これらが実行したプログラムを kill しても実際に元のプログラムを 中断させることはありません。

    @args = ("command", "arg1", "arg2");
    system(@args) == 0
         or die "system @args failed: $?"

You can check all the failure possibilities by inspecting $? like this:

以下のように $? を調べることで、全ての失敗の可能性を チェックすることができます:

    $exit_value  = $? >> 8;
    $signal_num  = $? & 127;
    $dumped_core = $? & 128;

When the arguments get executed via the system shell, results and return codes will be subject to its quirks and capabilities. See "`STRING`" in perlop and "exec" for details.

引数がシステムシェル経由で実行された場合、 結果と返り値はシェルの癖と能力によって変更されることがあります。 詳細については "`STRING`" in perlop"exec" を参照して下さい。

syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
syswrite FILEHANDLE,SCALAR,LENGTH
syswrite FILEHANDLE,SCALAR

Attempts to write LENGTH bytes of data from variable SCALAR to the specified FILEHANDLE, using the system call write(2). If LENGTH is not specified, writes whole SCALAR. It bypasses stdio, so mixing this with reads (other than sysread()), print, write, seek, tell, or eof may cause confusion because stdio usually buffers data. Returns the number of bytes actually written, or undef if there was an error. If the LENGTH is greater than the available data in the SCALAR after the OFFSET, only as much data as is available will be written.

write(2) システムコールを使って、指定した FILEHANDLEへ、 変数 SCALAR から、LENGTH バイトのデータの書き込みを試みます。 LENGTH が指定されなかった場合、 SCALAR 全体を書き込みます。 これは、stdio ルーチンを通りませんから、 他の入力関数(sysread()以外), print, write, seek, tell, or eofと混ぜて使うと、 出力がおかしくなるかもしれません。 stdio は普通データをバッファリングするからです。 実際に読み込まれたデータの長さか、エラー時には undef が返されます。 LENGTH が OFFSET 以降の SCALAR の利用可能なデータより大きかった場合、 利用可能なデータのみが書き込まれます。

An OFFSET may be specified to write the data from some part of the string other than the beginning. A negative OFFSET specifies writing that many bytes counting backwards from the end of the string. In the case the SCALAR is empty you can use OFFSET but only zero offset.

OFFSET を指定すると、SCALAR の先頭以外の場所から、 データを取り出して、書き込みを行なうことができます。 OFFSET に負の値を指定すると、文字列の最後から逆向きに数えて 何バイト目から書き込むかを示します。 SCALAR が空の場合、OFFSET はゼロのみ使用できます。

tell FILEHANDLE
tell

Returns the current position for FILEHANDLE, or -1 on error. FILEHANDLE may be an expression whose value gives the name of the actual filehandle. If FILEHANDLE is omitted, assumes the file last read.

FILEHANDLE の現在の位置を返します。エラーの場合は -1 を返します。 FILEHANDLE は、実際のファイルハンドル名を示す式でもかまいません。 FILEHANDLE が省略された場合には、 最後に読み込みを行なったファイルについて調べます。

The return value of tell() for the standard streams like the STDIN depends on the operating system: it may return -1 or something else. tell() on pipes, fifos, and sockets usually returns -1.

STDIN のような標準ストリームに対する tell() の返り値は OS に依存します。 -1 やその他の値が返ってくるかもしれません。 パイプ、FIFO、ソケットに対して tell() を使うと、普通は -1 が返ります。

There is no systell function. Use sysseek(FH, 0, 1) for that.

systell 関数はありません。 代わりに sysseek(FH, 0, 1) を使ってください。

telldir DIRHANDLE

Returns the current position of the readdir routines on DIRHANDLE. Value may be given to seekdir to access a particular location in a directory. Has the same caveats about possible directory compaction as the corresponding system library routine.

DIRHANDLE 上の readdir ルーチンに対する現在位置を返します。 値は、そのディレクトリで特定の位置をアクセスするため、 seekdir に渡すことができます。 同名のシステムライブラリルーチンと同じく、 ディレクトリ縮小時の問題が考えられます。

tie VARIABLE,CLASSNAME,LIST

This function binds a variable to a package class that will provide the implementation for the variable. VARIABLE is the name of the variable to be enchanted. CLASSNAME is the name of a class implementing objects of correct type. Any additional arguments are passed to the new method of the class (meaning TIESCALAR, TIEHANDLE, TIEARRAY, or TIEHASH). Typically these are arguments such as might be passed to the dbm_open() function of C. The object returned by the new method is also returned by the tie function, which would be useful if you want to access other methods in CLASSNAME.

この関数は、変数を、その変数の実装を行なうクラスと結び付けます。 VARIABLE は、魔法をかける変数の名前です。 CLASSNAME は、正しい型のオブジェクトを実装するクラスの名前です。 他に引数があれば、そのクラスの new メソッドに渡されます (つまり TIESCALAR, TIEHANDLE, TIEARRAY, TIEHASH)。 通常、これらは、C の dbm_open などの関数に渡す引数となります。 new メソッドで返されるオブジェクトはまた tie 関数でも返されます。 これは CLASSNAME の他のメソッドにアクセスしたいときに便利です。

Note that functions such as keys and values may return huge lists when used on large objects, like DBM files. You may prefer to use the each function to iterate over such. Example:

DBM ファイルのような大きなオブジェクトでは、keysvalues のような 関数は、大きなリストを返す可能性があります。 そのような場合では、each 関数を使って繰り返しを行なった方が よいかもしれません。 例:

    # print out history file offsets
    use NDBM_File;
    tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
    while (($key,$val) = each %HIST) {
        print $key, ' = ', unpack('L',$val), "\n";
    }
    untie(%HIST);

A class implementing a hash should have the following methods:

ハッシュを実装するクラスでは、次のようなメソッドを用意します:

    TIEHASH classname, LIST
    FETCH this, key
    STORE this, key, value
    DELETE this, key
    CLEAR this
    EXISTS this, key
    FIRSTKEY this
    NEXTKEY this, lastkey
    DESTROY this
    UNTIE this

A class implementing an ordinary array should have the following methods:

通常の配列を実装するクラスでは、次のようなメソッドを用意します:

    TIEARRAY classname, LIST
    FETCH this, key
    STORE this, key, value
    FETCHSIZE this
    STORESIZE this, count
    CLEAR this
    PUSH this, LIST
    POP this
    SHIFT this
    UNSHIFT this, LIST
    SPLICE this, offset, length, LIST
    EXTEND this, count
    DESTROY this
    UNTIE this

A class implementing a file handle should have the following methods:

ファイルハンドルを実装するクラスでは、次のようなメソッドを用意します:

    TIEHANDLE classname, LIST
    READ this, scalar, length, offset
    READLINE this
    GETC this
    WRITE this, scalar, length, offset
    PRINT this, LIST
    PRINTF this, format, LIST
    BINMODE this
    EOF this
    FILENO this
    SEEK this, position, whence
    TELL this
    OPEN this, mode, LIST
    CLOSE this
    DESTROY this
    UNTIE this

A class implementing a scalar should have the following methods:

スカラ変数を実装するクラスでは、次のようなメソッドを用意します:

    TIESCALAR classname, LIST
    FETCH this,
    STORE this, value
    DESTROY this
    UNTIE this

Not all methods indicated above need be implemented. See perltie, Tie::Hash, Tie::Array, Tie::Scalar, and Tie::Handle.

上記の全てのメソッドを実装する必要はありません。 perltie, Tie::Hash, Tie::Array, Tie::Scalar, Tie::Handle を参照して下さい。

Unlike dbmopen, the tie function will not use or require a module for you--you need to do that explicitly yourself. See DB_File or the Config module for interesting tie implementations.

dbmopen と違い、tie 関数はモジュールを use したり require したりしません -- 自分で明示的に行う必要があります。 tie の興味深い実装については DB_FileConfig モジュールを 参照して下さい。

For further details see perltie, "tied VARIABLE".

更なる詳細については perltie"tied VARIABLE" を参照して下さい。

tied VARIABLE

Returns a reference to the object underlying VARIABLE (the same value that was originally returned by the tie call that bound the variable to a package.) Returns the undefined value if VARIABLE isn't tied to a package.

VARIABLE の基となるオブジェクトへのリファレンスを返します (変数をパッケージに結びつけるために tie 呼び出しをしたときの 返り値と同じものです)。 VARIABLE がパッケージと結び付けられていない場合は未定義値を返します。

time

Returns the number of non-leap seconds since whatever time the system considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS, and 00:00:00 UTC, January 1, 1970 for most other systems). Suitable for feeding to gmtime and localtime.

システムが紀元と考える時点 (MacOS では 1904 年 1 月 1 日 00:00:00、 その他のほとんどのシステムでは UTC 1970 年 1 月 1 日 00:00:00) からの 連続秒数を返します。 gmtimelocaltime への入力形式にあっています。

For measuring time in better granularity than one second, you may use either the Time::HiRes module from CPAN, or if you have gettimeofday(2), you may be able to use the syscall interface of Perl, see perlfaq8 for details.

1 秒よりも細かい時間を計測するためには、 CPAN の Time::HiRes モジュールを使うか、 gettimeofday(2) があるなら、Perl の syscall インターフェースを 使った方がよいでしょう。 詳しくは perlfaq8 を参照して下さい。

times

Returns a four-element list giving the user and system times, in seconds, for this process and the children of this process.

現プロセス及びその子プロセスに対する、ユーザ時間とシステム時間を 秒で示した、4 要素のリスト値を返します。

    ($user,$system,$cuser,$csystem) = times;
tr///

The transliteration operator. Same as y///. See perlop.

変換演算子。y///と同じです。 perlop を参照してください。

truncate FILEHANDLE,LENGTH
truncate EXPR,LENGTH

Truncates the file opened on FILEHANDLE, or named by EXPR, to the specified length. Produces a fatal error if truncate isn't implemented on your system. Returns true if successful, the undefined value otherwise.

FILEHANDLE 上にオープンされたファイルか、EXPR で名前を表わしたファイルを、 指定した長さに切り詰めます。 システム上に truncate が実装されていなければ、致命的エラーとなります。 成功すれば真を、さもなければ未定義値を返します。

uc EXPR
uc

Returns an uppercased version of EXPR. This is the internal function implementing the \U escape in double-quoted strings. Respects current LC_CTYPE locale if use locale in force. See perllocale. Under Unicode (use utf8) it uses the standard Unicode uppercase mappings. (It does not attempt to do titlecase mapping on initial letters. See ucfirst for that.)

If EXPR is omitted, uses $_.

EXPR を大文字に変換したものを返します。 これは、ダブルクォート文字列における、\U エスケープを 実装する内部関数です。 use locale が有効な場合は、現在の LC_CTYPE ロケールを参照します。 perllocale を参照してください。 (use utf8 を使った) Unicode では、標準 Unicode 大文字マッピングを 使います。 (元の文字の titlecase マッピングは試みません。 このためには ucfirst を参照してください。)

EXPR が省略されると、$_ を使います。

ucfirst EXPR
ucfirst

Returns the value of EXPR with the first character in uppercase (titlecase in Unicode). This is the internal function implementing the \u escape in double-quoted strings. Respects current LC_CTYPE locale if use locale in force. See perllocale and utf8.

If EXPR is omitted, uses $_.

最初の文字だけを大文字にした、EXPR を返します (Unicode では titlecase)。 これは、ダブルクォート文字列における、\u エスケープを 実装する内部関数です。 use locale が有効な場合は、現在の LC_CTYPE ロケールを参照します。 perllocaleutf8 を参照してください。

EXPR が省略されると、$_ を使います。

umask EXPR
umask

Sets the umask for the process to EXPR and returns the previous value. If EXPR is omitted, merely returns the current umask.

現在のプロセスの umask を EXPR に設定し、以前の値を返します。 EXPR が省略されると、単にその時点の umask の値を返します。

The Unix permission rwxr-x--- is represented as three sets of three bits, or three octal digits: 0750 (the leading 0 indicates octal and isn't one of the digits). The umask value is such a number representing disabled permissions bits. The permission (or "mode") values you pass mkdir or sysopen are modified by your umask, so even if you tell sysopen to create a file with permissions 0777, if your umask is 0022 then the file will actually be created with permissions 0755. If your umask were 0027 (group can't write; others can't read, write, or execute), then passing sysopen 0666 would create a file with mode 0640 (0666 &~ 027 is 0640).

Unix パーミッション rwxr-x--- は 3 ビットの 3 つの組、 または 3 桁の 8 進数として表現されます: 0750 (先頭の 0 は 8 進数を意味し、実際の値ではありません)。 umask の値は無効にするパーミッションビットのこのような数値表現です。 mkdirsysopen で渡されたパーミッション(または「モード」)の値は umask で修正され、たとえ sysopen0777 のパーミッションで ファイルを作るように指定しても、umask が 0022 なら、 結果としてファイルは 0755 のパーミッションで作成されます。 umask0027 (グループは書き込めない; その他は読み込み、書き込み、 実行できない) のとき、sysopen0666 を渡すと、 ファイルはモード 0640 (0666 &~ 0270640)で作成されます。

Here's some advice: supply a creation mode of 0666 for regular files (in sysopen) and one of 0777 for directories (in mkdir) and executable files. This gives users the freedom of choice: if they want protected files, they might choose process umasks of 022, 027, or even the particularly antisocial mask of 077. Programs should rarely if ever make policy decisions better left to the user. The exception to this is when writing files that should be kept private: mail files, web browser cookies, .rhosts files, and so on.

以下は助言です: 作成モードとして、(sysopen による)通常ファイルでは 0666 を、(mkdir による)ディレクトリでは 0777 を指定しましょう。 これにより、ユーザーに選択の自由を与えます: もしファイルを守りたいなら、 プロセスの umask として 022, 027, あるいは特に非社交的な 077 を選択できます。 プログラムがユーザーより適切なポリシー選択ができることは稀です。 例外は、プライベートに保つべきファイル(メール、ウェブブラウザのクッキー、 .rhosts ファイルなど)を書く場合です。

If umask(2) is not implemented on your system and you are trying to restrict access for yourself (i.e., (EXPR & 0700) > 0), produces a fatal error at run time. If umask(2) is not implemented and you are not trying to restrict access for yourself, returns undef.

umask(2) が実装されていないシステムで、自分自身 へのアクセスを 制限しようとした(つまり (EXPR & 0700) > 0)場合、実行時に致命的エラーが 発生します。 umask(2) が実装されていないシステムで、自分自身へのアクセスは 制限しようとしなかった場合、undef を返します。

Remember that a umask is a number, usually given in octal; it is not a string of octal digits. See also "oct", if all you have is a string.

umask は通常 8 進数で与えられる数値であることを忘れないでください。 8 進数の文字列 ではありません。 文字列しかない場合、 "oct" も参照して下さい。

undef EXPR
undef

Undefines the value of EXPR, which must be an lvalue. Use only on a scalar value, an array (using @), a hash (using %), a subroutine (using &), or a typeglob (using <*>). (Saying undef $hash{$key} will probably not do what you expect on most predefined variables or DBM list values, so don't do that; see delete.) Always returns the undefined value. You can omit the EXPR, in which case nothing is undefined, but you still get an undefined value that you could, for instance, return from a subroutine, assign to a variable or pass as a parameter. Examples:

左辺値である EXPR の値を未定義にします。 スカラ値、(@を使った)配列、(%を使った)ハッシュ、(& を使った) サブルーチン、(*を使った)タイプグロブだけに使用します。 (特殊変数や DBM リスト値に undef $hash{$key}などとしても おそらく期待通りの結果にはなりませんから、 しないでください。deleteを参照してください。) 常に未定義値を返します。 EXPR は省略することができ、その場合には何も未定義にされませんが 未定義値は返されますので、それをたとえば、 サブルーチンの返り値、変数への割り当て、引数などとして使うことができます。 例:

    undef $foo;
    undef $bar{'blurfl'};      # Compare to: delete $bar{'blurfl'};
    undef @ary;
    undef %hash;
    undef &mysub;
    undef *xyz;       # destroys $xyz, @xyz, %xyz, &xyz, etc.
    return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
    select undef, undef, undef, 0.25;
    ($a, $b, undef, $c) = &foo;       # Ignore third value returned

Note that this is a unary operator, not a list operator.

これはリスト演算子ではなく、単項演算子であることに注意してください。

unlink LIST
unlink

Deletes a list of files. Returns the number of files successfully deleted.

LIST に含まれるファイルを削除します。 削除に成功したファイルの数を返します。

    $cnt = unlink 'a', 'b', 'c';
    unlink @goners;
    unlink <*.bak>;

Note: unlink will not delete directories unless you are superuser and the -U flag is supplied to Perl. Even if these conditions are met, be warned that unlinking a directory can inflict damage on your filesystem. Use rmdir instead.

If LIST is omitted, uses $_.

注: スーパーユーザ権限で、Perl に -U を付けて実行した 場合でなければ、unlink でディレクトリを削除することはありません。 この条件にあう場合にも、ディレクトリの削除は、 ファイルシステムに多大な損害を与える可能性がありますので、 特に注意が必要です。rmdir を代わりに使ってください。

LIST が省略されると、$_ を使います。

unpack TEMPLATE,EXPR

unpack does the reverse of pack: it takes a string and expands it out into a list of values. (In scalar context, it returns merely the first value produced.)

unpackpack の逆を行ないます: 構造体を表わす文字列をとり、 リスト値に展開し、その配列値を返します。 (スカラコンテキストでは、単に最初の値を返します。)

The string is broken into chunks described by the TEMPLATE. Each chunk is converted separately to a value. Typically, either the string is a result of pack, or the bytes of the string represent a C structure of some kind.

文字列は TEMPLATE で示された固まりに分割されます。 それぞれの固まりは別々に値に変換されます。 典型的には、文字列は pack の結果あるいはある種の C の構造体の 文字列表現のバイト列です。

The TEMPLATE has the same format as in the pack function. Here's a subroutine that does substring:

TEMPLATE は、pack 関数と同じフォーマットを使います。 部分文字列を取り出すうサブルーチンの例を示します:

    sub substr {
        my($what,$where,$howmuch) = @_;
        unpack("x$where a$howmuch", $what);
    }

and then there's

これもそうです。

    sub ordinal { unpack("c",$_[0]); } # same as ord()

In addition to fields allowed in pack(), you may prefix a field with a %<number> to indicate that you want a <number>-bit checksum of the items instead of the items themselves. Default is a 16-bit checksum. Checksum is calculated by summing numeric values of expanded values (for string fields the sum of ord($char) is taken, for bit fields the sum of zeroes and ones).

pack() で利用可能なフィールドの他に、 フィールドの前に %<数値> というものを付けて、 項目自身の代わりに、その項目の <数値>-ビットのチェックサムを 計算させることができます。 デフォルトは、16-ビットチェックサムです。 チェックサムは展開された値の数値としての値の合計 (文字列フィールドの場合は ord($char) の合計、 ビットフィールドの場合は 0 と 1 の合計) が用いられます。

For example, the following computes the same number as the System V sum program:

たとえば、以下のコードは System V の sum プログラムと同じ値を計算します。

    $checksum = do {
        local $/;  # slurp!
        unpack("%32C*",<>) % 65535;
    };

The following efficiently counts the number of set bits in a bit vector:

以下は、効率的にビットベクターの設定されているビットを 数えるものです。

    $setbits = unpack("%32b*", $selectmask);

The p and P formats should be used with care. Since Perl has no way of checking whether the value passed to unpack() corresponds to a valid memory location, passing a pointer value that's not known to be valid is likely to have disastrous consequences.

pP は注意深く使うべきです。 Perl は unpack() に渡された値が有効なメモリ位置を指しているかどうかを 確認する方法がないので、有効かどうかわからないポインタ値を渡すと 悲惨な結果を引き起こすかもしれません。

If the repeat count of a field is larger than what the remainder of the input string allows, repeat count is decreased. If the input string is longer than one described by the TEMPLATE, the rest is ignored.

フィールドの繰り返し回数が入力文字列の残りより大きい場合、繰り返し回数は 減らされます。もし入力文字列が TEMPLATE で表現されているものより 大きい場合、残りは無視されます。

See "pack" for more examples and notes.

さらなる例と注意に関しては "pack" を参照してください。

untie VARIABLE

Breaks the binding between a variable and a package. (See tie.)

変数とパッケージの間の結合を解きます。 (tie を参照してください。)

unshift ARRAY,LIST

Does the opposite of a shift. Or the opposite of a push, depending on how you look at it. Prepends list to the front of the array, and returns the new number of elements in the array.

shift の逆操作を行ないます。 見方を変えれば、pushの逆操作とも考えられます。 LIST を ARRAY の先頭に入れて、新しくできた配列の要素の数を返します。

    unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;

Note the LIST is prepended whole, not one element at a time, so the prepended elements stay in the same order. Use reverse to do the reverse.

LIST は、はらばらにではなく、一度に登録されるので、順番はそのままです。 逆順に登録するには、reverse を使ってください。

use Module VERSION LIST
use Module VERSION
use Module LIST
use Module
use VERSION

Imports some semantics into the current package from the named module, generally by aliasing certain subroutine or variable names into your package. It is exactly equivalent to

    BEGIN { require Module; import Module LIST; }

except that Module must be a bareword.

指定したモジュールから、現在のパッケージにさまざまな内容を インポートします。 多くは、パッケージのサブルーチン名や、変数名に別名を付けることで、 実現されています。これは、 Module が 単なる単語でなければならない ことを除けば、

    BEGIN { require Module; import Module LIST; }

と等価です。

VERSION, which can be specified as a literal of the form v5.6.1, demands that the current version of Perl ($^V or $PERL_VERSION) be at least as recent as that version. (For compatibility with older versions of Perl, a numeric literal will also be interpreted as VERSION.) If the version of the running Perl interpreter is less than VERSION, then an error message is printed and Perl exits immediately without attempting to parse the rest of the file. Compare with "require", which can do a similar check at run time.

VERSION (v5.6.1 の形のリテラルとしても指定できます)を指定すると、 現在の Perl のバージョン ($^V or $PERL_VERSION) が少なくとも 指定されたものよりも最近であることを要求します。 (古いバージョンの Perl との互換性のために、数値リテラルも VERSIONとして解釈されます。) もし動作している Perl インタプリタのバージョンが VERSION より低い場合、 エラーメッセージが表示され、Perl はファイルの残りをパースせずに 直ちに終了します。 似たようなチェックを実行時に行える "require" と比較してください。

    use v5.6.1;         # compile time version check
    use 5.6.1;          # ditto
    use 5.005_03;       # float version allowed for compatibility

This is often useful if you need to check the current Perl version before useing library modules that have changed in incompatible ways from older versions of Perl. (We try not to do this more than we have to.)

これは古いバージョンの Perl から互換性のない形で変更されたライブラリ モジュール(我々は必要な場合以外にそのようなことがないように 努力していますが)を use する前に、現在の Perl のバージョンを 調べたい場合に有用です。

The BEGIN forces the require and import to happen at compile time. The require makes sure the module is loaded into memory if it hasn't been yet. The import is not a builtin--it's just an ordinary static method call into the Module package to tell the module to import the list of features back into the current package. The module can implement its import method any way it likes, though most modules just choose to derive their import method via inheritance from the Exporter class that is defined in the Exporter module. See Exporter. If no import method can be found then the call is skipped.

BEGIN によって、requireimport は、コンパイル時に 実行されることになります。 require は、モジュールがまだメモリにロードされていなければ、ロードします。 import は、組込みの関数ではなく、さまざまな機能を現在のパッケージに インポートするように Module パッケージに伝えるために呼ばれる、 通常の静的メソッドです。 モジュール側では、import メソッドをどのようにでも実装することが できますが、多くのモジュールでは、Exporter モジュールで定義された、 Exporter クラスからの継承によって、import メソッドを行なうように しています。 Exporterモジュールを参照してください。 importメソッドが見つからなかった場合、呼び出しはスキップされます。

If you do not want to call the package's import method (for instance, to stop your namespace from being altered), explicitly supply the empty list:

パッケージの import メソッドを呼び出したくない場合(例えば、名前空間を 変更したくない場合など)は、明示的に空リストを指定してください:

    use Module ();

That is exactly equivalent to

これは以下と完全に等価です:

    BEGIN { require Module }

If the VERSION argument is present between Module and LIST, then the use will call the VERSION method in class Module with the given version as an argument. The default VERSION method, inherited from the UNIVERSAL class, croaks if the given version is larger than the value of the variable $Module::VERSION.

Module と LIST の間に VERSION 引数がある場合、use は Module クラスの VERSION メソッドを、与えられたバージョンを引数として呼び出します。 デフォルトの VERSION メソッドは、 UNIVERSAL クラスから継承したもので、 与えられたバージョンが 変数 $Module::VERSION の値より大きい場合に 警告を出します。

Again, there is a distinction between omitting LIST (import called with no arguments) and an explicit empty LIST () (import not called). Note that there is no comma after VERSION!

繰り返すと、LIST を省略する(import が引数なしで呼び出される)ことと 明示的に空の LIST () を指定する (import は呼び出されない)ことは 違います。 VERSION の後ろにカンマが不要なことに注意してください!

Because this is a wide-open interface, pragmas (compiler directives) are also implemented this way. Currently implemented pragmas are:

これは、広く公開されているインタフェースですので、 プラグマ (コンパイラディレクティブ) も、この方法で実装されています。 現在実装されているプラグマには、以下のものがあります:

    use constant;
    use diagnostics;
    use integer;
    use sigtrap  qw(SEGV BUS);
    use strict   qw(subs vars refs);
    use subs     qw(afunc blurfl);
    use warnings qw(all);

Some of these pseudo-modules import semantics into the current block scope (like strict or integer, unlike ordinary modules, which import symbols into the current package (which are effective through the end of the file).

通常のモジュールが、現在のパッケージにシンボルをインポートする (これは、ファイルの終わりまで有効です) のに対して、 これらの擬似モジュールの一部(strictinteger など)は、 現在のブロックスコープにインポートを行ないます。

There's a corresponding no command that unimports meanings imported by use, i.e., it calls unimport Module LIST instead of import.

これに対して、no コマンドという、use によってインポートされたものを、 インポートされていないことにするものがあります。 つまり、import の代わりに unimport Module LIST を呼び出します。

    no integer;
    no strict 'refs';
    no warnings;

If no unimport method can be found the call fails with a fatal error.

unimport メソッドが見つからなかった場合、呼び出しは致命的エラーで 失敗します。

See perlmodlib for a list of standard modules and pragmas. See perlrun for the -M and -m command-line options to perl that give use functionality from the command-line.

標準モジュールやプラグマの一覧は、perlmodlib を参照してください。 コマンドラインから use 機能を指定するための -M-m の コマンドラインオプションについては perlrun を参照して下さい。

utime LIST

Changes the access and modification times on each file of a list of files. The first two elements of the list must be the NUMERICAL access and modification times, in that order. Returns the number of files successfully changed. The inode change time of each file is set to the current time. This code has the same effect as the touch command if the files already exist:

ファイルのアクセス時刻と修正(modification) 時刻を変更します。 LIST の最初の 2 つの要素に、数値で表わしたアクセス時刻と修正時刻を 順に指定します。 LIST の残りの要素が、変更の対象となるファイルです。 変更に成功したファイルの数を返します。 各ファイルの inode 変更(change)時刻には、その時点の時刻が設定されます。 touch コマンドの例です:

    #!/usr/bin/perl
    $now = time;
    utime $now, $now, @ARGV;
values HASH

Returns a list consisting of all the values of the named hash. (In a scalar context, returns the number of values.) The values are returned in an apparently random order. The actual random order is subject to change in future versions of perl, but it is guaranteed to be the same order as either the keys or each function would produce on the same (unmodified) hash.

指定したハッシュのすべての value からなるリストを返します。 (スカラコンテキストでは、value の数を返します。) 返される value の順序は、見た目にばらばらなものです。 実際のランダムな順序は将来のバージョンの perl では変わる可能性が ありますが、同じ(変更されていない)ハッシュに対して、 keys関数や each関数が返すものと同じ順序であることは保証されます。

Note that the values are not copied, which means modifying them will modify the contents of the hash:

値はコピーされないので、返されたリストを変更すると ハッシュの中身が変更されることに注意してください。

    for (values %hash)      { s/foo/bar/g }   # modifies %hash values
    for (@hash{keys %hash}) { s/foo/bar/g }   # same

As a side effect, calling values() resets the HASH's internal iterator. See also keys, each, and sort.

副作用として、values() を呼び出すと HASH の内部イテレータをリセットします。 keys, each, sort も参照してください。

vec EXPR,OFFSET,BITS

Treats the string in EXPR as a bit vector made up of elements of width BITS, and returns the value of the element specified by OFFSET as an unsigned integer. BITS therefore specifies the number of bits that are reserved for each element in the bit vector. This must be a power of two from 1 to 32 (or 64, if your platform supports that).

文字列 EXPR を BITS 幅の要素からなるビットベクターとして扱い、 OFFSET で指定される要素の値を返します。 OFFSET で指定された要素を符号なし整数として返します。 従って、 BITS はビットベクターの中の各要素について予約されるビット数です。 BIT は、1 から 32 まで(プラットホームが 対応していれば 64 まで) の 2 のべき乗でなければなりません。

If BITS is 8, "elements" coincide with bytes of the input string.

BITS が 8 の場合、「要素」は入力文字列の各バイトと一致します。

If BITS is 16 or more, bytes of the input string are grouped into chunks of size BITS/8, and each group is converted to a number as with pack()/unpack() with big-endian formats n/N (and analogously for BITS==64). See "pack" for details.

BITS が 16 以上の場合、入力のバイト列は BITS/8 のサイズの固まりに グループ化され、各グループは pack()/unpack() のビッグエンディアン フォーマット n/N を用いて(BITS==64 の類似として)数値に変換されます。 詳細は "pack" を参照してください。

If bits is 4 or less, the string is broken into bytes, then the bits of each byte are broken into 8/BITS groups. Bits of a byte are numbered in a little-endian-ish way, as in 0x01, 0x02, 0x04, 0x08, 0x10, 0x20, 0x40, 0x80. For example, breaking the single input byte chr(0x36) into two groups gives a list (0x6, 0x3); breaking it into 4 groups gives (0x2, 0x1, 0x3, 0x0).

BITS が 4 以下の場合、文字列はバイトに分解され、バイトの各ビットは 8/BITS 個のグループに分割されます。 ビットはリトルエンディアン風に、0x01, 0x02, 0x04, 0x08, 0x10, 0x20, 0x40, 0x80 の順になります。 例えば、入力バイト chr(0x36) を 2 つのグループに分割すると、 (0x6, 0x3) になります。 4 つに分割すると (0x2, 0x1, 0x3, 0x0) になります。

vec may also be assigned to, in which case parentheses are needed to give the expression the correct precedence as in

左辺値として、代入の対象にすることもできます。 この場合、式を正しく先行させるために以下のように括弧が必要です。

    vec($image, $max_x * $x + $y, 8) = 3;

If the selected element is outside the string, the value 0 is returned. If an element off the end of the string is written to, Perl will first extend the string with sufficiently many zero bytes. It is an error to try to write off the beginning of the string (i.e. negative OFFSET).

選択された要素が文字列の外側だった場合、値 0 が返されます。 文字列の最後よりも後ろの要素に書き込もうとした場合、 Perl はまず文字列を必要な分だけ 0 のバイトで拡張します。 文字列の先頭より前に書き込もうとした(つまり OFFSET が負の数だった) 場合はエラーとなります。

The string should not contain any character with the value > 255 (which can only happen if you're using UTF8 encoding). If it does, it will be treated as something which is not UTF8 encoded. When the vec was assigned to, other parts of your program will also no longer consider the string to be UTF8 encoded. In other words, if you do have such characters in your string, vec() will operate on the actual byte string, and not the conceptual character string.

文字列は値が 255 を越える文字を含むべきではありません (これは UTF8 エンコーディングを使っているときにだけ起こりえます)。 もし含んでいると、UTF8 エンコードされていないものとして扱われます。 vec が割り当てられたとき、プログラムのその他の部分では もはやこの文字列が UTF8 エンコードされたと扱われなくなります。 言い換えると、もしこのような文字を文字列に含んでいると、 vec() は実際のバイト文字列として扱い、概念的な文字の文字列としては 扱いません。

Strings created with vec can also be manipulated with the logical operators |, &, ^, and ~. These operators will assume a bit vector operation is desired when both operands are strings. See "Bitwise String Operators" in perlop.

vec() で作られた文字列は、論理演算子 |&^ で扱うこともできます。 これらの演算子は、両方の被演算子に文字列を使うと、 ビットベクター演算を行ないます。

The following code will build up an ASCII string saying 'PerlPerlPerl'. The comments show the string after each step. Note that this code works in the same way on big-endian or little-endian machines.

次のコードは 'PerlPerlPerl' という ASCII 文字列を作成します。 コメントは各行の実行後の文字列を示します。 このコードはビッグエンディアンでもリトルエンディアンでも同じように 動作することに注意してください。

    my $foo = '';
    vec($foo,  0, 32) = 0x5065726C;     # 'Perl'

    # $foo eq "Perl" eq "\x50\x65\x72\x6C", 32 bits
    print vec($foo, 0, 8);              # prints 80 == 0x50 == ord('P')

    vec($foo,  2, 16) = 0x5065;         # 'PerlPe'
    vec($foo,  3, 16) = 0x726C;         # 'PerlPerl'
    vec($foo,  8,  8) = 0x50;           # 'PerlPerlP'
    vec($foo,  9,  8) = 0x65;           # 'PerlPerlPe'
    vec($foo, 20,  4) = 2;              # 'PerlPerlPe'   . "\x02"
    vec($foo, 21,  4) = 7;              # 'PerlPerlPer'
                                        # 'r' is "\x72"
    vec($foo, 45,  2) = 3;              # 'PerlPerlPer'  . "\x0c"
    vec($foo, 93,  1) = 1;              # 'PerlPerlPer'  . "\x2c"
    vec($foo, 94,  1) = 1;              # 'PerlPerlPerl'
                                        # 'l' is "\x6c"

To transform a bit vector into a string or list of 0's and 1's, use these:

ビットベクターを、0 と 1 の文字列や配列に変換するには、 以下のようにします。

    $bits = unpack("b*", $vector);
    @bits = split(//, unpack("b*", $vector));

If you know the exact length in bits, it can be used in place of the *.

ビット長が分かっていれば、* の代わりにその長さを使うことができます。

Here is an example to illustrate how the bits actually fall in place:

これはビットが実際にどのような位置に入るかを図示する例です。

    #!/usr/bin/perl -wl

    print <<'EOT';
                                      0         1         2         3  
                       unpack("V",$_) 01234567890123456789012345678901
    ------------------------------------------------------------------
    EOT

    for $w (0..3) {
        $width = 2**$w;
        for ($shift=0; $shift < $width; ++$shift) {
            for ($off=0; $off < 32/$width; ++$off) {
                $str = pack("B*", "0"x32);
                $bits = (1<<$shift);
                vec($str, $off, $width) = $bits;
                $res = unpack("b*",$str);
                $val = unpack("V", $str);
                write;
            }
        }
    }

    format STDOUT =
    vec($_,@#,@#) = @<< == @######### @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    $off, $width, $bits, $val, $res
    .
    __END__

Regardless of the machine architecture on which it is run, the above example should print the following table:

実行するマシンのアーキテクチャに関わらず、 上記の例は以下の表を出力します。

                                      0         1         2         3  
                       unpack("V",$_) 01234567890123456789012345678901
    ------------------------------------------------------------------
    vec($_, 0, 1) = 1   ==          1 10000000000000000000000000000000
    vec($_, 1, 1) = 1   ==          2 01000000000000000000000000000000
    vec($_, 2, 1) = 1   ==          4 00100000000000000000000000000000
    vec($_, 3, 1) = 1   ==          8 00010000000000000000000000000000
    vec($_, 4, 1) = 1   ==         16 00001000000000000000000000000000
    vec($_, 5, 1) = 1   ==         32 00000100000000000000000000000000
    vec($_, 6, 1) = 1   ==         64 00000010000000000000000000000000
    vec($_, 7, 1) = 1   ==        128 00000001000000000000000000000000
    vec($_, 8, 1) = 1   ==        256 00000000100000000000000000000000
    vec($_, 9, 1) = 1   ==        512 00000000010000000000000000000000
    vec($_,10, 1) = 1   ==       1024 00000000001000000000000000000000
    vec($_,11, 1) = 1   ==       2048 00000000000100000000000000000000
    vec($_,12, 1) = 1   ==       4096 00000000000010000000000000000000
    vec($_,13, 1) = 1   ==       8192 00000000000001000000000000000000
    vec($_,14, 1) = 1   ==      16384 00000000000000100000000000000000
    vec($_,15, 1) = 1   ==      32768 00000000000000010000000000000000
    vec($_,16, 1) = 1   ==      65536 00000000000000001000000000000000
    vec($_,17, 1) = 1   ==     131072 00000000000000000100000000000000
    vec($_,18, 1) = 1   ==     262144 00000000000000000010000000000000
    vec($_,19, 1) = 1   ==     524288 00000000000000000001000000000000
    vec($_,20, 1) = 1   ==    1048576 00000000000000000000100000000000
    vec($_,21, 1) = 1   ==    2097152 00000000000000000000010000000000
    vec($_,22, 1) = 1   ==    4194304 00000000000000000000001000000000
    vec($_,23, 1) = 1   ==    8388608 00000000000000000000000100000000
    vec($_,24, 1) = 1   ==   16777216 00000000000000000000000010000000
    vec($_,25, 1) = 1   ==   33554432 00000000000000000000000001000000
    vec($_,26, 1) = 1   ==   67108864 00000000000000000000000000100000
    vec($_,27, 1) = 1   ==  134217728 00000000000000000000000000010000
    vec($_,28, 1) = 1   ==  268435456 00000000000000000000000000001000
    vec($_,29, 1) = 1   ==  536870912 00000000000000000000000000000100
    vec($_,30, 1) = 1   == 1073741824 00000000000000000000000000000010
    vec($_,31, 1) = 1   == 2147483648 00000000000000000000000000000001
    vec($_, 0, 2) = 1   ==          1 10000000000000000000000000000000
    vec($_, 1, 2) = 1   ==          4 00100000000000000000000000000000
    vec($_, 2, 2) = 1   ==         16 00001000000000000000000000000000
    vec($_, 3, 2) = 1   ==         64 00000010000000000000000000000000
    vec($_, 4, 2) = 1   ==        256 00000000100000000000000000000000
    vec($_, 5, 2) = 1   ==       1024 00000000001000000000000000000000
    vec($_, 6, 2) = 1   ==       4096 00000000000010000000000000000000
    vec($_, 7, 2) = 1   ==      16384 00000000000000100000000000000000
    vec($_, 8, 2) = 1   ==      65536 00000000000000001000000000000000
    vec($_, 9, 2) = 1   ==     262144 00000000000000000010000000000000
    vec($_,10, 2) = 1   ==    1048576 00000000000000000000100000000000
    vec($_,11, 2) = 1   ==    4194304 00000000000000000000001000000000
    vec($_,12, 2) = 1   ==   16777216 00000000000000000000000010000000
    vec($_,13, 2) = 1   ==   67108864 00000000000000000000000000100000
    vec($_,14, 2) = 1   ==  268435456 00000000000000000000000000001000
    vec($_,15, 2) = 1   == 1073741824 00000000000000000000000000000010
    vec($_, 0, 2) = 2   ==          2 01000000000000000000000000000000
    vec($_, 1, 2) = 2   ==          8 00010000000000000000000000000000
    vec($_, 2, 2) = 2   ==         32 00000100000000000000000000000000
    vec($_, 3, 2) = 2   ==        128 00000001000000000000000000000000
    vec($_, 4, 2) = 2   ==        512 00000000010000000000000000000000
    vec($_, 5, 2) = 2   ==       2048 00000000000100000000000000000000
    vec($_, 6, 2) = 2   ==       8192 00000000000001000000000000000000
    vec($_, 7, 2) = 2   ==      32768 00000000000000010000000000000000
    vec($_, 8, 2) = 2   ==     131072 00000000000000000100000000000000
    vec($_, 9, 2) = 2   ==     524288 00000000000000000001000000000000
    vec($_,10, 2) = 2   ==    2097152 00000000000000000000010000000000
    vec($_,11, 2) = 2   ==    8388608 00000000000000000000000100000000
    vec($_,12, 2) = 2   ==   33554432 00000000000000000000000001000000
    vec($_,13, 2) = 2   ==  134217728 00000000000000000000000000010000
    vec($_,14, 2) = 2   ==  536870912 00000000000000000000000000000100
    vec($_,15, 2) = 2   == 2147483648 00000000000000000000000000000001
    vec($_, 0, 4) = 1   ==          1 10000000000000000000000000000000
    vec($_, 1, 4) = 1   ==         16 00001000000000000000000000000000
    vec($_, 2, 4) = 1   ==        256 00000000100000000000000000000000
    vec($_, 3, 4) = 1   ==       4096 00000000000010000000000000000000
    vec($_, 4, 4) = 1   ==      65536 00000000000000001000000000000000
    vec($_, 5, 4) = 1   ==    1048576 00000000000000000000100000000000
    vec($_, 6, 4) = 1   ==   16777216 00000000000000000000000010000000
    vec($_, 7, 4) = 1   ==  268435456 00000000000000000000000000001000
    vec($_, 0, 4) = 2   ==          2 01000000000000000000000000000000
    vec($_, 1, 4) = 2   ==         32 00000100000000000000000000000000
    vec($_, 2, 4) = 2   ==        512 00000000010000000000000000000000
    vec($_, 3, 4) = 2   ==       8192 00000000000001000000000000000000
    vec($_, 4, 4) = 2   ==     131072 00000000000000000100000000000000
    vec($_, 5, 4) = 2   ==    2097152 00000000000000000000010000000000
    vec($_, 6, 4) = 2   ==   33554432 00000000000000000000000001000000
    vec($_, 7, 4) = 2   ==  536870912 00000000000000000000000000000100
    vec($_, 0, 4) = 4   ==          4 00100000000000000000000000000000
    vec($_, 1, 4) = 4   ==         64 00000010000000000000000000000000
    vec($_, 2, 4) = 4   ==       1024 00000000001000000000000000000000
    vec($_, 3, 4) = 4   ==      16384 00000000000000100000000000000000
    vec($_, 4, 4) = 4   ==     262144 00000000000000000010000000000000
    vec($_, 5, 4) = 4   ==    4194304 00000000000000000000001000000000
    vec($_, 6, 4) = 4   ==   67108864 00000000000000000000000000100000
    vec($_, 7, 4) = 4   == 1073741824 00000000000000000000000000000010
    vec($_, 0, 4) = 8   ==          8 00010000000000000000000000000000
    vec($_, 1, 4) = 8   ==        128 00000001000000000000000000000000
    vec($_, 2, 4) = 8   ==       2048 00000000000100000000000000000000
    vec($_, 3, 4) = 8   ==      32768 00000000000000010000000000000000
    vec($_, 4, 4) = 8   ==     524288 00000000000000000001000000000000
    vec($_, 5, 4) = 8   ==    8388608 00000000000000000000000100000000
    vec($_, 6, 4) = 8   ==  134217728 00000000000000000000000000010000
    vec($_, 7, 4) = 8   == 2147483648 00000000000000000000000000000001
    vec($_, 0, 8) = 1   ==          1 10000000000000000000000000000000
    vec($_, 1, 8) = 1   ==        256 00000000100000000000000000000000
    vec($_, 2, 8) = 1   ==      65536 00000000000000001000000000000000
    vec($_, 3, 8) = 1   ==   16777216 00000000000000000000000010000000
    vec($_, 0, 8) = 2   ==          2 01000000000000000000000000000000
    vec($_, 1, 8) = 2   ==        512 00000000010000000000000000000000
    vec($_, 2, 8) = 2   ==     131072 00000000000000000100000000000000
    vec($_, 3, 8) = 2   ==   33554432 00000000000000000000000001000000
    vec($_, 0, 8) = 4   ==          4 00100000000000000000000000000000
    vec($_, 1, 8) = 4   ==       1024 00000000001000000000000000000000
    vec($_, 2, 8) = 4   ==     262144 00000000000000000010000000000000
    vec($_, 3, 8) = 4   ==   67108864 00000000000000000000000000100000
    vec($_, 0, 8) = 8   ==          8 00010000000000000000000000000000
    vec($_, 1, 8) = 8   ==       2048 00000000000100000000000000000000
    vec($_, 2, 8) = 8   ==     524288 00000000000000000001000000000000
    vec($_, 3, 8) = 8   ==  134217728 00000000000000000000000000010000
    vec($_, 0, 8) = 16  ==         16 00001000000000000000000000000000
    vec($_, 1, 8) = 16  ==       4096 00000000000010000000000000000000
    vec($_, 2, 8) = 16  ==    1048576 00000000000000000000100000000000
    vec($_, 3, 8) = 16  ==  268435456 00000000000000000000000000001000
    vec($_, 0, 8) = 32  ==         32 00000100000000000000000000000000
    vec($_, 1, 8) = 32  ==       8192 00000000000001000000000000000000
    vec($_, 2, 8) = 32  ==    2097152 00000000000000000000010000000000
    vec($_, 3, 8) = 32  ==  536870912 00000000000000000000000000000100
    vec($_, 0, 8) = 64  ==         64 00000010000000000000000000000000
    vec($_, 1, 8) = 64  ==      16384 00000000000000100000000000000000
    vec($_, 2, 8) = 64  ==    4194304 00000000000000000000001000000000
    vec($_, 3, 8) = 64  == 1073741824 00000000000000000000000000000010
    vec($_, 0, 8) = 128 ==        128 00000001000000000000000000000000
    vec($_, 1, 8) = 128 ==      32768 00000000000000010000000000000000
    vec($_, 2, 8) = 128 ==    8388608 00000000000000000000000100000000
    vec($_, 3, 8) = 128 == 2147483648 00000000000000000000000000000001
wait

Behaves like the wait(2) system call on your system: it waits for a child process to terminate and returns the pid of the deceased process, or -1 if there are no child processes. The status is returned in $?. Note that a return value of -1 could mean that child processes are being automatically reaped, as described in perlipc.

wait(2) システムコールと同様に振る舞います。 チャイルドプロセスが終了するのを待ち、消滅したプロセスの pid を返します。 チャイルドプロセスが存在しないときには、-1 を返します。 ステータスは $? に返されます。 perlipc に書いているように、返り値が -1 の場合は子プロセスが 自動的に刈り取られたことを意味するかもしれないことに注意してください。

waitpid PID,FLAGS

Waits for a particular child process to terminate and returns the pid of the deceased process, or -1 if there is no such child process. On some systems, a value of 0 indicates that there are processes still running. The status is returned in $?. If you say

特定のチャイルドプロセスが終了するのを待ち、消滅した プロセスの pid を返します。 指定したチャイルドプロセスが存在しないときには、-1 を返します。 値 0 がプロセスがまだ実行中であることを示すシステムもあります。 ステータスは $? に返されます。

    use POSIX ":sys_wait_h";
    #...
    do { 
        $kid = waitpid(-1,WNOHANG);
    } until $kid == -1;

then you can do a non-blocking wait for all pending zombie processes. Non-blocking wait is available on machines supporting either the waitpid(2) or wait4(2) system calls. However, waiting for a particular pid with FLAGS of 0 is implemented everywhere. (Perl emulates the system call by remembering the status values of processes that have exited but have not been harvested by the Perl script yet.)

とすると、ブロックが起こらないようにして、全ての待機中ゾンビプロセスを wait します。 ブロックなしの wait は、システムコール wait_pid(2) か、 システムコール wait4(2) をサポートしているマシンで利用可能です。 しかしながら、特定の pid を 0 の FLAGS での wait はどこでも 実装されています。 (exit したプロセスのステータス値を覚えておいて、Perl がシステムコールを エミュレートしますが、Perl スクリプトには取り入れられていません。)

Note that on some systems, a return value of -1 could mean that child processes are being automatically reaped. See perlipc for details, and for other examples.

システムによっては、返り値が -1 の場合は子プロセスが自動的に 刈り取られたことを意味するかもしれないことに注意してください。 詳細やその他の例については perlipc を参照してください。

wantarray

Returns true if the context of the currently executing subroutine is looking for a list value. Returns false if the context is looking for a scalar. Returns the undefined value if the context is looking for no value (void context).

現在実行中のサブルーチンのコンテキストが、リスト値を 要求するものであれば、真を返します。 スカラを要求するコンテキストであれば、偽を返します。 何も値を要求しない(無効コンテキスト)場合は未定義値を返します。

    return unless defined wantarray;    # don't bother doing more
    my @a = complex_calculation();
    return wantarray ? @a : "@a";

This function should have been named wantlist() instead.

この関数は wantlist() という名前にするべきでした。

warn LIST

Produces a message on STDERR just like die, but doesn't exit or throw an exception.

die と同じように STDERR にメッセージを出力しますが、 exit したり、例外を発生させたりしません。

If LIST is empty and $@ already contains a value (typically from a previous eval) that value is used after appending "\t...caught" to $@. This is useful for staying almost, but not entirely similar to die.

LIST が空かつ、(典型的には以前の eval によって) $@ に既に値が入っている 場合、$@"\t...caught" を追加した値が用いられます。 これはほとんどそのままにするときに便利ですが、 die と全体的に似ているわけではありません。

If $@ is empty then the string "Warning: Something's wrong" is used.

$@ が空の場合は、"Warning: Something's wrong" という文字列が 使われます。

No message is printed if there is a $SIG{__WARN__} handler installed. It is the handler's responsibility to deal with the message as it sees fit (like, for instance, converting it into a die). Most handlers must therefore make arrangements to actually display the warnings that they are not prepared to deal with, by calling warn again in the handler. Note that this is quite safe and will not produce an endless loop, since __WARN__ hooks are not called from inside one.

$SIG{__WARN__} ハンドラが設定されている場合は何のメッセージも 表示されません。 メッセージをどう扱うか(例えば die に変換するか)はハンドラの 責任ということです。 従ってほとんどのハンドラは、扱おうと準備していない警告を表示するために、 ハンドラの中で warn を再び呼び出します。 __WARN__ フックはハンドラ内では呼び出されないので、これは十分安全で、 無限ループを引き起こすことはないということに注意してください。

You will find this behavior is slightly different from that of $SIG{__DIE__} handlers (which don't suppress the error text, but can instead call die again to change it).

この振る舞いは $SIG{__DIE__} ハンドラ(エラーテキストは削除しませんが、 代わりに die をもう一度呼び出すことで変更できます)とは 少し違うことに気付くことでしょう。

Using a __WARN__ handler provides a powerful way to silence all warnings (even the so-called mandatory ones). An example:

__WARN__ ハンドラを使うと、(いわゆる必須のものを含む)全ての 警告を黙らせる強力な手段となります。 例:

    # wipe out *all* compile-time warnings
    BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
    my $foo = 10;
    my $foo = 20;          # no warning about duplicate my $foo,
                           # but hey, you asked for it!
    # no compile-time or run-time warnings before here
    $DOWARN = 1;

    # run-time warnings enabled after here
    warn "\$foo is alive and $foo!";     # does show up

See perlvar for details on setting %SIG entries, and for more examples. See the Carp module for other kinds of warnings using its carp() and cluck() functions.

%SIG エントリのセットに関する詳細とさらなる例に関しては perlvar を参照して下さい。 carp() 関数と cluck() 関数を用いた警告の方法に関しては Carp モジュールを参照して下さい。

write FILEHANDLE
write EXPR
write

Writes a formatted record (possibly multi-line) to the specified FILEHANDLE, using the format associated with that file. By default the format for a file is the one having the same name as the filehandle, but the format for the current output channel (see the select function) may be set explicitly by assigning the name of the format to the $~ variable.

指定された FILEHANDLE に対して、そのファイルに対応させた フォーマットを使って、(複数行の場合もある) 整形された レコードを書き出します。 デフォルトでは、ファイルに対応するフォーマットは、ファイルハンドルと 同じ名前のものですが、その時点の出力チャネル (select 関数の項を 参照してください) のフォーマットは、その名前を明示的に変数 $~ に 代入することで、変更が可能です。

Top of form processing is handled automatically: if there is insufficient room on the current page for the formatted record, the page is advanced by writing a form feed, a special top-of-page format is used to format the new page header, and then the record is written. By default the top-of-page format is the name of the filehandle with "_TOP" appended, but it may be dynamically set to the format of your choice by assigning the name to the $^ variable while the filehandle is selected. The number of lines remaining on the current page is in variable $-, which can be set to 0 to force a new page.

ページの先頭の処理は、自動的に行なわれます。 現在のページに整形されたレコードを出力するだけのスペースがない場合には、 改ページを行なってページを進め、新しいページヘッダを整形するため、 ページ先頭フォーマットが使われ、その後でレコードが書かれます。 デフォルトでは、ページ先頭フォーマットは、ファイルハンドルの名前に "_TOP" をつなげたものですが、ファイルハンドルが選択されている間に、 変数 $^ に名前を設定すれば、動的にフォーマットを 変更することができます。 そのページの残り行数は、変数 $- に入っており、この変数を 0 に 設定することで、強制的に改ページを行なうことができます。

If FILEHANDLE is unspecified, output goes to the current default output channel, which starts out as STDOUT but may be changed by the select operator. If the FILEHANDLE is an EXPR, then the expression is evaluated and the resulting string is used to look up the name of the FILEHANDLE at run time. For more on formats, see perlform.

FILEHANDLE を指定しないと、出力はその時点のデフォルト 出力チャネルに対して行なわれます。 これは、スクリプトの開始時点では STDOUT ですが、select() 演算子で 変更することができます。 FILEHANDLE が EXPR ならば、式が評価され、その結果の文字列が 実行時に FILEHANDLE の名前として見られます。 フォーマットについて、さらには、perlform を参照してください。

Note that write is not the opposite of read. Unfortunately.

残念ながら、write は read の反対のことをするもの ではありません

y///

The transliteration operator. Same as tr///. See perlop.

文字変換演算子です。tr///と同じです。perlopを参照して ください。